Σήμερα θα δούμε πώς να χρησιμοποιείτε το VLOOKUP στο Excel με πολλά λεπτομερή παραδείγματα βήμα προς βήμα. Θα μάθετε πώς να κάνετε Vlookup από άλλο φύλλο και διαφορετικό βιβλίο εργασίας, αναζήτηση με μπαλαντέρ και πολλά άλλα.

Αυτό το άρθρο ξεκινάει μια σειρά που καλύπτει την VLOOKUP, μια από τις πιο χρήσιμες συναρτήσεις του Excel και ταυτόχρονα μια από τις πιο περίπλοκες και λιγότερο κατανοητές. Θα προσπαθήσουμε να εξηγήσουμε τα βασικά σε μια πολύ απλή γλώσσα για να κάνουμε την εκμάθηση για έναν άπειρο χρήστη όσο το δυνατόν πιο εύκολη. Θα παρέχουμε επίσης παραδείγματα τύπων που καλύπτουν τις πιο τυπικές χρήσεις της VLOOKUP στο Excel και θα προσπαθήσουμε να κάνουμεκαι ενημερωτικό και διασκεδαστικό.

Λειτουργία VLOOKUP του Excel

Τι είναι το VLOOKUP; Κατ' αρχάς, είναι μια συνάρτηση του Excel :) Τι κάνει; Αναζητά την τιμή που καθορίζετε και επιστρέφει μια αντίστοιχη τιμή από μια άλλη στήλη. Πιο τεχνικά, η συνάρτηση VLOOKUP αναζητά μια τιμή στην πρώτη στήλη ενός συγκεκριμένου εύρους και επιστρέφει μια τιμή στην ίδια γραμμή από μια άλλη στήλη.

Στην κοινή του χρήση, το VLOOKUP του Excel αναζητά στο σύνολο δεδομένων σας με βάση το μοναδικό αναγνωριστικό και σας φέρνει μια πληροφορία που σχετίζεται με αυτό το μοναδικό αναγνωριστικό.

Το γράμμα "V" σημαίνει "κατακόρυφο" και χρησιμοποιείται για να διαφοροποιήσει τη VLOOKUP από τη συνάρτηση HLOOKUP που αναζητά μια τιμή σε μια γραμμή και όχι σε μια στήλη (H σημαίνει "οριζόντια").

Η λειτουργία είναι διαθέσιμη σε όλες τις εκδόσεις του Excel 365 έως το Excel 2007.

Συμβουλή. Στο Excel 365 και στο Excel 2021, μπορείτε να χρησιμοποιήσετε τη συνάρτηση XLOOKUP, η οποία είναι ένας πιο ευέλικτος και ισχυρός διάδοχος της VLOOKUP.

Σύνταξη VLOOKUP

Η σύνταξη της συνάρτησης VLOOKUP έχει ως εξής:

Πού:

• Lookup_value (υποχρεωτικό) - είναι η τιμή για την οποία θα γίνει αναζήτηση.

  Αυτή μπορεί να είναι μια τιμή (αριθμός, ημερομηνία ή κείμενο), αναφορά κελιού (αναφορά σε ένα κελί που περιέχει μια τιμή αναζήτησης) ή η τιμή που επιστρέφεται από κάποια άλλη συνάρτηση. Σε αντίθεση με τους αριθμούς και τις αναφορές κελιών, οι τιμές κειμένου πρέπει πάντα να περικλείονται σε "διπλά εισαγωγικά".

• Table_array (υποχρεωτικό) - είναι η περιοχή κελιών όπου θα αναζητηθεί η τιμή αναζήτησης και από την οποία θα ανακτηθεί μια αντιστοιχία. Η συνάρτηση VLOOKUP ψάχνει πάντα στην πρώτη στήλη του πίνακα , τα οποία μπορεί να περιέχουν διάφορες τιμές κειμένου, αριθμούς, ημερομηνίες και λογικές τιμές.
• Col_index_num (υποχρεωτικό) - είναι ο αριθμός της στήλης από την οποία θα επιστραφεί μια τιμή. Η μέτρηση ξεκινά από την πιο αριστερή στήλη του πίνακα, η οποία είναι 1.
• Range_lookup (προαιρετικό) - καθορίζει εάν θα γίνει αναζήτηση για κατά προσέγγιση ή ακριβή αντιστοιχία:
  • TRUE ή παραλείπεται (προεπιλογή) - κατά προσέγγιση αντιστοιχία. Εάν δεν βρεθεί ακριβής αντιστοιχία, ο τύπος αναζητά τη μεγαλύτερη τιμή που είναι μικρότερη από την τιμή αναζήτησης. Απαιτεί ταξινόμηση της στήλης αναζήτησης σε αύξουσα σειρά.
  • FALSE - ακριβής αντιστοιχία. Ο τύπος αναζητά μια τιμή ακριβώς ίση με την τιμή αναζήτησης. Εάν δεν βρεθεί ακριβής αντιστοιχία, επιστρέφεται μια τιμή #N/A.

