Tänään tarkastelemme VLOOKUPin käyttöä Excelissä monien yksityiskohtaisten vaiheittaisten esimerkkien avulla. Opit, miten voit tehdä Vlookupin toisesta arkista ja eri työkirjasta, etsiä jokerimerkkien avulla ja paljon muuta.

Tämä artikkeli aloittaa sarjan, jossa käsitellään VLOOKUPia, yhtä Excelin hyödyllisimmistä funktioista ja samalla yhtä monimutkaisimmista ja vähiten ymmärretyimmistä. Yritämme selittää perusteet hyvin yksinkertaisella kielellä, jotta kokemattoman käyttäjän oppiminen olisi mahdollisimman helppoa. Annamme myös kaavaesimerkkejä, jotka kattavat VLOOKUPin tyypillisimmät käyttökohteet Excelissä, ja pyrimme tekemäänne ovat sekä informatiivisia että hauskoja.

Excel VLOOKUP-toiminto

Mikä on VLOOKUP? Ensinnäkin se on Excel-funktio :) Mitä se tekee? Se etsii määrittämäsi arvon ja palauttaa sitä vastaavan arvon toisesta sarakkeesta. Tarkemmin sanottuna VLOOKUP-funktio etsii arvon tietyn alueen ensimmäisestä sarakkeesta ja palauttaa saman rivin arvon toisesta sarakkeesta.

Yleisessä käytössä Excelin VLOOKUP hakee tietoaineistosta yksilöllisen tunnisteen perusteella ja tuo sinulle kyseiseen yksilölliseen tunnisteeseen liittyvän tiedon.

Kirjain "V" tarkoittaa "pystysuoraa", ja sitä käytetään erottamaan VLOOKUP-toiminto HLOOKUP-toiminnosta, joka etsii arvoa riviltä eikä sarakkeesta (H tarkoittaa "vaakasuoraa").

Toiminto on käytettävissä kaikissa Excel 365 -versioissa Excel 2007:stä alkaen.

Vihje. Excel 365:ssä ja Excel 2021:ssä voit käyttää XLOOKUP-funktiota, joka on VLOOKUPin joustavampi ja tehokkaampi seuraaja.

VLOOKUP-syntaksi

VLOOKUP-toiminnon syntaksi on seuraava:

Missä:

• Lookup_value (pakollinen) - on arvo, jota haetaan.

  Tämä voi olla arvo (numero, päivämäärä tai teksti), soluviittaus (viittaus soluun, joka sisältää hakuarvon) tai jonkin muun toiminnon palauttama arvo. Toisin kuin numerot ja soluviittaukset, tekstiarvot on aina suljettava kaksinkertaisiin lainausmerkkeihin.

• Table_array (pakollinen) - on solualue, josta haetaan hakuarvoa ja josta haetaan vastaavuus. VLOOKUP-funktio etsii aina taulukkosarjan ensimmäisestä sarakkeesta. , joka voi sisältää erilaisia tekstiarvoja, numeroita, päivämääriä ja loogisia arvoja.
• Col_index_num (pakollinen) - on sen sarakkeen numero, josta arvo palautetaan. Laskenta alkaa taulukkomäärityksen vasemmanpuoleisimmasta sarakkeesta, joka on 1.
• Range_lookup (valinnainen) - määrittää, haetaanko likimääräistä vai tarkkaa vastaavuutta:
  • TRUE tai jätetään pois (oletusarvo) - likimääräinen vastaavuus. Jos tarkkaa vastaavuutta ei löydy, kaava etsii suurimman arvon, joka on pienempi kuin hakuarvo. Edellyttää hakusarakkeen lajittelua nousevaan järjestykseen.
  • FALSE - täsmällinen vastaavuus. Kaava etsii täsmälleen hakuarvoa vastaavaa arvoa. Jos täsmällistä vastaavuutta ei löydy, palautetaan arvo #N/A.

Perus VLOOKUP-kaava

Tässä on esimerkki Excelin VLOOKUP-kaavasta yksinkertaisimmassa muodossaan. Katso alla olevaa kaavaa ja yritä "kääntää" se englanniksi:

=VLOOKUP("leijona", A2:B11, 2, FALSE)

