Danas ćemo pogledati kako koristiti VLOOKUP u Excelu s mnogo detaljnih primjera korak po korak. Naučit ćete kako napraviti Vlookup s drugog lista i druge radne knjige, pretraživati ​​pomoću zamjenskih znakova i još mnogo toga.

Ovim člankom započinje serija o VLOOKUP-u, jednoj od najkorisnijih Excel funkcija i na istovremeno jedan od najsloženijih i najmanje razumljivih. Pokušat ćemo objasniti osnove vrlo jednostavnim jezikom kako bismo neiskusnom korisniku olakšali učenje što je više moguće. Također ćemo pružiti primjere formula koje pokrivaju najtipičniju upotrebu VLOOKUP-a u Excelu i pokušati ih učiniti informativnim i zabavnim.

Funkcija Excel VLOOKUP

Što je VLOOKUP? Za početak, to je Excel funkcija :) Što radi? Traži vrijednost koju navedete i vraća odgovarajuću vrijednost iz drugog stupca. Tehnički gledano, funkcija VLOOKUP traži vrijednost u prvom stupcu zadanog raspona i vraća vrijednost u istom retku iz drugog stupca.

U uobičajenoj upotrebi, Excel VLOOKUP pretražuje vaš skup podataka na temelju jedinstveni identifikator i donosi vam dio informacija povezanih s tim jedinstvenim identifikatorom.

Slovo "V" označava "vertikalno" i koristi se za razlikovanje VLOOKUP od funkcije HLOOKUP koja traži vrijednost u nizu umjesto stupca (H označava "horizontalno").

Funkcija je dostupna u svimreferenca ćelije.

Recimo, želite dobiti naziv koji odgovara određenom licencnom ključu, ali ne znate cijeli ključ, samo nekoliko znakova. S ključevima u stupcu A, imenima u stupcu B i dijelom ciljnog ključa u E1, možete napraviti Vlookup sa zamjenskim znakom na ovaj način:

Ekstrahirajte ključ:

=VLOOKUP("*"&E1&"*", $A$2:$B$10, 1, FALSE)

Izdvojite ime:

=VLOOKUP("*"&E1&"*", $A$2:$B$10, 2, FALSE)

Napomene:

• Da bi VLOOKUP formula sa zamjenskim znakom radila ispravno, koristite točno podudaranje (FALSE je zadnji argument).
• Ako se pronađe više od jednog podudaranja, vraća se prvo .

VLOOKUP TRUE vs FALSE

A sada je vrijeme da pobliže pogledamo zadnji argument funkcije Excel VLOOKUP. Iako nije obavezan, parametar range_lookup vrlo je važan. Ovisno o tome jeste li odabrali TRUE ili FALSE, vaša formula može dati različite rezultate.

Excel VLOOKUP točno podudaranje (FALSE)

Ako je range_lookup postavljeno na FALSE, Vlookup formula traži vrijednost koja je točno jednaka traženoj vrijednosti. Ako se pronađu dva ili više rezultata, prvi se vraća. Ako se točno podudaranje ne pronađe, pojavljuje se pogreška #N/A.

Excel VLOOKUP približno podudaranje (TRUE)

Ako je range_lookup postavljeno na TRUE ili izostavljeno ( zadano), formula traži najbliže podudaranje. Točnije, prvo traži točno podudaranje, a ako se točno podudaranje ne pronađe, traži sljedeću najveću vrijednostmanji od vrijednosti traženja.

Približno podudaranje Vlookup radi sa sljedećim upozorenjima:

• Stupac traženja mora biti poredan uzlaznim redoslijedom , od najmanjeg do najveće, inače se možda neće pronaći točna vrijednost.
• Ako je vrijednost pretraživanja manja od najmanje vrijednosti u nizu pretraživanja, vraća se pogreška #N/A.

Sljedeći primjeri pomoći će vam da bolje razumijete razliku između Vlookupa točnog i približnog podudaranja i kada je svaku formulu najbolje koristiti.

