Ayeuna urang bakal ningali kumaha ngagunakeun VLOOKUP dina Excel sareng seueur conto léngkah-léngkah anu lengkep. Anjeun bakal diajar kumaha cara Vlookup tina lembar sareng buku kerja anu sanés, milarian nganggo wildcard, sareng seueur deui.

Artikel ieu ngamimitian runtuyan anu ngawengku VLOOKUP, salah sahiji fungsi Excel anu pang gunana sareng di Dina waktos anu sami, salah sahiji anu paling rumit sareng teu kahartos. Kami bakal nyobian ngajelaskeun dasar-dasar dina basa anu sederhana pikeun ngajantenkeun kurva diajar pikeun pangguna anu teu ngalaman sagampangna. Urang ogé bakal nyadiakeun conto rumus nu ngawengku pamakéan paling has tina VLOOKUP di Excel, sarta coba sangkan aranjeunna duanana informatif jeung senang.

Excel VLOOKUP fungsi

Naon VLOOKUP? Pikeun mimitian, éta mangrupikeun fungsi Excel :) Naon anu dilakukeun? Éta milarian nilai anu anjeun tangtukeun sareng mulihkeun nilai anu cocog tina kolom anu sanés. Sacara teknis, pungsi VLOOKUP néangan niléy dina kolom kahiji tina rentang nu tangtu sarta mulangkeun hiji nilai dina baris nu sarua ti kolom séjén.

Dina pamakéan umumna, Excel VLOOKUP maluruh ngaliwatan set data anjeun dumasar kana identifier unik tur mawa Anjeun sapotong informasi pakait sareng eta identifier unik.

Huruf "V" nangtung pikeun "vertikal" sarta dipaké pikeun ngabedakeun VLOOKUP tina fungsi HLOOKUP nu kasampak up hiji nilai dina urutan. tinimbang kolom (H nangtung pikeun "horizontal").

Pungsi ieu sadia dina sakabéhrujukan sél.

Misalkeun, anjeun badé kéngingkeun nami anu cocog sareng konci lisénsi anu tangtu, tapi anjeun henteu terang sadayana konci, ngan ukur sababaraha karakter. Kalayan konci dina kolom A, nami dina kolom B, sareng bagian tina konci target dina E1, anjeun tiasa ngalakukeun Vlookup wildcard ku cara kieu:

Ekstrak konci:

=VLOOKUP("*"&E1&"*", $A$2:$B$10, 1, FALSE)

Ekstrak ngaran:

=VLOOKUP("*"&E1&"*", $A$2:$B$10, 2, FALSE)

Catetan:

• Pikeun rumus VLOOKUP wildcard tiasa jalanna leres, make patandingan pasti (PALSU teh argumen pamungkas).
• Lamun kapanggih leuwih ti hiji patandingan, nu kahiji dibalikkeun .

VLOOKUP TRUE vs PALSU

Jeung ayeuna, waktuna pikeun nempo leuwih deukeut argumen panungtungan sahiji fungsi Excel VLOOKUP. Sanaos opsional, parameter range_lookup penting pisan. Gumantung kana naha anjeun milih BENER atanapi SALAH, rumus anjeun tiasa ngahasilkeun hasil anu béda.

Excel VLOOKUP cocok (SALAH)

Lamun range_lookup disetel ka FALSE, hiji Vlookup rumus neangan nilai nu persis sarua jeung nilai lookup. Lamun dua atawa leuwih patandingan kapanggih, nu 1st balik. Lamun cocok pasti teu kapanggih, kasalahan #N/A lumangsung.

Excel VLOOKUP perkiraan cocok (BENER)

Lamun rentang_lookup disetel ka BENER atawa dileungitkeun ( standar), rumus kasampak up cocok pangdeukeutna. Leuwih tepatna, éta néangan hiji patandingan pasti mimitina, sarta lamun hiji patandingan pasti teu kapanggih, néangan nilai panggedena salajengna nukurang tina nilai lookup.

Perkiraan patandingan Vlookup tiasa dianggo sareng caveats ieu:

• Kolom lookup kedah diurutkeun dina urutan naek , ti nu pangleutikna. mun panggedena, lamun teu aya nilai nu bener moal kapanggih.
• Lamun nilai lookup leuwih leutik batan nilai pangleutikna dina array lookup, kasalahan #N/A dibalikeun.

