Ma a VLOOKUP használatát nézzük meg az Excelben, sok részletes, lépésről lépésre bemutatott példával. Megtanulja, hogyan lehet Vlookup-ot használni egy másik lapról és egy másik munkafüzetből, hogyan lehet vadkártyákkal keresni, és még sok minden mást.

Ez a cikk egy olyan sorozatot indít, amely a VLOOKUP-ról szól, az egyik leghasznosabb Excel-funkcióról, ugyanakkor az egyik legbonyolultabb és legkevésbé értett funkcióról. Megpróbáljuk az alapokat nagyon egyszerű nyelven elmagyarázni, hogy egy tapasztalatlan felhasználó számára a lehető legkönnyebb legyen a tanulási folyamat. A VLOOKUP legjellemzőbb Excel-használatait lefedő képletpéldákat is adunk, és megpróbáljuk aegyszerre informatívak és szórakoztatóak.

Excel VLOOKUP funkció

Mi az a VLOOKUP? Először is, ez egy Excel-funkció :) Mit csinál? Megkeresi az Ön által megadott értéket, és egy másik oszlopból visszaadja a megfelelő értéket. Technikailag a VLOOKUP függvény egy adott tartomány első oszlopában keres egy értéket, és egy másik oszlopból visszaad egy értéket ugyanabban a sorban.

Az Excel VLOOKUP a szokásos használatban az egyedi azonosító alapján keresi meg az adathalmazát, és az adott egyedi azonosítóhoz kapcsolódó információt hoz.

A "V" betű a "vertikális" betűt jelenti, és a VLOOKUP függvényt a HLOOKUP függvénytől különbözteti meg, amely egy értéket nem oszlopban, hanem sorban keres (a H a "horizontális" betűt jelenti).

A funkció az Excel 365 és az Excel 2007 közötti összes verzióban elérhető.

Tipp. Az Excel 365 és az Excel 2021 programban használhatja az XLOOKUP funkciót, amely a VLOOKUP rugalmasabb és erőteljesebb utódja.

VLOOKUP szintaxis

A VLOOKUP funkció szintaxisa a következő:

Hol:

• Lookup_value (kötelező) - a keresendő érték.

  Ez lehet érték (szám, dátum vagy szöveg), cellahivatkozás (hivatkozás egy keresési értéket tartalmazó cellára), vagy valamilyen más függvény által visszaadott érték. A számokkal és a cellahivatkozásokkal ellentétben a szöveges értékeket mindig idézőjelek közé kell zárni.

• Table_array (kötelező) - a cellák azon tartománya, ahol a keresési értéket keresni kell, és ahonnan az egyezést le kell kérni. A VLOOKUP függvény mindig a táblázattömb első oszlopában keres , amely különböző szöveges értékeket, számokat, dátumokat és logikai értékeket tartalmazhat.
• Col_index_num (kötelező) - annak az oszlopnak a száma, amelyből az értéket vissza kell adni. A számolás a táblázat tömbjének bal szélső oszlopától kezdődik, ami 1.
• Range_lookup (opcionális) - meghatározza, hogy közelítő vagy pontos egyezést keressen:
  • TRUE vagy elhagyva (alapértelmezett) - hozzávetőleges egyezés. Ha nem talál pontos egyezést, a képlet a legnagyobb értéket keresi, amely kisebb, mint a keresési érték. A keresési oszlop növekvő sorrendbe rendezését igényli.
  • FALSE - pontos egyezés. A képlet olyan értéket keres, amely pontosan megegyezik a keresési értékkel. Ha nem talál pontos egyezést, akkor egy #N/A értéket ad vissza.

Alapvető VLOOKUP képlet

Íme egy példa az Excel VLOOKUP képletére a legegyszerűbb formában. Kérjük, nézze meg az alábbi képletet, és próbálja meg "lefordítani" angolra:

=VLOOKUP("lion", A2:B11, 2, FALSE)

