Tässä opetusohjelmassa tutustutaan erilaisiin tapoihin käyttää ISNA-funktiota Excelissä #N/A-virheiden käsittelyyn.

Kun Excel ei löydä sitä, mitä siltä pyydetään, soluun ilmestyy #N/A-virhe. Tällaisten virheiden havaitsemiseen ja käsittelyyn voit käyttää ISNA-funktiota. Mitä hyötyä siitä on käytännössä? Pohjimmiltaan se auttaa tekemään kaavoista käyttäjäystävällisempiä ja työtauluista paremman näköisiä.

ISNA-toiminto Excelissä

Excelin ISNA-funktiota käytetään solujen tai kaavojen tarkistamiseen #N/A-virheiden varalta. Tuloksena on looginen arvo: TRUE, jos havaitaan #N/A-virhe, ja muuten FALSE.

Toiminto on käytettävissä kaikissa Excel 2000-2021- ja Excel 365 -versioissa.

ISNA-funktion syntaksi on niin yksinkertainen kuin se vain voi olla:

Missä arvo on solun arvo tai kaava, jonka haluat tarkistaa #N/A virheiden varalta.

Voit luoda ISNA-kaavan perusmuodossaan antamalla soluviitteen sen ainoana argumenttina:

=ISNA(A2)

Jos viitattu solu sisältää #N/A-virheen, saat tuloksen TRUE. Jos kyseessä on jokin muu virhe, arvo tai tyhjä solu, saat tuloksen FALSE:

ISNAn käyttö Excelissä

ISNA-funktion käyttäminen puhtaassa muodossaan ei ole käytännössä kovin järkevää. Useimmiten sitä käytetään yhdessä muiden funktioiden kanssa tietyn kaavan tuloksen arvioimiseksi. Tätä varten laitetaan vain tämä toinen kaava kohtaan arvo ISNA:n väite:

Oletetaan, että alla olevassa tietokokonaisuudessa halutaan verrata kahta luetteloa (sarakkeet A ja D) ja tunnistaa nimet, jotka esiintyvät molemmissa luetteloissa, ja nimet, jotka esiintyvät vain luettelossa 1.

Verrattaessa A3:n nimeä sarakkeessa D olevaan nimeen kaava on seuraava:

=MATCH(A3, $D$2:$D$9, 0)

Jos hakuarvo löytyy, MATCH-funktio palauttaa sen suhteellisen sijainnin hakumassassa, muutoin tulee virhe #N/A. Testaamaan MATCH-funktion tulosta pesitämme sen ISNA:han:

=ISNA(MATCH(A3, $D$2:$D$9, 0))

Tämä kaava siirtyy B3:een ja kopioidaan sitten B14:n kautta.

Nyt näet selvästi, mitkä opiskelijat ovat läpäisseet kaikki testit (sarakkeessa D ei ole nimeä> MATCH palauttaa #N/A> ISNA palauttaa TRUE) ja mitkä ovat läpäisseet ainakin yhden testin (sarakkeessa D on nimi> ei virhettä> ISNA palauttaa FALSE).

Vihje. Excel 365:ssä ja Excel 2021:ssä voit käyttää nykyaikaisempaa XMATCH-funktiota. MATCH-funktion sijasta.

IF ISNA -kaava Excelissä

ISNA-funktio voi palauttaa vain kaksi Boolen arvoa. Jos haluat näyttää mukautettuja viestejä, käytä sitä yhdessä IF-funktion kanssa:

Tarkennetaan esimerkkiä vielä hieman, ja selvitetään, mitkä ryhmän A opiskelijat eivät reputtaneet missään kokeessa, ja palautetaan heidän osaltaan "Ei reputtuja kokeita". Muiden opiskelijoiden osalta palautetaan "reputettu". Tätä varten upotetaan ISNA MATCH -kaava IF:n loogiseen testiin niin, että IF:stä tulee uloin funktio:

=IF(ISNA(MATCH(A3,$D$2:$D$9,0)), "Ei epäonnistuneita testejä", "Ei onnistunut")

Tulokset näyttävät nyt paljon paremmilta ja intuitiivisemmilta, oletko samaa mieltä?

ISNAn käyttö Excelissä VLOOKUPin avulla

IF ISNA -yhdistelmä on yleispätevä ratkaisu, jota voidaan käyttää minkä tahansa funktion kanssa, joka etsii jotakin tietosarjasta ja palauttaa #N/A-virheen, kun hakuarvoa ei löydy.

ISNA-funktion syntaksi VLOOKUPin kanssa on seuraava:

Ihmiskielelle käännettynä se sanoo: jos VLOOKUP tuottaa #N/A-virheen, palauta mukautettu teksti, muuten palauta VLOOKUPin tulos.

Oletetaan, että esimerkkitaulukossamme halutaan palauttaa ne oppiaineet, joissa opiskelijat ovat reputtaneet kokeissa. Niille, jotka ovat läpäisseet kaikki kokeet hyväksytysti, näytetään "Ei reputtuja kokeita".

Aiheiden etsimistä varten laadimme tämän klassisen VLOOKUP-kaavan:

=VLOOKUP(A3, $D$3:$E$9, 2, FALSE)

Sitten se sijoitetaan edellä käsiteltyyn yleiseen IF ISNA -kaavaan:

=IF(ISNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE)), "Ei epäonnistuneita testejä", VLOOKUP(A3, $D$3:$E$9, 2, FALSE)))

Excel 2013:ssa ja uudemmissa versioissa voit käyttää IFNA-funktiota #N/A-virheiden havaitsemiseen ja käsittelyyn. Tämä tekee kaavasta lyhyemmän ja helpommin luettavan.

Korvaamme esimerkiksi #N/A-virheet katkoviivoilla ("-") ja saamme tämän tyylikkään ratkaisun:

=IFNA(VLOOKUP(A3, $D$3:$E$9, 2, FALSE), "-")

Excel 365:n ja 2021:n käyttäjät eivät tarvitse lainkaan käärintäfunktiota, sillä VLOOKUPin moderni seuraaja, XLOOKUP-funktio, pystyy käsittelemään #N/A-virheitä natiivisti:

=XLOOKUP(A3, $D$3:$D$9, $E$3:$E$9, "-")

Tulos on täsmälleen sama kuin yllä olevassa kuvakaappauksessa.

SUMPRODUCT ISNA -kaava #N/A virheiden laskemiseksi.

Jos haluat laskea #N/A-virheet tietyllä alueella, käytä ISNA-funktiota yhdessä SUMPRODUCTin kanssa tällä tavalla:

Tässä ISNA palauttaa TRUE- ja FALSE-arvojen joukon, kaksoisnegaatio (--) pakottaa loogiset arvot 1:n ja 0:n arvoihin, ja SUMPRODUCT laskee tuloksen yhteen.

Jos haluat esimerkiksi selvittää, kuinka monta opiskelijaa onnistui kaikissa kokeissa, muokkaa MATCH-kaavaa hakuarvojen (A3:A14) alueelle ja sijoita se ISNAan:

=SUMPRODUCT(--ISNA(MATCH(A3:A14, D2:D9, 0)))

Kaava määrittää, että 9 opiskelijalla ei ole yhtään hylättyä koetta, eli MATCH-funktio palauttaa 9 #N/A-virhettä:

Näin luodaan ja käytetään ISNA-kaavoja Excelissä. Kiitän sinua lukemisesta ja odotan innolla, että tapaamme blogissamme ensi viikolla!

Saatavilla olevat lataukset

Esimerkkejä ISNA-kaavoista (.xlsx-tiedosto)