Βασικός τύπος VLOOKUP

Ακολουθεί ένα παράδειγμα του τύπου VLOOKUP του Excel στην απλούστερη μορφή του. Ρίξτε μια ματιά στον παρακάτω τύπο και προσπαθήστε να τον "μεταφράσετε" στα αγγλικά:

=VLOOKUP("lion", A2:B11, 2, FALSE)

• Το 1ο επιχείρημα ( lookup_value ) δείχνει σαφώς ότι ο τύπος αναζητά τη λέξη "λιοντάρι".
• Το 2ο επιχείρημα ( table_array ) είναι A2:B11. Έχοντας κατά νου ότι η αναζήτηση πραγματοποιείται στην αριστερότερη στήλη, μπορείτε να διαβάσετε τον παραπάνω τύπο λίγο πιο πέρα: αναζητήστε το "λιοντάρι" στο εύρος A2:A11. Μέχρι εδώ, όλα καλά, σωστά;
• Το 3ο επιχείρημα col_index_num είναι 2. Δηλαδή, θέλουμε να επιστρέψουμε μια αντίστοιχη τιμή από τη στήλη B, η οποία είναι η δεύτερη στον πίνακα.
• Το 4ο επιχείρημα range_lookup είναι FALSE, το οποίο υποδηλώνει ότι αναζητούμε ακριβή αντιστοιχία.

Με όλα τα επιχειρήματα να έχουν καθοριστεί, δεν θα πρέπει να έχετε κανένα πρόβλημα να διαβάσετε ολόκληρο τον τύπο: αναζητήστε το "lion" στο A2:A11, βρείτε μια ακριβή αντιστοιχία και επιστρέψτε μια τιμή από τη στήλη B της ίδιας γραμμής.

Για λόγους ευκολίας, μπορείτε να πληκτρολογήσετε την τιμή που σας ενδιαφέρει σε κάποιο κελί, ας πούμε στο E1, να αντικαταστήσετε το "σκληρά κωδικοποιημένο" κείμενο με την αναφορά του κελιού και να κάνετε τον τύπο να αναζητήσει οποιαδήποτε τιμή εισάγετε στο E1:

=VLOOKUP(E1, A2:B11, 2, FALSE)

Παραμένει κάτι ασαφές; Τότε προσπαθήστε να το δείτε με τον εξής τρόπο:

Πώς να κάνετε ένα Vlookup στο Excel

Κατά τη χρήση τύπων VLOOKUP σε πραγματικά φύλλα εργασίας, ο βασικός κανόνας είναι ο εξής: πίνακας κλειδώματος με απόλυτες αναφορές κελιών (όπως $A$2:$C$11) για να μην αλλάζει κατά την αντιγραφή ενός τύπου σε άλλα κελιά.

Το τιμή αναζήτησης στις περισσότερες περιπτώσεις θα πρέπει να είναι μια σχετική αναφορά (όπως το E2) ή μπορείτε να κλειδώσετε μόνο τη συντεταγμένη της στήλης ($E2). Όταν ο τύπος αντιγράφεται προς τα κάτω στη στήλη, η αναφορά θα προσαρμοστεί αυτόματα για κάθε γραμμή.

Για να δείτε πώς λειτουργεί στην πράξη, αναλογιστείτε το ακόλουθο παράδειγμα. Στον πίνακα του δείγματός μας, έχουμε προσθέσει μια ακόμη στήλη που κατατάσσει τα ζώα με βάση την ταχύτητα (στήλη Α) και θέλουμε να βρούμε τον 1ο, 5ο και 10ο ταχύτερο σπρίντερ στον κόσμο. Για το σκοπό αυτό, εισάγετε τις τάξεις αναζήτησης σε ορισμένα κελιά (Ε2:Ε4 στο παρακάτω στιγμιότυπο οθόνης) και χρησιμοποιήστε τους ακόλουθους τύπους:

Για να τραβήξετε τα ονόματα των ζώων από τη στήλη Β:

=VLOOKUP($E2, $A$2:$C$11, 2, FALSE)

Για να εξαγάγετε την ταχύτητα από τη στήλη C:

=VLOOKUP($E2, $A$2:$C$11, 3, FALSE)

Εισάγετε τους παραπάνω τύπους στα κελιά F2 και G2, επιλέξτε αυτά τα κελιά και σύρετε τους τύπους στις παρακάτω γραμμές:

Αν εξετάσετε τον τύπο σε μια χαμηλότερη γραμμή, θα παρατηρήσετε ότι η αναφορά της τιμής αναζήτησης έχει προσαρμοστεί για τη συγκεκριμένη γραμμή, ενώ ο πίνακας παραμένει αμετάβλητος:

Παρακάτω θα βρείτε μερικές ακόμα χρήσιμες συμβουλές που θα σας γλιτώσουν από πολύ πονοκέφαλο και χρόνο για την αντιμετώπιση προβλημάτων.

Excel VLOOKUP - 5 πράγματα που πρέπει να θυμάστε!

1. Η συνάρτηση VLOOKUP δεν μπορεί να κοιτάξει στα αριστερά της . Ψάχνει πάντα στο πιο αριστερή στήλη του πίνακα και επιστρέφει μια τιμή από μια στήλη στα δεξιά. Εάν πρέπει να τραβήξετε τιμές από τα αριστερά, χρησιμοποιήστε το συνδυασμό INDEX MATCH (ή INDEX XMATCH στο Excel 365) που δεν ενδιαφέρεται για τη θέση των στηλών αναζήτησης και επιστροφής.
2. Η συνάρτηση VLOOKUP δεν λαμβάνει υπόψη την πεζότητα , που σημαίνει ότι οι κεφαλαίοι και οι πεζοί χαρακτήρες αντιμετωπίζονται ως ισοδύναμοι. Για να διακρίνετε την πεζότητα των γραμμάτων, χρησιμοποιήστε τύπους VLOOKUP με ευαισθησία στην πεζότητα.
3. Να θυμάστε τη σημασία της τελευταίας παραμέτρου. Χρησιμοποιήστε TRUE για προσεγγιστική αντιστοίχιση και FALSE για ακριβή αντιστοίχιση. Για πλήρεις λεπτομέρειες, ανατρέξτε στην ενότητα VLOOKUP TRUE vs. FALSE.
4. Κατά την αναζήτηση για κατά προσέγγιση αντιστοιχία, βεβαιωθείτε ότι τα δεδομένα στη στήλη αναζήτησης είναι ταξινομημένα σε αύξουσα σειρά.
5. Εάν η τιμή αναζήτησης δεν βρεθεί, επιστρέφεται ένα σφάλμα #N/A. Για πληροφορίες σχετικά με άλλα σφάλματα, ανατρέξτε στην ενότητα Γιατί δεν λειτουργεί το VLOOKUP του Excel.

Παραδείγματα Excel VLOOKUP

Ελπίζω ότι η κάθετη αναζήτηση αρχίζει να σας φαίνεται λίγο πιο οικεία. Για να ενισχύσετε τις γνώσεις σας, ας φτιάξουμε μερικούς ακόμη τύπους VLOOKUP.

Πώς να Vlookup από ένα άλλο φύλλο στο Excel

Στην πράξη, η λειτουργία VLOOKUP του Excel χρησιμοποιείται σπάνια με δεδομένα στο ίδιο φύλλο εργασίας. Τις περισσότερες φορές θα πρέπει να αντλήσετε τα αντίστοιχα δεδομένα από ένα διαφορετικό φύλλο εργασίας.

Για να κάνετε Vlookup από ένα διαφορετικό φύλλο του Excel, βάλτε το όνομα του φύλλου εργασίας ακολουθούμενο από ένα θαυμαστικό στο πεδίο table_array Για παράδειγμα, για να κάνετε αναζήτηση στην περιοχή A2:B10 στο φύλλο2, χρησιμοποιήστε αυτόν τον τύπο:

=VLOOKUP("Product1", Sheet2!A2:B10, 2)

