Hari ini kita akan melihat cara menggunakan VLOOKUP di Excel dengan banyak contoh langkah demi langkah yang mendetail. Anda akan belajar cara Vlookup dari lembar lain dan buku kerja yang berbeda, mencari dengan wildcard, dan banyak lagi.

Artikel ini memulai seri yang membahas VLOOKUP, salah satu fungsi Excel yang paling berguna dan sekaligus salah satu fungsi yang paling rumit dan paling tidak dipahami. Kami akan mencoba menjelaskan dasar-dasar dalam bahasa yang sangat sederhana untuk membuat kurva pembelajaran bagi pengguna yang tidak berpengalaman semudah mungkin. Kami juga akan memberikan contoh rumus yang mencakup penggunaan VLOOKUP yang paling umum di Excel, dan mencoba membuatmereka informatif dan menyenangkan.

Fungsi VLOOKUP Excel

Apa itu VLOOKUP? Pertama-tama, ini adalah fungsi Excel :) Apa fungsinya? Ini mencari nilai yang Anda tentukan dan mengembalikan nilai yang cocok dari kolom lain. Lebih teknisnya, fungsi VLOOKUP mencari nilai di kolom pertama dari rentang tertentu dan mengembalikan nilai di baris yang sama dari kolom lain.

Dalam penggunaan umumnya, Excel VLOOKUP mencari melalui kumpulan data Anda berdasarkan pengidentifikasi unik dan memberi Anda sepotong informasi yang terkait dengan pengidentifikasi unik tersebut.

Huruf "V" adalah singkatan dari "vertical" dan digunakan untuk membedakan VLOOKUP dari fungsi HLOOKUP yang mencari nilai dalam baris dan bukan kolom (H adalah singkatan dari "horizontal").

Fungsi ini tersedia di semua versi Excel 365 hingga Excel 2007.

Tip. Di Excel 365 dan Excel 2021, Anda dapat menggunakan fungsi XLOOKUP, yang merupakan penerus VLOOKUP yang lebih fleksibel dan kuat.

Sintaks VLOOKUP

Sintaks untuk fungsi VLOOKUP adalah sebagai berikut:

Di mana:

• Lookup_value (wajib) - adalah nilai yang akan dicari.

  Ini bisa berupa nilai (angka, tanggal atau teks), referensi sel (referensi ke sel yang berisi nilai pencarian), atau nilai yang dikembalikan oleh beberapa fungsi lain. Tidak seperti angka dan referensi sel, nilai teks harus selalu diapit dalam "tanda kutip ganda".

• Table_array (wajib) - adalah rentang sel tempat mencari nilai pencarian dan untuk mengambil kecocokan. Fungsi VLOOKUP selalu mencari di kolom pertama dari larik tabel yang bisa berisi berbagai nilai teks, angka, tanggal, dan nilai logika.
• Col_index_num (wajib) - adalah nomor kolom yang akan dikembalikan nilainya. Penghitungan dimulai dari kolom paling kiri dalam larik tabel, yaitu 1.
• Range_lookup (opsional) - menentukan apakah akan mencari perkiraan atau kecocokan persis:
  • TRUE atau dihilangkan (default) - perkiraan kecocokan. Jika kecocokan yang tepat tidak ditemukan, rumus mencari nilai terbesar yang lebih kecil dari nilai pencarian. Membutuhkan pengurutan kolom pencarian dalam urutan menaik.
  • FALSE - pencocokan persis. Rumus mencari nilai yang persis sama dengan nilai pencarian. Jika pencocokan persis tidak ditemukan, nilai #N/A akan dikembalikan.

Rumus dasar VLOOKUP

Berikut adalah contoh rumus Excel VLOOKUP dalam bentuknya yang paling sederhana. Silakan lihat rumus di bawah ini dan cobalah "menerjemahkannya" ke dalam bahasa Inggris:

=VLOOKUP("singa", A2:B11, 2, FALSE)

