Danes si bomo ogledali, kako uporabljati VLOOKUP v Excelu s številnimi podrobnimi primeri po korakih. Naučili se boste, kako Vlookup iz drugega lista in drugega delovnega zvezka, iskati z nadomestnimi znaki in še veliko več.

S tem člankom začenjamo serijo člankov o funkciji VLOOKUP, ki je ena izmed najbolj uporabnih funkcij programa Excel in hkrati ena izmed najbolj zapletenih in najmanj razumljivih. Osnove bomo poskušali razložiti v zelo preprostem jeziku, da bi neizkušenemu uporabniku čim bolj olajšali učenje. Navedli bomo tudi primere formul, ki zajemajo najbolj tipične uporabe funkcije VLOOKUP v programu Excel, in poskušali približatijih informativno in zabavno.

Excelova funkcija VLOOKUP

Kaj je VLOOKUP? Najprej je to funkcija programa Excel :) Kaj počne? Poišče vrednost, ki jo določite, in vrne ustrezno vrednost iz drugega stolpca. Bolj tehnično, funkcija VLOOKUP poišče vrednost v prvem stolpcu danega območja in vrne vrednost v isti vrstici iz drugega stolpca.

Pri običajni uporabi Excel VLOOKUP preišče niz podatkov na podlagi edinstvenega identifikatorja in prikaže informacije, povezane s tem edinstvenim identifikatorjem.

Črka "V" pomeni "navpično" in se uporablja za razlikovanje med funkcijo VLOOKUP in funkcijo HLOOKUP, ki išče vrednost v vrstici in ne v stolpcu (H pomeni "vodoravno").

Funkcija je na voljo v vseh različicah Excel 365 do Excel 2007.

Nasvet: V Excelu 365 in Excelu 2021 lahko uporabite funkcijo XLOOKUP, ki je prilagodljivejša in zmogljivejša naslednica funkcije VLOOKUP.

Skladnja VLOOKUP

Sintaksa funkcije VLOOKUP je naslednja:

Kje:

• Lookup_value (obvezno) - je vrednost, ki jo želite poiskati.

  To je lahko vrednost (številka, datum ali besedilo), referenca na celico (referenca na celico, ki vsebuje vrednost iskanja) ali vrednost, ki jo vrne druga funkcija. Za razliko od številk in referenc na celice morajo biti besedilne vrednosti vedno zaprte v "dvojne narekovaje".

• Table_array (obvezno) - je območje celic, v katerih se išče vrednost iskanja in iz katerih se pridobi ujemanje. Funkcija VLOOKUP vedno išče v prvem stolpcu tabele , ki lahko vsebuje različne besedilne vrednosti, številke, datume in logične vrednosti.
• Col_index_num (obvezno) - je številka stolpca, iz katerega se vrne vrednost. Računanje se začne od najbolj levega stolpca v polju tabele, ki je 1.
• Razpon_iskanja (neobvezno) - določa, ali naj se išče približno ali natančno ujemanje:
  • TRUE ali izpuščeno (privzeto) - približno ujemanje. Če ni natančnega ujemanja, formula poišče največjo vrednost, ki je manjša od vrednosti iskanja. Zahteva razvrščanje stolpca iskanja v naraščajočem vrstnem redu.
  • FALSE - natančno ujemanje. Formula išče vrednost, ki je natančno enaka vrednosti iskanja. Če natančnega ujemanja ne najde, se vrne vrednost #N/A.

Osnovna formula VLOOKUP

Tukaj je primer Excelove formule VLOOKUP v najpreprostejši obliki. Oglejte si spodnjo formulo in jo poskusite "prevesti" v slovenščino:

=VLOOKUP("lev", A2:B11, 2, FALSE)

• Prvi argument ( lookup_value ) jasno kaže, da formula išče besedo "lev".
• Drugi argument ( table_array ) je A2:B11. Če upoštevamo, da se iskanje izvaja v najbolj levem stolpcu, lahko zgornjo formulo preberemo še malo naprej: iščemo "lev" v območju A2:A11. Do tu je vse v redu, kajne?
• Tretji argument col_index_num je 2. To pomeni, da želimo vrniti ustrezno vrednost iz stolpca B, ki je drugi v tabeli.
• Četrti argument range_lookup je FALSE, kar pomeni, da iščemo natančno ujemanje.

Z vsemi navedenimi argumenti ne bi smeli imeti težav z branjem celotne formule: poiščite "lev" v A2:A11, poiščite natančno ujemanje in vrnite vrednost iz stolpca B v isti vrstici.

