Bien que le comptage des mots et des caractères dans Google Sheets soit utilisé dans de rares cas, il s'agit toujours d'une fonctionnalité que certains d'entre nous s'attendent à voir directement dans le menu. Mais contrairement à Google Docs, pour Google Sheets, c'est la fonction LEN qui s'en charge.

Même s'il existe de nombreuses façons de compter les caractères dans les feuilles de calcul, l'article d'aujourd'hui portera sur la fonction LEN, car sa principale fonction dans les tableaux est de compter :) Cependant, elle est rarement utilisée seule. Vous apprendrez ci-dessous à utiliser correctement la fonction LEN de Google Sheets et trouverez les formules les plus utilisées pour calculer les caractères dans les feuilles de calcul.

Fonction LEN de Google Sheets - utilisation et syntaxe

Le principal et unique objectif de la fonction LEN dans Google Sheets est d'obtenir la longueur d'une chaîne de caractères, ce qui est si simple qu'elle ne requiert qu'un seul argument :

• il peut prendre soit le texte lui-même entre guillemets :

  =LEN("Yggdrasil")

• ou une référence à une cellule contenant le texte en question :

  =LEN(A2)

Voyons s'il existe des particularités dans l'utilisation de la fonction dans les feuilles de calcul.

Nombre de caractères dans Google Sheets

Je commencerai par l'opération la plus simple : faire un comptage de caractères dans Google Sheets de la manière la plus courante - en référençant une cellule avec le texte à l'aide de la fonction LEN.

J'entre la formule en B2 et je la copie dans toute la colonne pour compter les caractères dans chaque ligne :

=LEN(A2)

Remarque : la fonction LEN calcule tous les caractères : lettres, chiffres, espaces, signes de ponctuation, etc.

Vous pouvez penser que, de la même manière, vous pourriez compter les caractères de toute une série de cellules, comme ceci : LEN(A2:A6) Mais, aussi bizarre que cela puisse paraître, ça ne fonctionne pas simplement comme ça.

Pour faire le total des caractères dans plusieurs cellules, vous devez envelopper votre LEN dans SUMPRODUCT - la fonction qui additionne les nombres des plages saisies :

=SUMPRODUIT(LEN(A2:A6))

Bien sûr, vous pourriez utiliser la fonction SUM à la place. Mais la fonction SUM de Google Sheets ne traite pas les tableaux provenant d'autres fonctions. Pour que cela fonctionne, vous devrez ajouter une autre fonction - ArrayFormula :

=ArrayFormula(SUM(LEN(A2:A6)))

Comment compter les caractères sans espaces dans Google Sheets

Comme je l'ai indiqué plus haut, la fonction LEN de Google Sheets compte tous les caractères qu'elle voit, y compris les espaces.

Mais que faire si des espaces supplémentaires ont été ajoutés par erreur et que vous ne voulez pas en tenir compte dans le résultat ?

Pour ce genre de cas, il existe la fonction TRIM dans Google Sheets. Elle vérifie que le texte ne comporte pas d'espaces avant, arrière ou répétés. Lorsque TRIM est associée à LEN, cette dernière ne tient pas compte de tous ces espaces bizarres.

Voici un exemple : j'ai ajouté des espaces à différentes positions dans la colonne A. Comme vous pouvez le constater, lorsqu'il est seul, Google Sheets LEN les compte tous :

=LEN(A2)

Mais dès que vous intégrez TRIM, tous les espaces supplémentaires sont ignorés :

=LEN(TRIM(A2))

Vous pouvez aller plus loin et faire en sorte que votre formule ne tienne pas compte des simples espaces entre les mots. La fonction SUBSTITUTE vous y aidera. Bien que son objectif principal soit de remplacer un caractère par un autre, il existe une astuce pour qu'elle réduise complètement les espaces :

• texte_à_rechercher est la plage avec laquelle vous travaillez : colonne A, ou A2 pour être exact.
• chercher doit être un caractère d'espacement entre guillemets : " "
• remplacer_avec doit contenir des guillemets vides. Si vous voulez ignorer les espaces, vous devez les remplacer par rien du tout (chaîne vide) : ""
• nombre d'occurrences est normalement utilisé pour spécifier l'instance à remplacer. Mais comme je décris comment compter les caractères sans tous les espaces, je vous suggère d'omettre cet argument car il est facultatif.

Essayez maintenant d'assembler tout cela dans le LEN de Google Sheets et vous verrez qu'aucun espace n'est pris en compte :

=LEN(SUBSTITUTE(A2, " ", ""))

Google Sheets : compter des caractères spécifiques

Le même tandem de LEN et SUBSTITUTE de Google Sheets est utilisé lorsque vous devez compter des caractères, des lettres ou des chiffres spécifiques.