• Argumen pertama ( lookup_value ) secara jelas mengindikasikan bahwa rumus tersebut mencari kata "lion".
• Argumen ke-2 ( table_array ) adalah A2:B11. Dengan mengingat bahwa pencarian dilakukan di kolom paling kiri, Anda dapat membaca rumus di atas sedikit lebih jauh: cari "singa" dalam rentang A2:A11. Sejauh ini, bagus, bukan?
• Argumen ke-3 col_index_num adalah 2. Artinya, kita ingin mengembalikan nilai yang cocok dari kolom B, yang kedua dalam larik tabel.
• Argumen ke-4 range_lookup adalah FALSE, yang mengindikasikan bahwa kita mencari kecocokan persis.

Dengan semua argumen yang ditetapkan, Anda seharusnya tidak memiliki masalah dalam membaca seluruh rumus: cari "singa" di A2: A11, temukan kecocokan yang tepat, dan kembalikan nilai dari kolom B di baris yang sama.

Demi kenyamanan, Anda bisa mengetikkan nilai yang diinginkan dalam beberapa sel, misalnya E1, mengganti teks "hardcoded" dengan referensi sel, dan mendapatkan rumus untuk mencari nilai apa pun yang Anda masukkan di E1:

=VLOOKUP(E1, A2:B11, 2, FALSE)

Apakah ada yang masih belum jelas? Kalau begitu, cobalah melihatnya dengan cara ini:

Bagaimana melakukan Vlookup di Excel

Ketika menggunakan rumus VLOOKUP dalam lembar kerja kehidupan nyata, aturan praktis utamanya adalah ini: larik tabel kunci dengan referensi sel absolut (seperti $A$2:$C$11) untuk mencegahnya berubah saat menyalin rumus ke sel lain.

The nilai pencarian dalam banyak kasus harus berupa referensi relatif (seperti E2) atau kamu bisa mengunci koordinat kolomnya saja ($E2). Ketika rumusnya disalin ke bawah kolom, referensinya akan menyesuaikan secara otomatis untuk setiap baris.

Untuk melihat bagaimana cara kerjanya dalam praktek, silahkan perhatikan contoh berikut ini. Pada tabel contoh kita, kita telah menambahkan satu kolom lagi yang mengurutkan peringkat hewan berdasarkan kecepatan (kolom A) dan ingin menemukan sprinter tercepat ke-1, ke-5, dan ke-10 di dunia. Untuk ini, masukkan peringkat pencarian dalam beberapa sel (E2:E4 dalam screenshot di bawah), dan gunakan rumus berikut:

Untuk menarik nama-nama hewan dari kolom B:

=VLOOKUP($E2, $A$2:$C$11, 2, FALSE)

Untuk mengekstrak kecepatan dari kolom C:

=VLOOKUP($E2, $A$2:$C$11, 3, FALSE)

Masukkan rumus di atas dalam sel F2 dan G2, pilih sel tersebut, dan seret rumus ke baris di bawah ini:

Jika Anda menyelidiki rumus di baris yang lebih rendah, Anda akan melihat bahwa referensi nilai pencarian telah disesuaikan untuk baris tertentu, sementara larik tabel tidak berubah:

Di bawah ini, Anda akan mendapatkan beberapa saran berguna yang akan menghemat banyak waktu dan waktu pemecahan masalah.

Excel VLOOKUP - 5 hal yang perlu diingat!

1. Fungsi VLOOKUP tidak bisa melihat di sebelah kirinya Selalu mencari di dalam kolom paling kiri dari larik tabel dan mengembalikan nilai dari kolom ke kanan. Jika Anda perlu menarik nilai dari kiri, gunakan kombinasi INDEX MATCH (atau INDEX XMATCH di Excel 365) yang tidak peduli dengan posisi kolom pencarian dan pengembalian.
2. Fungsi VLOOKUP tidak peka huruf besar-kecil Untuk membedakan kasus huruf, gunakan rumus VLOOKUP yang case sensitive.
3. Ingat tentang pentingnya parameter terakhir. Gunakan TRUE untuk perkiraan kecocokan dan FALSE untuk kecocokan yang tepat. Untuk detail lengkapnya, silakan lihat VLOOKUP TRUE vs FALSE.
4. Ketika mencari perkiraan kecocokan, pastikan data dalam kolom pencarian diurutkan dalam urutan menaik.
5. Jika nilai pencarian tidak ditemukan, kesalahan # N / A dikembalikan. Untuk informasi tentang kesalahan lainnya, silakan lihat Mengapa Excel VLOOKUP tidak berfungsi.