• Az 1. érv ( lookup_value ) egyértelműen jelzi, hogy a képlet az "oroszlán" szót keresi.
• A 2. érv ( table_array ) az A2:B11. Ha szem előtt tartjuk, hogy a keresés a bal szélső oszlopban történik, akkor a fenti képletet egy kicsit tovább olvashatjuk: keressük az "oroszlán" szót az A2:A11 tartományban. Eddig minden rendben, igaz?
• A 3. érv col_index_num 2. Ez azt jelenti, hogy a táblázat tömbjének második oszlopában lévő B oszlopból szeretnénk visszaadni egy megfelelő értéket.
• A 4. érv range_lookup FALSE, ami azt jelzi, hogy pontos egyezést keresünk.

Ha minden argumentum megvan, nem okozhat gondot a teljes képlet olvasása: keresse meg az "oroszlán" szót az A2:A11 sorban, találja meg a pontos egyezést, és adja vissza az értéket a B oszlopból ugyanabban a sorban.

Az egyszerűség kedvéért beírhatja a kívánt értéket valamelyik cellába, mondjuk az E1-be, a "keményen kódolt" szöveget a cellahivatkozással helyettesítheti, és a képlet az E1-be beírt bármely értéket megkeresheti:

=VLOOKUP(E1, A2:B11, 2, FALSE)

Nem maradt valami tisztázatlan? Akkor próbáld meg így nézni a dolgot:

Hogyan készítsünk egy Vlookupot az Excelben

A VLOOKUP képletek valós munkalapokban történő használatakor a fő szabály a következő: zárolási táblázat tömb abszolút cellahivatkozásokkal (mint például $A$2:$C$11), hogy megakadályozza, hogy a képlet más cellákba történő másolásakor megváltozzon.

A keresési érték a legtöbb esetben relatív hivatkozásnak kell lennie (mint például E2), vagy csak az oszlopkoordinátát rögzítheti ($E2). Amikor a képletet az oszlopba másolja, a hivatkozás minden sorban automatikusan kiigazodik.

Hogy lássuk, hogyan működik a gyakorlatban, nézzük meg a következő példát. A mintatáblázatunkhoz hozzáadtunk még egy oszlopot, amely az állatokat a sebességük alapján rangsorolja (A oszlop), és szeretnénk megtalálni a világ 1., 5. és 10. leggyorsabb sprinterét. Ehhez írjuk be a keresési rangsorokat néhány cellába (E2:E4 az alábbi képernyőképen), és használjuk a következő képleteket:

Az állatnevek kihúzása a B oszlopból:

=VLOOKUP($E2, $A$2:$C$11, 2, FALSE)

A sebesség kivonása a C oszlopból:

=VLOOKUP($E2, $A$2:$C$11, 3, FALSE)

Írja be a fenti képleteket az F2 és G2 cellákba, jelölje ki ezeket a cellákat, és húzza a képleteket az alábbi sorokba:

Ha megvizsgálja a képletet egy alsó sorban, akkor észreveheti, hogy a keresési értékre való hivatkozás az adott sorhoz igazodott, míg a táblázat tömbje nem változott:

Az alábbiakban néhány további hasznos tippet talál, amelyekkel sok fejfájástól és hibaelhárítási időtől kímélheti meg magát.

Excel VLOOKUP - 5 dolog, amit érdemes megjegyezni!

1. A VLOOKUP függvény nem tud a bal oldali részre nézni. . Mindig a legbaloldali oszlop a táblázat tömbjének, és visszaad egy értéket a jobb oldali oszlopból. Ha balról kell értékeket húzni, használja az INDEX MATCH (vagy INDEX XMATCH az Excel 365-ben) kombinációt, amely nem törődik a keresési és visszatérési oszlopok pozícionálásával.
2. A VLOOKUP funkció nem érzékeny a nagy- és kisbetűkre. , ami azt jelenti, hogy a nagy- és kisbetűket egyenértékűnek kell tekinteni. A betűjelek megkülönböztetése érdekében használjon nagy- és kisbetű-érzékeny VLOOKUP-képleteket.
3. Ne feledje az utolsó paraméter fontosságát. Használja a TRUE-t a közelítő egyezéshez és a FALSE-t a pontos egyezéshez. A teljes részleteket lásd: VLOOKUP TRUE vs. FALSE.
4. A közelítő egyezés keresésekor győződjön meg arról, hogy a keresési oszlopban lévő adatok növekvő sorrendbe vannak rendezve.
5. Ha a keresési érték nem található, a rendszer egy #N/A hibaüzenetet küld vissza. Az egyéb hibákkal kapcsolatos információkért lásd a Miért nem működik az Excel VLOOKUP.

