Vandaag bekijken we hoe u VLOOKUP in Excel kunt gebruiken, met veel gedetailleerde stap-voor-stap voorbeelden. U leert hoe u een VLOOKUP kunt gebruiken vanuit een ander blad en een andere werkmap, zoeken met jokertekens, en nog veel meer.

Dit artikel begint met een serie over VLOOKUP, één van de meest nuttige Excel functies en tegelijkertijd één van de meest ingewikkelde en minst begrepen functies. We zullen proberen de basisprincipes uit te leggen in een zeer duidelijke taal om de leercurve voor een onervaren gebruiker zo gemakkelijk mogelijk te maken. We zullen ook formulevoorbeelden geven die de meest typische toepassingen van VLOOKUP in Excel behandelen, en proberen omze zowel informatief als leuk.

Excel VLOOKUP functie

Wat is VLOOKUP? Om te beginnen is het een Excel-functie :) Wat doet het? Het zoekt de waarde die u opgeeft en retourneert een overeenkomende waarde uit een andere kolom. Technisch gezien zoekt de VLOOKUP-functie een waarde op in de eerste kolom van een bepaald bereik en retourneert een waarde in dezelfde rij uit een andere kolom.

In zijn algemeen gebruik doorzoekt Excel VLOOKUP uw gegevensverzameling op basis van de unieke identificatiecode en brengt u een stuk informatie in verband met die unieke identificatiecode.

De letter "V" staat voor "verticaal" en wordt gebruikt om VLOOKUP te onderscheiden van de HLOOKUP-functie die een waarde opzoekt in een rij in plaats van in een kolom (H staat voor "horizontaal").

De functie is beschikbaar in alle versies van Excel 365 tot en met Excel 2007.

Tip. In Excel 365 en Excel 2021 kunt u de functie XLOOKUP gebruiken, een flexibelere en krachtigere opvolger van VLOOKUP.

VLOOKUP syntaxis

De syntaxis voor de VLOOKUP-functie is als volgt:

Waar:

• Lookup_value (vereist) - is de waarde waarnaar moet worden gezocht.

  Dit kan een waarde zijn (getal, datum of tekst), een celverwijzing (verwijzing naar een cel die een opzoekwaarde bevat), of de waarde die door een andere functie wordt geretourneerd. In tegenstelling tot getallen en celverwijzingen moeten tekstwaarden altijd tussen "dubbele aanhalingstekens" staan.

• Tabel_array (vereist) - is het cellenbereik waarin moet worden gezocht naar de opzoekwaarde en waaruit een overeenkomst moet worden gehaald. Het De VLOOKUP-functie zoekt altijd in de eerste kolom van de tabelreeks die verschillende tekstwaarden, getallen, datums en logische waarden kan bevatten.
• Col_index_num (vereist) - is het nummer van de kolom waarvan een waarde moet worden teruggegeven. Het tellen begint bij de meest linkse kolom in de tabel-array, die 1 is.
• Range_lookup (facultatief) - bepaalt of moet worden gezocht naar een approximatieve of exacte overeenkomst:
  • TRUE of weggelaten (standaard) - benaderende overeenkomst. Als geen exacte overeenkomst wordt gevonden, zoekt de formule naar de grootste waarde die kleiner is dan de opzoekwaarde. Vereist dat de opzoekkolom in oplopende volgorde wordt gesorteerd.
  • FALSE - exacte overeenkomst. De formule zoekt naar een waarde die precies gelijk is aan de opzoekwaarde. Als geen exacte overeenkomst wordt gevonden, wordt een #N/A-waarde geretourneerd.

Basisformule VLOOKUP

Hier volgt een voorbeeld van de Excel VLOOKUP-formule in zijn eenvoudigste vorm. Bekijk de onderstaande formule en probeer deze te "vertalen" naar het Engels:

=VLOOKUP("leeuw", A2:B11, 2, FALSE)

