I dag vil vi se på, hvordan du bruger VLOOKUP i Excel med mange detaljerede trin-for-trin eksempler. Du vil lære at lave Vlookup fra et andet ark og en anden projektmappe, søge med jokertegn og meget mere.

Denne artikel er starten på en serie om VLOOKUP, en af de mest nyttige Excel-funktioner og samtidig en af de mest indviklede og mindst forståede. Vi vil forsøge at forklare det grundlæggende i et meget enkelt sprog for at gøre indlæringskurven for en uerfaren bruger så let som muligt. Vi vil også give eksempler på formler, der dækker de mest typiske anvendelser af VLOOKUP i Excel, og forsøge at gøre det lettere for en uerfaren bruger at forstå VLOOKUP.de er både informative og sjove.

Excel VLOOKUP-funktion

Hvad er VLOOKUP? Til at begynde med er det en Excel-funktion :) Hvad gør den? Den søger efter den værdi, du angiver, og returnerer en tilsvarende værdi fra en anden kolonne. Mere teknisk set søger VLOOKUP-funktionen en værdi i den første kolonne i et givet interval og returnerer en værdi i samme række fra en anden kolonne.

I sin almindelige anvendelse søger Excel VLOOKUP gennem dit datasæt baseret på den unikke identifikator og giver dig en oplysning, der er forbundet med den unikke identifikator.

Bogstavet "V" står for "lodret" og bruges til at skelne VLOOKUP fra HLOOKUP-funktionen, som søger en værdi i en række i stedet for en kolonne (H står for "vandret").

Funktionen er tilgængelig i alle versioner af Excel 365 til og med Excel 2007.

Tip. I Excel 365 og Excel 2021 kan du bruge XLOOKUP-funktionen, som er en mere fleksibel og kraftfuld efterfølger til VLOOKUP.

Syntaks for VLOOKUP

Syntaksen for VLOOKUP-funktionen er som følger:

Hvor:

• Lookup_value (påkrævet) - er den værdi, der skal søges efter.

  Dette kan være en værdi (tal, dato eller tekst), en cellehenvisning (henvisning til en celle, der indeholder en opslagsværdi) eller den værdi, der returneres af en anden funktion. I modsætning til tal og cellehenvisninger skal tekstværdier altid være omsluttet af "dobbelte anførselstegn".

• Tabel_array (påkrævet) - er det område af celler, hvor der skal søges efter opslagsværdien, og hvorfra der skal hentes et match. VLOOKUP-funktionen søger altid i den første kolonne i tabelmatrixen , som kan indeholde forskellige tekstværdier, tal, datoer og logiske værdier.
• Col_index_num (påkrævet) - er nummeret på den kolonne, hvorfra der skal returneres en værdi. Optællingen starter fra den kolonne længst til venstre i tabelarrayet, som er 1.
• Range_lookup (valgfrit) - bestemmer, om der skal søges efter tilnærmelsesvis eller nøjagtig overensstemmelse:
  • TRUE eller udeladt (standard) - tilnærmelsesvis match. Hvis der ikke findes et nøjagtigt match, søger formlen efter den største værdi, der er mindre end opslagsværdien. Kræver sortering af opslagskolonnen i stigende orden.
  • FALSE - nøjagtigt match. Formlen søger efter en værdi, der er nøjagtigt lig med opslagsværdien. Hvis der ikke findes et nøjagtigt match, returneres en #N/A-værdi.

Grundlæggende VLOOKUP-formel

Her er et eksempel på Excel VLOOKUP-formlen i sin enkleste form. Se nedenstående formel og prøv at "oversætte" den til engelsk:

=VLOOKUP("lion", A2:B11, 2, FALSE)

• Det første argument ( opslagsværdi ) viser tydeligt, at formlen slår ordet "løve" op i formlen.
• Det andet argument ( table_array ) er A2:B11. Når man husker på, at der søges i kolonnen længst til venstre, kan man læse ovenstående formel lidt videre: Søg efter "lion" i intervallet A2:A11. Så langt, så godt, ikke?
• Det tredje argument col_index_num er 2. Det betyder, at vi ønsker at returnere en matchende værdi fra kolonne B, som er den anden kolonne i tabellen array.
• Det fjerde argument range_lookup er FALSK, hvilket indikerer, at vi søger efter nøjagtig match.

Når alle argumenterne er fastlagt, burde det ikke være noget problem at læse hele formlen: søg efter "lion" i A2:A11, find et nøjagtigt match og returner en værdi fra kolonne B i samme række.