• Ensimmäinen argumentti ( lookup_value ) osoittaa selvästi, että kaava etsii sanaa "leijona".
• Toinen argumentti ( table_array ) on A2:B11. Kun muistat, että haku suoritetaan vasemmanpuoleisimmassa sarakkeessa, voit lukea yllä olevaa kaavaa hieman pidemmälle: etsi "leijona" alueelta A2:A11. Tähän asti kaikki hyvin, eikö niin?
• Kolmas väite col_index_num on 2. Tämä tarkoittaa, että haluamme palauttaa vastaavan arvon sarakkeesta B, joka on taulukkomäärityksen toinen.
• Neljäs väite range_lookup on FALSE, mikä tarkoittaa, että etsimme tarkkaa vastaavuutta.

Kun kaikki argumentit on määritetty, sinun ei pitäisi olla ongelma lukea koko kaavaa: etsi "leijona" kohdasta A2:A11, etsi tarkka vastaavuus ja palauta arvo saman rivin sarakkeesta B.

Yksinkertaisuuden vuoksi voit kirjoittaa haluamasi arvon johonkin soluun, esimerkiksi E1, korvata "kovakoodatun" tekstin soluviittauksella ja saada kaavan etsimään minkä tahansa arvon, jonka syötät E1:een:

=VLOOKUP(E1, A2:B11, 2, FALSE)

Jääkö jokin asia epäselväksi? Yritä sitten katsoa asiaa näin:

Kuinka tehdä Vlookup Excelissä

Kun käytät VLOOKUP-kaavoja tosielämän laskentataulukoissa, tärkein nyrkkisääntö on tämä: lukituspöytämatriisi absoluuttisilla soluviittauksilla (kuten $A$2:$C$11), jotta se ei muutu, kun kaava kopioidaan muihin soluihin.

The hakuarvo tulisi useimmissa tapauksissa olla suhteellinen viittaus (kuten E2) tai voit lukita vain sarakekoordinaatin ($E2). Kun kaava kopioidaan saraketta alaspäin, viittaus mukautuu automaattisesti jokaiselle riville.

Jos haluat nähdä, miten se toimii käytännössä, katso seuraava esimerkki. Esimerkkitaulukkoon on lisätty vielä yksi sarake, jossa eläimet on luokiteltu nopeuden mukaan (sarake A), ja haluamme löytää maailman 1., 5. ja 10. nopeimman sprintterin. Syötä tätä varten hakusarjat joihinkin soluihin (E2:E4 alla olevassa kuvassa) ja käytä seuraavia kaavoja:

Eläinten nimien poimiminen sarakkeesta B:

=VLOOKUP($E2, $A$2:$C$11, 2, FALSE)

Nopeuden poimiminen sarakkeesta C:

=VLOOKUP($E2, $A$2:$C$11, 3, FALSE)

Kirjoita yllä olevat kaavat soluihin F2 ja G2, valitse kyseiset solut ja vedä kaavat alla oleville riveille:

Jos tutkit kaavaa alemmalla rivillä, huomaat, että hakuarvoviittaus on mukautettu kyseiselle riville, kun taas taulukkomalli on ennallaan:

Alla on vielä muutama hyödyllinen vinkki, jotka säästävät sinulta paljon päänsärkyä ja aikaa vianmääritykseen.

Excel VLOOKUP - 5 muistettavaa asiaa!

1. VLOOKUP-funktio ei voi katsoa sen vasenta . Se etsii aina vasemmanpuoleisin sarake taulukkotietueesta ja palauttaa arvon oikeanpuoleisesta sarakkeesta. Jos haluat vetää arvoja vasemmalta, käytä INDEX MATCH (tai INDEX XMATCH Excel 365:ssä) -yhdistelmää, joka ei välitä haku- ja palautussarakkeiden sijainnista.
2. VLOOKUP-toiminto ei erota isoja ja pieniä kirjaimia. , mikä tarkoittaa, että isoja ja pieniä kirjaimia käsitellään samanarvoisina. Jos haluat erottaa kirjainkirjaimet toisistaan, käytä VLOOKUP-kaavoja, joissa on huomioitu isojen ja pienten kirjainten väliset erot.
3. Muista viimeisen parametrin merkitys. Käytä TRUE, jos haluat likimääräisen vastaavuuden, ja FALSE, jos haluat tarkan vastaavuuden. Lisätietoja on kohdassa VLOOKUP TRUE vs. FALSE.
4. Kun etsit likimääräistä vastaavuutta, varmista, että hakusarakkeen tiedot on lajiteltu nousevaan järjestykseen.
5. Jos hakuarvoa ei löydy, palautetaan virhe #N/A. Lisätietoja muista virheistä on kohdassa Miksi Excel VLOOKUP ei toimi.