• Het 1e argument ( lookup_waarde ) geeft duidelijk aan dat de formule het woord "leeuw" opzoekt.
• Het 2e argument ( tabel_array ) is A2:B11. In gedachten houdend dat de zoekopdracht wordt uitgevoerd in de meest linkse kolom, kunt u de bovenstaande formule een beetje verder lezen: zoek naar "leeuw" in het bereik A2:A11. Tot zover alles goed, toch?
• Het 3e argument col_index_num is 2. Dat betekent dat we een overeenkomstige waarde willen teruggeven uit kolom B, die tweede is in de tabel-array.
• Het 4e argument range_lookup is FALSE, wat aangeeft dat we zoeken naar een exacte overeenkomst.

Nu alle argumenten vastliggen, moet het geen probleem zijn de hele formule af te lezen: zoek naar "leeuw" in A2:A11, zoek een exacte match, en geef een waarde terug uit kolom B in dezelfde rij.

Gemakshalve kunt u de gewenste waarde in een cel typen, bijvoorbeeld E1, de "hardcoded" tekst vervangen door de celverwijzing, en de formule elke waarde laten opzoeken die u in E1 invoert:

=VLOOKUP(E1, A2:B11, 2, FALSE)

Blijft er iets onduidelijk? Probeer het dan zo te bekijken:

Hoe doe je een Vlookup in Excel?

Bij het gebruik van VLOOKUP-formules in reële werkbladen geldt de volgende vuistregel: array van vergrendeltabellen met absolute celverwijzingen (zoals $A$2:$C$11) om te voorkomen dat deze verandert bij het kopiëren van een formule naar andere cellen.

De opzoekwaarde moet in de meeste gevallen een relatieve verwijzing zijn (zoals E2) of u kunt alleen de kolomcoördinaat vergrendelen ($E2). Wanneer de formule naar beneden in de kolom wordt gekopieerd, wordt de verwijzing automatisch voor elke rij aangepast.

Om te zien hoe het in de praktijk werkt, kunnen we het volgende voorbeeld bekijken. Aan onze voorbeeldtabel hebben we nog een kolom toegevoegd die de dieren rangschikt volgens snelheid (kolom A) en we willen de 1e, 5e en 10e snelste sprinter ter wereld vinden. Hiervoor voert u de lookup-rangen in enkele cellen in (E2:E4 in de schermafbeelding hieronder), en gebruikt u de volgende formules:

Om de dierennamen uit kolom B te halen:

=VLOOKUP($E2, $A$2:$C$11, 2, FALSE)

Om de snelheid uit kolom C te halen:

=VLOOKUP($E2, $A$2:$C$11, 3, FALSE)

Voer de bovenstaande formules in de cellen F2 en G2 in, selecteer die cellen, en sleep de formules naar de onderstaande rijen:

Als u de formule in een lagere rij onderzoekt, zult u merken dat de verwijzing naar de opzoekwaarde is aangepast voor die specifieke rij, terwijl de tabelarray ongewijzigd is:

Hieronder vindt u nog enkele nuttige tips die u veel hoofdpijn en tijd voor het oplossen van problemen zullen besparen.

Excel VLOOKUP - 5 dingen om te onthouden!

1. De VLOOKUP-functie kan niet kijken naar zijn linker Het zoekt altijd in de meest linkse kolom Als u waarden van links moet halen, gebruik dan de combinatie INDEX MATCH (of INDEX XMATCH in Excel 365) die zich niets aantrekt van de positionering van de opzoek- en retourkolommen.
2. De VLOOKUP-functie is hoofdletterongevoelig. Dit betekent dat hoofdletters en kleine letters als gelijkwaardig worden behandeld. Om onderscheid te maken tussen hoofdletters en kleine letters kunt u hoofdlettergevoelige VLOOKUP-formules gebruiken.
3. Denk aan het belang van de laatste parameter. Gebruik TRUE voor een benaderende overeenkomst en FALSE voor een exacte overeenkomst. Voor volledige details, zie VLOOKUP TRUE vs. FALSE.
4. Zorg ervoor dat de gegevens in de opzoekkolom in oplopende volgorde zijn gesorteerd.
5. Indien de opzoekwaarde niet wordt gevonden, wordt een #N/A fout geretourneerd. Voor informatie over andere fouten, zie Waarom Excel VLOOKUP niet werkt.