Conto-conto di handap ieu bakal ngabantosan anjeun langkung ngartos bédana antara patandingan pasti sareng perkiraan Vlookup anu cocog sareng iraha unggal rumus anu paling hadé dianggo.

Conto 1. Kumaha cara ngalakukeun Vlookup patandingan tepat

Pikeun néangan hiji patandingan pasti, ngan nempatkeun FALSE dina argumen panungtungan.

Pikeun conto ieu, hayu urang nyandak tabel speed sato, swap kolom, jeung cobaan pikeun manggihan sato nu bisa ngajalankeun 80 , 50 jeung 30 mil per jam. Kalayan niléy milarian dina D2, D3 sareng D4, lebetkeun rumus di handap ieu dina E2, teras salin ka handap ka dua sél deui:

=VLOOKUP(D2, $A$2:$B$12, 2, FALSE)

Sakumaha anjeun tiasa tingali, rumusna mulihkeun " Singa" dina E3 sabab ngajalankeun persis 50 per jam. Pikeun dua nilai panéangan anu sanés, hiji patandingan pasti henteu kapendak, sareng kasalahan #N/A némbongan.

Conto 2. Kumaha Vlookup pikeun perkiraan pertandingan

Pikeun milarian perkiraan patandingan, aya dua hal penting anu anjeun kedah laksanakeun:

• Urutkeun kolom kahiji tina table_array tina pangleutikna dugi ka panggedéna.
• Paké TRUE pikeun range_lookup argumen atawa hapus.

Nyortir kolom lookup penting pisan sabab fungsi VLOOKUP eureun neangan pas manggihan hiji patandingan deukeut leuwih leutik batan nilai lookup. Upami data henteu diurutkeun leres, anjeun tiasa gaduh hasil anu anéh atanapi sakumpulan kasalahan #N/A.

Kanggo data sampel urang, rumus Vlookup perkiraan cocog sapertos kieu:

=VLOOKUP(D2, $A$2:$B$12, 2, TRUE)

Sareng mulihkeun hasil ieu:

• Pikeun nilai panéangan "80", "Cheetah" dipulangkeun sabab lajuna (70) mangrupikeun pertandingan anu pangdeukeutna. leuwih leutik batan nilai lookup.
• Pikeun nilai lookup "50", cocok pasti balik (Singa).
• Pikeun nilai lookup "30", a #N/A kasalahan dipulangkeun sabab nilai lookup kurang ti nilai pangleutikna dina kolom lookup.

Alat husus pikeun Vlookup dina Excel

Undoubtedly, VLOOKUP mangrupakeun salah sahiji fungsi Excel pangkuatna sarta mangpaat, tapi oge salah sahiji anu pang ngabingungkeun. Pikeun ngajantenkeun kurva diajar kirang lungkawing sareng pangalaman langkung pikaresepeun, kami kalebet sababaraha alat anu ngahémat waktos dina Suite Ultimate kami pikeun Excel.

VLOOKUP Wizard - cara anu gampang pikeun nyerat rumus kompleks

The VLOOKUP Wizard interaktif bakal ngajalanan anjeun dina pilihan konfigurasi pikeun ngawangun rumus anu sampurna pikeun kriteria anu anjeun pikahoyong. Gumantung kana struktur data anjeun, éta bakal nganggo fungsi VLOOKUP standar atanapi rumus INDEX MATCH anu tiasa narik nilai tinaditinggalkeun.

Pikeun meunangkeun rumus anu disaluyukeun khusus anjeun, ieu anu anjeun kedah laksanakeun:

1. Jalankeun Wizard VLOOKUP.

1. Pilih tabel utama anjeun sareng tabel milarian.
2. Sebutkeun kolom di handap ieu (dina seueur kasus aranjeunna dipilih sacara otomatis):
   • Kolom konci - kolom dina tabel utama anjeun ngandung niléy-niléy nu kudu diteangan.
   • Kolom Pilarian - kolom nu rék ditingalikeun.
   • Kolom Balikkeun - kolom nu rék dipulut nilai. .
3. Klik tombol Selapkeun .

Conto di handap ieu mintonkeun wizard dina aksi.

Vlookup Standar

Lamun kolom lookup ( Hewan ) mangrupa kolom paling kenca dina tabel lookup, rumus VLOOKUP normal pikeun patandingan pasti diselapkeun:

