Dnes se podíváme na to, jak používat VLOOKUP v Excelu, a to na mnoha podrobných příkladech krok za krokem. Dozvíte se, jak VLOOKUP použít z jiného listu a jiného sešitu, jak vyhledávat pomocí zástupných znaků a mnoho dalšího.

Tímto článkem začínáme seriál věnovaný funkci VLOOKUP, jedné z nejužitečnějších funkcí Excelu a zároveň jedné z nejsložitějších a nejméně srozumitelných. Pokusíme se vysvětlit základy velmi jednoduchým jazykem, abychom nezkušenému uživateli co nejvíce usnadnili učení. Uvedeme také příklady vzorců, které pokrývají nejtypičtější použití funkce VLOOKUP v Excelu, a pokusíme se přiblížit, jak se VLOOKUPje poučné i zábavné.

Funkce VLOOKUP aplikace Excel

Co je to VLOOKUP? Začněme tím, že je to funkce Excelu :) Co dělá? Vyhledá zadanou hodnotu a vrátí odpovídající hodnotu z jiného sloupce. Odborněji řečeno, funkce VLOOKUP vyhledá hodnotu v prvním sloupci daného rozsahu a vrátí hodnotu ve stejném řádku z jiného sloupce.

Při běžném použití prohledává Excel VLOOKUP soubor dat na základě jedinečného identifikátoru a přináší informace spojené s tímto jedinečným identifikátorem.

Písmeno "V" znamená "vertikální" a používá se k odlišení funkce VLOOKUP od funkce HLOOKUP, která vyhledává hodnotu v řádku, nikoli ve sloupci (H znamená "horizontální").

Funkce je k dispozici ve všech verzích aplikace Excel 365 až Excel 2007.

Tip: V aplikacích Excel 365 a Excel 2021 můžete používat funkci XLOOKUP, která je flexibilnějším a výkonnějším nástupcem funkce VLOOKUP.

Syntaxe VLOOKUP

Syntaxe funkce VLOOKUP je následující:

Kde:

• Lookup_value (povinné) - je hodnota, která se má vyhledat.

  Může to být hodnota (číslo, datum nebo text), odkaz na buňku (odkaz na buňku obsahující vyhledávací hodnotu) nebo hodnota vrácená jinou funkcí. Na rozdíl od čísel a odkazů na buňky by textové hodnoty měly být vždy uzavřeny ve dvojitých uvozovkách.

• Table_array (povinné) - je rozsah buněk, ve kterých se má hledat hodnota vyhledávání a ze kterých se má získat shoda. Funkce VLOOKUP hledá vždy v prvním sloupci pole tabulky , které mohou obsahovat různé textové hodnoty, čísla, data a logické hodnoty.
• Col_index_num (povinné) - je číslo sloupce, ze kterého se má vrátit hodnota. Počítání začíná od nejlevějšího sloupce v poli tabulky, což je 1.
• Range_lookup (nepovinné) - určuje, zda se má hledat přibližná nebo přesná shoda:
  • TRUE nebo vynecháno (výchozí) - přibližná shoda. Pokud není nalezena přesná shoda, vzorec hledá největší hodnotu, která je menší než hodnota vyhledávání. Vyžaduje seřazení sloupce vyhledávání vzestupně.
  • FALSE - přesná shoda. Vzorec hledá hodnotu, která se přesně rovná hodnotě vyhledávání. Pokud není nalezena přesná shoda, je vrácena hodnota #N/A.

Základní vzorec VLOOKUP

Zde je příklad vzorce Excel VLOOKUP v jeho nejjednodušší podobě. Podívejte se prosím na níže uvedený vzorec a pokuste se ho "přeložit" do češtiny:

=VLOOKUP("lev", A2:B11, 2, FALSE)