Φυσικά, δεν χρειάζεται να πληκτρολογήσετε το όνομα του φύλλου χειροκίνητα. Απλά, αρχίστε να πληκτρολογείτε τον τύπο και όταν φτάσετε στο πεδίο table_array επιχείρημα, μεταβείτε στο φύλλο εργασίας αναζήτησης και επιλέξτε την περιοχή με το ποντίκι.

Για παράδειγμα, με τον εξής τρόπο μπορείτε να αναζητήσετε την τιμή A2 στο εύρος A2:A9 στο Τιμές φύλλο εργασίας και να επιστρέψει μια αντίστοιχη τιμή από τη στήλη C:

=VLOOKUP(A2, Prices!$A$2:$C$9, 3, FALSE)

Σημειώσεις:

• Εάν το όνομα του λογιστικού φύλλου περιέχει κενά ή μη αλφαβητικοί χαρακτήρες , πρέπει να περικλείεται σε απλά εισαγωγικά, π.χ. "Τιμοκατάλογος"!$A$2:$C$9.
• Σε περίπτωση που χρησιμοποιείτε έναν τύπο VLOOKUP για πολλαπλά κελιά, θυμηθείτε να lock table_array με το σύμβολο $, όπως $A$2:$C$9.

Πώς να κάνετε Vlookup από ένα άλλο βιβλίο εργασίας στο Excel

Για να κάνετε Vlookup από ένα διαφορετικό βιβλίο εργασίας του Excel, βάλτε το όνομα του βιβλίου εργασίας μέσα σε αγκύλες πριν από το όνομα του φύλλου εργασίας.

Για παράδειγμα, εδώ είναι ο τύπος για να αναζητήσετε την τιμή A2 στο φύλλο με όνομα Τιμές στο Τιμοκατάλογος.xlsx βιβλίο εργασίας:

=VLOOKUP(A2, [Price_List.xlsx]Prices!$A$2:$C$9, 3, FALSE)

Εάν το όνομα του βιβλίου εργασίας ή του φύλλου εργασίας περιέχει κενά ή μη αλφαβητικούς χαρακτήρες, θα πρέπει να τα περικλείετε σε μονά εισαγωγικά, όπως παρακάτω:

=VLOOKUP(A2, '[Price List.xlsx]Prices'!$A$2:$C$9, 3, FALSE)

Ο ευκολότερος τρόπος για να δημιουργήσετε έναν τύπο VLOOKUP που αναφέρεται σε διαφορετικό βιβλίο εργασίας είναι ο εξής:

1. Ανοίξτε και τα δύο αρχεία.
2. Ξεκινήστε να πληκτρολογείτε τον τύπο σας, μεταβείτε στο άλλο βιβλίο εργασίας και επιλέξτε τη σειρά πινάκων χρησιμοποιώντας το ποντίκι.
3. Εισάγετε τα υπόλοιπα ορίσματα και πατήστε το πλήκτρο Enter για να ολοκληρώσετε τον τύπο σας.

Το αποτέλεσμα θα μοιάζει κάπως με το παρακάτω στιγμιότυπο οθόνης:

Μόλις close το αρχείο με τον πίνακα αναζήτησης, ο τύπος VLOOKUP θα συνεχίσει να λειτουργεί, αλλά τώρα θα εμφανίζει την πλήρη διαδρομή για το κλειστό βιβλίο εργασίας:

Για περισσότερες πληροφορίες, ανατρέξτε στην ενότητα Πώς να παραπέμψετε σε άλλο φύλλο ή βιβλίο εργασίας του Excel.

Πώς να κάνετε Vlookup από μια ονομαστική περιοχή σε ένα άλλο φύλλο

Σε περίπτωση που σκοπεύετε να χρησιμοποιήσετε το ίδιο εύρος αναζήτησης σε πολλούς τύπους, μπορείτε να δημιουργήσετε ένα εύρος με όνομα και να πληκτρολογήσετε το όνομα απευθείας στο πεδίο table_array επιχείρημα.

Για να δημιουργήσετε μια περιοχή με όνομα, απλά επιλέξτε τα κελιά και πληκτρολογήστε το όνομα που θέλετε στο πεδίο Όνομα Για τα λεπτομερή βήματα, ανατρέξτε στην ενότητα Πώς να ονομάσετε μια περιοχή στο Excel.