Vlookup ka kénca

Lamun kolom lookup ( Hewan ) aya di sisi katuhu kolom balik ( Speed ), wizard nyelapkeun rumus INDEX MATCH ka Vlookup katuhu ka kenca:

Bonus tambahan! Alatan pinter ngagunakeun rujukan sél, rumusna bisa ditiron atawa dipindahkeun ka kolom mana waé, tanpa anjeun kudu ngamutahirkeun référénsina.

Gabungkeun Dua Tabél - alternatif bébas rumus pikeun Excel VLOOKUP

Upami file Excel anjeun ageung pisan sareng kompleks, tangtos waktos proyék caket, sareng anjeun milarian jalma anu tiasa ngabantosan anjeun, cobian Wizard Merge Tables.

Alat ieu mangrupikeun alternatif visual sareng bébas setrés pikeun fungsi VLOOKUP Excel, anu tiasa dianggo ku cara kieu:

1. Pilih méja utama anjeun.
2. Pilih tabel milarian.
3. Pilih hiji atawa sababaraha kolom umum salaku idéntifikasi unik.
4. Sebutkeun kolom mana nu rék diapdet.
5. Pilihan, pilih kolom nu rék ditambahkeun.
6. Idinan Gabungan Tables Wizard sababaraha detik pikeun ngolah… teras nikmati hasilna :)

Kitu kumaha cara ngagunakeun VLOOKUP dina Excel dina tingkat dasar. Dina bagian salajengna tina tutorial urang, urang bakal ngabahas conto canggih VLOOKUP anu bakal ngajarkeun maneh kumaha Vlookup sababaraha kriteria, balikkeun sagala patandingan atawa kajadian Nth, ngalakukeun ganda Vlookup, néangan nepi sakuliah sababaraha lembar kalayan rumus tunggal, sarta leuwih. Hatur nuhun pikeun maca sareng ngarepkeun anjeun tiasa pendak minggu payun!

Unduh anu sayogi

Conto rumus Excel VLOOKUP (file .xlsx)

Ultimate Suite 14 dinten sapinuhna fungsina versi (file .exe)

Tip. Dina Excel 365 sareng Excel 2021, anjeun tiasa nganggo fungsi XLOOKUP, anu mangrupikeun panerus VLOOKUP anu langkung fleksibel sareng kuat.

Sintaksis VLOOKUP

Sintaksis pikeun fungsi VLOOKUP nyaéta kieu:

Dimana:

• Lookup_value (diperlukeun) - nyaeta nilai nu kudu diteangan.

  Ieu bisa mangrupa nilai (nomer, tanggal atawa téks), rujukan sél (rujukan kana sél ngandung hiji nilai lookup), atawa nilai balik ku sababaraha fungsi séjén. Teu kawas angka jeung rujukan sél, nilai téks kudu salawasna di enclosed dina "tanda petik ganda".

• Table_array (diperlukeun) - nyaeta rentang sél dimana neangan pilarian. nilai jeung ti mana pikeun meunangkeun patandingan. Pungsi VLOOKUP sok milarian dina kolom kahiji tina susunan tabel , nu bisa ngandung rupa-rupa nilai téks, angka, kaping, jeung nilai logis.
• Col_index_num (diperlukeun ) - nyaeta jumlah kolom ti mana balik nilai a. Cacahna dimimitian ti kolom pangkéncana dina susunan méja, nyaéta 1.
• Range_lookup (opsional) - nangtukeun naha rék néangan perkiraan atawa patandingan pasti:
  • BENER atanapi disingkahkeun (standar) - perkiraan cocok. Lamun hiji patandingan pasti teu kapanggih, rumus maluruh nilai pangbadagna nu leuwih leutik batan nilai lookup.Merlukeun nyortir kolom pilarian dina urutan naek.
  • SALAH - cocok pasti. Rumus milarian nilai anu sami sareng nilai lookup. Lamun hiji patandingan pasti teu kapanggih, hiji nilai #N/A balik.

Rumus VLOOKUP Dasar

Ieu conto rumus Excel VLOOKUP dina wangun pangbasajanna. Mangga tingali rumus di handap ieu sareng cobian "narjamahkeun" kana basa Inggris:

=VLOOKUP("lion", A2:B11, 2, FALSE)

