Šodien mēs aplūkosim, kā lietot VLOOKUP programmā Excel, izmantojot daudzus detalizētus pakāpeniskus piemērus. Uzzināsiet, kā izmantot VLOOKUP no citas lapas un citas darbgrāmatas, meklēt ar aizstājējzīmēm un daudz ko citu.

Ar šo rakstu sākam sēriju, kas aptver VLOOKUP, vienu no noderīgākajām Excel funkcijām un vienlaikus vienu no sarežģītākajām un vismazāk saprotamajām. Mēs centīsimies izskaidrot pamatus ļoti vienkāršā valodā, lai nepieredzējušam lietotājam būtu pēc iespējas vieglāk apgūt. Mēs arī sniegsim formulas piemērus, kas ietver visbiežāk izmantotās VLOOKUP Excel un mēģināsim padarīt to par vienu no vispiemērotākajām.tos gan informatīvi, gan jautri.

Excel VLOOKUP funkcija

Kas ir VLOOKUP? Vispirms jāsāk ar to, ka tā ir Excel funkcija :) Ko tā dara? Tā meklē norādīto vērtību un atgriež atbilstošu vērtību no citas kolonnas. Tehniski runājot, VLOOKUP funkcija meklē vērtību noteiktā diapazona pirmajā kolonnā un atgriež vērtību tajā pašā rindā no citas kolonnas.

Parasti Excel VLOOKUP meklē datu kopu, pamatojoties uz unikālo identifikatoru, un iegūst informāciju, kas saistīta ar šo unikālo identifikatoru.

Burts "V" nozīmē "vertikāls" un tiek lietots, lai atšķirtu VLOOKUP no funkcijas HLOOKUP, kas meklē vērtību rindā, nevis kolonnā (H nozīmē "horizontāls").

Šī funkcija ir pieejama visās Excel 365 versijās, sākot no Excel 2007.

Padoms. Programmās Excel 365 un Excel 2021 varat izmantot funkciju XLOOKUP, kas ir elastīgāka un jaudīgāka VLOOKUP pēctece.

VLOOKUP sintakse

VLOOKUP funkcijas sintakse ir šāda:

Kur:

• Lookup_value (obligāts) - meklēšanas vērtība.

  Tā var būt vērtība (skaitlis, datums vai teksts), šūnas atsauce (atsauce uz šūnu, kurā ir meklēšanas vērtība) vai kādas citas funkcijas atgriezta vērtība. Atšķirībā no skaitļiem un šūnas atsaucēm teksta vērtības vienmēr jāiekļauj "dubultās pēdiņās".

• Table_array (obligāts) - ir šūnu diapazons, kurā meklēt meklēšanas vērtību un no kura iegūt atbilstību. VLOOKUP funkcija vienmēr meklē tabulas masīva pirmajā slejā , kas var saturēt dažādas teksta vērtības, skaitļus, datumus un loģiskās vērtības.
• Col_index_num (obligāts) - ir tās kolonnas numurs, no kuras jāatgriež vērtība. Skaitīšana sākas no tabulas masīva kreisākās kolonnas, kas ir 1.
• Range_lookup (nav obligāti) - nosaka, vai meklēt pēc aptuvenas vai precīzas atbilstības:
  • TRUE vai izlaists (noklusējums) - aptuvena atbilstība. Ja precīza atbilstība nav atrasta, formulā tiek meklēta lielākā vērtība, kas ir mazāka par meklēšanas vērtību. Nepieciešams sakārtot meklēšanas kolonnu augošā secībā.
  • FALSE - precīza atbilstība. Formulā tiek meklēta vērtība, kas ir precīzi vienāda ar meklēšanas vērtību. Ja precīza atbilstība netiek atrasta, tiek atgriezta vērtība #N/A.

VLOOKUP pamatformula

Šeit ir Excel VLOOKUP formulas piemērs tās vienkāršākajā formā. Lūdzu, aplūkojiet zemāk redzamo formulu un mēģiniet to "iztulkot" angļu valodā:

=VLOOKUP("lauva", A2:B11, 2, FALSE)