Για αυτό το παράδειγμα, δώσαμε το όνομα Τιμές_2020 στα κελιά δεδομένων (A2:C9) στο φύλλο αναζήτησης και να λάβετε αυτόν τον συμπαγή τύπο:

=VLOOKUP(A2, Prices_2020, 3, FALSE)

Τα περισσότερα ονόματα στο Excel ισχύουν για το ολόκληρο το βιβλίο εργασίας , οπότε δεν χρειάζεται να καθορίσετε το όνομα του φύλλου εργασίας όταν χρησιμοποιείτε ονομαστικές περιοχές.

Εάν η ονομαζόμενη περιοχή βρίσκεται στην ένα άλλο βιβλίο εργασίας , βάλτε το όνομα του βιβλίου εργασίας πριν από το όνομα της περιοχής, για παράδειγμα:

=VLOOKUP(A2, 'Price List.xlsx'!Prices_2020, 3, FALSE)

Τέτοιοι τύποι είναι πολύ πιο κατανοητοί, έτσι δεν είναι; Εκτός αυτού, η χρήση ονομαστικών περιοχών μπορεί να είναι μια καλή εναλλακτική λύση στις απόλυτες αναφορές. Δεδομένου ότι μια ονομαστική περιοχή δεν αλλάζει, μπορείτε να είστε σίγουροι ότι ο πίνακας σας θα παραμείνει κλειδωμένος όπου κι αν μετακινηθεί ή αντιγραφεί ο τύπος.

Εάν έχετε μετατρέψει την περιοχή αναζήτησης σε έναν πλήρως λειτουργικό πίνακα του Excel, τότε μπορείτε να κάνετε μια αναζήτηση Vlookup με βάση το όνομα του πίνακα, π.χ. Price_table στον παρακάτω τύπο:

=VLOOKUP(A2, Price_table, 3, FALSE)

Οι αναφορές σε πίνακες, που ονομάζονται επίσης δομημένες αναφορές, είναι ανθεκτικές και απρόσβλητες σε πολλούς χειρισμούς δεδομένων. Για παράδειγμα, μπορείτε να αφαιρείτε ή να προσθέτετε νέες γραμμές στον πίνακα αναζήτησης χωρίς να ανησυχείτε για την ενημέρωση των αναφορών.

Χρήση μπαλαντέρ στον τύπο VLOOKUP

Όπως και πολλοί άλλοι τύποι, η συνάρτηση VLOOKUP του Excel δέχεται τους ακόλουθους χαρακτήρες μπαλαντέρ:

• Ερωτηματικό (?) για να ταιριάζει με οποιονδήποτε μεμονωμένο χαρακτήρα.
• Αστερίσκος (*) για να ταιριάζει με οποιαδήποτε ακολουθία χαρακτήρων.

Οι μπαλαντέρ αποδεικνύονται πραγματικά χρήσιμες σε πολλές περιπτώσεις:

• Όταν δεν θυμάστε το ακριβές κείμενο που ψάχνετε.
• Όταν αναζητάτε μια συμβολοσειρά κειμένου που αποτελεί μέρος του περιεχομένου του κελιού.
• Όταν μια στήλη αναζήτησης περιέχει κενά στην αρχή ή στο τέλος. Σε αυτή την περίπτωση, μπορεί να σπάσετε το κεφάλι σας προσπαθώντας να καταλάβετε γιατί ένας κανονικός τύπος δεν λειτουργεί.

Παράδειγμα 1. Αναζήτηση κειμένου που αρχίζει ή τελειώνει με ορισμένους χαρακτήρες

Ας υποθέσουμε ότι θέλετε να βρείτε έναν συγκεκριμένο πελάτη στην παρακάτω βάση δεδομένων. Δεν θυμάστε το επώνυμό του, αλλά είστε σίγουροι ότι αρχίζει με "ack".

Για να επιστρέψετε το επώνυμο από τη στήλη A, χρησιμοποιήστε τον ακόλουθο τύπο Vlookup με μπαλαντέρ:

=VLOOKUP("ack*", $A$2:$B$10, 1, FALSE)

Για να ανακτήσετε το κλειδί άδειας χρήσης από τη στήλη Β, χρησιμοποιήστε αυτό (η διαφορά είναι μόνο στον αριθμό δείκτη της στήλης):

=VLOOKUP("ack*", $A$2:$B$10, 2, FALSE)