• Argumen kahiji ( lookup_value ) jelas nunjukkeun yén rumus néangan kecap "singa".
• Argumen ka-2 ( table_array ) nyaéta A2:B11. Émut yén panéangan dilakukeun dina kolom paling kénca, anjeun tiasa maca rumus di luhur sakedik: milarian "singa" dina rentang A2:A11. Sajauh ieu, saé, leres?
• Argumen ka-3 col_index_num nyaéta 2. Hartina, urang badé mulangkeun nilai anu cocog tina kolom B, anu kadua dina susunan tabel.
• Argumen ka-4 range_lookup nyaéta PALSU, anu nunjukkeun yén urang milarian patandingan anu pasti.

Kalayan sadaya argumen anu ditetepkeun, anjeun kedah henteu ngagaduhan masalah maca sadayana. rumus: milarian "singa" dina A2:A11, panggihan hiji patandingan pasti, sarta balikkeun nilai tina kolom B dina baris anu sarua.

Demi genah, anjeun tiasa ngetik nilai dipikaresep dina sababaraha sél, sebutkeun E1, ganti téks "hardcoded" sareng rujukan sél, sareng kéngingkeun rumus pikeun milarian naon waé.nilai anjeun input dina E1:

=VLOOKUP(E1, A2:B11, 2, FALSE)

Naha aya anu teu jelas? Teras cobian tingali ku cara kieu:

Kumaha cara ngalakukeun Vlookup dina Excel

Nalika nganggo rumus VLOOKUP dina lembar kerja kahirupan nyata, Aturan utama nyaéta kieu: Asép Sunandar Sunarya tabel konci kalayan rujukan sél mutlak (sapertos $A$2:$C$11) pikeun nyegah parobahan nalika nyalin rumus ka sél séjén.

The Nilai lookup dina kalolobaan kasus kedah janten rujukan relatif (sapertos E2) atanapi anjeun tiasa ngonci ukur koordinat kolom ($E2). Nalika rumus disalin ka handap kolom, rujukan bakal otomatis nyaluyukeun unggal baris.

Pikeun ningali kumaha prakna, mangga tingali conto ieu di handap. Dina tabel sampel kami, kami geus ditambahkeun hiji deui kolom nu urutan sato ku speed (kolom A) jeung hayang manggihan 1st, 5th jeung 10th sprinter panggancangna di dunya. Jang ngalampahkeun ieu, lebetkeun jajaran lookup dina sababaraha sél (E2:E4 dina screenshot handap), sarta make rumus ieu:

Pikeun narik ngaran sato ti kolom B:

=VLOOKUP($E2, $A$2:$C$11, 2, FALSE)

Pikeun nimba speed tina kolom C:

=VLOOKUP($E2, $A$2:$C$11, 3, FALSE)

Asupkeun rumus di luhur dina sél F2 jeung G2, pilih sél éta, tur sered rumus ka baris handap:

Lamun anjeun nalungtik rumus dina baris handap, anjeun bakal aya bewara yén rujukan nilai lookup geus disaluyukeun pikeun baris husus, sedengkeun susunan tabel teu robah:

Di handap, anjeun bakal boga sababarahatips nu leuwih mangpaat nu bakal nyalametkeun anjeun loba nyeri sirah jeung ngungkulan waktu.

Excel VLOOKUP - 5 hal pikeun nginget!

1. Fungsi VLOOKUP teu bisa nempo kénca na . Éta salawasna milarian dina kolom pangkénca tina susunan tabel sareng ngabalikeun nilai tina kolom ka katuhu. Upami anjeun kedah narik niléy ti kénca, paké kombinasi INDEX MATCH (atanapi INDEX XMATCH dina Excel 365) anu henteu paduli kana posisi kolom milarian sareng mulang.
2. Fungsi VLOOKUP nyaéta case-insensitive , hartina aksara gede jeung aksara leutik dianggap sarimbag. Pikeun ngabédakeun hurup hurup, paké rumus VLOOKUP anu sensitip kana hurup.
3. Émut ngeunaan pentingna parameter anu terakhir. Anggo BENER pikeun perkiraan pertandingan sareng PALSU kanggo pertandingan pasti. Kanggo detil lengkepna, mangga tingali VLOOKUP BENER vs. PALSU.
4. Nalika milarian perkiraan anu cocog, pastikeun data dina kolom milarian diurutkeun dina urutan naek.
5. Lamun nilai pilarian henteu kapanggih, kasalahan #N / ​​A dipulangkeun. Kanggo inpormasi ngeunaan kasalahan anu sanés, mangga tingali Naha Excel VLOOKUP teu tiasa dianggo.