Excel VLOOKUP példák

Remélem, hogy a függőleges keresés már kezd egy kicsit ismerősebbnek tűnni számodra. Hogy megerősítsük a tudásodat, építsünk fel néhány további VLOOKUP képletet.

Hogyan lehet Vlookup egy másik lapról az Excelben

A gyakorlatban az Excel VLOOKUP funkcióját ritkán használják az ugyanazon a munkalapon lévő adatokkal. Leggyakrabban egy másik munkalapról kell megfelelő adatokat húzni.

Ha egy másik Excel lapról szeretné a Vlookupot létrehozni, akkor a munkalap nevét egy felkiáltójellel követve írja be a table_array argumentumot a tartományhivatkozás előtt. Például, ha a 2. lap A2:B10 tartományában szeretne keresni, használja ezt a képletet:

=VLOOKUP("Product1", Sheet2!A2:B10, 2)

Természetesen nem kell manuálisan beírni a lap nevét. Egyszerűen csak kezdje el begépelni a képletet, és amikor eléri a table_array argumentummal váltson a keresési munkalapra, és jelölje ki a tartományt az egérrel.

Például így kereshetjük meg az A2 értéket az A2:A9 tartományban a következő módon Árak munkalapot, és adja vissza a C oszlopban lévő megfelelő értéket:

=VLOOKUP(A2, Árak!$A$2:$C$9, 3, FALSE)

Megjegyzések:

• Ha a táblázatkezelő neve tartalmazza a szóközök vagy nem ábécés karakterek , azt szimpla idézőjelek közé kell zárni, pl. "Árlista"!$A$2:$C$9.
• Ha több cellára is használ VLOOKUP képletet, ne feledje, hogy lock table_array a $ jellel, például $A$2:$C$9.

Hogyan lehet Vlookup egy másik munkafüzetből az Excelben

Ha egy másik Excel-munkafüzetből szeretne Vlookupot létrehozni, tegye a munkafüzet nevét szögletes zárójelbe a munkalap neve elé.

Itt van például a képlet az A2 érték kereséséhez a következő nevű lapon Árak a Ár_List.xlsx munkafüzet:

=VLOOKUP(A2, [Price_List.xlsx]Prices!$A$2:$C$9, 3, FALSE)

Ha a munkafüzet neve vagy a munkalap neve szóközöket vagy nem ábécés karaktereket tartalmaz, akkor azokat szimpla idézőjelek közé kell zárni, például így:

=VLOOKUP(A2, '[Árlista.xlsx]Árak'!$A$2:$C$9, 3, FALSE)

A legegyszerűbb módja annak, hogy egy másik munkafüzetre hivatkozó VLOOKUP-formulát készítsünk, a következő:

1. Nyissa meg mindkét fájlt.
2. Kezdje el begépelni a képletet, váltson át a másik munkafüzetre, és jelölje ki a táblázat tömbjét az egérrel.
3. Írja be a többi argumentumot, és nyomja meg az Enter billentyűt a képlet befejezéséhez.

Az eredmény nagyjából úgy fog kinézni, mint az alábbi képernyőképen:

Ha egyszer close a keresőtáblázatot tartalmazó fájlt, a VLOOKUP formula továbbra is működik, de most már a zárt munkafüzet teljes elérési útvonalát fogja megjeleníteni:

További információért lásd: Hogyan hivatkozhat egy másik Excel-táblára vagy munkafüzetre?

Hogyan lehet Vlookup egy megnevezett tartományból egy másik lapban

Abban az esetben, ha ugyanazt a keresési tartományt több képletben is használni kívánja, létrehozhat egy elnevezett tartományt, és a nevet közvetlenül beírhatja a table_array érv.

Nevesített tartomány létrehozásához egyszerűen jelölje ki a cellákat, és írja be a kívánt nevet a Név A részletes lépéseket lásd a Hogyan nevezzünk el egy tartományt az Excelben című fejezetben.