Excel VLOOKUP esimerkkejä

Toivottavasti pystysuora haku alkaa näyttää sinulle hieman tutummalta. Vahvistaaksemme tietojasi, rakennetaan muutama VLOOKUP-kaava lisää.

Miten Vlookup toisesta Excel-arkista Excelissä

Käytännössä Excelin VLOOKUP-toimintoa käytetään harvoin samassa työarkissa olevien tietojen kanssa. Useimmiten sinun on haettava vastaavat tiedot eri työarkista.

Jos haluat tehdä Vlookup-haun eri Excel-arkista, laita työarkin nimi ja sen jälkeen huutomerkki kenttään table_array argumentti ennen alueviitettä. Jos haluat esimerkiksi etsiä Sheet2:n alueelta A2:B10, käytä tätä kaavaa:

=VLOOKUP("Tuote1", Sheet2!A2:B10, 2)

Sinun ei tietenkään tarvitse kirjoittaa arkin nimeä manuaalisesti. Aloita yksinkertaisesti kaavan kirjoittaminen ja kun tulee kohta table_array argumenttia, siirry hakutaulukkoon ja valitse alue hiirellä.

Esimerkiksi näin voit etsiä A2-arvoa alueelta A2:A9 seuraavassa taulukossa Hinnat ja palauttaa vastaavan arvon sarakkeesta C:

=VLOOKUP(A2, Hinnat!$A$2:$C$9, 3, FALSE)

Huomautuksia:

• Jos laskentataulukon nimi sisältää välilyönnit tai muut kuin aakkoselliset merkit , se on suljettava yksinkertaisiin lainausmerkkeihin, esim. 'Hinnasto'!$A$2:$C$9.
• Jos käytät VLOOKUP-kaavaa useille soluille, muista käyttää lock table_array $-merkillä, kuten $A$2:$C$9.

Miten Vlookup toisesta työkirjasta Excelissä

Jos haluat tehdä Vlookup-haun eri Excel-työkirjasta, laita työkirjan nimi hakasulkeisiin ennen työarkin nimeä.

Tässä on esimerkiksi kaava, jolla haetaan A2-arvoa nimetyltä arkilta. Hinnat vuonna Hintaluettelo.xlsx työkirja:

=VLOOKUP(A2, [Price_List.xlsx]Prices!$A$2:$C$9, 3, FALSE)

Jos työkirjan tai työarkin nimi sisältää välilyöntejä tai muita kuin aakkosellisia merkkejä, ne on suljettava yksinkertaisiin lainausmerkkeihin seuraavasti:

=VLOOKUP(A2, '[Hinnasto.xlsx]Hinnat'!$A$2:$C$9, 3, FALSE)

Helpoin tapa tehdä VLOOKUP-kaava, joka viittaa eri työkirjaan, on tämä:

1. Avaa molemmat tiedostot.
2. Aloita kaavan kirjoittaminen, siirry toiseen työkirjaan ja valitse taulukkokokoelma hiirellä.
3. Syötä loput argumentit ja paina Enter-näppäintä kaavan loppuun saattamiseksi.

Tulos näyttää jokseenkin alla olevan kuvan kaltaiselta:

Kun olet sulje tiedoston, jossa on hakutaulukkosi, VLOOKUP-kaava toimii edelleen, mutta se näyttää nyt suljetun työkirjan koko polun:

Lisätietoja on kohdassa Viittaaminen toiseen Excel-arkkiin tai työkirjaan.

Miten Vlookup nimetyltä alueelta toisessa arkissa?

Jos aiot käyttää samaa hakualuetta useissa kaavoissa, voit luoda sille nimetyn alueen ja kirjoittaa nimen suoraan kenttään nimellä table_array argumentti.

Jos haluat luoda nimetyn alueen, valitse solut ja kirjoita haluamasi nimi kenttään nimetty alue. Nimi Yksityiskohtaiset vaiheet ovat kohdassa Alueen nimeäminen Excelissä.