Primjer 1. Kako napraviti Vlookup točnog podudaranja

Da biste pronašli točno podudaranje, samo stavite FALSE u zadnji argument.

Za ovaj primjer, uzmimo tablicu brzine životinja, zamijenimo stupce i pokušajmo pronaći životinje koje mogu trčati 80 , 50 i 30 milja na sat. S vrijednostima pretraživanja u D2, D3 i D4, unesite donju formulu u E2, a zatim je kopirajte u još dvije ćelije:

=VLOOKUP(D2, $A$2:$B$12, 2, FALSE)

Kao što vidite, formula vraća " Lion" u E3 jer rade točno 50 na sat. Za druge dvije vrijednosti pretraživanja nije pronađeno točno podudaranje i pojavljuju se pogreške #N/A.

Primjer 2. Kako Vlookup za približno podudaranje

Da biste pronašli približno podudaranje, morate učiniti dvije bitne stvari:

• Razvrstajte prvi stupac table_array od najmanjeg do najvećeg.
• Koristite TRUE za argument range_lookup ili ga izostavite.

Razvrstavanje stupca za traženje vrlo je važno jer funkcija VLOOKUP zaustavlja pretraživanje čim pronađe blisko podudaranje manje od vrijednosti za traženje. Ako podaci nisu pravilno sortirani, mogli biste dobiti stvarno čudne rezultate ili hrpu #N/A pogrešaka.

Za naše uzorke podataka, formula Vlookup približnog podudaranja je sljedeća:

=VLOOKUP(D2, $A$2:$B$12, 2, TRUE)

I vraća sljedeće rezultate:

• Za vrijednost traženja "80", "Cheetah" se vraća jer je njegova brzina (70) najbliže podudaranje manja od vrijednosti traženja.
• Za vrijednost traženja "50", vraća se točno podudaranje (Lav).
• Za vrijednost traženja "30", #N/A vraća se pogreška jer je vrijednost pretraživanja manja od najmanje vrijednosti u stupcu pretraživanja.

Posebni alati za Vlookup u programu Excel

Bez sumnje, VLOOKUP je jedna od najmoćnijih i najkorisnijih Excel funkcija, ali je također i jedna od onih koje najviše zbunjuju. Kako bismo krivulju učenja učinili manje strmom, a iskustvo ugodnijim, uključili smo nekoliko alata za uštedu vremena u naš Ultimate Suite for Excel.

VLOOKUP Wizard - jednostavan način za pisanje složenih formula

interaktivni čarobnjak VLOOKUP provest će vas kroz opcije konfiguracije za izradu savršene formule za kriterije koje navedete. Ovisno o vašoj strukturi podataka, koristit će standardnu ​​funkciju VLOOKUP ili formulu INDEX MATCH koja može povući vrijednosti izlijevo.

Da biste dobili prilagođenu formulu, ovo trebate učiniti:

1. Pokrenite čarobnjak VLOOKUP.

1. Odaberite svoju glavnu tablicu i tablicu za pretraživanje.
2. Odredite sljedeće stupce (u mnogim slučajevima biraju se automatski):
   • Ključni stupac - stupac u vašoj glavnoj tablici koji sadrži vrijednosti za traženje.
   • Stupac za traženje - stupac za traženje.
   • Povratni stupac - stupac iz kojeg se traže vrijednosti .
3. Kliknite gumb Umetni .

Sljedeći primjeri pokazuju čarobnjaka na djelu.

Standardni Vlookup

Kada je stupac pretraživanja ( Životinja ) krajnji lijevi stupac u tablici pretraživanja, umetnuta je normalna VLOOKUP formula za točno podudaranje:

Vlookup lijevo

Kada je stupac pretraživanja ( Životinja ) na desnoj strani povratnog stupca ( Brzina ), čarobnjak umeće formulu INDEX MATCH u Vlookup zdesna nalijevo:

Dodatni bonus! Zbog pametna upotreba referenci ćelija, formule se mogu kopirati ili premjestiti u bilo koji stupac, bez potrebe za ažuriranjem referenci.

Spoji dvije tablice - alternativa Excel VLOOKUP-u bez formula

Ako su vaše Excel datoteke enormno velike i složene, rok za projekt je blizu, a vi tražite nekoga tko vam može pomoći, isprobajte čarobnjak za spajanje tablica.

Ovaj alat je naša vizualna i bez stresa alternativa Excelovoj funkciji VLOOKUP, koja radi na sljedeći način:

1. Odaberite svoju glavnu tablicu.
2. Odaberite tablicu za pretraživanje.
3. Odaberite jedan ili nekoliko uobičajenih stupaca kao jedinstveni identifikator(e).
4. Odredite koje stupce ažurirati.
5. Po izboru, odaberite stupce koje želite dodati.
6. Dopusti spajanje Čarobnjak za tablice nekoliko sekundi za obradu… i uživajte u rezultatima :)

Evo kako koristiti VLOOKUP u Excelu na osnovnoj razini. U sljedećem dijelu našeg vodiča raspravljat ćemo o naprednim VLOOKUP primjerima koji će vas naučiti kako Vlookupirati više kriterija, vratiti sva podudaranja ili N-to pojavljivanje, izvesti dvostruki Vlookup, tražiti više listova s ​​jednom formulom i više. Zahvaljujem vam na čitanju i nadam se da se vidimo sljedeći tjedan!

Dostupna preuzimanja

Primjeri formula Excel VLOOKUP (.xlsx datoteka)

Ultimate Suite 14 dana potpuno funkcionalan verzija (.exe datoteka)

Savjet. U programima Excel 365 i Excel 2021 možete koristiti funkciju XLOOKUP, koja je fleksibilniji i snažniji nasljednik VLOOKUP-a.

VLOOKUP sintaksa

Sintaksa za VLOOKUP funkciju je sljedeća:

Gdje:

• Lookup_value (obavezno) - je vrijednost za pretraživanje.

  Ovo može biti vrijednost (broj, datum ili tekst), referenca ćelije (referenca na ćeliju koja sadrži traženu vrijednost) ili vrijednost koju vraća neka druga funkcija. Za razliku od brojeva i referenci na ćelije, tekstualne vrijednosti uvijek bi trebale biti unutar "dvostrukih navodnika".

• Table_array (obavezno) - je raspon ćelija u kojima se traži traženje vrijednost i iz koje treba dohvatiti podudaranje. Funkcija VLOOKUP uvijek pretražuje u prvom stupcu niza tablice , koji može sadržavati različite tekstualne vrijednosti, brojeve, datume i logičke vrijednosti.
• Col_index_num (obavezno ) - je broj stupca iz kojeg se vraća vrijednost. Brojanje počinje od krajnje lijevog stupca u nizu tablice, što je 1.
• Range_lookup (neobavezno) - određuje hoće li se tražiti približno ili točno podudaranje:
  • TRUE ili izostavljeno (zadano) - približno podudaranje. Ako nije pronađeno točno podudaranje, formula traži najveću vrijednost koja je manja od tražene vrijednosti.Zahtijeva sortiranje stupca traženja uzlaznim redoslijedom.
  • FALSE - točno podudaranje. Formula traži vrijednost točno jednaku traženoj vrijednosti. Ako se točno podudaranje ne pronađe, vraća se vrijednost #N/A.

Osnovna VLOOKUP formula

Ovo je primjer formule Excel VLOOKUP u najjednostavnijem obliku. Molimo pogledajte donju formulu i pokušajte je "prevesti" na engleski:

=VLOOKUP("lion", A2:B11, 2, FALSE)