Ehhez a példához a következő nevet adtuk Árak_2020 a keresési lap (A2:C9) adatcelláira, és megkapja ezt a kompakt képletet:

=VLOOKUP(A2, Prices_2020, 3, FALSE)

Az Excelben a legtöbb név a teljes munkafüzet , így nem kell megadnia a munkalap nevét, ha nevesített tartományokat használ.

Ha a megnevezett tartomány a egy másik munkafüzet , a tartomány neve elé tegye a munkafüzet nevét, például:

=VLOOKUP(A2, 'Árlista.xlsx'!Árak_2020, 3, FALSE)

Az ilyen képletek sokkal érthetőbbek, nem igaz? Emellett a megnevezett tartományok használata jó alternatívája lehet az abszolút hivatkozásoknak. Mivel egy megnevezett tartomány nem változik, biztos lehet benne, hogy a táblázat tömbje zárolva marad, függetlenül attól, hogy a képletet hová mozgatjuk vagy másoljuk.

Ha a keresési tartományt teljesen működőképes Excel-táblává alakította át, akkor a táblázat neve alapján Vlookupot végezhet, például. Price_table az alábbi képletben:

=VLOOKUP(A2, Price_table, 3, FALSE)

A táblázathivatkozások, más néven strukturált hivatkozások rugalmasak és immunisak számos adatmanipulációra. Például eltávolíthat vagy hozzáadhat új sorokat a keresőtáblához anélkül, hogy aggódnia kellene a hivatkozások frissítése miatt.

A VLOOKUP-képletben szereplő jokerek használata

Sok más képlethez hasonlóan az Excel VLOOKUP függvény is elfogadja a következő helyettesítő karaktereket:

• Kérdőjel (?), hogy bármelyik karakterre illeszkedjen.
• Asterisk (*) bármely karaktersorozatra.

A vadkártyák sok helyzetben nagyon hasznosnak bizonyulnak:

• Ha nem emlékszik a keresett szövegre.
• Ha a cellatartalom részét képező szöveges karakterláncot keres.
• Ha egy keresési oszlop vezető vagy követő szóközöket tartalmaz. Ebben az esetben az agyadat törheted, hogy kitaláld, miért nem működik a normál képlet.

Példa 1. Bizonyos karakterekkel kezdődő vagy végződő szöveg keresése

Tegyük fel, hogy meg akarsz találni egy bizonyos ügyfelet az alábbi adatbázisban. Nem emlékszel a vezetéknevére, de biztos vagy benne, hogy "ack" betűvel kezdődik.

Az A oszlopban szereplő vezetéknév visszaadásához használja a következő Vlookup helyettesítő képletet:

=VLOOKUP("ack*", $A$2:$B$10, 1, FALSE)

Ha a licenckulcsot a B oszlopból szeretné lekérni, használja ezt (a különbség csak az oszlop indexszámában van):

=VLOOKUP("ack*", $A$2:$B$10, 2, FALSE)

A név ismert részét beírhatja valamelyik cellába is, mondjuk az E1-be, és kombinálhatja a joker karaktert a cellahivatkozással:

=VLOOKUP(E1& "*", $A$2:$B$10, 1, FALSE)

Az alábbi képernyőkép mutatja az eredményeket:

Az alábbiakban néhány további VLOOKUP-képletet mutatunk be vadkártyákkal.

Keresse meg a "son" végződésű vezetékneveket:

=VLOOKUP("*son", $A$2:$B$10, 1, FALSE)

Szerezd meg azt a nevet, amelyik "joh"-val kezdődik és "son"-nal végződik:

=VLOOKUP("joh*son", $A$2:$B$10, 1, FALSE)

Húzzon ki egy 5 karakteres vezetéknevet:

=VLOOKUP("?????", $A$2:$B$10, 1, FALSE)

Példa 2. VLOOKUP jokerjegy a cella értéke alapján

Az előző példából már tudod, hogy lehetséges egy zárójel (&) és egy cellahivatkozás összekapcsolása egy keresési karakterlánc létrehozásához. Ha olyan értéket szeretnél találni, amely egy adott karakter(eke)t tartalmaz bármelyik pozícióban, tegyél egy zárójelet a cellahivatkozás elé és után.