• 1. argument ( lookup_value ) jasně naznačuje, že vzorec vyhledává slovo "lev".
• Druhý argument ( table_array ) je A2:B11. Vzhledem k tomu, že hledání se provádí v levém sloupci, můžete výše uvedený vzorec číst o něco dále: hledat "lev" v rozsahu A2:A11. Zatím je to dobré, že?
• Třetí argument col_index_num je 2. To znamená, že chceme vrátit odpovídající hodnotu ze sloupce B, který je druhý v poli tabulky.
• Čtvrtý argument range_lookup je FALSE, což znamená, že hledáme přesnou shodu.

Po zadání všech argumentů by neměl být problém přečíst celý vzorec: vyhledat "lev" v A2:A11, najít přesnou shodu a vrátit hodnotu ze sloupce B ve stejném řádku.

Pro větší pohodlí můžete zadat hodnotu, která vás zajímá, do některé buňky, například E1, nahradit "natvrdo" zadaný text odkazem na buňku a nechat vzorec vyhledat jakoukoli hodnotu zadanou do E1:

=VLOOKUP(E1, A2:B11, 2, FALSE)

Zůstává vám něco nejasné? Zkuste se na to podívat takto:

Jak provést Vlookup v aplikaci Excel

Při používání vzorců VLOOKUP v reálných pracovních listech platí toto hlavní pravidlo: pole zamykací tabulky s absolutními odkazy na buňky (například $A$2:$C$11), aby se při kopírování vzorce do jiných buněk nezměnil.

Na stránkách vyhledávací hodnota ve většině případů by měl být relativní odkaz (jako E2) nebo můžete uzamknout pouze souřadnici sloupce ($E2). Když se vzorec zkopíruje dolů do sloupce, odkaz se automaticky upraví pro každý řádek.

Abyste viděli, jak to funguje v praxi, podívejte se na následující příklad. Do naší vzorové tabulky jsme přidali ještě jeden sloupec, který řadí zvířata podle rychlosti (sloupec A), a chceme zjistit 1., 5. a 10. nejrychlejšího sprintera na světě. Za tímto účelem zadejte do některých buněk (E2:E4 na obrázku níže) vyhledávací pořadí a použijte následující vzorce:

Vytažení názvů zvířat ze sloupce B:

=VLOOKUP($E2, $A$2:$C$11, 2, FALSE)

Výběr rychlosti ze sloupce C:

=VLOOKUP($E2, $A$2:$C$11, 3, FALSE)

Zadejte výše uvedené vzorce do buněk F2 a G2, vyberte tyto buňky a přetáhněte vzorce do následujících řádků:

Pokud prozkoumáte vzorec v nižším řádku, zjistíte, že odkaz na hodnotu vyhledávání se pro tento konkrétní řádek upravil, zatímco pole tabulky se nezměnilo:

Níže najdete několik dalších užitečných tipů, které vám ušetří spoustu bolesti hlavy a času na řešení problémů.

Excel VLOOKUP - 5 věcí, které je třeba si zapamatovat!

1. Funkce VLOOKUP se nemůže podívat na svou levou stranu . Vždy hledá v nejlevější sloupec pole tabulky a vrací hodnotu ze sloupce vpravo. Pokud potřebujete vytáhnout hodnoty zleva, použijte kombinaci INDEX MATCH (nebo INDEX XMATCH v Excelu 365), která se nestará o umístění vyhledávacích a návratových sloupců.
2. Funkce VLOOKUP nerozlišuje velká a malá písmena. , což znamená, že velká a malá písmena jsou považována za rovnocenná. Chcete-li rozlišit velikost písmen, použijte vzorce VLOOKUP, které rozlišují velikost písmen.
3. Nezapomeňte na důležitost posledního parametru. Pro přibližnou shodu použijte TRUE a pro přesnou shodu FALSE. Podrobné informace naleznete v části VLOOKUP TRUE vs. FALSE.
4. Při hledání přibližné shody se ujistěte, že jsou data ve sloupci vyhledávání seřazena vzestupně.
5. Pokud není hodnota vyhledávání nalezena, je vrácena chyba #N/A. Informace o dalších chybách naleznete v části Proč nefunguje Excel VLOOKUP.