Μπορείτε επίσης να εισαγάγετε το γνωστό μέρος του ονόματος σε κάποιο κελί, π.χ. E1, και να συνδυάσετε τον χαρακτήρα μπαλαντέρ με την αναφορά του κελιού:

=VLOOKUP(E1& "*", $A$2:$B$10, 1, FALSE)

Το παρακάτω στιγμιότυπο οθόνης δείχνει τα αποτελέσματα:

Ακολουθούν μερικοί ακόμη τύποι VLOOKUP με μπαλαντέρ.

Βρείτε το επώνυμο που τελειώνει με "son":

=VLOOKUP("*son", $A$2:$B$10, 1, FALSE)

Πάρτε το όνομα που αρχίζει με "joh" και τελειώνει με "son":

=VLOOKUP("joh*son", $A$2:$B$10, 1, FALSE)

Τραβήξτε ένα επώνυμο 5 χαρακτήρων:

=VLOOKUP("?????", $A$2:$B$10, 1, FALSE)

Παράδειγμα 2. VLOOKUP μπαλαντέρ με βάση την τιμή κελιού

Από το προηγούμενο παράδειγμα, γνωρίζετε ήδη ότι είναι δυνατή η συνένωση μιας τελείας (&) και μιας αναφοράς κελιού για να δημιουργήσετε μια συμβολοσειρά αναζήτησης. Για να βρείτε μια τιμή που περιέχει έναν ή περισσότερους χαρακτήρες σε οποιαδήποτε θέση, τοποθετήστε μια τελεία πριν και μετά την αναφορά κελιού.

Ας υποθέσουμε ότι θέλετε να βρείτε ένα όνομα που αντιστοιχεί σε ένα συγκεκριμένο κλειδί άδειας χρήσης, αλλά δεν γνωρίζετε ολόκληρο το κλειδί, παρά μόνο μερικούς χαρακτήρες. Με τα κλειδιά στη στήλη Α, τα ονόματα στη στήλη Β και μέρος του κλειδιού-στόχου στο E1, μπορείτε να κάνετε ένα wildcard Vlookup με αυτόν τον τρόπο:

Εξάγετε το κλειδί:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 1, FALSE)

Εξάγετε το όνομα:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 2, FALSE)

Σημειώσεις:

• Για να λειτουργήσει σωστά ένας τύπος VLOOKUP με μπαλαντέρ, χρησιμοποιήστε μια ακριβή αντιστοιχία (το FALSE είναι το τελευταίο όρισμα).
• Εάν βρεθούν περισσότερες από μία αντιστοιχίες, επιστρέφεται η πρώτη. .

VLOOKUP TRUE vs FALSE

Και τώρα, ήρθε η ώρα να ρίξουμε μια πιο προσεκτική ματιά στο τελευταίο όρισμα της συνάρτησης VLOOKUP του Excel. Αν και προαιρετικό, το range_lookup Ανάλογα με το αν θα επιλέξετε TRUE ή FALSE, ο τύπος σας μπορεί να δώσει διαφορετικά αποτελέσματα.

Excel VLOOKUP ακριβής αντιστοιχία (FALSE)

Εάν range_lookup έχει οριστεί σε FALSE, ένας τύπος Vlookup αναζητά μια τιμή που είναι ακριβώς ίση με την τιμή αναζήτησης. Εάν βρεθούν δύο ή περισσότερες αντιστοιχίες, επιστρέφεται η 1η. Εάν δεν βρεθεί ακριβής αντιστοιχία, εμφανίζεται το σφάλμα #N/A.

Excel VLOOKUP προσεγγιστική αντιστοιχία (TRUE)

Εάν range_lookup έχει οριστεί σε TRUE ή παραλείπεται (προεπιλογή), ο τύπος αναζητά την πλησιέστερη αντιστοιχία. Πιο συγκεκριμένα, αναζητά πρώτα μια ακριβή αντιστοιχία και αν δεν βρεθεί ακριβής αντιστοιχία, αναζητά την αμέσως μεγαλύτερη τιμή που είναι μικρότερη από την τιμή αναζήτησης.

Μια κατά προσέγγιση αντιστοίχιση Vlookup λειτουργεί με τις ακόλουθες επιφυλάξεις:

• Η στήλη αναζήτησης πρέπει να είναι ταξινομημένη σε αύξουσα σειρά , από το μικρότερο προς το μεγαλύτερο, διαφορετικά μπορεί να μην βρεθεί σωστή τιμή.
• Εάν η τιμή αναζήτησης είναι μικρότερη από τη μικρότερη τιμή στον πίνακα αναζήτησης, επιστρέφεται σφάλμα #N/A.