Tegyük fel, hogy egy bizonyos licenckulcsnak megfelelő nevet szeretne kapni, de nem ismeri a teljes kulcsot, csak néhány karaktert. Az A oszlopban lévő kulcsokkal, a B oszlopban lévő nevekkel és az E1 oszlopban lévő célkulcs egy részével így végezhet egy wildcard Vlookupot:

Vegye ki a kulcsot:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 1, FALSE)

Vegye ki a nevet:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 2, FALSE)

Megjegyzések:

• Ahhoz, hogy a VLOOKUP-képlet helyesen működjön, használjon pontos egyezést (FALSE az utolsó argumentum).
• Ha egynél több egyezést találunk, az elsőt kapjuk vissza. .

VLOOKUP TRUE vs FALSE

És most itt az ideje, hogy közelebbről megvizsgáljuk az Excel VLOOKUP függvény utolsó argumentumát. Bár opcionális, a range_lookup paraméter rendkívül fontos. Attól függően, hogy a TRUE vagy a FALSE értéket választja, a képlet eltérő eredményeket adhat.

Excel VLOOKUP pontos egyezés (FALSE)

Ha range_lookup FALSE értékre van állítva, a Vlookup formula olyan értéket keres, amely pontosan megegyezik a keresési értékkel. Ha két vagy több egyezést talál, akkor az 1. értéket adja vissza. Ha nem talál pontos egyezést, akkor #N/A hiba lép fel.

Excel VLOOKUP közelítő egyezés (TRUE)

Ha range_lookup értéke TRUE vagy elhagyva (alapértelmezett), a képlet a legközelebbi egyezést keresi. Pontosabban, először a pontos egyezést keresi, és ha nem talál pontos egyezést, akkor a következő legnagyobb értéket keresi, amely kisebb, mint a keresési érték.

A közelítő egyezés Vlookup a következő fenntartásokkal működik:

• A keresési oszlopot a növekvő sorrendben , a legkisebbtől a legnagyobbig, különben előfordulhat, hogy nem találjuk meg a helyes értéket.
• Ha a keresési érték kisebb, mint a keresési tömb legkisebb értéke, a rendszer #N/A hibát küld vissza.

A következő példák segítenek jobban megérteni a különbséget a pontos és a közelítő egyezésű Vlookup között, valamint azt, hogy mikor melyik képletet érdemes használni.

Példa 1. Hogyan készítsünk pontos egyezésű Vlookupot?

Ha pontos egyezést szeretne keresni, akkor az utolsó argumentumba csak FALSE-t írjon.

Ehhez a példához vegyük az állatok sebességét tartalmazó táblázatot, cseréljük fel az oszlopokat, és próbáljuk megkeresni azokat az állatokat, amelyek 80, 50 és 30 mérföldet tudnak futni óránként. A D2, D3 és D4 cellákban lévő keresési értékekkel írjuk be az alábbi képletet az E2 cellába, majd másoljuk le két további cellába:

=VLOOKUP(D2, $A$2:$B$12, 2, FALSE)

Amint látható, a képlet az E3-ban az "Oroszlán" értéket adja vissza, mivel óránként pontosan 50-et futtatnak. A másik két keresési érték esetében nem talál pontos egyezést, és #N/A hiba jelenik meg.

Példa 2. Hogyan kell Vlookup-ot használni a közelítő egyezéshez?

Egy közelítő egyezés kereséséhez két alapvető dolgot kell tennie:

• Rendezze az első oszlopot a table_array a legkisebbtől a legnagyobbig.
• Használja a TRUE-t a range_lookup argumentumot, vagy hagyja ki.

A keresési oszlop rendezése nagyon fontos, mivel a VLOOKUP funkció leállítja a keresést, amint a keresési értéknél kisebb közeli egyezést talál. Ha az adatok nincsenek megfelelően rendezve, akkor nagyon furcsa eredményeket vagy egy csomó #N/A hibát kaphat.

A mintaadataink esetében a Vlookup-képlet közelítő egyezése a következőképpen néz ki:

=VLOOKUP(D2, $A$2:$B$12, 2, TRUE)