Příklady VLOOKUP aplikace Excel

Doufám, že vám vertikální vyhledávání začíná připadat o něco známější. Abychom vaše znalosti upevnili, sestavíme si několik dalších vzorců VLOOKUP.

Jak v aplikaci Excel provést Vlookup z jiného listu

V praxi se funkce VLOOKUP v aplikaci Excel používá jen zřídka s daty na stejném listu. Nejčastěji budete muset odpovídající data vytáhnout z jiného listu.

Chcete-li vyhledávat z jiného listu aplikace Excel, vložte název listu následovaný vykřičníkem do pole table_array například pro vyhledávání v rozsahu A2:B10 na listu 2 použijte tento vzorec:

=VLOOKUP("Product1", List2!A2:B10, 2)

Název listu samozřejmě nemusíte zadávat ručně. Jednoduše začněte psát vzorec, a když dojde na jeho table_array přepněte na list vyhledávání a vyberte rozsah pomocí myši.

Takto můžete například vyhledat hodnotu A2 v rozsahu A2:A9 na obrazovce Ceny a vrátit odpovídající hodnotu ze sloupce C:

=VLOOKUP(A2, Ceny!$A$2:$C$9, 3, FALSE)

Poznámky:

• Pokud název tabulky obsahuje mezery nebo jiné než abecední znaky , musí být uzavřen v jednoduchých uvozovkách, např. "Ceník"!$A$2:$C$9.
• V případě, že používáte vzorec VLOOKUP pro více buněk, nezapomeňte. lock table_array se znakem $, například $A$2:$C$9.

Jak v aplikaci Excel použít funkci Vlookup z jiného sešitu

Chcete-li vyhledávat z jiného sešitu aplikace Excel, vložte před název listu název sešitu uzavřený do hranatých závorek.

Například zde je vzorec pro vyhledání hodnoty A2 na listu s názvem Ceny v Price_List.xlsx pracovní sešit:

=VLOOKUP(A2, [Price_List.xlsx]Ceny!$A$2:$C$9, 3, FALSE)

Pokud název sešitu nebo listu obsahuje mezery nebo jiné než abecední znaky, měli byste je uzavřít do jednoduchých uvozovek, jako je tento příklad:

=VLOOKUP(A2, '[Ceník.xlsx]Ceny'!$A$2:$C$9, 3, FALSE)

Nejjednodušší způsob, jak vytvořit vzorec VLOOKUP, který odkazuje na jiný sešit, je následující:

1. Otevřete oba soubory.
2. Začněte psát vzorec, přepněte se do druhého sešitu a vyberte pole tabulek pomocí myši.
3. Zadejte zbývající argumenty a stisknutím klávesy Enter vzorec dokončete.

Výsledek bude vypadat jako na obrázku níže:

Jakmile zavřít soubor s vyhledávací tabulkou, bude vzorec VLOOKUP fungovat i nadále, ale nyní bude zobrazovat celou cestu k uzavřenému sešitu:

Další informace naleznete v části Jak odkázat na jiný list nebo sešit aplikace Excel.

Jak vyhledávat z pojmenovaného rozsahu v jiném listu

V případě, že plánujete používat stejný rozsah vyhledávání v mnoha vzorcích, můžete pro něj vytvořit pojmenovaný rozsah a zadat jeho název přímo do pole table_array argument.

Chcete-li vytvořit pojmenovaný rozsah, jednoduše vyberte buňky a zadejte požadovaný název do pole Název pole vlevo od panelu vzorců. Podrobný postup naleznete v části Jak pojmenovat rozsah v aplikaci Excel.

Pro tento příklad jsme zadali název Ceny_2020 do datových buněk (A2:C9) v listu vyhledávání a získáte tento kompaktní vzorec:

=VLOOKUP(A2, Prices_2020, 3, FALSE)

Většina názvů v aplikaci Excel se vztahuje na celý sešit , takže při použití pojmenovaných rozsahů nemusíte zadávat název pracovního listu.

Pokud je pojmenovaný rozsah v další sešit , vložte název sešitu před název rozsahu, například:

=VLOOKUP(A2, 'Price List.xlsx'!Prices_2020, 3, FALSE)

Takové vzorce jsou mnohem srozumitelnější, že? Kromě toho může být použití pojmenovaných rozsahů dobrou alternativou k absolutním odkazům. Protože se pojmenovaný rozsah nemění, můžete si být jisti, že pole tabulky zůstane uzamčeno bez ohledu na to, kam vzorec přesunete nebo zkopírujete.

Pokud jste převedli rozsah vyhledávání na plně funkční tabulku aplikace Excel, můžete provést Vlookup na základě názvu tabulky, např. Price_table v následujícím vzorci:

=VLOOKUP(A2, Price_table, 3, FALSE)

Reference na tabulky, nazývané také strukturované reference, jsou odolné a imunní vůči mnoha manipulacím s daty. Můžete například odebírat nebo přidávat nové řádky do vyhledávací tabulky, aniž byste se museli starat o aktualizaci referencí.

Použití zástupných znaků ve vzorci VLOOKUP

Stejně jako mnoho jiných vzorců i funkce VLOOKUP aplikace Excel akceptuje následující zástupné znaky:

• Otazník (?) pro porovnání libovolného jednotlivého znaku.
• Hvězdička (*) pro přiřazení libovolné posloupnosti znaků.

Zástupné znaky jsou v mnoha situacích opravdu užitečné:

• Když si nepamatujete přesný text, který hledáte.
• Pokud hledáte textový řetězec, který je součástí obsahu buňky.
• Pokud sloupec pro vyhledávání obsahuje počáteční nebo koncové mezery. V takovém případě si můžete lámat hlavu, proč běžný vzorec nefunguje.

Příklad 1. Vyhledání textu začínajícího nebo končícího určitými znaky

Předpokládejme, že chcete najít určitého zákazníka v níže uvedené databázi. Nepamatujete si jeho příjmení, ale jste si jisti, že začíná na "ack".

Chcete-li vrátit příjmení ze sloupce A, použijte následující vzorec Vlookup se zástupným znakem:

=VLOOKUP("ack*", $A$2:$B$10, 1, FALSE)

Chcete-li získat licenční klíč ze sloupce B, použijte tento klíč (rozdíl je pouze v indexovém čísle sloupce):

=VLOOKUP("ack*", $A$2:$B$10, 2, FALSE)

Můžete také zadat známou část názvu do některé buňky, například E1, a kombinovat zástupný znak s odkazem na buňku:

=VLOOKUP(E1& "*", $A$2:$B$10, 1, FALSE)

Níže uvedený snímek obrazovky ukazuje výsledky:

Níže je uvedeno několik dalších vzorců VLOOKUP se zástupnými znaky.

Najděte příjmení končící na "son":

=VLOOKUP("*son", $A$2:$B$10, 1, FALSE)

Získejte jméno, které začíná na "joh" a končí na "son":

=VLOOKUP("joh*son", $A$2:$B$10, 1, FALSE)

Vytáhněte pětimístné příjmení:

=VLOOKUP("?????", $A$2:$B$10, 1, FALSE)

Příklad 2. Zástupný znak VLOOKUP na základě hodnoty buňky

Z předchozího příkladu již víte, že je možné spojit ampersand (&) a odkaz na buňku a vytvořit tak vyhledávací řetězec. Chcete-li najít hodnotu, která obsahuje daný znak (znaky) na libovolné pozici, vložte ampersand před a za odkaz na buňku.