Excel VLOOKUP voorbeelden

Ik hoop dat verticaal opzoeken u wat bekender begint te lijken. Om uw kennis te versterken, laten we nog een paar VLOOKUP-formules maken.

Hoe te Vlookup-en vanuit een ander blad in Excel

In de praktijk wordt de Excel VLOOKUP-functie zelden gebruikt met gegevens in hetzelfde werkblad. Meestal zult u overeenkomstige gegevens uit een ander werkblad moeten halen.

Om te Vlookup-en vanuit een ander Excel-blad, zet u de naam van het werkblad gevolgd door een uitroepteken in het tabel_array Bijvoorbeeld, om te zoeken in het bereik A2:B10 op blad2, gebruikt u deze formule:

=VLOOKUP("Product1", Blad2!A2:B10, 2)

Natuurlijk hoeft u de naam van het blad niet handmatig te typen. Begin gewoon de formule te typen en wanneer het bij de tabel_array argument, ga naar het lookup-werkblad en selecteer het bereik met de muis.

Zo kunt u bijvoorbeeld de waarde A2 opzoeken in het bereik A2:A9 op de Prijzen werkblad en geeft een overeenkomende waarde uit kolom C:

=VLOOKUP(A2, Prijzen!$A$2:$C$9, 3, FALSE)

Opmerkingen:

• Als de naam van de spreadsheet spaties of niet-alfabetische tekens moet het tussen enkele aanhalingstekens staan, bijv. "Prijslijst"!$A$2:$C$9.
• Als u een VLOOKUP-formule gebruikt voor meerdere cellen, vergeet dan niet om lock table_array met het $ teken, zoals $A$2:$C$9.

Hoe te Vlookup-en vanuit een andere werkmap in Excel

Om te Vlookup-en vanuit een andere Excel-werkmap, zet u de naam van de werkmap tussen vierkante haken vóór de naam van het werkblad.

Hier is bijvoorbeeld de formule om de A2-waarde op te zoeken op het blad met de naam Prijzen in de Prijslijst.xlsx werkboek:

=VLOOKUP(A2, [Price_List.xlsx]Prijzen!$A$2:$C$9, 3, FALSE)

Indien een werkboeknaam of werkbladnaam spaties of niet-alfabetische tekens bevat, dient u deze tussen enkele aanhalingstekens te plaatsen zoals hier:

=VLOOKUP(A2, '[Prijslijst.xlsx]Prijzen'!$A$2:$C$9, 3, FALSE)

De eenvoudigste manier om een VLOOKUP-formule te maken die verwijst naar een andere werkmap is deze:

1. Open beide bestanden.
2. Begin uw formule te typen, schakel naar de andere werkmap en selecteer de tabelrij met de muis.
3. Voer de overige argumenten in en druk op de Enter-toets om uw formule te voltooien.

Het resultaat zal er ongeveer uitzien als de schermafbeelding hieronder:

Zodra je Sluit het bestand met uw opzoektabel, blijft de VLOOKUP-formule werken, maar toont nu het volledige pad van de gesloten werkmap:

Voor meer informatie, zie Hoe verwijzen naar een ander Excel-blad of werkmap.

Hoe Vlookup van een benoemd bereik in een ander blad

Indien u van plan bent hetzelfde opzoekbereik in veel formules te gebruiken, kunt u er een naambereik voor maken en de naam rechtstreeks in het tabel_array argument.

Om een naambereik te maken, selecteert u gewoon de cellen en typt u de gewenste naam in het Naam vak links van de Formulebalk. Voor de gedetailleerde stappen, zie Hoe benoem ik een bereik in Excel.

Voor dit voorbeeld hebben we de naam Prijzen_2020 naar de gegevenscellen (A2:C9) in het opzoekblad en krijg deze compacte formule:

=VLOOKUP(A2, Prices_2020, 3, FALSE)