És a következő eredményeket adja vissza:

• A "80" keresési értékre a "Cheetah" kerül visszaküldésre, mivel a sebesség (70) a legközelebbi egyezés, amely kisebb, mint a keresési érték.
• Az "50" keresési érték esetén pontos egyezést kapunk (Lion).
• A "30" keresési érték esetén a rendszer #N/A hibát küld vissza, mivel a keresési érték kisebb, mint a keresési oszlop legkisebb értéke.

Speciális eszközök a Vlookuphoz az Excelben

Kétségtelen, hogy a VLOOKUP az egyik legerősebb és leghasznosabb Excel-funkció, de egyben az egyik legzavaróbb is. Hogy a tanulási görbe kevésbé meredek és az élmény élvezetesebb legyen, az Ultimate Suite for Excel programcsomagunkba beépítettünk néhány időtakarékos eszközt.

VLOOKUP varázsló - egyszerű módja az összetett képletek írásának

Az interaktív VLOOKUP varázsló végigvezeti Önt a konfigurációs lehetőségeken, hogy tökéletes képletet készítsen az Ön által megadott kritériumoknak. Az adatszerkezettől függően a standard VLOOKUP funkciót vagy egy INDEX MATCH képletet fog használni, amely balról húzhat értékeket.

A személyre szabott formula megszerzéséhez a következőket kell tennie:

1. Futtassa a VLOOKUP varázslót.

1. Válassza ki a fő táblázatot és a keresőtáblát.
2. Adja meg a következő oszlopokat (sok esetben automatikusan kiválasztódnak):
   • Kulcs oszlop - a fő táblázat oszlopát, amely a keresendő értékeket tartalmazza.
   • Kereső oszlop - az oszlopot, hogy felfelé nézzen.
   • Visszatérési oszlop - az oszlop, amelyből az értékeket lekérdezi.
3. Kattintson a Beillesztés gomb.

A következő példák a varázslót működés közben mutatják be.

Standard Vlookup

Amikor a kereső oszlop ( Állat ) a keresési táblázat legbaloldali oszlopa, a pontos egyezéshez egy normál VLOOKUP-képlet kerül beillesztésre:

Vlookup balra

Amikor a kereső oszlop ( Állat ) a visszatérési oszlop jobb oldalán van ( Sebesség ), a varázsló egy INDEX MATCH képletet illeszt be a Vlookup jobbra-balra mutató képletbe:

Extra bónusz! A cellahivatkozások okos használatának köszönhetően a képletek másolhatók vagy áthelyezhetők bármelyik oszlopba anélkül, hogy a hivatkozásokat frissítenie kellene.

Két táblázat egyesítése - az Excel VLOOKUP képletmentes alternatívája

Ha az Excel-fájljai rendkívül nagyok és összetettek, a projekt határideje közeleg, és keres valakit, aki segítő kezet nyújthat, próbálja ki a Táblák egyesítése varázslót.

Ez az eszköz az Excel VLOOKUP funkciójának vizuális és stresszmentes alternatívája, amely így működik:

1. Válassza ki a fő táblázatot.
2. Válassza ki a keresőtáblát.
3. Válasszon egy vagy több közös oszlopot egyedi azonosító(k)nak.
4. Adja meg, hogy mely oszlopokat kívánja frissíteni.
5. Opcionálisan válassza ki a hozzáadandó oszlopokat.
6. Hagyja, hogy a táblázategyesítés varázsló néhány másodpercig dolgozzon... és élvezze az eredményt :)

Ez a VLOOKUP használata az Excelben alapszinten. A bemutató következő részében a fejlett VLOOKUP példákat fogjuk megvitatni, amelyek megtanítják, hogyan lehet több kritériumot Vlookup-olni, az összes egyezést vagy az N-edik előfordulást visszaadni, dupla Vlookup-ot végrehajtani, több lapon keresztül keresni egyetlen képlettel, és így tovább. Köszönöm, hogy elolvasták, és remélem, hogy találkozunk a jövő héten!

Elérhető letöltések

Excel VLOOKUP képlet példák (.xlsx fájl)

Ultimate Suite 14 napos, teljesen funkcionális verzió (.exe fájl)