Řekněme, že si přejete získat název odpovídající určitému licenčnímu klíči, ale neznáte celý klíč, pouze několik znaků. S klíči ve sloupci A, názvy ve sloupci B a částí cílového klíče v E1 můžete tímto způsobem provést Vlookup se zástupnými znaky:

Vyjměte klíč:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 1, FALSE)

Výpis názvu:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 2, FALSE)

Poznámky:

• Aby vzorec VLOOKUP se zástupným znakem fungoval správně, použijte přesnou shodu (posledním argumentem je FALSE).
• Pokud je nalezena více než jedna shoda, je vrácena první z nich. .

VLOOKUP TRUE vs FALSE

A nyní je čas podívat se blíže na poslední argument funkce VLOOKUP aplikace Excel. Ačkoli je nepovinný, je tento argument range_lookup V závislosti na tom, zda zvolíte hodnotu TRUE nebo FALSE, může vzorec poskytovat různé výsledky.

Excel VLOOKUP přesná shoda (FALSE)

Pokud range_lookup je nastavena na FALSE, hledá vzorec Vlookup hodnotu, která se přesně rovná hodnotě vyhledávání. Pokud jsou nalezeny dvě nebo více shod, je vrácena 1. z nich. Pokud není nalezena přesná shoda, dojde k chybě #N/A.

Přibližná shoda Excel VLOOKUP (TRUE)

Pokud range_lookup je nastavena na hodnotu TRUE nebo vynechána (výchozí hodnota), vzorec vyhledá nejbližší shodu. Přesněji řečeno, nejprve hledá přesnou shodu, a pokud ji nenajde, hledá další největší hodnotu, která je menší než hodnota vyhledávání.

Přibližná shoda Vlookup funguje s následujícími výhradami:

• Sloupec pro vyhledávání musí být seřazen v. vzestupné pořadí , od nejmenší po největší, jinak nemusí být nalezena správná hodnota.
• Pokud je hodnota vyhledávání menší než nejmenší hodnota v poli vyhledávání, je vrácena chyba #N/A.

Následující příklady vám pomohou lépe porozumět rozdílu mezi přesnou a přibližnou shodou a tomu, kdy je nejlepší použít jednotlivé vzorce.

Příklad 1. Jak provést přesnou shodu Vlookup

Chcete-li vyhledat přesnou shodu, stačí do posledního argumentu zadat FALSE.

Pro tento příklad vezměme tabulku rychlosti zvířat, prohoďme sloupce a zkusme najít zvířata, která dokáží běžet rychlostí 80, 50 a 30 mil za hodinu. S vyhledávacími hodnotami v buňkách D2, D3 a D4 zadejte do buňky E2 níže uvedený vzorec a poté jej zkopírujte dolů do dalších dvou buněk:

=VLOOKUP(D2, $A$2:$B$12, 2, FALSE)

Jak vidíte, vzorec vrací v položce E3 hodnotu "Lion", protože jich za hodinu proběhne přesně 50. Pro ostatní dvě vyhledávané hodnoty není nalezena přesná shoda a objeví se chyby #N/A.

Příklad 2. Jak provést Vlookup pro přibližnou shodu

Chcete-li vyhledat přibližnou shodu, musíte provést dvě základní věci:

• Seřadit první sloupec table_array od nejmenšího po největší.
• Použijte TRUE pro range_lookup nebo jej vynechat.

Seřazení sloupce vyhledávání je velmi důležité, protože funkce VLOOKUP přestane hledat, jakmile najde blízkou shodu menší než hodnota vyhledávání. Pokud nejsou data správně seřazena, může dojít k opravdu podivným výsledkům nebo k hromadě chyb #N/A.

Pro naše vzorová data je přibližný vzorec shody Vlookup následující:

=VLOOKUP(D2, $A$2:$B$12, 2, TRUE)

A vrátí následující výsledky:

• Pro hodnotu vyhledávání "80" je vrácena hodnota "Cheetah", protože její rychlost (70) je nejbližší shodou, která je menší než hodnota vyhledávání.
• Pro hodnotu vyhledávání "50" je vrácena přesná shoda (Lion).
• Pro hodnotu vyhledávání "30" je vrácena chyba #N/A, protože hodnota vyhledávání je menší než nejmenší hodnota ve sloupci vyhledávání.

Speciální nástroje pro Vlookup v aplikaci Excel

VLOOKUP je bezpochyby jednou z nejmocnějších a nejužitečnějších funkcí Excelu, ale také jednou z nejzmatenějších. Aby křivka učení nebyla tak strmá a zkušenost s ní byla příjemnější, zařadili jsme do naší sady Ultimate Suite for Excel několik nástrojů, které vám ušetří čas.

Průvodce VLOOKUP - snadný způsob zápisu složitých vzorců

Interaktivní průvodce VLOOKUP vás provede možnostmi konfigurace a sestaví dokonalý vzorec pro zadaná kritéria. V závislosti na struktuře dat použije standardní funkci VLOOKUP nebo vzorec INDEX MATCH, který může vybírat hodnoty zleva.

Chcete-li získat vzorec na míru, musíte udělat následující kroky:

1. Spusťte Průvodce VLOOKUP.

1. Vyberte hlavní tabulku a vyhledávací tabulku.
2. Zadejte následující sloupce (v mnoha případech se vyberou automaticky):
   • Klíčový sloupec - sloupec v hlavní tabulce obsahující hodnoty, které chcete vyhledat.
   • Sloupec vyhledávání - sloupek, proti kterému se má dívat.
   • Návratový sloupec - sloupec, ze kterého se mají načítat hodnoty.
3. Klikněte na Vložte tlačítko.

Následující příklady ukazují průvodce v akci.

Standardní vyhledávání

Pokud je sloupec vyhledávání ( Zvířata ) je nejlevější sloupec v tabulce vyhledávání, vloží se běžný vzorec VLOOKUP pro přesnou shodu:

Vlookup vlevo

Pokud je sloupec vyhledávání ( Zvířata ) je na pravé straně sloupce pro návrat ( Rychlost ), průvodce vloží vzorec INDEX MATCH do Vlookup zprava doleva:

Bonus navíc! Díky chytrému použití odkazů na buňky lze vzorce kopírovat nebo přesouvat do libovolného sloupce, aniž byste museli aktualizovat odkazy.

Sloučení dvou tabulek - alternativa k Excelu VLOOKUP bez vzorců

Pokud jsou vaše soubory aplikace Excel nesmírně velké a složité, termín dokončení projektu se blíží a hledáte někoho, kdo vám podá pomocnou ruku, vyzkoušejte Průvodce sloučením tabulek.

Tento nástroj je naší vizuální a bezstresovou alternativou k funkci VLOOKUP aplikace Excel, která funguje tímto způsobem:

1. Vyberte hlavní stůl.
2. Vyberte vyhledávací tabulku.
3. Jako jedinečný identifikátor (identifikátory) zvolte jeden nebo několik společných sloupců.
4. Zadejte, které sloupce se mají aktualizovat.
5. Volitelně vyberte sloupce, které chcete přidat.
6. Nechte Průvodce sloučením tabulek několik sekund na zpracování... a vychutnejte si výsledky :)

To je návod, jak používat VLOOKUP v Excelu na základní úrovni. V příští části našeho tutoriálu probereme pokročilé příklady VLOOKUP, které vás naučí, jak VLOOKUP používat pro více kritérií, vracet všechny shody nebo N-tý výskyt, provádět dvojitý VLOOKUP, vyhledávat ve více listech pomocí jednoho vzorce a další. Děkuji vám za přečtení a doufám, že se uvidíme příští týden!

Dostupné soubory ke stažení

Příklady vzorců Excel VLOOKUP (.xlsx soubor)

Ultimate Suite 14denní plně funkční verze (.exe soubor)