For nemheds skyld kan du skrive den ønskede værdi i en celle, f.eks. E1, erstatte den "hardcodede" tekst med cellehenvisningen og få formlen til at slå enhver værdi op, som du indtaster i E1:

=VLOOKUP(E1, A2:B11, 2, FALSE)

Er der stadig noget, der er uklart, så prøv at se på det på denne måde:

Sådan laver du en Vlookup i Excel

Når du bruger VLOOKUP-formler i virkelige regneark, er hovedreglen følgende: låsetabel array med absolutte cellereferencer (f.eks. $A$2:$C$11) for at forhindre, at den ændres, når du kopierer en formel til andre celler.

opslagsværdi bør i de fleste tilfælde være en relativ reference (som E2), eller du kan kun låse kolonnekoordinaten ($E2). Når formlen kopieres nedad i kolonnen, justeres referencen automatisk for hver række.

For at se, hvordan det fungerer i praksis, kan du se på følgende eksempel. Til vores eksempeltabel har vi tilføjet endnu en kolonne, der rangerer dyrene efter hastighed (kolonne A), og vi ønsker at finde den 1., 5. og 10. hurtigste sprinter i verden. Indtast opslagsrækkefølgerne i nogle celler (E2:E4 i skærmbilledet nedenfor), og brug følgende formler:

For at trække dyrenavnene fra kolonne B:

=VLOOKUP($E2, $A$2:$C$11, 2, FALSE)

Udtrække hastighed fra kolonne C:

=VLOOKUP($E2, $A$2:$C$11, 3, FALSE)

Indtast ovenstående formler i cellerne F2 og G2, vælg disse celler, og træk formlerne til de nedenstående rækker:

Hvis du undersøger formlen i en lavere række, vil du bemærke, at referencen til opslagsværdien er justeret for den pågældende række, mens tabelmatrixen er uændret:

Nedenfor får du nogle flere nyttige tips, som vil spare dig for en masse hovedpine og tid til fejlfinding.

Excel VLOOKUP - 5 ting, du skal huske!

1. VLOOKUP-funktionen kan ikke se på sin venstre . Den søger altid i den kolonne længst til venstre Hvis du har brug for at trække værdier fra venstre, skal du bruge kombinationen INDEX MATCH (eller INDEX XMATCH i Excel 365), som er ligeglad med placeringen af opslags- og returkolonnerne.
2. VLOOKUP-funktionen tager ikke hensyn til store og små bogstaver , hvilket betyder, at store og små bogstaver behandles som ækvivalente. For at skelne mellem bogstaver skal du bruge VLOOKUP-formler, der tager hensyn til store og små bogstaver.
3. Husk vigtigheden af den sidste parameter. Brug TRUE for tilnærmelsesvis overensstemmelse og FALSE for nøjagtig overensstemmelse. For yderligere oplysninger, se VLOOKUP TRUE vs. FALSE.
4. Når du søger efter et tilnærmelsesvis match, skal du sørge for, at dataene i opslagskolonnen er sorteret i stigende orden.
5. Hvis opslagsværdien ikke findes, returneres en #N/A-fejl. Du kan finde oplysninger om andre fejl i Hvorfor Excel VLOOKUP ikke virker.

Excel VLOOKUP eksempler

Jeg håber, at vertikale opslag er begyndt at virke lidt mere bekendt for dig. For at styrke din viden, lad os opbygge nogle flere VLOOKUP-formler.

Sådan Vlookup fra et andet ark i Excel

I praksis bruges Excel VLOOKUP-funktionen sjældent med data i det samme regneark. Oftest skal du hente matchende data fra et andet regneark.

Hvis du vil foretage et Vlookup fra et andet Excel-ark, skal du angive regnearkets navn efterfulgt af et udråbstegn i table_array argumentet før intervalreferencen. Hvis du f.eks. vil søge i intervallet A2:B10 på ark2, skal du bruge denne formel:

=VLOOKUP("Produkt1", Ark2!A2:B10, 2)

Du behøver naturligvis ikke at skrive arkets navn manuelt. Du skal blot begynde at skrive formlen, og når du kommer til table_array argumentet, skifter du til opslagsarket og vælger området med musen.

Sådan kan du f.eks. slå værdien A2 op i intervallet A2:A9 på Priser regnearket og returnerer en tilsvarende værdi fra kolonne C:

=VLOOKUP(A2, Priser!$A$2:$C$9, 3, FALSE)

Bemærkninger:

• Hvis regnearkets navn indeholder mellemrum eller andre tegn end bogstaver skal det omsluttes af enkelte anførselstegn, f.eks. "Prisliste"!$A$2:$C$9.
• Hvis du bruger en VLOOKUP-formel til flere celler, skal du huske at lås table_array med $-tegnet, som f.eks. $A$2:$C$9.

Sådan Vlookup fra en anden projektmappe i Excel

Hvis du vil lave et Vlookup fra en anden Excel-arbejdsbog, skal du sætte arbejdsbogens navn i firkantede parenteser før regnearkets navn.

Her er f.eks. formlen til at finde værdien A2 i arket med navnet Priser i den Pris_Liste.xlsx arbejdsbog:

=VLOOKUP(A2, [Price_List.xlsx]Prices!$A$2:$C$9, 3, FALSE)

Hvis enten et regnebogsnavn eller et regnearknavn indeholder mellemrum eller andre tegn end bogstaver, skal du omslutte dem i anførselstegn på følgende måde:

=VLOOKUP(A2, '[Price List.xlsx]Prices'!$A$2:$C$9, 3, FALSE)

Den nemmeste måde at lave en VLOOKUP-formel, der henviser til en anden projektmappe, er som følger:

1. Åbn begge filer.
2. Begynd at skrive din formel, skift til den anden projektmappe, og vælg tabelmatrixen med musen.
3. Indtast de resterende argumenter, og tryk på Enter-tasten for at færdiggøre formlen.

Resultatet vil se nogenlunde ud som i skærmbilledet nedenfor:

Når du luk filen med din opslagstabel, vil VLOOKUP-formlen fortsat fungere, men den vil nu vise den fulde sti til den lukkede projektmappe:

Du kan finde flere oplysninger under Sådan henviser du til et andet Excel-ark eller en anden arbejdsmappe.

Sådan Vlookup fra et navngivet område i et andet ark

Hvis du har planer om at bruge det samme opslagsinterval i mange formler, kan du oprette et navngivet interval til det og skrive navnet direkte i table_array argument.

Hvis du vil oprette et navngivet område, skal du blot vælge cellerne og skrive det ønskede navn i feltet Navn til venstre for Formelbjælken. Du kan finde detaljerede trin i Sådan navngiver du et område i Excel.

I dette eksempel har vi givet navnet Priser_2020 til datacellerne (A2:C9) i opslagsarket og får denne kompakte formel:

=VLOOKUP(A2, Prices_2020, 3, FALSE)

De fleste navne i Excel gælder for den hele arbejdsbogen , så du behøver ikke at angive regnearkets navn, når du bruger navngivne intervaller.

Hvis det angivne område er i en anden arbejdsbog , sæt arbejdsbogens navn foran navnet på området, f.eks:

=VLOOKUP(A2, 'Price List.xlsx'!Prices_2020, 3, FALSE)

Sådanne formler er langt mere forståelige, ikke sandt? Desuden kan det være et godt alternativ til absolutte referencer at bruge navngivne intervaller. Da et navngivet interval ikke ændres, kan du være sikker på, at dit tabelområde forbliver låst, uanset hvor formlen flyttes eller kopieres.

Hvis du har konverteret dit opslagsinterval til en fuldt funktionsdygtig Excel-tabelle, kan du lave et Vlookup baseret på tabellens navn, f.eks. Pris_tabel i nedenstående formel:

=VLOOKUP(A2, Price_table, 3, FALSE)

Tabelreferencer, også kaldet strukturerede referencer, er modstandsdygtige og immune over for mange datamanipulationer. Du kan f.eks. fjerne eller tilføje nye rækker til din opslagstabel uden at bekymre dig om at opdatere referencerne.

Brug af jokertegn i VLOOKUP-formlen

Ligesom mange andre formler accepterer Excel VLOOKUP-funktionen følgende jokertegn:

• Spørgsmålstegn (?) til at matche et hvilket som helst enkelt tegn.
• Asterisk (*) til at matche en hvilken som helst sekvens af tegn.

Wildcards er meget nyttige i mange situationer:

• Når du ikke kan huske den nøjagtige tekst, du leder efter.
• Når du leder efter en tekststreng, der er en del af celleindholdet.
• Når en opslagskolonne indeholder ledende eller afsluttende mellemrum, kan det være, at du i så fald kan være svært at finde ud af, hvorfor en normal formel ikke virker.

Eksempel 1. Opsøgning af tekst, der begynder eller slutter med bestemte tegn

Lad os antage, at du ønsker at finde en bestemt kunde i nedenstående database. Du kan ikke huske efternavnet, men du er sikker på, at det begynder med "ack".