Tässä esimerkissä annoimme nimeksi Hinnat_2020 tietojen soluihin (A2:C9) ja saat tämän kompaktin kaavan:

=VLOOKUP(A2, Prices_2020, 3, FALSE)

Useimmat Excelin nimet koskevat koko työkirja , joten sinun ei tarvitse määrittää työarkin nimeä, kun käytät nimettyjä alueita.

Jos nimetty alue on toinen työkirja , laita työkirjan nimi ennen alueen nimeä, esimerkiksi:

=VLOOKUP(A2, 'Hinnasto.xlsx'!Hinnat_2020, 3, FALSE)

Tällaiset kaavat ovat paljon ymmärrettävämpiä, eikö totta? Lisäksi nimettyjen alueiden käyttö voi olla hyvä vaihtoehto absoluuttisille viittauksille. Koska nimetty alue ei muutu, voit olla varma, että taulukkomäärittelysi pysyy lukittuna riippumatta siitä, minne kaavaa siirretään tai kopioidaan.

Jos olet muuttanut hakualueesi täysin toimivaksi Excel-taulukoksi, voit tehdä Vlookup-haun taulukon nimen perusteella, esimerkiksi seuraavasti. Hinta_taulukko alla olevassa kaavassa:

=VLOOKUP(A2, Hintataulukko, 3, FALSE)

Taulukkoviittaukset, joita kutsutaan myös rakenteellisiksi viitteiksi, ovat joustavia ja immuuneja monille tietomuokkauksille. Voit esimerkiksi poistaa tai lisätä uusia rivejä hakutaulukkoon huolehtimatta viitteiden päivittämisestä.

Jokerimerkkien käyttäminen VLOOKUP-kaavassa

Kuten monet muutkin kaavat, Excelin VLOOKUP-funktio hyväksyy seuraavat jokerimerkit:

• Kysymysmerkki (?), joka vastaa mitä tahansa yksittäistä merkkiä.
• Asteriski (*) vastaa mitä tahansa merkkijonoa.

Jokerimerkit ovat todella hyödyllisiä monissa tilanteissa:

• Kun et muista tarkalleen etsimääsi tekstiä.
• Kun etsit merkkijonoa, joka on osa solun sisältöä.
• Kun hakusarakkeessa on etu- tai jälkimmäisiä välilyöntejä, saatat yrittää miettiä, miksi normaali kaava ei toimi.

Esimerkki 1. Etsi tietyillä merkeillä alkavaa tai päättyvää tekstiä.

Oletetaan, että haluat löytää tietyn asiakkaan alla olevasta tietokannasta. Et muista sukunimeä, mutta olet varma, että se alkaa kirjaimella "ack".

Jos haluat palauttaa sukunimen sarakkeesta A, käytä seuraavaa Vlookupin jokerimerkkikaavaa:

=VLOOKUP("ack*", $A$2:$B$10, 1, FALSE)

Jos haluat hakea lisenssiavaimen sarakkeesta B, käytä tätä (ero on vain sarakkeen indeksinumerossa):

=VLOOKUP("ack*", $A$2:$B$10, 2, FALSE)

Voit myös kirjoittaa nimen tunnetun osan johonkin soluun, esimerkiksi E1, ja yhdistää jokerimerkin soluviittaukseen:

=VLOOKUP(E1& "*", $A$2:$B$10, 1, FALSE)

Alla olevassa kuvakaappauksessa näkyvät tulokset:

Alla on muutama muu VLOOKUP-kaava, joissa on jokerimerkkejä.

Etsi sukunimi, joka päättyy sanaan "son":

=VLOOKUP("*son", $A$2:$B$10, 1, FALSE)

Hanki nimi, joka alkaa "joh" ja päättyy "son":

=VLOOKUP("joh*son", $A$2:$B$10, 1, FALSE)

Vedä 5-merkkinen sukunimi:

=VLOOKUP("?????", $A$2:$B$10, 1, FALSE)

Esimerkki 2. VLOOKUP jokerimerkki solun arvon perusteella

Edellisestä esimerkistä tiedät jo, että on mahdollista liittää amperand (&) ja soluviittaus toisiinsa hakujonon muodostamiseksi. Jos haluat etsiä arvon, joka sisältää tietyn merkin (merkit) missä tahansa kohdassa, laita amperand ennen ja jälkeen soluviittauksen.