De meeste namen in Excel zijn van toepassing op de hele werkboek zodat u de naam van het werkblad niet hoeft op te geven wanneer u reeksen met naam gebruikt.

Als het genoemde bereik in een ander werkboek zet de naam van de werkmap vóór de naam van het bereik, bijvoorbeeld:

=VLOOKUP(A2, "Prijslijst.xlsx"!Prijzen_2020, 3, FALSE)

Dergelijke formules zijn veel begrijpelijker, nietwaar? Bovendien kan het gebruik van genoemde bereiken een goed alternatief zijn voor absolute verwijzingen. Aangezien een genoemd bereik niet verandert, kunt u er zeker van zijn dat uw tabelarray vergrendeld blijft, ongeacht waar de formule wordt verplaatst of gekopieerd.

Indien u uw opzoekbereik hebt omgezet in een volledig functionele Excel-tabel, dan kunt u een Vlookup doen op basis van de tabelnaam, bijv. Prijslijst in de onderstaande formule:

=VLOOKUP(A2, Prijs_tabel, 3, FALSE)

Tabelverwijzingen, ook wel gestructureerde verwijzingen genoemd, zijn veerkrachtig en immuun voor veel gegevensmanipulaties. U kunt bijvoorbeeld nieuwe rijen verwijderen of toevoegen aan uw opzoektabel zonder dat u zich zorgen hoeft te maken over het bijwerken van de verwijzingen.

Jokertekens gebruiken in VLOOKUP-formule

Net als vele andere formules accepteert de Excel VLOOKUP-functie de volgende jokertekens:

• Vraagteken (?) om overeen te komen met elk afzonderlijk teken.
• Asterisk (*) om overeen te komen met een willekeurige reeks tekens.

Wildcards blijken in veel situaties echt nuttig:

• Wanneer u zich de exacte tekst die u zoekt niet meer herinnert.
• Wanneer u een tekststring zoekt die deel uitmaakt van de celinhoud.
• Wanneer een opzoekkolom voorloop- of achterloopspaties bevat. In dat geval kunt u uw hersenen pijnigen om uit te zoeken waarom een normale formule niet werkt.

Voorbeeld 1. Tekst opzoeken die begint of eindigt met bepaalde tekens

Stel dat u een bepaalde klant wilt vinden in de onderstaande database. U weet de achternaam niet meer, maar u weet zeker dat die begint met "ack".

Om de achternaam uit kolom A terug te krijgen, gebruikt u de volgende Vlookup-formule met jokerteken:

=VLOOKUP("ack*", $A$2:$B$10, 1, FALSE)

Om de licentiesleutel uit kolom B te halen, gebruikt u deze (het verschil zit alleen in het indexnummer van de kolom):

=VLOOKUP("ack*", $A$2:$B$10, 2, FALSE)

U kunt ook het bekende deel van de naam invoeren in een cel, bijvoorbeeld E1, en het jokerteken combineren met de celverwijzing:

=VLOOKUP(E1&"*", $A$2:$B$10, 1, FALSE)

Het onderstaande screenshot toont de resultaten:

Hieronder staan nog enkele VLOOKUP-formules met jokertekens.

Zoek de achternaam die eindigt op "zoon":

=VLOOKUP("*son", $A$2:$B$10, 1, FALSE)

Krijg de naam die begint met "joh" en eindigt met "zoon":

=VLOOKUP("joh*son", $A$2:$B$10, 1, FALSE)

Trek een achternaam van 5 karakters:

=VLOOKUP("?????", $A$2:$B$10, 1, FALSE)

Voorbeeld 2. VLOOKUP jokerteken gebaseerd op celwaarde

Uit het vorige voorbeeld weet u al dat het mogelijk is een ampersand (&) en een celverwijzing aan elkaar te koppelen om een opzoekstring te maken. Om een waarde te vinden die een gegeven teken(s) op een willekeurige plaats bevat, zet u een ampersand voor en na de celverwijzing.