• 1. arguments ( lookup_value ) skaidri norāda, ka formula meklē vārdu "lauva".
• 2. arguments ( table_array ) ir A2:B11. Paturot prātā, ka meklēšana tiek veikta kreisajā slejā, iepriekšminēto formulu var lasīt nedaudz tālāk: meklēt "lauva" diapazonā A2:A11. Līdz šim viss ir labi, vai ne?
• Trešais arguments col_index_num ir 2. Tas nozīmē, ka mēs vēlamies atgriezt atbilstošo vērtību no slejas B, kas ir otrā vērtība tabulas masīvā.
• Ceturtais arguments range_lookup ir FALSE, kas norāda, ka tiek meklēta precīza atbilstība.

Kad visi argumenti ir noteikti, jums nevajadzētu rasties problēmām ar visas formulas nolasīšanu: meklējiet "lauva" A2:A11, atrodiet precīzu atbilstību un atgrieziet vērtību no B slejas tajā pašā rindā.

Ērtības labad varat ievadīt interesējošo vērtību kādā šūnā, piemēram, E1, aizstāt "cietā koda" tekstu ar šūnas atsauci un panākt, lai formula meklētu jebkuru vērtību, ko ievadāt E1:

=VLOOKUP(E1, A2:B11, 2, FALSE)

Vai kaut kas paliek neskaidrs? Tad mēģiniet uz to paskatīties šādi:

Kā veikt Vlookup programmā Excel

Lietojot VLOOKUP formulas reālās darblapās, galvenais noteikums ir šāds: bloķēšanas tabulas masīvs ar absolūtām atsaucēm uz šūnām (piemēram, $A$2:$C$11), lai nepieļautu tās maiņu, kopējot formulu uz citām šūnām.

Portāls meklēšanas vērtība vairumā gadījumu jābūt relatīvai atsaucei (piemēram, E2) vai arī var bloķēt tikai kolonnas koordinātu ($E2). Kad formula tiek kopēta pa kolonnu, atsauce automātiski pielāgosies katrai rindai.

Lai redzētu, kā tas darbojas praksē, aplūkojiet šādu piemēru. Mūsu parauga tabulai esam pievienojuši vēl vienu sleju, kurā dzīvnieki tiek sarindoti pēc ātruma (A sleja), un vēlamies atrast 1., 5. un 10. ātrāko sprinteri pasaulē. Šim nolūkam dažās šūnās (E2:E4 attēlā zemāk) ievadiet meklēšanas rangus un izmantojiet šādas formulas:

Dzīvnieku nosaukumu izvilkšana no B slejas:

=VLOOKUP($E2, $A$2:$C$11, 2, FALSE)

Ātruma iegūšana no C slejas:

=VLOOKUP($E2, $A$2:$C$11, 3, FALSE)

Ievadiet iepriekš minētās formulas šūnās F2 un G2, atlasiet šīs šūnas un pārvelciet formulas uz zemāk esošajām rindām:

Ja izpētīsiet formulu zemākā rindā, pamanīsiet, ka meklēšanas vērtības atsauce ir pielāgota konkrētai rindai, bet tabulas masīvs ir nemainīgs:

Zemāk atradīsiet vēl dažus noderīgus padomus, kas ietaupīs jums daudz galvassāpju un laika problēmu novēršanai.

Excel VLOOKUP - 5 lietas, kas jāatceras!

1. VLOOKUP funkcija nevar apskatīt tās kreiso pusi . Tas vienmēr meklē galējā kreisā sleja tabulas masīva un atgriež vērtību no labās kolonnas. Ja nepieciešams izvilkt vērtības no kreisās puses, izmantojiet kombināciju INDEX MATCH (vai INDEX XMATCH programmā Excel 365), kurai nav svarīga meklēšanas un atgriešanas kolonnu izvietojums.
2. VLOOKUP funkcijai ir lieli un mazi burti. , kas nozīmē, ka lielie un mazie burti tiek uzskatīti par līdzvērtīgiem. Lai atšķirtu burtu lielumu, izmantojiet VLOOKUP formulas, kurās ņem vērā burtu lielumu.
3. Atcerieties, cik svarīgs ir pēdējais parametrs. Izmantojiet TRUE aptuvenai sakritībai un FALSE precīzai sakritībai. Lai iegūtu sīkāku informāciju, lūdzu, skatiet VLOOKUP TRUE vs. FALSE.
4. Meklējot aptuvenu sakritību, pārliecinieties, ka dati meklēšanas slejā ir sakārtoti augošā secībā.
5. Ja meklēšanas vērtība nav atrasta, tiek atgriezta kļūda #N/A. Informāciju par citām kļūdām skatiet sadaļā Kāpēc Excel VLOOKUP nedarbojas.