Zaradi priročnosti lahko v neko celico, na primer E1, vnesete vrednost, ki vas zanima, besedilo, ki je "zakodirano", nadomestite s sklicevanjem na celico in v formuli poiščete katero koli vrednost, ki ste jo vnesli v E1:

=VLOOKUP(E1, A2:B11, 2, FALSE)

Ali je še kaj nejasno? Potem poskusite na to pogledati na naslednji način:

Kako narediti Vlookup v Excelu

Pri uporabi formul VLOOKUP v realnih delovnih listih velja naslednje glavno pravilo: polje tabele za zaklepanje z absolutnimi referencami celic (kot so $A$2:$C$11), da se ne spremenijo pri kopiranju formule v druge celice.

Spletna stran vrednost iskanja v večini primerov mora biti relativna referenca (na primer E2) ali pa lahko zaklenete samo koordinato stolpca ($E2). Ko se formula kopira po stolpcu navzdol, se referenca samodejno prilagodi za vsako vrstico.

Če si želite ogledati, kako to deluje v praksi, si oglejte naslednji primer. Naši vzorčni tabeli smo dodali še en stolpec, ki razvršča živali po hitrosti (stolpec A), in želimo poiskati 1., 5. in 10. najhitrejšega sprinterja na svetu. V ta namen v nekatere celice (E2:E4 na spodnji sliki zaslona) vnesite rang iskanja in uporabite naslednje formule:

Iz stolpca B izberite imena živali:

=VLOOKUP($E2, $A$2:$C$11, 2, FALSE)

Izpis hitrosti iz stolpca C:

=VLOOKUP($E2, $A$2:$C$11, 3, FALSE)

V celici F2 in G2 vnesite zgornji formuli, izberite ti celici in povlecite formuli v spodnje vrstice:

Če preučite formulo v spodnji vrstici, boste opazili, da se je sklic na vrednost iskanja prilagodil za določeno vrstico, medtem ko je polje tabele nespremenjeno:

V nadaljevanju boste našli še nekaj koristnih nasvetov, ki vam bodo prihranili veliko glavobola in časa za odpravljanje težav.

Excel VLOOKUP - 5 stvari, ki si jih morate zapomniti!

1. Funkcija VLOOKUP ne more pogledati na svojo levo stran . Vedno išče v skrajni levi stolpec tabelarnega polja in vrne vrednost iz stolpca na desni strani. Če morate izvleči vrednosti z leve strani, uporabite kombinacijo INDEX MATCH (ali INDEX XMATCH v Excelu 365), pri kateri ni pomembna postavitev stolpcev za iskanje in vračanje.
2. Funkcija VLOOKUP ne upošteva velikih in malih črk. , kar pomeni, da se velike in male črke obravnavajo kot enakovredne. Za razlikovanje velikosti črk uporabite formule VLOOKUP, ki upoštevajo velikost črk.
3. Ne pozabite na pomembnost zadnjega parametra. Za približno ujemanje uporabite TRUE, za natančno ujemanje pa FALSE. Za vse podrobnosti glejte VLOOKUP TRUE vs. FALSE.
4. Pri iskanju približnega ujemanja se prepričajte, da so podatki v stolpcu iskanja razvrščeni v naraščajočem vrstnem redu.
5. Če vrednost iskanja ni najdena, se vrne napaka #N/A. Če želite informacije o drugih napakah, glejte poglavje Zakaj Excelov VLOOKUP ne deluje.

Excelovi primeri VLOOKUP

Upam, da vam je navpično iskanje postalo bolj znano. Da bi okrepili svoje znanje, sestavimo še nekaj formul VLOOKUP.

Kako Vlookup iz drugega lista v Excelu

V praksi se funkcija Excel VLOOKUP redko uporablja s podatki v istem delovnem listu. Najpogosteje boste morali ustrezne podatke pridobiti iz drugega delovnega lista.

Če želite Vlookup iz drugega Excelovega lista, vnesite ime delovnega lista, ki mu sledi vzklikanec, v polje table_array argument pred sklicem na območje. Če želite na primer iskati v območju A2:B10 na listu 2, uporabite to formulo:

=VLOOKUP("Product1", List2!A2:B10, 2)

Seveda vam ni treba ročno vnesti imena lista. Preprosto začnite vnašati formulo in ko pride do okenca table_array preklopite na delovni list iskanja in z miško izberite območje.

Tako lahko na primer poiščete vrednost A2 v območju A2:A9 na Cene in vrne ustrezno vrednost iz stolpca C:

=VLOOKUP(A2, Cene!$A$2:$C$9, 3, FALSE)

Opombe:

• Če ime preglednice vsebuje presledki ali nealfabetski znaki. , mora biti zaprt z enojnimi narekovaji, npr. "Cenik"!$A$2:$C$9.
• Če uporabljate formulo VLOOKUP za več celic, ne pozabite zaklepanje table_array z znakom $, na primer $A$2:$C$9.

Kako Vlookup iz drugega delovnega zvezka v Excelu

Če želite Vlookup iz drugega delovnega zvezka programa Excel, pred imenom delovnega lista vpišite ime delovnega zvezka, ki je zaprto v oglatih oklepajih.

Na primer, tukaj je formula za iskanje vrednosti A2 na listu z imenom Cene v Price_List.xlsx delovni zvezek:

=VLOOKUP(A2, [Price_List.xlsx]Cene!$A$2:$C$9, 3, FALSE)

Če ime delovnega zvezka ali delovnega lista vsebuje presledke ali nealfabetske znake, jih morate zapreti v enojne narekovaje, kot sledi:

=VLOOKUP(A2, '[Cenik.xlsx]Cene'!$A$2:$C$9, 3, FALSE)

Formula VLOOKUP, ki se nanaša na drug delovni zvezek, se najlažje ustvari na naslednji način:

1. Odprite obe datoteki.
2. Začnite tipkati formulo, preklopite v drugi delovni zvezek in z miško izberite tabelsko polje.
3. Vnesite preostale argumente in pritisnite tipko Enter, da dokončate formulo.

Rezultat bo podoben spodnji sliki zaslona:

Ko boste zaprite datoteko s preglednico za iskanje, bo formula VLOOKUP še naprej delovala, vendar bo zdaj prikazovala celotno pot do zaprtega delovnega zvezka:

Za več informacij glejte Kako se sklicujete na drug Excelov list ali delovni zvezek.

Kako Vlookup iz poimenovanega območja v drugem listu

Če nameravate isto območje iskanja uporabiti v več formulah, lahko zanj ustvarite poimenovano območje in ime vnesete neposredno v table_array argument.

Če želite ustvariti poimenovano območje, preprosto izberite celice in vnesite želeno ime v polje Ime polje na levi strani vrstice Formula. Za podrobne korake glejte Kako poimenovati območje v Excelu.

V tem primeru smo dali ime Cene_2020 v podatkovne celice (A2:C9) v preglednici za iskanje in dobite to kompaktno formulo:

=VLOOKUP(A2, Cene_2020, 3, FALSE)

Večina imen v Excelu se nanaša na celoten delovni zvezek zato vam pri uporabi poimenovanih obsegov ni treba navesti imena delovnega lista.

Če je poimenovano območje v drug delovni zvezek , pred imenom območja vpišite ime delovnega zvezka, na primer:

=VLOOKUP(A2, 'Cenik.xlsx'!Cene_2020, 3, FALSE)

Takšne formule so veliko bolj razumljive, kajne? Poleg tega je uporaba poimenovanih območij lahko dobra alternativa absolutnim referencam. Ker se poimenovano območje ne spreminja, ste lahko prepričani, da bo polje tabele ostalo zaklenjeno ne glede na to, kam boste premaknili ali kopirali formulo.

Če ste območje iskanja pretvorili v popolnoma funkcionalno Excelovo tabelo, lahko na podlagi imena tabele izvedete Vlookup, npr. Tabela cen_tabel v spodnji formuli:

=VLOOKUP(A2, Tabela cen, 3, FALSE)

Reference tabel, imenovane tudi strukturirane reference, so odporne in imune na številne manipulacije s podatki. Na primer, v tabelo za iskanje lahko odstranite ali dodate nove vrstice, ne da bi vas skrbelo posodabljanje referenc.

Uporaba nadomestnih znakov v formuli VLOOKUP

Tako kot številne druge formule tudi Excelova funkcija VLOOKUP sprejema naslednje nadomestne znake:

• Vprašalni znak (?) za ujemanje poljubnega posameznega znaka.
• Zvezdica (*) za ujemanje poljubnega zaporedja znakov.

Nadomestni znaki so zelo uporabni v številnih situacijah:

• Kadar se ne spomnite natančnega besedila, ki ga iščete.
• Ko iščete besedilni niz, ki je del vsebine celice.
• Če stolpec za iskanje vsebuje vodilne ali končne presledke, si lahko v tem primeru razbijate glavo, da bi ugotovili, zakaj običajna formula ne deluje.

Primer 1. Poiščite besedilo, ki se začne ali konča z določenimi znaki

Predpostavimo, da želite v spodnji zbirki podatkov poiskati določeno stranko. Ne spomnite se njenega priimka, vendar ste prepričani, da se začenja z "ack".