Conto Excel VLOOKUP

Mugi-mugi pamaluruhan vertikal mimiti katingali langkung akrab ka anjeun. Pikeun nguatkeun pangaweruh anjeun, hayu urang ngawangun deui sababaraha rumus VLOOKUP.

Kumaha cara Vlookup tina lembar séjén dina Excel

Dina prakna, fungsi Excel VLOOKUP jarang pisan.dipaké jeung data dina LKS sarua. Paling sering anjeun kedah narik data anu cocog tina lembar kerja anu béda.

Pikeun Vlookup tina lambaran Excel anu béda, lebetkeun nami lembar kerja dituturkeun ku tanda seru dina argumen table_array sateuacan rentang. rujukan. Contona, pikeun milarian dina rentang A2:B10 dina Sheet2, paké rumus ieu:

=VLOOKUP("Product1", Sheet2!A2:B10, 2)

Tangtosna, anjeun henteu kedah ngetik nami lambar sacara manual. Kantun, mimitian ngetik rumus jeung lamun datang ka table_array argumen, pindah ka lembar kerja lookup tur pilih rentang maké mouse.

Contona, ieu kumaha anjeun tiasa néangan up nilai A2 dina rentang A2:A9 dina lembar kerja Harga sareng mulangkeun nilai anu cocog tina kolom C:

=VLOOKUP(A2, Prices!$A$2:$C$9, 3, FALSE)

Catetan:

• Lamun ngaran spreadsheet ngandung spasi atawa karakter non-alfabétis , éta kudu diapit ku tanda petik tunggal, misalna. 'Daptar harga'!$A$2:$C$9.
• Upami anjeun nganggo rumus VLOOKUP pikeun sababaraha sél, émut ngonci table_array nganggo tanda $, sapertos $A$2: $C$9.

Kumaha cara Vlookup tina buku kerja anu sanés dina Excel

Pikeun Vlookup tina buku kerja Excel anu sanés, lebetkeun nami buku kerja anu diapit dina kurung kuadrat sateuacan nami lembar kerja.

Contona, ieu rumus pikeun néangan nilai A2 dina lambaran ngaranna Prices dina Price_List.xlsx workbook:

=VLOOKUP(A2, [Price_List.xlsx]Prices!$A$2:$C$9, 3, FALSE)

Lamunboh nami buku kerja atanapi nami lembar kerja ngandung spasi atanapi karakter non-alfabétis, anjeun kedah ngalampirkeunana dina tanda petik tunggal sapertos kieu:

=VLOOKUP(A2, '[Price List.xlsx]Prices'!$A$2:$C$9, 3, FALSE)

Cara panggampangna pikeun ngadamel rumus VLOOKUP anu ngarujuk kana buku kerja anu béda nyaéta kieu:

1. Buka kadua file.
2. Mimitian ngetik rumus anjeun, pindah ka buku kerja anu sanés, sareng pilih susunan tabel nganggo beurit.
3. Lebetkeun argumen anu sesa teras pencét tombol Enter pikeun ngalengkepan rumus anjeun.

Hasilna bakal katingali sapertos screenshot di handap:

Sakali anjeun tutup file sareng tabel lookup anjeun, rumus VLOOKUP bakal terus jalan, tapi ayeuna bakal mintonkeun jalur lengkep pikeun workbook katutup:

Pikeun inpo nu leuwih lengkep, mangga tingali Kumaha ningali lembar Excel sejen atawa workbook.

Kumaha Vlookup tina rentang ngaranna dina lambar sejen

Lamun rencanana ngagunakeun rentang lookup nu sarua dina loba rumus, Anjeun bisa nyieun rentang ngaranna pikeun eta tur ngetik nami directl y dina argumen table_array .

Pikeun nyieun rentang ngaranna, cukup pilih sél jeung ketik ngaran nu Anjeun hoyongkeun dina kotak Nami di kénca Rumus. bar. Pikeun léngkah-léngkah anu lengkep, mangga tingali Kumaha nami rentang dina Excel.

Pikeun conto ieu, kami masihan nami Prices_2020 kana sél data (A2:C9) dina lambaran panéangan sareng meunang rumus kompak ieu:

=VLOOKUP(A2, Prices_2020, 3, FALSE)

Kalolobaan ngaran dina Excel dilarapkeun ka sakabéh workbook , jadi anjeun teu kudu nangtukeun ngaran lembar kerja nalika maké rentang ngaranna.

Lamun rentang ngaranna aya dina workbook sejen , lebetkeun nami workbook sateuacan nami rentang, contona:

=VLOOKUP(A2, 'Price List.xlsx'!Prices_2020, 3, FALSE)

Rumus sapertos kitu langkung kaharti, sanés? Sajaba ti éta, ngagunakeun rentang ngaranna bisa jadi alternatif alus pikeun rujukan mutlak. Kusabab rentang ngaranna teu robah, anjeun bisa yakin yén susunan tabel anjeun bakal tetep dikonci teu paduli dimana rumus dipindahkeun atawa disalin.

Lamun anjeun geus ngarobah rentang lookup anjeun kana tabel Excel-fungsi pinuh. , teras anjeun tiasa ngalakukeun Vlookup dumasar kana nami méja, f.eks. Tabel_harga dina rumus di handap ieu:

=VLOOKUP(A2, Price_table, 3, FALSE)

Rujukan tabel, disebut oge rujukan terstruktur, tahan banting sarta kebal kana loba manipulasi data. Salaku conto, anjeun tiasa mupus atanapi nambihan baris énggal kana méja panéangan anjeun tanpa hariwang ngeunaan ngapdet référénsi.

Maké wildcard dina rumus VLOOKUP

Sapertos seueur rumus sanés, fungsi Excel VLOOKUP. narima karakter wildcard ieu:

• Tanda tanya (?) pikeun cocog jeung karakter tunggal.
• Asterisk (*) pikeun cocog. sagala runtuyan karakter.

Wildcards ngabuktikeun bener mangpaat dina loba situasi:

• Lamun anjeun teu apal kana téks pasti nu ditéang.
• Nalika anjeun milarian téksstring anu mangrupa bagian tina eusi sél.
• Nalika kolom lookup ngandung spasi ngarah atawa labuh. Dina hal ieu, anjeun tiasa ngabodaskeun uteuk anjeun nyobian ngartos naha rumus normal henteu jalan.

Conto 1. Tingali téks anu dimimitian atanapi ditungtungan ku karakter anu tangtu

Anggap anjeun hoyong milarian palanggan anu tangtu dina pangkalan data di handap ieu. Anjeun teu apal ngaran kulawarga, tapi anjeun yakin yén éta dimimitian ku "ack".

Pikeun mulangkeun ngaran tukang ti kolom A, paké rumus wildcard Vlookup di handap ieu:

=VLOOKUP("ack*", $A$2:$B$10, 1, FALSE)

Pikeun meunangkeun konci lisénsi ti kolom B, pake ieu (bédana ngan dina nomer indéks kolom):

=VLOOKUP("ack*", $A$2:$B$10, 2, FALSE)

Anjeun oge bisa ngasupkeun bagian nu dipikawanoh tina ngaran dina sababaraha sél, sebutkeun E1, tur gabungkeun karakter wildcard jeung rujukan sél:

=VLOOKUP(E1&"*", $A$2:$B$10, 1, FALSE)

Potret layar di handap nembongkeun hasil:

Di handap ieu aya sababaraha deui rumus VLOOKUP kalawan wildcard.

Teangan ngaran tukang ditungtungan ku "putra":

=VLOOKUP("*son", $A$2:$B$10, 1, FALSE)

Meunangkeun ngaran nu dimimitian ku "joh " sarta ditungtungan ku "putra":

=VLOOKUP("joh*son", $A$2:$B$10, 1, FALSE)

Tarik ngaran tukang 5 karakter:

=VLOOKUP("?????", $A$2:$B$10, 1, FALSE)

Conto 2. VLOOKUP wildcard dumasar kana nilai sél

Ti conto saméméhna, anjeun geus nyaho yén kasebut nyaéta dimungkinkeun pikeun concatenate hiji ampersand (& amp;) jeung rujukan sél pikeun nyieun string lookup. Pikeun manggihan hiji nilai nu ngandung karakter dibikeun (s) dina posisi mana wae, nempatkeun hiji ampersand saméméh jeung sanggeus