Contoh VLOOKUP Excel

Saya harap pencarian vertikal mulai terlihat sedikit lebih akrab bagi Anda. Untuk memperkuat pengetahuan Anda, mari kita buat beberapa rumus VLOOKUP lagi.

Cara Vlookup dari lembar lain di Excel

Dalam praktiknya, fungsi Excel VLOOKUP jarang digunakan dengan data di lembar kerja yang sama. Paling sering Anda harus menarik data yang cocok dari lembar kerja yang berbeda.

Untuk Vlookup dari lembar Excel yang berbeda, letakkan nama lembar kerja diikuti dengan tanda seru di table_array argumen sebelum referensi rentang. Misalnya, untuk mencari dalam rentang A2: B10 di Sheet2, gunakan rumus ini:

=VLOOKUP("Produk1", Sheet2!A2:B10, 2)

Tentu saja, Anda tidak perlu mengetikkan nama sheet secara manual. Cukup, mulailah mengetikkan rumusnya dan ketika sampai pada bagian table_array argumen, beralih ke lembar kerja pencarian dan pilih rentang menggunakan mouse.

Contohnya, beginilah cara Anda bisa mencari nilai A2 dalam kisaran A2:A9 pada Harga lembar kerja dan mengembalikan nilai yang cocok dari kolom C:

=VLOOKUP(A2, Harga!$A$2:$C$9, 3, FALSE)

Catatan:

• Jika nama spreadsheet berisi spasi atau karakter non-alfabetis , harus diapit dengan tanda kutip tunggal, misalnya, 'Daftar harga'!$A$2:$C$9.
• Jika Anda menggunakan formula VLOOKUP untuk beberapa sel, ingatlah untuk kunci table_array dengan tanda $, seperti $A$2:$C$9.

Cara Vlookup dari buku kerja lain di Excel

Untuk Vlookup dari buku kerja Excel yang berbeda, letakkan nama buku kerja yang diapit tanda kurung siku sebelum nama lembar kerja.

Contohnya, berikut ini rumus untuk mencari nilai A2 pada sheet bernama Harga di Daftar_Harga.xlsx buku kerja:

=VLOOKUP(A2, [Price_List.xlsx]Prices!$A$2:$C$9, 3, FALSE)

Jika nama buku kerja atau nama lembar kerja berisi spasi atau karakter non-alfabetis, Anda harus mengapitnya dalam tanda kutip tunggal seperti ini:

=VLOOKUP(A2, '[Daftar Harga.xlsx]Harga'!$A$2:$C$9, 3, FALSE)

Cara termudah untuk membuat rumus VLOOKUP yang merujuk ke buku kerja yang berbeda adalah sebagai berikut:

1. Buka kedua file.
2. Mulailah mengetik rumus Anda, beralih ke buku kerja lain, dan pilih larik tabel menggunakan mouse.
3. Masukkan argumen yang tersisa dan tekan tombol Enter untuk menyelesaikan rumus Anda.

Hasilnya akan terlihat seperti tangkapan layar di bawah ini:

Setelah Anda tutup file dengan tabel pencarian Anda, rumus VLOOKUP akan terus bekerja, tetapi sekarang akan menampilkan jalur lengkap untuk buku kerja yang ditutup:

Untuk informasi lebih lanjut, lihat Bagaimana merujuk ke lembar Excel atau buku kerja lain.

Cara Vlookup dari rentang bernama di lembar lain

Jika Anda berencana menggunakan lookup range yang sama dalam banyak formula, Anda bisa membuat range bernama untuknya dan mengetikkan namanya secara langsung di dalam table_array argumen.

Untuk membuat rentang bernama, cukup pilih sel dan ketik nama yang Anda inginkan di Nama kotak di sebelah kiri bilah Formula. Untuk langkah-langkah mendetail, silakan lihat Cara memberi nama rentang di Excel.