Dans mes exemples, je vais trouver le nombre d'occurrences de la lettre 's'. Et cette fois, je vais commencer avec une formule toute faite :

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Décortiquons-le pour comprendre comment il fonctionne :

1. SUBSTITUTE(A2, "s", "") recherche la lettre 's' dans A2 et remplace toutes les occurrences par "rien", ou une chaîne vide ("").
2. LEN(SUBSTITUTE(A2, "s", "") calcule le nombre de tous les caractères sauf 's' dans A2.
3. LEN(A2) compte tous les caractères de A2.
4. Enfin, vous soustrayez l'un de l'autre.

La différence de résultat indique combien de "s" il y a dans la cellule :

Note : Vous vous demandez peut-être pourquoi B1 dit qu'il n'y a qu'un seul "s" dans A2 alors que vous en voyez trois ?

Le problème est que la fonction SUBSTITUTE est sensible à la casse. Je lui ai demandé de prendre toutes les occurrences de 's' en minuscules et c'est ce qu'elle a fait.

Pour qu'il ignore la casse du texte et traite les lettres en minuscules et en majuscules, vous devrez faire appel à une autre fonction de Google Sheets pour vous aider : LOWER.

Conseil : découvrez d'autres façons de modifier la casse du texte dans Google Sheets.

C'est aussi simple que LEN et TRIM de Google Sheets, car tout ce dont il a besoin est le texte :

=LOWER(texte)

Cette astuce est exactement ce dont vous avez besoin pour que Google Sheets compte certains caractères, quelle que soit leur casse :

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

Astuce : comme précédemment, pour compter le total de caractères spécifiques dans la plage, enroulez votre LEN dans SUMPRODUCT :

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", ""))))

Compter les mots dans Google Sheets

Lorsque les cellules contiennent plusieurs mots, il est fort probable que vous ayez besoin de leur nombre au lieu de la longueur de la chaîne de caractères de Google Sheets.

Et bien qu'il existe de multiples façons de le faire, aujourd'hui je vais mentionner comment Google Sheets LEN fait le travail.

Vous vous souvenez de la formule que j'ai utilisée pour compter des caractères spécifiques dans Google Sheets ? En fait, elle sera utile ici aussi, car je ne vais pas compter littéralement les mots, mais plutôt le nombre d'espaces entre les mots, puis j'ajouterai simplement 1. Regardez :

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) compte le nombre de tous les caractères dans la cellule.
2. LEN(SUBSTITUTE((A2), " ","")) supprime tous les espaces de la chaîne de texte et compte les caractères restants.
3. Ensuite, vous soustrayez l'un de l'autre, et la différence que vous obtenez est le nombre d'espaces dans la cellule.
4. Comme les mots sont toujours plus nombreux que les espaces dans une phrase, vous ajoutez 1 à la fin.

Google Sheets : compter des mots spécifiques

Enfin, j'aimerais partager une formule Google Sheets que vous pouvez utiliser pour compter des mots spécifiques.

Ici, j'ai la chanson de la tortue fantaisie des Aventures d'Alice au pays des merveilles :

Je veux savoir combien de fois le mot "will" apparaît dans chaque ligne. Je pense que vous ne serez pas surpris si je vous dis que la formule dont j'ai besoin se compose des mêmes fonctions que précédemment : LEN, SUBSTITUTE et LOWER de Google Sheets :

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

La formule peut sembler effrayante mais je peux vous assurer qu'elle est facile à comprendre, alors soyez indulgent avec moi :)

1. Puisque la casse du texte n'a pas d'importance pour moi, j'utilise LOWER(A2) pour tout mettre en minuscules.
2. Puis va SUBSTITUTE(LOWER(A2), "will",""))) - il se débarrasse de toutes les occurrences de "will" en les remplaçant par des chaînes vides ("").
3. Ensuite, je soustrais le nombre de caractères sans le mot "will" de la longueur totale de la chaîne. Le nombre que j'obtiens compte tous les caractères de toutes les occurrences de "will" dans chaque ligne.

   Ainsi, si le mot "volonté" apparaît une fois, le nombre est 4 car il comporte 4 lettres, s'il apparaît deux fois, le nombre est 8, et ainsi de suite.

4. Enfin, je divise ce nombre par la longueur du mot "will".

Conseil : si vous préférez obtenir le nombre total d'apparitions du mot "will", il suffit d'entourer la formule entière de SUMPRODUCT :

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

Comme vous pouvez le constater, tous ces cas de comptage de caractères sont résolus par les mêmes schémas des mêmes fonctions pour Google Sheets : LEN, SUBSTITUTE, LOWER, et SUMPRODUCT.

Si certaines formules vous déroutent encore, ou si vous ne savez pas comment les appliquer à votre tâche particulière, ne vous gênez pas et posez vos questions dans la section des commentaires ci-dessous !