Excel VLOOKUP piemēri

Es ceru, ka vertikālā uzskate jums sāk šķist nedaudz pazīstamāka. Lai nostiprinātu jūsu zināšanas, izveidosim vēl dažas VLOOKUP formulas.

Kā veikt Vlookup no citas lapas programmā Excel

Praksē Excel VLOOKUP funkcija reti tiek izmantota ar datiem vienā darblapā. Visbiežāk jums būs jāizņem atbilstošie dati no citas darblapas.

Lai veiktu Vlookup no citas Excel lapas, ielieciet darblapas nosaukumu, kam seko izsaukuma zīme. table_array Piemēram, lai veiktu meklēšanu 2. lapas A2:B10 diapazonā, izmantojiet šo formulu:

=VLOOKUP("Product1", lapa2!A2:B10, 2)

Protams, lapas nosaukums nav jāievada manuāli. Vienkārši sāciet rakstīt formulu un, kad tā nonāk līdz laukam table_array argumentu, pārslēdzieties uz darba lapu un atlasiet diapazonu, izmantojot peli.

Piemēram, šādā veidā varat meklēt A2 vērtību diapazonā A2:A9. Cenas darblapā un atgriež atbilstošo vērtību no C slejas:

=VLOOKUP(A2, Prices!$A$2:$C$9, 3, FALSE)

Piezīmes:

• Ja izklājlapas nosaukumā ir atstarpes vai rakstzīmes, kas nav alfabēta burti. , tas ir jāiekļauj pēdiņās, piemēram, "Cenrādis"!$A$2:$C$9.
• Ja izmantojat VLOOKUP formulu vairākām šūnām, neaizmirstiet. bloķēt table_array ar $ zīmi, piemēram, $A$2:$C$9.

Kā Vlookup no citas darbgrāmatas programmā Excel

Lai veiktu Vlookup no citas Excel darbgrāmatas, pirms darblapas nosaukuma kvadrātiekavās ielieciet darbgrāmatas nosaukumu.

Piemēram, šeit ir sniegta formula, lai meklētu A2 vērtību lapā ar nosaukumu Cenas in the Price_List.xlsx darba burtnīca:

=VLOOKUP(A2, [Price_List.xlsx]Prices!$A$2:$C$9, 3, FALSE)

Ja darbgrāmatas vai darblapas nosaukumā ir atstarpes vai rakstzīmes, kas nav alfabēta zīmes, tās jāietver vienpēdiņās, piemēram, šādā veidā:

=VLOOKUP(A2, '[Cenrādis.xlsx]Cenas'!$A$2:$C$9, 3, FALSE)

Vienkāršākais veids, kā izveidot VLOOKUP formulu, kas attiecas uz citu darbgrāmatu, ir šāds:

1. Atveriet abus failus.
2. Sāciet rakstīt formulu, pārslēdzieties uz citu darbgrāmatu un atlasiet tabulas masīvu, izmantojot peli.
3. Ievadiet atlikušos argumentus un nospiediet taustiņu Enter, lai pabeigtu formulu.

Rezultāts būs līdzīgs zemāk redzamajam ekrāna attēlam:

Kad jūs aizvērt failu ar meklēšanas tabulu, VLOOKUP formula turpinās darboties, taču tagad tiks parādīts pilns ceļš uz slēgto darbgrāmatu:

Lai uzzinātu vairāk, skatiet sadaļu Kā atsaukties uz citu Excel lapu vai darbgrāmatu.

Kā Vlookup no nosaukta diapazona citā lapā

Ja plānojat izmantot vienu un to pašu meklēšanas diapazonu daudzās formulās, varat izveidot tam nosaukumu diapazonu un ievadīt nosaukumu tieši formulā. table_array arguments.

Lai izveidotu nosaukumu diapazonu, vienkārši atlasiet šūnas un ierakstiet vajadzīgo nosaukumu laukā Nosaukums lodziņā pa kreisi no formulas joslas. Sīkāku informāciju skatiet sadaļā Kā nosaukt diapazonu programmā Excel.

Šajā piemērā mēs piešķīrām nosaukumu Cenas_2020 uz datu šūnām (A2:C9) meklēšanas lapā un iegūstiet šo kompakto formulu:

=VLOOKUP(A2, Prices_2020, 3, FALSE)