Oletetaan, että haluat saada tiettyä lisenssiavainta vastaavan nimen, mutta et tiedä koko avainta, vaan vain muutaman merkin. Kun sarakkeessa A on avaimet, sarakkeessa B nimet ja sarakkeessa E1 osa kohdeavaimesta, voit tehdä Vlookup-etsintäkortin tällä tavalla:

Pura avain:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 1, FALSE)

Pura nimi:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 2, FALSE)

Huomautuksia:

• Jotta VLOOKUP-kaava toimisi oikein, käytä tarkkaa vastaavuutta (FALSE on viimeinen argumentti).
• Jos löytyy useampi kuin yksi vastaavuus, palautetaan ensimmäinen. .

VLOOKUP TRUE vs FALSE

Ja nyt on aika tarkastella lähemmin Excelin VLOOKUP-funktion viimeistä argumenttia. Vaikka se on valinnainen, on range_lookup parametri on erittäin tärkeä. Riippuen siitä, valitsetko TRUE vai FALSE, kaava voi antaa erilaisia tuloksia.

Excel VLOOKUP tarkka vastaavuus (FALSE)

Jos range_lookup on asetettu FALSE, Vlookup-kaava etsii arvoa, joka on täsmälleen sama kuin hakuarvo. Jos löytyy kaksi tai useampia vastaavuuksia, palautetaan ensimmäinen. Jos täsmällistä vastaavuutta ei löydy, tulee #N/A-virhe.

Excel VLOOKUP likimääräinen ottelu (TRUE)

Jos range_lookup on TRUE tai jätetty pois (oletusarvo), kaava etsii lähimmän vastaavuuden. Tarkemmin sanottuna se etsii ensin tarkan vastaavuuden, ja jos tarkkaa vastaavuutta ei löydy, se etsii seuraavaksi suurimman arvon, joka on pienempi kuin hakuarvo.

Likimääräinen ottelu Vlookup toimii seuraavin varauksin:

• Hakusarake on lajiteltava nouseva järjestys pienimmästä suurimpaan, muuten oikeaa arvoa ei välttämättä löydy.
• Jos hakuarvo on pienempi kuin hakumassan pienin arvo, palautetaan virhe #N/A.

Seuraavat esimerkit auttavat sinua ymmärtämään paremmin tarkan ja likimääräisen vastaavuuden Vlookupin eron ja sen, milloin kumpaakin kaavaa on parasta käyttää.

Esimerkki 1. Kuinka tehdä tarkka vastaavuus Vlookup -luettelo

Jos haluat etsiä tarkan vastaavuuden, laita viimeiseen argumenttiin FALSE.

Tässä esimerkissä otetaan eläinten nopeutta koskeva taulukko, vaihdetaan sarakkeet ja yritetään löytää eläimet, jotka voivat juosta 80, 50 ja 30 mailia tunnissa. Kun hakuarvot ovat D2:ssa, D3:ssa ja D4:ssä, kirjoita alla oleva kaava E2:een ja kopioi se sitten kahteen muuhun soluun:

=VLOOKUP(D2, $A$2:$B$12, 2, FALSE)

Kuten näet, kaava palauttaa E3:n arvoksi "Leijona", koska niitä ajetaan tasan 50 tunnissa. Kahdelle muulle hakuarvolle ei löydy täsmällistä vastaavuutta, ja näkyviin tulee #N/A-virheitä.

Esimerkki 2. Miten Vlookup-menetelmää käytetään likimääräistä vastaavuutta varten?

Jos haluat etsiä likimääräisen vastaavuuden, sinun on tehtävä kaksi olennaista asiaa:

• Lajittele ensimmäinen sarake table_array pienimmästä suurimpaan.
• Käytä TRUE -merkintää range_lookup argumentti tai jätä se pois.

Etsintäsarakkeen lajittelu on erittäin tärkeää, koska VLOOKUP-funktio lopettaa haun heti, kun se löytää lähellä olevan vastaavuuden, joka on pienempi kuin etsintäarvo. Jos tietoja ei ole lajiteltu kunnolla, saatat saada todella outoja tuloksia tai kasan #N/A-virheitä.

Esimerkkitietojemme osalta likimääräinen Vlookup-kaava on seuraava:

=VLOOKUP(D2, $A$2:$B$12, 2, TRUE)

Ja palauttaa seuraavat tulokset:

• Kun hakuarvo on "80", "Cheetah" palautetaan, koska sen nopeus (70) on lähin vastaavuus, joka on pienempi kuin hakuarvo.
• Jos hakuarvo on "50", palautetaan tarkka vastaavuus (Lion).
• Jos hakuarvo on "30", palautetaan virhe #N/A, koska hakuarvo on pienempi kuin hakusarakkeen pienin arvo.

Erikoistyökalut Vlookupiin Excelissä

VLOOKUP on epäilemättä yksi tehokkaimmista ja hyödyllisimmistä Excel-funktioista, mutta se on myös yksi hämmentävimmistä. Jotta oppimiskäyrä ei olisi niin jyrkkä ja kokemus miellyttävämpi, sisällytimme Ultimate Suite for Excel -ohjelmistoon pari aikaa säästävää työkalua.

VLOOKUP Wizard - helppo tapa kirjoittaa monimutkaisia kaavoja

Vuorovaikutteinen VLOOKUP-avustaja ohjaa sinua määritysvaihtoehtojen läpi, jotta voit rakentaa täydellisen kaavan määrittelemillesi kriteereille. Tietorakenteestasi riippuen se käyttää tavallista VLOOKUP-toimintoa tai INDEX MATCH -kaavaa, joka voi vetää arvot vasemmalta.

Saadaksesi räätälöidyn kaavan, sinun on tehtävä näin:

1. Suorita ohjatun VLOOKUP-ohjelman suoritus.

1. Valitse päätaulukko ja hakutaulukko.
2. Määritä seuraavat sarakkeet (monissa tapauksissa ne valitaan automaattisesti):
   • Avainsarake - päätaulukon sarake, joka sisältää etsittävät arvot.
   • Hakusarake - pylväs, jota vasten voi katsoa.
   • Palautussarake - sarake, josta arvot haetaan.
3. Napsauta Lisää nappi.

Seuraavat esimerkit näyttävät ohjatun toiminnon.

Standardi Vlookup

Kun hakusarake ( Eläimet ) on hakutaulukon vasemmanpuoleisin sarake, lisätään normaali VLOOKUP-kaava tarkkaa vastaavuutta varten:

Vlookup vasemmalle

Kun hakusarake ( Eläimet ) on paluusarakkeen oikealla puolella ( Nopeus ), ohjattu toiminto lisää INDEX MATCH -kaavan Vlookupiin oikealta vasemmalle:

Lisäbonus! Soluviittausten älykkään käytön ansiosta kaavat voidaan kopioida tai siirtää mihin tahansa sarakkeeseen ilman, että viittauksia tarvitsee päivittää.

Yhdistä kaksi taulukkoa - kaavaton vaihtoehto Excel VLOOKUPille

Jos Excel-tiedostosi ovat valtavan suuria ja monimutkaisia, projektin määräaika lähestyy ja etsit jotakuta, joka voisi antaa sinulle auttavan käden, kokeile Ohjattu taulukoiden yhdistäminen -ohjelmaa.

Tämä työkalu on visuaalinen ja stressitön vaihtoehto Excelin VLOOKUP-toiminnolle, joka toimii näin:

1. Valitse pääpöytäsi.
2. Valitse hakutaulukko.
3. Valitse yksi tai useampi yhteinen sarake yksilölliseksi tunnisteeksi.
4. Määritä päivitettävät sarakkeet.
5. Valitse valinnaisesti lisättävät sarakkeet.
6. Anna Ohjatun taulukoiden yhdistämisen kestää muutaman sekunnin... ja nauti tuloksista :)

Näin käytät VLOOKUPia Excelissä perustasolla. Ohjeemme seuraavassa osassa käsittelemme kehittyneitä VLOOKUP-esimerkkejä, joissa opit, miten voit tehdä VLOOKUPin useilla kriteereillä, palauttaa kaikki osumat tai N:nnen esiintymän, suorittaa kaksinkertaisen VLOOKUPin, etsiä useiden arkkien yli yhdellä kaavalla ja paljon muuta. Kiitän lukemisesta ja toivon näkeväni sinut ensi viikolla!

Saatavilla olevat lataukset

Excel VLOOKUP-kaavan esimerkkejä (.xlsx-tiedosto)

Ultimate Suite 14 päivän täysin toimiva versio (.exe-tiedosto)