Če želite vrniti priimek iz stolpca A, uporabite naslednjo nadomestno formulo Vlookup:

=VLOOKUP("ack*", $A$2:$B$10, 1, FALSE)

Če želite pridobiti licenčni ključ iz stolpca B, uporabite tega (razlika je le v številki indeksa stolpca):

=VLOOKUP("ack*", $A$2:$B$10, 2, FALSE)

Znani del imena lahko vnesete tudi v neko celico, na primer E1, in kombinirate nadomestni znak s sklicem na celico:

=VLOOKUP(E1& "*", $A$2:$B$10, 1, FALSE)

Spodnja slika zaslona prikazuje rezultate:

Spodaj je še nekaj formul VLOOKUP z nadomestnimi znaki.

Poiščite priimek, ki se konča na "son":

=VLOOKUP("*son", $A$2:$B$10, 1, FALSE)

Izberite ime, ki se začne z "joh" in konča s "son":

=VLOOKUP("joh*son", $A$2:$B$10, 1, FALSE)

Izvlecite 5-znakovni priimek:

=VLOOKUP("?????", $A$2:$B$10, 1, FALSE)

Primer 2. Nadomestni znak VLOOKUP na podlagi vrednosti celice

Iz prejšnjega primera že veste, da je mogoče združiti ampersand (&) in referenco na celico, da nastane niz za iskanje. Če želite poiskati vrednost, ki vsebuje določen(e) znak(e) na katerem koli mestu, vstavite ampersand pred in za referenco na celico.

Recimo, da želite dobiti ime, ki ustreza določenemu licenčnemu ključu, vendar ne poznate celotnega ključa, temveč le nekaj znakov. S ključi v stolpcu A, imeni v stolpcu B in delom ciljnega ključa v E1 lahko na ta način izvedete iskanje z nadomestnim znakom Vlookup:

Izvlecite ključ:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 1, FALSE)

Izvleček imena:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 2, FALSE)

Opombe:

• Če želite, da formula VLOOKUP z nadomestnim znakom deluje pravilno, uporabite natančno ujemanje (zadnji argument je FALSE).
• Če je najdenih več zadetkov, se vrne prvi. .

VLOOKUP TRUE vs FALSE

Zdaj je čas, da si podrobneje ogledamo zadnji argument Excelove funkcije VLOOKUP. range_lookup Odvisno od tega, ali izberete možnost TRUE ali FALSE, lahko vaša formula daje različne rezultate.

Excel VLOOKUP natančno ujemanje (FALSE)

Če range_lookup je nastavljena na FALSE, formula Vlookup išče vrednost, ki je natančno enaka vrednosti iskanja. Če sta najdeni dve ali več ujemanj, se vrne prvo. Če ni najdeno natančno ujemanje, se pojavi napaka #N/A.

Približno ujemanje Excelovega VLOOKUP (TRUE)

Če range_lookup je nastavljena na TRUE ali izpuščena (privzeto), formula poišče najbližje ujemanje. Natančneje, najprej poišče natančno ujemanje, in če ga ne najde, poišče naslednjo največjo vrednost, ki je manjša od vrednosti iskanja.

Približno ujemanje Vlookup deluje z naslednjimi opozorili:

• Stolpec za iskanje mora biti razvrščen v naraščajoči vrstni red , od najmanjše do največje, sicer se lahko zgodi, da ne bo mogoče najti pravilne vrednosti.
• Če je vrednost iskanja manjša od najmanjše vrednosti v polju iskanja, se vrne napaka #N/A.

Naslednji primeri vam bodo pomagali bolje razumeti razliko med natančnim in približnim iskanjem ter kdaj je najbolje uporabiti posamezno formulo.

Primer 1. Kako narediti natančno ujemanje Vlookup

Če želite poiskati natančno ujemanje, v zadnji argument vpišite FALSE.

Za ta primer vzemimo tabelo hitrosti živali, zamenjajmo stolpce in poskušajmo najti živali, ki lahko tečejo 80, 50 in 30 milj na uro. Z vrednostmi iskanja v D2, D3 in D4 vnesite spodnjo formulo v E2 in jo nato kopirajte v dve dodatni celici:

=VLOOKUP(D2, $A$2:$B$12, 2, FALSE)

Kot lahko vidite, formula vrne "Lion" v E3, ker se jih na uro izvede natanko 50. Za drugi dve vrednosti iskanja ni mogoče najti natančnega ujemanja, zato se pojavijo napake #N/A.

Primer 2. Kako uporabiti Vlookup za približno ujemanje

Če želite poiskati približno ujemanje, morate storiti dve bistveni stvari:

• Razvrsti prvi stolpec table_array od najmanjšega do največjega.
• Uporabite TRUE za range_lookup ali pa ga izpustite.

Razvrstitev stolpca iskanja je zelo pomembna, saj funkcija VLOOKUP preneha iskati takoj, ko najde bližnje ujemanje, manjše od vrednosti iskanja. Če podatki niso pravilno razvrščeni, lahko pride do zelo čudnih rezultatov ali številnih napak #N/A.

Za naše vzorčne podatke je približna formula za ujemanje Vlookup naslednja:

=VLOOKUP(D2, $A$2:$B$12, 2, TRUE)

In vrne naslednje rezultate:

• Za vrednost iskanja "80" se vrne "Cheetah", ker je njegova hitrost (70) najbližje ujemanje, ki je manjše od vrednosti iskanja.
• Za vrednost iskanja "50" se vrne natančno ujemanje (Lion).
• Za vrednost iskanja "30" se vrne napaka #N/A, ker je vrednost iskanja manjša od najmanjše vrednosti v stolpcu iskanja.

Posebna orodja za Vlookup v Excelu

VLOOKUP je nedvomno ena od najmočnejših in najuporabnejših funkcij programa Excel, vendar je tudi ena od najbolj zmedenih. Da bi bila krivulja učenja manj strma, izkušnja pa prijetnejša, smo v naš Ultimate Suite za Excel vključili nekaj orodij, ki prihranijo čas.

Čarovnik VLOOKUP - enostaven način pisanja zapletenih formul

Interaktivni čarovnik VLOOKUP Wizard vas bo vodil skozi možnosti konfiguracije, da bo sestavil popolno formulo za merila, ki jih določite. Glede na strukturo podatkov bo uporabil standardno funkcijo VLOOKUP ali formulo INDEX MATCH, ki lahko povleče vrednosti z leve strani.

Če želite dobiti formulo po meri, morate storiti naslednje:

1. Zaženite čarovnika VLOOKUP.

1. Izberite glavno tabelo in tabelo za iskanje.
2. Določite naslednje stolpce (v mnogih primerih so izbrani samodejno):
   • Ključni stolpec - stolpec v glavni tabeli, ki vsebuje vrednosti, ki jih želite poiskati.
   • Stolpec za iskanje - stolpec, proti kateremu je treba pogledati.
   • Vrniti stolpec - stolpec, iz katerega želite pridobiti vrednosti.
3. Kliknite na Vstavite gumb.

Naslednji primeri prikazujejo delovanje čarovnika.

Standardni pregledovalnik Vlookup

Ko je stolpec za iskanje ( Žival ) je skrajni levi stolpec v preglednici iskanja, se vstavi običajna formula VLOOKUP za natančno ujemanje:

Vlookup na levo

Ko je stolpec za iskanje ( Žival ) je na desni strani stolpca za vračanje ( Hitrost ), čarovnik vstavi formulo INDEX MATCH za pregledovanje od desne proti levi:

Dodaten bonus! Zaradi pametne uporabe referenc celic lahko formule kopirate ali premaknete v kateri koli stolpec, ne da bi vam bilo treba posodobiti reference.

Združitev dveh tabel - alternativa brez formul za Excelov VLOOKUP

Če so vaše datoteke Excel izjemno velike in zapletene, rok za dokončanje projekta se bliža in iščete nekoga, ki bi vam lahko pomagal, preizkusite čarovnika za združevanje tabel.

To orodje je naša vizualna alternativa Excelovi funkciji VLOOKUP, ki deluje na ta način:

1. Izberite glavno mizo.
2. Izberite preglednico za iskanje.
3. Kot edinstvene identifikatorje izberite enega ali več skupnih stolpcev.
4. Določite, katere stolpce želite posodobiti.
5. Po želji lahko izberete stolpce, ki jih želite dodati.
6. Čarovniku za združevanje tabel omogočite nekaj sekund za obdelavo... in uživajte v rezultatih :)

To je način uporabe VLOOKUP v Excelu na osnovni ravni. V naslednjem delu našega vodnika bomo obravnavali napredne primere VLOOKUP, ki vas bodo naučili, kako Vlookup več meril, vrniti vsa ujemanja ali N-ti pojav, izvesti dvojni Vlookup, poiskati več listov z eno samo formulo in še več. Zahvaljujem se vam za branje in upam, da se vidimo naslednji teden!

Razpoložljivi prenosi

Primeri formul Excel VLOOKUP (.xlsx datoteka)

Ultimate Suite 14-dnevna popolnoma funkcionalna različica (.exe datoteka)