Lielākā daļa nosaukumu programmā Excel attiecas uz visu darbgrāmatu , tāpēc, izmantojot nosauktos diapazonus, darblapas nosaukums nav jānorāda.

Ja norādītais diapazons ir vēl viena darba burtnīca , pirms diapazona nosaukuma ierakstiet darbgrāmatas nosaukumu, piemēram:

=VLOOKUP(A2, 'Price List.xlsx'!Prices_2020, 3, FALSE)

Šādas formulas ir daudz saprotamākas, vai ne? Turklāt nosaukto diapazonu izmantošana var būt laba alternatīva absolūtajām atsaucēm. Tā kā nosauktais diapazons nemainās, varat būt droši, ka jūsu tabulas masīvs paliks bloķēts neatkarīgi no tā, kur formula tiks pārvietota vai kopēta.

Ja esat pārveidojis meklēšanas diapazonu par pilnfunkcionālu Excel tabulu, varat veikt Vlookup, pamatojoties uz tabulas nosaukumu, piem.,. Price_table tālāk dotajā formulā:

=VLOOKUP(A2, Price_table, 3, FALSE)

Tabulu atsauces, ko sauc arī par strukturētām atsaucēm, ir elastīgas un noturīgas pret daudzām datu manipulācijām. Piemēram, varat noņemt vai pievienot jaunas rindas uzmeklēšanas tabulā, neuztraucoties par atsauču atjaunināšanu.

Aizstājējzīmju izmantošana VLOOKUP formulā

Tāpat kā daudzas citas formulas, arī Excel VLOOKUP funkcija pieļauj šādas aizstājējzīmes:

• Jautājuma zīme (?), lai atbilstu jebkurai vienai rakstzīmei.
• Zvaigznīte (*), lai saskaņotu jebkuru rakstzīmju virkni.

Daudzās situācijās ir ļoti noderīgi izmantot aizstājējkartes:

• Ja neatceraties precīzu meklēto tekstu.
• Ja meklējat teksta virkni, kas ir šūnas satura daļa.
• Ja meklēšanas slejā ir sākuma vai beigu atstarpes. Šādā gadījumā var nākties lauzīt galvu, mēģinot noskaidrot, kāpēc parastā formula nedarbojas.

Piemērs 1. Meklējiet tekstu, kas sākas vai beidzas ar noteiktām rakstzīmēm

Pieņemsim, ka vēlaties atrast kādu konkrētu klientu zemāk redzamajā datubāzē. Jūs neatceraties tā uzvārdu, bet esat pārliecināts, ka tas sākas ar "ack".

Lai atgrieztu uzvārdu no A slejas, izmantojiet šādu Vlookup aizstājējvārda formulu:

=VLOOKUP("ack*", $A$2:$B$10, 1, FALSE)

Lai iegūtu licences atslēgu no slejas B, izmantojiet šo (atšķirība ir tikai slejas indeksa numurā):

=VLOOKUP("ack*", $A$2:$B$10, 2, FALSE)

Varat arī ievadīt zināmo nosaukuma daļu kādā šūnā, piemēram, E1, un apvienot aizstājējzīmi ar šūnas atsauci:

=VLOOKUP(E1& "*", $A$2:$B$10, 1, FALSE)

Zemāk redzamajā ekrāna attēlā parādīti rezultāti:

Zemāk ir vēl dažas VLOOKUP formulas ar aizstājējzīmēm.

Atrodiet uzvārdu, kas beidzas ar "son":

=VLOOKUP("*son", $A$2:$B$10, 1, FALSE)

Iegūstiet vārdu, kas sākas ar "joh" un beidzas ar "son":

=VLOOKUP("joh*son", $A$2:$B$10, 1, FALSE)

Izvelciet 5 zīmju uzvārdu:

=VLOOKUP("?????", $A$2:$B$10, 1, FALSE)

Piemērs 2. VLOOKUP aizstājējzīme, pamatojoties uz šūnas vērtību

No iepriekšējā piemēra jau zināt, ka ir iespējams savienot ampersandu (&) un šūnas atsauci, lai izveidotu meklēšanas virkni. Lai atrastu vērtību, kas satur noteiktu(-as) rakstzīmi(-es) jebkurā pozīcijā, ievietojiet ampersandu pirms un pēc šūnas atsauces.