Hvis du vil have efternavnet fra kolonne A tilbage, skal du bruge følgende Vlookup-jokerformel:

=VLOOKUP("ack*", $A$2:$B$10, 1, FALSE)

Hvis du vil hente licensnøglen fra kolonne B, skal du bruge denne (forskellen er kun i kolonneindeksnummeret):

=VLOOKUP("ack*", $A$2:$B$10, 2, FALSE)

Du kan også indtaste den kendte del af navnet i en celle, f.eks. E1, og kombinere jokertegnet med cellereferencen:

=VLOOKUP(E1& "*", $A$2:$B$10, 1, FALSE)

Nedenstående skærmbillede viser resultaterne:

Nedenfor er der et par andre VLOOKUP-formler med jokertegn.

Find det efternavn, der ender på "son":

=VLOOKUP("*son", $A$2:$B$10, 1, FALSE)

Få det navn, der begynder med "joh" og slutter med "son":

=VLOOKUP("joh*son", $A$2:$B$10, 1, FALSE)

Vælg et efternavn på 5 tegn:

=VLOOKUP("?????", $A$2:$B$10, 1, FALSE)

Eksempel 2. VLOOKUP-jokertegn baseret på celleværdi

Fra det foregående eksempel ved du allerede, at det er muligt at sammenkæde et ampersand (&) og en cellehenvisning til en opslagsstreng. Hvis du vil finde en værdi, der indeholder et eller flere tegn i en vilkårlig position, skal du sætte et ampersand før og efter cellehenvisningen.

Lad os sige, at du ønsker at få et navn, der svarer til en bestemt licensnøgle, men du kender ikke hele nøglen, men kun nogle få tegn. Med nøglerne i kolonne A, navnene i kolonne B og en del af målnøglen i E1 kan du lave et wildcard Vlookup på denne måde:

Udtrække nøglen:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 1, FALSE)

Udtrække navnet:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 2, FALSE)

Bemærkninger:

• Hvis en VLOOKUP-formel med wildcard skal fungere korrekt, skal du bruge et nøjagtigt match (FALSE er det sidste argument).
• Hvis der findes mere end et match, returneres det første .

VLOOKUP TRUE vs. FALSK

Og nu er det tid til at se nærmere på det sidste argument i Excel VLOOKUP-funktionen. Selv om det er valgfrit, er det range_lookup parameteren er meget vigtig. Afhængigt af, om du vælger TRUE eller FALSE, kan din formel give forskellige resultater.

Excel VLOOKUP nøjagtigt match (FALSK)

Hvis range_lookup er sat til FALSE, søger en Vlookup-formel efter en værdi, der er nøjagtigt lig med opslagsværdien. Hvis der findes to eller flere match, returneres den første. Hvis der ikke findes et nøjagtigt match, opstår fejlen #N/A.

Excel VLOOKUP tilnærmelsesvis match (TRUE)

Hvis range_lookup er sat til TRUE eller udeladt (standard), søger formlen efter den nærmeste match. Mere præcist søger den først efter en nøjagtig match, og hvis den ikke finder en nøjagtig match, søger den efter den næststørste værdi, der er mindre end opslagsværdien.

En Vlookup med tilnærmelsesvis matchning fungerer med følgende forbehold:

• Opslagskolonnen skal være sorteret i stigende rækkefølge , fra den mindste til den største, da der ellers ikke kan findes en korrekt værdi.
• Hvis opslagsværdien er mindre end den mindste værdi i opslagsarrayet, returneres en #N/A-fejl.

De følgende eksempler vil hjælpe dig med at forstå forskellen mellem en Vlookup med nøjagtigt match og en Vlookup med tilnærmelsesvis match, og hvornår det er bedst at bruge de enkelte formler.

Eksempel 1. Sådan udføres et Vlookup med nøjagtigt match

Hvis du vil finde et nøjagtigt match, skal du blot angive FALSE i det sidste argument.

I dette eksempel tager vi tabellen over dyrenes hastighed, bytter kolonnerne og forsøger at finde de dyr, der kan løbe 80, 80 og 80 miles i timen. Med opslagsværdierne i D2, D3 og D4 indtaster du nedenstående formel i E2 og kopierer den derefter ned til to andre celler:

=VLOOKUP(D2, $A$2:$B$12, 2, FALSE)

Som du kan se, giver formlen "Lion" i E3, fordi de kører præcis 50 gange i timen. For de to andre opslagsværdier findes der ikke et nøjagtigt match, og der vises #N/A-fejl.