Untuk contoh ini, kita memberi nama Harga_2020 ke sel data (A2: C9) di lembar pencarian dan dapatkan rumus ringkas ini:

=VLOOKUP(A2, Prices_2020, 3, FALSE)

Sebagian besar nama di Excel berlaku untuk seluruh buku kerja , jadi Anda tidak perlu menentukan nama lembar kerja saat menggunakan rentang bernama.

Jika kisaran yang dinamai berada dalam buku kerja lain , letakkan nama buku kerja sebelum nama rentang, misalnya:

=VLOOKUP(A2, 'Daftar Harga.xlsx'!Harga_2020, 3, FALSE)

Selain itu, menggunakan range bernama bisa menjadi alternatif yang baik untuk referensi absolut. Karena range bernama tidak berubah, kamu bisa yakin bahwa array tabelmu akan tetap terkunci di mana pun rumusnya dipindahkan atau disalin.

Jika Anda telah mengonversi rentang pencarian Anda menjadi tabel Excel yang berfungsi penuh, maka Anda dapat melakukan Vlookup berdasarkan nama tabel, mis. Tabel harga dalam rumus di bawah ini:

=VLOOKUP(A2, Tabel_Harga, 3, FALSE)

Referensi tabel, juga disebut referensi terstruktur, tahan banting dan kebal terhadap banyak manipulasi data. Misalnya, Anda bisa menghapus atau menambahkan baris baru ke tabel lookup Anda tanpa perlu khawatir tentang memperbarui referensi.

Menggunakan wildcard dalam rumus VLOOKUP

Seperti banyak rumus lainnya, fungsi Excel VLOOKUP menerima karakter wildcard berikut:

• Tanda tanya (?) untuk mencocokkan karakter tunggal apa pun.
• Tanda bintang (*) untuk mencocokkan urutan karakter apa pun.

Wildcard terbukti sangat berguna dalam banyak situasi:

• Apabila Anda tidak ingat teks persis yang Anda cari.
• Saat Anda mencari string teks yang merupakan bagian dari konten sel.
• Ketika kolom lookup mengandung spasi di depan atau di belakangnya. Dalam hal ini, kamu mungkin memutar otak untuk mencari tahu mengapa formula normal tidak bekerja.

Contoh 1. Mencari teks yang dimulai atau diakhiri dengan karakter tertentu

Misalkan Anda ingin menemukan pelanggan tertentu dalam database di bawah ini. Anda tidak ingat nama keluarga, tetapi Anda yakin bahwa nama itu dimulai dengan "ack".

Untuk mengembalikan nama belakang dari kolom A, gunakan rumus wildcard Vlookup berikut:

=VLOOKUP("ack*", $A$2:$B$10, 1, FALSE)

Untuk mengambil kunci lisensi dari kolom B, gunakan yang ini (perbedaannya hanya pada nomor indeks kolom):

=VLOOKUP("ack*", $A$2:$B$10, 2, FALSE)

Anda juga bisa memasukkan bagian nama yang diketahui dalam beberapa sel, misalnya E1, dan menggabungkan karakter wildcard dengan referensi sel:

=VLOOKUP(E1& "*", $A$2:$B$10, 1, FALSE)

Tangkapan layar di bawah ini menunjukkan hasilnya:

Di bawah ini adalah beberapa rumus VLOOKUP lainnya dengan wildcard.

Temukan nama belakang yang berakhiran "son":

=VLOOKUP("*son", $A$2:$B$10, 1, FALSE)

Dapatkan nama yang dimulai dengan "joh" dan diakhiri dengan "son":

=VLOOKUP("joh*son", $A$2:$B$10, 1, FALSE)

Tarik nama belakang 5 karakter:

=VLOOKUP("?????", $A$2:$B$10, 1, FALSE)

Contoh 2. VLOOKUP wildcard berdasarkan nilai sel

Dari contoh sebelumnya, Anda sudah tahu bahwa Anda dapat menggabungkan ampersand (&) dan referensi sel untuk membuat string pencarian. Untuk menemukan nilai yang berisi karakter tertentu di posisi mana pun, letakkan ampersand sebelum dan sesudah referensi sel.