• Prvi argument ( lookup_value ) jasno pokazuje da formula traži riječ "lav".
• Drugi argument ( table_array ) je A2:B11. Imajući na umu da se pretraga izvodi u krajnjem lijevom stupcu, gornju formulu možete pročitati malo dalje: tražite "lava" u rasponu A2:A11. Za sada je dobro, zar ne?
• Treći argument col_index_num je 2. Što znači, želimo vratiti odgovarajuću vrijednost iz stupca B, koji je drugi u nizu tablice.
• Četvrti argument range_lookup je FALSE, što znači da tražimo točno podudaranje.

Sa svim utvrđenim argumentima, ne biste trebali imati problema s čitanjem cijelog formula: tražite "lav" u A2:A11, pronađite točno podudaranje i vratite vrijednost iz stupca B u istom retku.

Radi praktičnosti, možete unijeti vrijednost od interesa u neki ćeliju, recimo E1, zamijenite "tvrdo kodirani" tekst referencom ćelije i dobijete formulu za traženje bilo kojegvrijednost koju ste unijeli u E1:

=VLOOKUP(E1, A2:B11, 2, FALSE)

Je li nešto ostalo nejasno? Zatim pokušajte to gledati na sljedeći način:

Kako napraviti Vlookup u Excelu

Kada koristite VLOOKUP formule u stvarnim radnim listovima, glavno pravilo je sljedeće: zaključajte polje tablice s apsolutnim referencama ćelije (kao što je $A$2:$C$11) kako biste spriječili njegovu promjenu prilikom kopiranja formule u druge ćelije.

vrijednost pretraživanja bi u većini slučajeva trebala biti relativna referenca (poput E2) ili možete zaključati samo koordinate stupca ($E2). Kada se formula kopira niz stupac, referenca će se automatski prilagoditi za svaki redak.

Da biste vidjeli kako funkcionira u praksi, razmotrite sljedeći primjer. U našu oglednu tablicu dodali smo još jedan stupac koji rangira životinje po brzini (stupac A) i želimo pronaći 1., 5. i 10. najbržeg sprintera na svijetu. U tu svrhu unesite rangove pretraživanja u neke ćelije (E2:E4 na snimci zaslona u nastavku) i upotrijebite sljedeće formule:

Za izvlačenje imena životinja iz stupca B:

=VLOOKUP($E2, $A$2:$C$11, 2, FALSE)

Za izdvajanje brzine iz stupca C:

=VLOOKUP($E2, $A$2:$C$11, 3, FALSE)

Unesite gornje formule u ćelije F2 i G2, odaberite te ćelije i povucite formule u donje retke:

Ako istražite formulu u nižem retku, primijetit ćete da je referenca tražene vrijednosti prilagođena za taj određeni red, dok je polje tablice nepromijenjeno:

U nastavku ćete imati nekolikoviše korisnih savjeta koji će vam uštedjeti mnogo glavobolje i vremena za rješavanje problema.

Excel VLOOKUP - 5 stvari koje treba zapamtiti!

1. Funkcija VLOOKUP ne može gledati lijevo . Uvijek pretražuje u krajnjem lijevom stupcu niza tablice i vraća vrijednost iz stupca s desne strane. Ako trebate povući vrijednosti slijeva, upotrijebite kombinaciju INDEX MATCH (ili INDEX XMATCH u programu Excel 365) koja ne vodi računa o pozicioniranju stupaca za pretraživanje i povrat.
2. Funkcija VLOOKUP je neosjetljivo na velika i mala slova , što znači da se velika i mala slova tretiraju kao ekvivalenti. Kako biste razlikovali mala slova, koristite VLOOKUP formule osjetljive na velika i mala slova.
3. Zapamtite važnost posljednjeg parametra. Koristite TRUE za približno podudaranje i FALSE za točno podudaranje. Za sve pojedinosti pogledajte VLOOKUP TRUE vs. FALSE.
4. Kada tražite približno podudaranje, provjerite jesu li podaci u stupcu pretraživanja poredani uzlaznim redoslijedom.
5. Ako vrijednost pretraživanja nije pronađena, vraća se pogreška #N/A. Za informacije o drugim pogreškama pogledajte Zašto Excel VLOOKUP ne radi.