Stel, u wilt een naam krijgen die overeenkomt met een bepaalde licentiesleutel, maar u kent niet de hele sleutel, alleen een paar tekens. Met de sleutels in kolom A, de namen in kolom B, en een deel van de doelsleutel in E1, kunt u op deze manier een wildcard Vlookup doen:

Pak de sleutel:

=VLOOKUP("*"&E1&"*", $A$2:$B$10, 1, FALSE)

Haal de naam eruit:

=VLOOKUP("*"&E1&"*", $A$2:$B$10, 2, FALSE)

Opmerkingen:

• Om een wildcard VLOOKUP-formule correct te laten werken, gebruikt u een exacte overeenkomst (FALSE is het laatste argument).
• Als er meer dan één overeenkomst wordt gevonden, wordt de eerste geretourneerd. .

VLOOKUP WAAR vs ONWAAR

En nu is het tijd om het laatste argument van de Excel VLOOKUP functie nader te bekijken. Hoewel optioneel, is het range_lookup Afhankelijk van of u WAAR of ONWAAR kiest, kan uw formule andere resultaten opleveren.

Excel VLOOKUP exacte overeenkomst (FALSE)

Als range_lookup is ingesteld op FALSE, zoekt een Vlookup-formule naar een waarde die exact gelijk is aan de lookup-waarde. Als er twee of meer overeenkomsten worden gevonden, wordt de eerste geretourneerd. Als er geen exacte overeenkomst wordt gevonden, treedt de #N/A-fout op.

Excel VLOOKUP benadert overeenkomst (TRUE)

Als range_lookup is ingesteld op TRUE of is weggelaten (standaard), zoekt de formule de dichtstbijzijnde overeenkomst. Preciezer gezegd, er wordt eerst gezocht naar een exacte overeenkomst, en als er geen exacte overeenkomst wordt gevonden, wordt gezocht naar de volgende grootste waarde die kleiner is dan de opzoekwaarde.

Een Vlookup die bij benadering overeenkomt, werkt met het volgende voorbehoud:

• De opzoekkolom moet gesorteerd zijn in oplopende volgorde , van klein naar groot, anders wordt er misschien geen correcte waarde gevonden.
• Indien de lookup-waarde kleiner is dan de kleinste waarde in de lookup-array, wordt een #N/A-fout teruggestuurd.

De volgende voorbeelden helpen u het verschil te begrijpen tussen een exact match en een approximate match Vlookup en wanneer elke formule het best kan worden gebruikt.

Voorbeeld 1. Hoe doe je een exacte match Vlookup?

Om een exacte overeenkomst op te zoeken, zet u FALSE in het laatste argument.

Laten we voor dit voorbeeld de snelheidstabel van de dieren nemen, de kolommen verwisselen en proberen de dieren te vinden die 80, 50 en 30 mijl per uur kunnen lopen. Met de opzoekwaarden in D2, D3 en D4 voert u de onderstaande formule in E2 in, en kopieert u die naar twee andere cellen:

=VLOOKUP(D2, $A$2:$B$12, 2, FALSE)

Zoals u kunt zien, geeft de formule "Lion" in E3 omdat ze precies 50 per uur draaien. Voor de andere twee opzoekwaarden wordt geen exacte overeenkomst gevonden, en verschijnen er #N/A fouten.

Voorbeeld 2. Hoe Vlookup te gebruiken voor een benaderende overeenkomst

Om een overeenkomst bij benadering op te zoeken, zijn er twee essentiële dingen die u moet doen:

• Sorteer de eerste kolom van tabel_array van klein naar groot.
• Gebruik TRUE voor de range_lookup argument of laat het weg.

Het sorteren van de opzoekkolom is heel belangrijk, omdat de VLOOKUP-functie stopt met zoeken zodra hij een nauwe overeenkomst vindt die kleiner is dan de opzoekwaarde. Als de gegevens niet goed gesorteerd zijn, kunt u heel vreemde resultaten krijgen of een heleboel #N/A-fouten.

Voor onze voorbeeldgegevens gaat een Vlookup-formule bij benadering als volgt:

=VLOOKUP(D2, $A$2:$B$12, 2, TRUE)