Katakanlah, Anda ingin mendapatkan nama yang sesuai dengan kunci lisensi tertentu, tetapi Anda tidak tahu seluruh kunci, hanya beberapa karakter. Dengan kunci di kolom A, nama di kolom B, dan bagian dari kunci target di E1, Anda dapat melakukan Vlookup wildcard dengan cara ini:

Ekstrak kuncinya:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 1, FALSE)

Ekstrak nama:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 2, FALSE)

Catatan:

• Agar rumus VLOOKUP wildcard bekerja dengan benar, gunakan pencocokan yang tepat (FALSE adalah argumen terakhir).
• Jika ditemukan lebih dari satu kecocokan, yang pertama dikembalikan .

VLOOKUP BENAR vs SALAH

Dan sekarang, saatnya untuk melihat lebih dekat pada argumen terakhir dari fungsi Excel VLOOKUP. Meskipun opsional, fungsi range_lookup Parameter ini sangat penting. Tergantung pada apakah kamu memilih TRUE atau FALSE, rumusmu mungkin akan memberikan hasil yang berbeda.

Excel VLOOKUP pencocokan tepat (SALAH)

Jika range_lookup diatur ke FALSE, rumus Vlookup mencari nilai yang persis sama dengan nilai pencarian. Jika dua atau lebih kecocokan ditemukan, yang pertama dikembalikan. Jika kecocokan persis tidak ditemukan, kesalahan # N / A terjadi.

Excel VLOOKUP perkiraan kecocokan (TRUE)

Jika range_lookup diatur ke TRUE atau dihilangkan (default), rumus mencari kecocokan terdekat. Lebih tepatnya, rumus mencari kecocokan yang tepat terlebih dahulu, dan jika kecocokan yang tepat tidak ditemukan, cari nilai terbesar berikutnya yang kurang dari nilai pencarian.

Perkiraan kecocokan Vlookup bekerja dengan peringatan berikut:

• Kolom pencarian harus diurutkan dalam urutan menaik dari yang terkecil ke yang terbesar, jika tidak, nilai yang benar mungkin tidak ditemukan.
• Jika nilai pencarian lebih kecil dari nilai terkecil dalam array pencarian, kesalahan #N/A dikembalikan.

Contoh berikut akan membantu Anda lebih memahami perbedaan antara pencocokan tepat dan perkiraan pencocokan Vlookup dan kapan setiap rumus paling baik digunakan.

Contoh 1. Bagaimana melakukan Vlookup pencocokan tepat

Untuk mencari kecocokan yang tepat, cukup masukkan FALSE di argumen terakhir.

Untuk contoh ini, mari kita ambil tabel kecepatan hewan, menukar kolom, dan mencoba menemukan hewan yang dapat berlari 80, 50, dan 30 mil per jam. Dengan nilai pencarian di D2, D3, dan D4, masukkan rumus di bawah ini di E2, lalu salin ke dua sel lagi:

=VLOOKUP(D2, $A$2:$B$12, 2, FALSE)

Seperti yang bisa Anda lihat, rumus mengembalikan "Lion" di E3 karena mereka menjalankan tepat 50 per jam. Untuk dua nilai pencarian lainnya, kecocokan yang tepat tidak ditemukan, dan kesalahan #N/A muncul.

Contoh 2. Cara Vlookup untuk perkiraan kecocokan

Untuk mencari perkiraan kecocokan, ada dua hal penting yang perlu Anda lakukan:

• Urutkan kolom pertama dari table_array dari yang terkecil hingga terbesar.
• Gunakan TRUE untuk range_lookup argumen atau menghilangkannya.

Menyortir kolom pencarian sangat penting karena fungsi VLOOKUP berhenti mencari segera setelah menemukan kecocokan yang lebih kecil dari nilai pencarian. Jika datanya tidak diurutkan dengan benar, Anda mungkin akan mendapatkan hasil yang sangat aneh atau banyak kesalahan #N/A.

Untuk data sampel kami, perkiraan kecocokan rumus Vlookup berjalan sebagai berikut:

=VLOOKUP(D2, $A$2:$B$12, 2, TRUE)