Excel VLOOKUP primjeri

Nadam se da vam okomito pretraživanje počinje izgledati malo poznatije. Kako bismo ojačali vaše znanje, napravimo još nekoliko VLOOKUP formula.

Kako Vlookup s drugog lista u Excelu

U praksi, Excel VLOOKUP funkcija je rijetkokoristi se s podacima na istom radnom listu. Najčešće ćete morati povući podudarne podatke s drugog radnog lista.

Za Vlookup s drugog Excel lista, stavite naziv radnog lista nakon kojeg slijedi uskličnik u argument table_array ispred raspona referenca. Na primjer, za pretraživanje u rasponu A2:B10 na Sheet2, koristite ovu formulu:

=VLOOKUP("Product1", Sheet2!A2:B10, 2)

Naravno, ne morate ručno upisivati ​​naziv lista. Jednostavno počnite upisivati ​​formulu i kada dođe do argumenta table_array , prebacite se na radni list traženja i odaberite raspon pomoću miša.

Na primjer, ovako možete tražiti vrijednost A2 u rasponu A2:A9 na radnom listu Cijene i vrati odgovarajuću vrijednost iz stupca C:

=VLOOKUP(A2, Prices!$A$2:$C$9, 3, FALSE)

Napomene:

• Ako naziv proračunske tablice sadrži razmake ili neabecedne znakove , mora biti u jednostrukim navodnicima, npr. 'Cjenik'!$A$2:$C$9.
• U slučaju da koristite VLOOKUP formulu za više ćelija, ne zaboravite zaključati table_array sa znakom $, kao $A$2: $C$9.

Kako izvršiti Vlookup iz druge radne knjige u Excelu

Za Vlookup iz druge Excel radne knjige, stavite naziv radne knjige u uglate zagrade ispred naziva radnog lista.

Na primjer, evo formule za traženje A2 vrijednosti na listu pod nazivom Cijene u radnoj knjizi Cjenik.xlsx :

=VLOOKUP(A2, [Price_List.xlsx]Prices!$A$2:$C$9, 3, FALSE)

Akobilo da naziv radne knjige ili radnog lista sadrži razmake ili neabecedne znakove, trebali biste ih staviti u jednostruke navodnike poput ovog:

=VLOOKUP(A2, '[Price List.xlsx]Prices'!$A$2:$C$9, 3, FALSE)

Najlakši način da napravite VLOOKUP formulu koja se odnosi na drugačija radna knjiga je ova:

1. Otvorite obje datoteke.
2. Počnite upisivati ​​svoju formulu, prebacite se na drugu radnu knjigu i odaberite polje tablice pomoću miša.
3. Unesite preostale argumente i pritisnite tipku Enter kako biste dovršili formulu.

Rezultat će izgledati otprilike kao na slici ispod:

Nakon što zatvorite datoteku s vašom tablicom pretraživanja, VLOOKUP formula će nastaviti raditi, ali će sada prikazati puni put za zatvorenu radnu knjigu:

Za više informacija potražite u članku Kako uputiti na drugi Excel list ili radnu knjigu.

Kako Vpretraživati ​​iz imenovanog raspona u drugom listu

U slučaju da planirate koristiti isti raspon pretraživanja u mnogim formulama možete stvoriti imenovani raspon za njega i izravno upisati naziv y u argumentu table_array .

Da biste stvorili imenovani raspon, jednostavno odaberite ćelije i upišite naziv koji želite u okvir Naziv lijevo od formule bar. Detaljne korake potražite u odjeljku Kako imenovati raspon u Excelu.

Za ovaj primjer dali smo naziv Cijene_2020 ćelijama s podacima (A2:C9) na listu za pretraživanje i dobiti ovu kompaktnu formulu:

=VLOOKUP(A2, Prices_2020, 3, FALSE)

Većina imena u Excelu odnosi se na cijelu radnu knjigu , tako da ne morate navesti naziv radnog lista kada koristite imenovane raspone.

Ako je imenovani raspon u drugoj radnoj knjizi , stavite naziv radne knjige ispred naziva raspona, na primjer:

=VLOOKUP(A2, 'Price List.xlsx'!Prices_2020, 3, FALSE)

Takve su formule daleko razumljivije, zar ne? Osim toga, korištenje imenovanih raspona može biti dobra alternativa apsolutnim referencama. Budući da se imenovani raspon ne mijenja, možete biti sigurni da će niz vaše tablice ostati zaključan bez obzira na to gdje se formula premjesti ili kopira.

Ako ste svoj raspon pretraživanja pretvorili u potpuno funkcionalnu Excel tablicu , tada možete napraviti Vlookup na temelju naziva tablice, npr. Tablica_cjena u donjoj formuli:

=VLOOKUP(A2, Price_table, 3, FALSE)

Reference tablice, koje se nazivaju i strukturirane reference, otporne su i otporne na mnoge manipulacije podacima. Na primjer, možete ukloniti ili dodati nove retke u svoju tablicu pretraživanja bez brige o ažuriranju referenci.

Korištenje zamjenskih znakova u formuli VLOOKUP

Kao i mnoge druge formule, funkcija Excel VLOOKUP prihvaća sljedeće zamjenske znakove:

• Upitnik (?) za podudaranje s bilo kojim pojedinačnim znakom.
• Zvjezdica (*) za podudaranje bilo koji niz znakova.

Zamjenski znakovi pokazali su se stvarno korisnima u mnogim situacijama:

• Kada se ne sjećate točnog teksta koji tražite.
• Kada tražite tekstniz koji je dio sadržaja ćelije.
• Kada stupac pretraživanja sadrži razmake na početku ili na kraju. U tom slučaju možete razbijati glavu pokušavajući shvatiti zašto normalna formula ne funkcionira.

Primjer 1. Potražite tekst koji počinje ili završava određenim znakovima

Pretpostavimo da želite pronaći određenog kupca u donjoj bazi podataka. Ne sjećate se prezimena, ali ste uvjereni da počinje s "ack".

Da biste vratili prezime iz stupca A, upotrijebite sljedeću formulu Vlookup zamjenskog znaka:

=VLOOKUP("ack*", $A$2:$B$10, 1, FALSE)

Za dohvaćanje licencnog ključa iz stupca B upotrijebite ovaj (razlika je samo u broju indeksa stupca):

=VLOOKUP("ack*", $A$2:$B$10, 2, FALSE)

Također možete unijeti poznati dio ime u nekoj ćeliji, recimo E1, i kombinirajte zamjenski znak s referencom ćelije:

=VLOOKUP(E1&"*", $A$2:$B$10, 1, FALSE)

Snimak zaslona u nastavku prikazuje rezultate:

Ispod je još nekoliko VLOOKUP formula sa zamjenskim znakovima.

Pronađite prezime koje završava sa "son":

=VLOOKUP("*son", $A$2:$B$10, 1, FALSE)

Pronađite ime koje počinje sa "joh " i završava sa "sin":

=VLOOKUP("joh*son", $A$2:$B$10, 1, FALSE)

Izvucite prezime od 5 znakova:

=VLOOKUP("?????", $A$2:$B$10, 1, FALSE)

Primjer 2. VLOOKUP zamjenski znak na temelju vrijednosti ćelije

Iz prethodnog primjera već znate da je moguće spojiti znak & (&) i referencu ćelije da biste napravili niz za pretraživanje. Da biste pronašli vrijednost koja sadrži zadane znakove na bilo kojem mjestu, stavite znak & ispred i iza