Eksempel 2. Hvordan du laver et Vlookup for tilnærmelsesvis match

For at finde et omtrentligt match er der to vigtige ting, du skal gøre:

• Sortere den første kolonne i table_array fra den mindste til den største.
• Brug TRUE til range_lookup argument eller udelade det.

Det er meget vigtigt at sortere opslagskolonnen, fordi VLOOKUP-funktionen stopper med at søge, så snart den finder et tæt match, der er mindre end opslagsværdien. Hvis dataene ikke er sorteret korrekt, kan du ende med at få meget mærkelige resultater eller en masse #N/A-fejl.

For vores eksempeldata kan en Vlookup-formel for et tilnærmelsesvis match bruges på følgende måde:

=VLOOKUP(D2, $A$2:$B$12, 2, TRUE)

Og giver følgende resultater:

• For en opslagsværdi på "80" returneres "Cheetah", fordi dens hastighed (70) er den nærmeste match, der er mindre end opslagsværdien.
• For en opslagsværdi på "50" returneres et nøjagtigt match (Lion).
• For en opslagsværdi på "30" returneres en #N/A-fejl, fordi opslagsværdien er mindre end den mindste værdi i opslagskolonnen.

Særlige værktøjer til Vlookup i Excel

VLOOKUP er uden tvivl en af de mest kraftfulde og nyttige Excel-funktioner, men det er også en af de mest forvirrende. For at gøre indlæringskurven mindre stejl og oplevelsen mere behagelig har vi inkluderet et par tidsbesparende værktøjer i vores Ultimate Suite for Excel.

VLOOKUP Wizard - nem måde at skrive komplekse formler på

Den interaktive VLOOKUP-guide hjælper dig gennem konfigurationsmulighederne med at opbygge en perfekt formel til de kriterier, du angiver. Afhængigt af din datastruktur vil den bruge standard VLOOKUP-funktionen eller en INDEX MATCH-formel, der kan trække værdier fra venstre.

For at få din skræddersyede formel skal du gøre følgende:

1. Kør guiden VLOOKUP.

1. Vælg din hovedtabel og din opslagstabel.
2. Angiv følgende kolonner (i mange tilfælde vælges de automatisk):
   • Nøglespalte - kolonnen i hovedtabellen, som indeholder de værdier, der skal søges op.
   • Opslagskolonne - søjlen til at se op imod.
   • Returneringsspalte - den kolonne, hvorfra værdierne skal hentes.
3. Klik på den Indsæt knap.

De følgende eksempler viser guiden i aktion.

Standard Vlookup

Når opslagskolonnen ( Dyr ) er kolonnen længst til venstre i opslagstabellen, indsættes en normal VLOOKUP-formel for nøjagtig match:

Vlookup til venstre

Når opslagskolonnen ( Dyr ) er på højre side af returkolonnen ( Hastighed ), indsætter guiden en INDEX MATCH-formel til Vlookup fra højre til venstre:

Ekstra bonus! Takket være den smarte brug af cellehenvisninger kan formlerne kopieres eller flyttes til en hvilken som helst kolonne, uden at du behøver at opdatere referencerne.

Sammenlægning af to tabeller - formelfrit alternativ til Excel VLOOKUP

Hvis dine Excel-filer er enormt store og komplekse, hvis projektets deadline er nært forestående, og du leder efter en person, der kan give dig en hjælpende hånd, så prøv guiden Sammenlægning af tabeller.

Dette værktøj er vores visuelle og stressfrie alternativ til Excel's VLOOKUP-funktion, som fungerer på denne måde:

1. Vælg dit hovedbord.
2. Vælg opslagsskemaet.
3. Vælg en eller flere fælles kolonner som unik(e) identifikator(er).
4. Angiv, hvilke kolonner der skal opdateres.
5. Du kan eventuelt vælge de kolonner, der skal tilføjes.
6. Giv guiden Sammenlægning af tabeller et par sekunder til at behandle den... og nyd resultatet :)

Sådan bruger du VLOOKUP i Excel på det grundlæggende niveau. I næste del af vores tutorial vil vi diskutere avancerede VLOOKUP-eksempler, som vil lære dig at Vlookup flere kriterier, returnere alle kampe eller Nth forekomst, udføre dobbelt Vlookup, slå op på tværs af flere ark med en enkelt formel og meget mere. Jeg takker dig for at læse og håber at se dig i næste uge!

Tilgængelige downloads

Eksempler på Excel VLOOKUP-formler (.xlsx-fil)

Ultimate Suite 14-dages fuldt funktionsdygtig version (.exe-fil)