Τα παρακάτω παραδείγματα θα σας βοηθήσουν να κατανοήσετε καλύτερα τη διαφορά μεταξύ ενός Vlookup ακριβούς και ενός Vlookup προσεγγιστικής αντιστοίχισης και πότε είναι καλύτερο να χρησιμοποιείται ο κάθε τύπος.

Παράδειγμα 1. Πώς να κάνετε μια ακριβή αντιστοίχιση Vlookup

Για να αναζητήσετε μια ακριβή αντιστοιχία, απλά βάλτε FALSE στο τελευταίο όρισμα.

Για αυτό το παράδειγμα, ας πάρουμε τον πίνακα ταχύτητας των ζώων, ας αλλάξουμε τις στήλες και ας προσπαθήσουμε να βρούμε τα ζώα που μπορούν να τρέξουν με 80, 50 και 30 μίλια την ώρα. Με τις τιμές αναζήτησης στα D2, D3 και D4, εισαγάγετε τον παρακάτω τύπο στο E2 και, στη συνέχεια, αντιγράψτε τον σε δύο ακόμη κελιά:

=VLOOKUP(D2, $A$2:$B$12, 2, FALSE)

Όπως μπορείτε να δείτε, ο τύπος επιστρέφει "Lion" στο E3 επειδή εκτελούνται ακριβώς 50 ανά ώρα. Για τις άλλες δύο τιμές αναζήτησης δεν βρέθηκε ακριβής αντιστοιχία και εμφανίζονται σφάλματα #N/A.

Παράδειγμα 2. Πώς να κάνετε Vlookup για κατά προσέγγιση αντιστοίχιση

Για να αναζητήσετε μια κατά προσέγγιση αντιστοιχία, υπάρχουν δύο βασικά πράγματα που πρέπει να κάνετε:

• Ταξινόμηση της πρώτης στήλης της table_array από το μικρότερο προς το μεγαλύτερο.
• Χρησιμοποιήστε TRUE για το range_lookup επιχείρημα ή παραλείψτε το.

Η ταξινόμηση της στήλης αναζήτησης είναι πολύ σημαντική, επειδή η συνάρτηση VLOOKUP σταματά την αναζήτηση μόλις βρει μια κοντινή αντιστοιχία μικρότερη από την τιμή αναζήτησης. Εάν τα δεδομένα δεν είναι σωστά ταξινομημένα, μπορεί να καταλήξετε να έχετε πραγματικά περίεργα αποτελέσματα ή ένα σωρό σφάλματα #N/A.

Για τα δεδομένα του δείγματός μας, ένας προσεγγιστικός τύπος Vlookup έχει ως εξής:

=VLOOKUP(D2, $A$2:$B$12, 2, TRUE)

Και επιστρέφει τα ακόλουθα αποτελέσματα:

• Για μια τιμή αναζήτησης "80", επιστρέφεται το "Cheetah" επειδή η ταχύτητά του (70) είναι η πλησιέστερη αντιστοιχία που είναι μικρότερη από την τιμή αναζήτησης.
• Για μια τιμή αναζήτησης "50", επιστρέφεται μια ακριβής αντιστοιχία (Lion).
• Για μια τιμή αναζήτησης "30", επιστρέφεται σφάλμα #N/A, επειδή η τιμή αναζήτησης είναι μικρότερη από τη μικρότερη τιμή στη στήλη αναζήτησης.

Ειδικά εργαλεία για το Vlookup στο Excel

Αναμφίβολα, το VLOOKUP είναι μία από τις πιο ισχυρές και χρήσιμες συναρτήσεις του Excel, αλλά είναι επίσης μία από τις πιο μπερδεμένες. Για να κάνουμε την καμπύλη εκμάθησης λιγότερο απότομη και την εμπειρία πιο ευχάριστη, συμπεριλάβαμε μερικά εργαλεία εξοικονόμησης χρόνου στην Ultimate Suite για το Excel.

Οδηγός VLOOKUP - εύκολος τρόπος για να γράψετε σύνθετους τύπους