Dan mengembalikan hasil berikut ini:

• Untuk nilai pencarian "80", "Cheetah" dikembalikan karena kecepatannya (70) adalah kecocokan terdekat yang lebih kecil daripada nilai pencarian.
• Untuk nilai pencarian "50", kecocokan persis dikembalikan (Lion).
• Untuk nilai pencarian "30", kesalahan #N/A dikembalikan karena nilai pencarian kurang dari nilai terkecil dalam kolom pencarian.

Alat khusus untuk Vlookup di Excel

Tidak diragukan lagi, VLOOKUP adalah salah satu fungsi Excel yang paling kuat dan berguna, tetapi juga salah satu yang paling membingungkan. Untuk membuat kurva pembelajaran tidak terlalu curam dan pengalaman lebih menyenangkan, kami menyertakan beberapa alat penghemat waktu di Ultimate Suite untuk Excel kami.

VLOOKUP Wizard - cara mudah untuk menulis rumus yang kompleks

VLOOKUP Wizard yang interaktif akan memandu Anda melalui opsi konfigurasi untuk membuat formula yang sempurna untuk kriteria yang Anda tentukan. Tergantung pada struktur data Anda, ini akan menggunakan fungsi VLOOKUP standar atau formula INDEX MATCH yang dapat menarik nilai dari kiri.

Untuk mendapatkan formula yang disesuaikan dengan kebutuhan Anda, inilah yang perlu Anda lakukan:

1. Jalankan VLOOKUP Wizard.

1. Pilih tabel utama dan tabel pencarian Anda.
2. Tentukan kolom-kolom berikut ini (dalam banyak kasus, kolom-kolom ini dipilih secara otomatis):
   • Kolom kunci - kolom dalam tabel utama Anda yang berisi nilai yang akan dicari.
   • Kolom pencarian - kolom untuk melihat ke atas.
   • Kolom kembali - kolom untuk mengambil nilai.
3. Klik Sisipkan tombol.

Contoh-contoh berikut ini menunjukkan wizard yang sedang beraksi.

Vlookup Standar

Apabila kolom pencarian ( Hewan ) adalah kolom paling kiri dalam tabel pencarian, rumus VLOOKUP normal untuk pencocokan tepat dimasukkan:

Vlookup ke kiri

Apabila kolom pencarian ( Hewan ) berada di sisi kanan kolom pengembalian ( Kecepatan ), wizard memasukkan rumus INDEX MATCH ke Vlookup kanan ke kiri:

Bonus ekstra! Karena penggunaan referensi sel yang cerdas, rumus dapat disalin atau dipindahkan ke kolom mana pun, tanpa Anda harus memperbarui referensi.

Gabungkan Dua Tabel - alternatif bebas rumus untuk Excel VLOOKUP

Jika file Excel Anda sangat besar dan kompleks, tenggat waktu proyek sudah dekat, dan Anda mencari seseorang yang dapat membantu Anda, cobalah Merge Tables Wizard.

Alat ini adalah alternatif visual dan bebas stres kami untuk fungsi VLOOKUP Excel, yang bekerja dengan cara ini:

1. Pilih meja utama Anda.
2. Pilih tabel pencarian.
3. Pilih satu atau beberapa kolom umum sebagai pengidentifikasi unik.
4. Tentukan kolom mana yang akan diperbarui.
5. Secara opsional, pilih kolom yang akan ditambahkan.
6. Biarkan Wizard Gabungkan Tabel beberapa detik untuk pemrosesan... dan nikmati hasilnya :)

Di bagian selanjutnya dari tutorial ini, kita akan membahas contoh-contoh VLOOKUP tingkat lanjut yang akan mengajarkan Anda cara Vlookup beberapa kriteria, mengembalikan semua kecocokan atau kemunculan ke-N, melakukan Vlookup ganda, mencari di beberapa lembar dengan satu rumus, dan banyak lagi. Saya berterima kasih telah membaca dan berharap untuk melihat Anda minggu depan!

Unduhan yang tersedia

Contoh rumus VLOOKUP Excel (file .xlsx)

Ultimate Suite 14 hari versi yang berfungsi penuh (file .exe)