En geeft de volgende resultaten:

• Voor een opzoekwaarde van "80" wordt "Cheetah" geretourneerd omdat zijn snelheid (70) de dichtstbijzijnde overeenkomst is die kleiner is dan de opzoekwaarde.
• Voor een opzoekwaarde van "50" wordt een exacte overeenkomst teruggezonden (Lion).
• Voor een lookup waarde van "30", wordt een #N/A fout teruggestuurd omdat de lookup waarde kleiner is dan de kleinste waarde in de lookup kolom.

Speciale hulpmiddelen voor Vlookup in Excel

VLOOKUP is ongetwijfeld een van de krachtigste en nuttigste Excel-functies, maar ook een van de meest verwarrende. Om de leercurve minder steil te maken en de ervaring aangenamer, hebben we een paar tijdbesparende tools opgenomen in onze Ultimate Suite voor Excel.

VLOOKUP Wizard - eenvoudige manier om complexe formules te schrijven

De interactieve VLOOKUP Wizard zal u door de configuratieopties leiden om een perfecte formule te bouwen voor de criteria die u opgeeft. Afhankelijk van uw gegevensstructuur zal het de standaard VLOOKUP functie gebruiken of een INDEX MATCH formule die waarden van links kan halen.

Dit is wat u moet doen om uw formule op maat te krijgen:

1. Start de VLOOKUP Wizard.

1. Kies uw hoofdtabel en uw opzoektabel.
2. Geef de volgende kolommen op (in veel gevallen worden ze automatisch gekozen):
   • Belangrijke kolom - de kolom in uw hoofdtabel die de op te zoeken waarden bevat.
   • Kolom opzoeken - de kolom om tegen op te kijken.
   • Terugkerende kolom - de kolom waarvan de waarden moeten worden opgehaald.
3. Klik op de Plaats knop.

De volgende voorbeelden tonen de wizard in actie.

Standaard Vlookup

Wanneer de opzoekkolom ( Dier ) de meest linkse kolom in de opzoektabel is, wordt een normale VLOOKUP-formule voor een exacte overeenkomst ingevoegd:

Vlookup naar links

Wanneer de opzoekkolom ( Dier ) staat rechts van de retourkolom ( Snelheid ) voegt de wizard een INDEX MATCH-formule toe aan de Vlookup van rechts naar links:

Extra bonus! Door het slimme gebruik van celverwijzingen kunnen de formules naar elke kolom worden gekopieerd of verplaatst, zonder dat u de verwijzingen hoeft bij te werken.

Twee tabellen samenvoegen - formule-vrij alternatief voor Excel VLOOKUP

Als uw Excel-bestanden enorm groot en complex zijn, de deadline van het project nabij is, en u iemand zoekt die u een handje kan helpen, probeer dan eens de Wizard Tabellen samenvoegen.

Dit hulpmiddel is ons visueel en stressvrij alternatief voor de VLOOKUP-functie van Excel, die zo werkt:

1. Selecteer uw hoofdtabel.
2. Selecteer de opzoektabel.
3. Kies een of meer gemeenschappelijke kolommen als unieke identificatiecode(s).
4. Geef aan welke kolommen moeten worden bijgewerkt.
5. Kies optioneel de toe te voegen kolommen.
6. Geef de wizard Tabellen samenvoegen enkele seconden de tijd voor de verwerking... en geniet van het resultaat :)

Dat is hoe u VLOOKUP in Excel op basisniveau kunt gebruiken. In het volgende deel van onze tutorial bespreken we geavanceerde VLOOKUP-voorbeelden die u zullen leren hoe u meerdere criteria kunt Vlookup-en, alle overeenkomsten of het N-de voorkomen kunt retourneren, een dubbele Vlookup kunt uitvoeren, met één enkele formule in meerdere bladen kunt opzoeken en meer. Ik dank u voor het lezen en hoop u volgende week te zien!

Beschikbare downloads

Excel VLOOKUP formule voorbeelden (.xlsx bestand)

Ultimate Suite 14 dagen volledig functionele versie (.exe bestand)