Ο διαδραστικός Οδηγός VLOOKUP θα σας καθοδηγήσει μέσω των επιλογών διαμόρφωσης για να δημιουργήσετε έναν τέλειο τύπο για τα κριτήρια που καθορίζετε. Ανάλογα με τη δομή των δεδομένων σας, θα χρησιμοποιήσει την τυπική συνάρτηση VLOOKUP ή έναν τύπο INDEX MATCH που μπορεί να αντλήσει τιμές από αριστερά.

Για να αποκτήσετε την προσαρμοσμένη φόρμουλα, πρέπει να κάνετε τα εξής:

1. Εκτελέστε τον Οδηγό VLOOKUP.

1. Επιλέξτε τον κύριο πίνακα και τον πίνακα αναζήτησης.
2. Καθορίστε τις ακόλουθες στήλες (σε πολλές περιπτώσεις επιλέγονται αυτόματα):
   • Βασική στήλη - τη στήλη του κύριου πίνακα που περιέχει τις τιμές που πρέπει να αναζητήσετε.
   • Στήλη αναζήτησης - τη στήλη για να κοιτάξετε προς τα πάνω.
   • Στήλη επιστροφής - η στήλη από την οποία θα ανακτηθούν οι τιμές.
3. Κάντε κλικ στο Εισαγωγή κουμπί.

Τα παρακάτω παραδείγματα δείχνουν τον οδηγό σε δράση.

Τυπικό Vlookup

Όταν η στήλη αναζήτησης ( Ζώα ) είναι η πιο αριστερή στήλη στον πίνακα αναζήτησης, εισάγεται ένας κανονικός τύπος VLOOKUP για ακριβή αντιστοίχιση:

Vlookup προς τα αριστερά

Όταν η στήλη αναζήτησης ( Ζώα ) βρίσκεται στη δεξιά πλευρά της στήλης επιστροφής ( Ταχύτητα ), ο οδηγός εισάγει έναν τύπο INDEX MATCH στο Vlookup από τα δεξιά προς τα αριστερά:

Επιπλέον μπόνους! Χάρη στην έξυπνη χρήση των αναφορών κελιών, οι τύποι μπορούν να αντιγραφούν ή να μετακινηθούν σε οποιαδήποτε στήλη, χωρίς να χρειάζεται να ενημερώσετε τις αναφορές.

Συγχώνευση δύο πινάκων - εναλλακτική λύση χωρίς τύπους στο Excel VLOOKUP

Εάν τα αρχεία σας στο Excel είναι εξαιρετικά μεγάλα και πολύπλοκα, η προθεσμία του έργου είναι επικείμενη και ψάχνετε κάποιον που μπορεί να σας δώσει ένα χέρι βοήθειας, δοκιμάστε τον Οδηγό Συγχώνευσης Πινάκων.

Αυτό το εργαλείο είναι η οπτική και χωρίς άγχος εναλλακτική λύση στη συνάρτηση VLOOKUP του Excel, η οποία λειτουργεί με αυτόν τον τρόπο:

1. Επιλέξτε το κύριο τραπέζι σας.
2. Επιλέξτε τον πίνακα αναζήτησης.
3. Επιλέξτε μία ή περισσότερες κοινές στήλες ως μοναδικό αναγνωριστικό(-ά).
4. Καθορίστε ποιες στήλες θα ενημερωθούν.
5. Προαιρετικά, επιλέξτε τις στήλες που θέλετε να προσθέσετε.
6. Αφήστε τον Οδηγό Συγχώνευσης Πινάκων να επεξεργαστεί μερικά δευτερόλεπτα... και απολαύστε τα αποτελέσματα :)

Αυτός είναι ο τρόπος χρήσης του VLOOKUP στο Excel σε βασικό επίπεδο. Στο επόμενο μέρος του σεμιναρίου μας, θα συζητήσουμε προηγμένα παραδείγματα VLOOKUP που θα σας διδάξουν πώς να κάνετε Vlookup με πολλαπλά κριτήρια, να επιστρέφετε όλες τις αντιστοιχίες ή την Ν-οστή εμφάνιση, να εκτελείτε διπλό Vlookup, να κάνετε αναζήτηση σε πολλαπλά φύλλα με έναν μόνο τύπο και πολλά άλλα. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω την επόμενη εβδομάδα!

Διαθέσιμες λήψεις

Παραδείγματα τύπων VLOOKUP του Excel (.xlsx αρχείο)

Ultimate Suite 14 ημερών πλήρως λειτουργική έκδοση (.exe αρχείο)