Pieņemsim, ka vēlaties iegūt nosaukumu, kas atbilst noteiktai licences atslēgai, bet nezināt visu atslēgu, tikai dažas rakstzīmes. Izmantojot atslēgas A slejā, nosaukumus B slejā un daļu mērķa atslēgas E1 slejā, varat veikt aizstājējzīmju Vlookup šādā veidā:

Atslēgas izvilkšana:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 1, FALSE)

Izraksta nosaukumu:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 2, FALSE)

Piezīmes:

• Lai VLOOKUP formula ar aizstājējzīmēm darbotos pareizi, izmantojiet precīzu atbilstību (pēdējais arguments ir FALSE).
• Ja tiek atrasts vairāk nekā viens sakritības variants, tiek atgriezts pirmais. .

VLOOKUP TRUE vs FALSE

Un tagad ir pienācis laiks tuvāk aplūkot Excel VLOOKUP funkcijas pēdējo argumentu. Lai gan tas nav obligāts, tomēr range_lookup Atkarībā no tā, vai izvēlaties TRUE vai FALSE, jūsu formula var dot atšķirīgus rezultātus.

Excel VLOOKUP precīza atbilstība (FALSE)

Ja range_lookup ir iestatīta uz FALSE, Vlookup formula meklē vērtību, kas ir precīzi vienāda ar meklēšanas vērtību. Ja tiek atrasti divi vai vairāki sakritieni, tiek atgriezts pirmais. Ja precīzs sakritiens netiek atrasts, tiek pieļauta #N/A kļūda.

Excel VLOOKUP aptuvenā atbilstība (TRUE)

Ja range_lookup ir iestatīts uz TRUE vai izlaists (noklusējums), formula meklē tuvāko atbilstību. Precīzāk, vispirms tiek meklēta precīza atbilstība, un, ja precīza atbilstība nav atrasta, tiek meklēta nākamā lielākā vērtība, kas ir mazāka par meklēšanas vērtību.

Vlookup ar aptuvenu atbilstību darbojas ar šādiem iebildumiem:

• Pārlūkošanas kolonnai jābūt sakārtotai pēc augošā secībā , sākot no mazākā līdz lielākajam, pretējā gadījumā var netikt atrasta pareiza vērtība.
• Ja meklēšanas vērtība ir mazāka par mazāko vērtību meklēšanas masīvā, tiek atgriezta #N/A kļūda.

Turpmākie piemēri palīdzēs jums labāk izprast atšķirību starp precīzu un aptuvenu Vlookup un to, kad vislabāk izmantot katru formulu.

Piemērs 1. Kā veikt precīzu atbilstību Vlookup

Lai atrastu precīzu atbilstību, pēdējā argumentā ierakstiet FALSE.

Šajā piemērā ņemsim dzīvnieku ātruma tabulu, apmainīsim kolonnas un mēģināsim atrast dzīvniekus, kas spēj skriet 80, 50 un 30 jūdžu stundā. Izmantojot meklēšanas vērtības D2, D3 un D4, ievadiet tālāk redzamo formulu E2 un pēc tam nokopējiet to uz divām citām šūnām:

=VLOOKUP(D2, $A$2:$B$12, 2, FALSE)

Kā redzams, formula atgriež "Lion" (lauva) E3, jo tie darbojas tieši 50 stundā. Pārējām divām meklēšanas vērtībām precīza atbilstība nav atrasta, un parādās #N/A kļūdas.

Piemērs 2. Kā veikt Vlookup, lai iegūtu aptuvenu atbilstību

Lai atrastu aptuvenu atbilstību, ir jāveic divas būtiskas darbības:

• Kārtot pirmo kolonnu table_array no mazākā līdz lielākajam.
• Izmantojiet TRUE, lai range_lookup argumentu vai izlaist to.

Ir ļoti svarīgi sakārtot meklēšanas kolonnu, jo VLOOKUP funkcija pārtrauc meklēšanu, tiklīdz atrod tuvu sakritību, kas ir mazāka par meklēšanas vērtību. Ja dati nav pareizi sakārtoti, var rasties ļoti dīvaini rezultāti vai virkne #N/A kļūdu.

Mūsu parauga datiem aptuvena atbilstības Vlookup formula ir šāda:

=VLOOKUP(D2, $A$2:$B$12, 2, TRUE)

Un atgriež šādus rezultātus:

• Ja meklēšanas vērtība ir "80", tiek atgriezts "Cheetah", jo tā ātrums (70) ir tuvākā atbilstība, kas ir mazāka par meklēšanas vērtību.
• Ja meklēšanas vērtība ir "50", tiek atgriezta precīza atbilstība (Lion).
• Ja meklēšanas vērtība ir "30", tiek atgriezta kļūda #N/A, jo meklēšanas vērtība ir mazāka par mazāko vērtību meklēšanas kolonnā.

Īpaši rīki Vlookup programmā Excel

VLOOKUP neapšaubāmi ir viena no jaudīgākajām un noderīgākajām Excel funkcijām, taču tā ir arī viena no mulsinošākajām funkcijām. Lai mācīšanās līkne nebūtu tik stāvas un pieredze būtu patīkamāka, mūsu galīgajā Excel komplektā esam iekļāvuši vairākus laika taupīšanas rīkus.

VLOOKUP vednis - vienkāršs veids, kā rakstīt sarežģītas formulas

Interaktīvais VLOOKUP vednis palīdzēs jums izmantot konfigurācijas opcijas, lai izveidotu perfektu formulu atbilstoši norādītajiem kritērijiem. Atkarībā no jūsu datu struktūras tiks izmantota standarta VLOOKUP funkcija vai INDEX MATCH formula, kas var iegūt vērtības no kreisās puses.

Lai iegūtu pielāgotu formulu, jums ir jādara tas, kas jums jādara:

1. Palaidiet VLOOKUP vedni.

1. Izvēlieties galveno tabulu un uzmeklēšanas tabulu.
2. Norādiet šādas kolonnas (daudzos gadījumos tās tiek atlasītas automātiski):
   • Galvenā sleja - galvenās tabulas kolonnu, kurā ir meklējamās vērtības.
   • Meklēšanas sleja - kolonnu, pret kuru jāskatās.
   • Atgriešanās sleja - kolonnu, no kuras iegūt vērtības.
3. Noklikšķiniet uz Ievietot pogu.

Turpmākajos piemēros ir parādīta vedņa darbība.

Standarta Vlookup

Ja meklēšanas slejā ( Dzīvnieki ) ir meklējumu tabulas kreisākā slejā, tiek ievietota parasta VLOOKUP formula precīzai sakritībai:

Vlookup pa kreisi

Ja meklēšanas slejā ( Dzīvnieki ) atrodas atgriešanas slejas labajā pusē ( Ātrums ), vednis ievieto INDEX MATCH formulu Vlookup no labās puses uz kreiso:

Papildu bonuss! Pateicoties prasmīgai šūnu atsauču izmantošanai, formulas var kopēt vai pārvietot uz jebkuru kolonnu, un jums nav jāatjaunina atsauces.

Divu tabulu apvienošana - Excel VLOOKUP alternatīva bez formulas

Ja jūsu Excel faili ir ārkārtīgi lieli un sarežģīti, projekta termiņš tuvojas un jūs meklējat kādu, kas varētu sniegt jums palīdzīgu roku, izmēģiniet apvienošanas tabulas vedni.

Šis rīks ir mūsu vizuālā un bezstresa alternatīva Excel funkcijai VLOOKUP, kas darbojas šādā veidā:

1. Izvēlieties galveno tabulu.
2. Atlasiet meklēšanas tabulu.
3. Izvēlieties vienu vai vairākas kopīgas kolonnas kā unikālo(-os) identifikatoru(-us).
4. Norādiet, kuras kolonnas atjaunināt.
5. Pēc izvēles izvēlieties kolonnas, kuras vēlaties pievienot.
6. Ļaujiet apvienošanas tabulas vednim dažas sekundes apstrādei... un baudiet rezultātus :)

Tas ir, kā lietot VLOOKUP programmā Excel pamatlīmenī. Nākamajā pamācības daļā mēs aplūkosim padziļinātus VLOOKUP piemērus, kuros uzzināsiet, kā VLOOKUP izmantot vairākus kritērijus, kā atgriezt visus atbilstības vai N-o atkārtojumu, veikt dubultu VLOOKUP, meklēt vairākās lapās ar vienu formulu un daudz ko citu. Paldies, ka izlasījāt, un ceru uz tikšanos nākamnedēļ!

Pieejamās lejupielādes

Excel VLOOKUP formulas piemēri (.xlsx fails)

Ultimate Suite 14 dienu pilnībā funkcionāla versija (.exe fails)