En ĉi tiu lernilo, vi lernos kiel kalkuli unikajn valorojn en Excel per formuloj, kaj kiel akiri aŭtomatan kalkulon de apartaj valoroj en pivottabelo. Ni ankaŭ diskutos pri kelkaj formulekzemploj por kalkuli unikajn nomojn, tekstojn, nombrojn, minuskle-sentemajn unikajn valorojn, kaj pli.

Kiam vi laboras kun granda datumaro en Excel, vi eble ofte bezonos sciu kiom da duoblaj kaj unika valoroj ekzistas. Kaj foje, vi eble volas kalkuli nur la distingajn (malsamajn) valorojn.

Se vi vizitis ĉi tiun blogon laŭ regula baza, vi jam konas la Excel-formulon por kalkuli duplikatojn. Kaj hodiaŭ ni esploros malsamajn manierojn kalkuli unikajn valorojn en Excel. Sed por klareco, ni unue difinu la terminojn.

• Unikaj valoroj - ĉi tiuj estas la valoroj kiuj aperas en la listo nur unufoje.
• Distingaj -valoroj - ĉi tiuj ĉiuj estas malsamaj valoroj en la listo, t.e. unikaj valoroj plus la unuaj okazoj de duplikataj valoroj.

La sekva ekrankopio montras la diferencon:

Kaj nun, ni vidu kiel vi povas kalkuli unikajn kaj apartajn valorojn en Excel uzante formulojn kaj Pivottabajn funkciojn.

Kiel kalkuli unikajn valorojn en Excel

Jen komuna tasko, kiun ĉiuj uzantoj de Excel devas plenumi foje. Vi havas liston de datumoj kaj vi devas ekscii la nombron da unikaj valoroj en tiorestu agordita!

Nombri unikajn valorojn en kolumno

Supoze, ke vi havas kolumnon de nomoj en via Excel. laborfolio, kaj vi devas kalkuli unikajn nomojn en tiu kolumno. La solvo estas uzi la funkcion SUM en kombinaĵo kun SE kaj NOMBRUSE:

Noto . Ĉi tio estas tabelformulo, do nepre premu Ctrl + Shift + Enter por kompletigi ĝin. Post kiam vi faros tion, Excel aŭtomate enmetos la formulon en {buklaj krampoj} kiel en la ekrankopio sube. En neniu kazo vi tajpu la buklajn krampojn permane, tio ne funkcios.

En ĉi tiu ekzemplo, ni kalkulas unikajn nomojn en intervalo A2:A10, do nia formulo prenas la jenan formon:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Plue en ĉi tiu lernilo, ni diskutos pri manpleno da aliaj formuloj por kalkuli unikajn valorojn de malsamaj tipoj. Kaj ĉar ĉiuj tiuj formuloj estas variaĵoj de la baza formulo de unikaj valoroj de Excel, ĝi havas sencon malkonstrui la supran formulon, do vi povas plene kompreni kiel ĝi funkcias kaj ĝustigi ĝin por viaj datumoj. Se iu ne interesiĝas pri teknikaĵoj, vi povas salti rekte al la sekva formulekzemplo.

Kiel funkcias la formulo de Excel kalkulu unikajn valorojn

Kiel vi vidas, 3 malsamaj funkcioj estas uzataj en nia unika valoroj formulo - SUM, SEkaj COUNTIF. Rigardante de interne eksteren, jen kion faras ĉiu funkcio:

• La funkcio COUNTIF kalkulas kiom da fojoj ĉiu individua valoro aperas en la specifita intervalo.

  En ĉi tiu ekzemplo, COUNTIF(A2:A10,A2:A10) resendas la tabelon {1;2;2;1;2;2;2;1;2} .

• La IF-funkcio taksas ĉiun valoron en la tabelo redonita de COUNTIF, konservas ĉiujn 1-ojn (unikaj valoroj), kaj anstataŭigas ĉiujn aliajn valorojn per nuloj. .

  Do, la funkcio IF(COUNTIF(A2:A10,A2:A10)=1,1,0) fariĝas IF(1;2;2;1;2;2;2;1;2) = 1,1,0, kiu iĝas la tabelo {1;0;0;1;0;0;0;1;0} kie 1 estas unika valoro kaj 0 estas duplikata valoro.

• Fine, la SUM-funkcio adicias la valorojn en la tabelo redonita de IF kaj eligas la totalan nombron de unikaj valoroj, kio estas ĝuste tio, kion ni volis.

Konsilo. . Por vidi, al kio specifa parto de via Excel-unika valorformulo taksas, elektu tiun parton en la formulbreto kaj premu la F9-klavon.

Nombri unikajn tekstajn valorojn en Excel

Se via Excel-listo enhavas kaj nombrajn kaj tekstajn valorojn, kaj vi volas kalkuli nur unikajn tekstajn valorojn, aldonu la ISTEXT-funkcion al la tabelformulo diskutita supre:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Kiel vi scias, la Excel ISTEXT-funkcio liveras VERA se taksita valoro estas teksto, FALSA alie. Ĉar la asterisko (*) funkcias kiel la operatoro AND en tabelaj formuloj, la IF-funkcio liveras 1 nur se valoro estas kaj teksto kaj unika, 0 alie. Kaj post kiam la SUM-funkcio adicias ĉiujn 1-ojn, vi ricevos kalkulon de unikaj tekstaj valoroj en la specifita.intervalo.

Ne forgesu premi Ctrl + Shift + Enter por ĝuste enigi la tabelformulon, kaj vi ricevos rezulton similan al ĉi tio:

Kiel vi povas vidi en la supra ekrankopio, la formulo redonas la totalan nombron de unikaj tekstaj valoroj, ekskludante malplenajn ĉelojn, nombrojn, logikaj valoroj de VERA kaj FALSA kaj eraroj.

Nombri unikajn nombrajn valorojn en Excel

Por kalkuli unikajn nombrojn en listo de datumoj, uzu tabelan formulon kiel ni ĵus uzis por kalkuli unikajn tekstajn valorojn, kun la nura diferenco, ke vi enigas ISNUMBER anstataŭ ISTEXT en via unika valorformulo:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Notu. Ĉar Microsoft Excel konservas datojn kaj horojn kiel seriajn numerojn, ili ankaŭ estas kalkulitaj.

Nombri uskle-distintajn unikajn valorojn en Excel

Se via tabelo enhavas uskle-distintajn datumojn, la plej facila maniero kalkuli unikaj valoroj estus krei helpan kolumnon kun la sekva tabelformulo por identigi duplikatajn kaj unikajn erojn:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

Kaj poste, uzu simplan COUNTIF-funkcion por kalkuli unikajn valorojn:

=COUNTIF(B2:B10, "unique")

Nombri apartajn valorojn en Excel (unikaj kaj unuaj duplikataj okazoj)

Por akiri kalkulon de apartaj valoroj en listo, uzu la jenan formulo:

Memoru, ĝi estas tabelformulo, kaj tial vi devus premi la Ctrl + Shift + Enter ŝparvojo anstataŭ la kutima Eniguklavopremo.

Alternative, vi povas uzi la funkcion SUMPRODUCT kaj kompletigi la formulon en la kutima maniero premante la Enigu klavon:

Ekzemple, por kalkuli la apartajn valorojn en intervalo A2:A10, vi povas iri kun aŭ:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Aŭ

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Kiel funkcias la distinga formulo de Excel

Kiel vi jam scias, ni uzas la funkcion COUNTIF por ekscii kiomfoje ĉiu individua valoro aperas en la specifita intervalo. En la ĉi-supra ekzemplo, la rezulto de la funkcio COUNTIF estas la sekva tabelo: {2;2;3;1;2;2;3;1;3} .

Post tio, kelkaj dividaj operacioj estas faritaj, kie ĉiu valoro de la tabelo estas uzata kiel dividanto kun 1 kiel la dividendo. Ĉi tio igas ĉiujn duplikatajn valorojn en frakciajn nombrojn respondajn al la nombro da duplikataj okazoj. Ekzemple, se valoro aperas 2 fojojn en la listo, ĝi generas 2 erojn en la tabelo kun valoro de 0,5 (1/2=0,5). Kaj se valoro aperas 3 fojojn, ĝi produktas 3 erojn en la tabelo kun valoro de 0,3(3). En nia ekzemplo, la rezulto de 1/COUNTIF(A2:A10,A2:A10)) estas la tabelo {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Ĉu ĝis nun ne havas multe da senco? Tio estas ĉar ni ankoraŭ ne aplikis la funkcion SUM / SUMPRODUCT. Kiam unu el ĉi tiuj funkcioj adicias la valorojn en la tabelo, la sumo de ĉiuj frakciaj nombroj por ĉiu individua ero ĉiam donas 1, negrave kiom da okazoj de tiu ero ekzistas en la listo. Kajĉar ĉiuj unikaj valoroj aperas en la tabelo kiel 1 (1/1=1), la fina rezulto redonita de la formulo estas la tuta nombro de ĉiuj malsamaj valoroj en la listo.

Formuloj por kalkuli apartajn valorojn de malsamaj. tipoj

Kiel okazas kun kalkulado de unikaj valoroj en Excel, vi povas uzi variaĵojn de la baza Excel-kalkula distinga formulo por trakti specifajn valortipojn kiel nombrojn, tekstojn kaj uskle-distintajn valorojn.

Bonvolu memori, ke ĉiuj subaj formuloj estas tabelaj formuloj kaj postulas premado de Ctrl + Shift + Enter .

Nombri apartajn valorojn ignorante malplenajn ĉelojn

Se kolumno kie vi volas kalkuli apartajn valorojn povus enhavi malplenajn ĉelojn, vi devus aldoni IF-funkcion kiu kontrolos la specifitan intervalon por malplenaj (la baza Excel-distinga formulo diskutita supre redonus la #DIV/0-eraron ĉi-kaze):

Ekzemple, por kalkuli apartajn valorojn en intervalo A2:A10, uzu la sekva tabelformulo :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Formulo por kalkuli apartajn tekstajn valorojn

Por kalkuli apartajn tekstajn valorojn en kolumno, ni uzos la saman metodon, kiun ni ĵus uzis por ekskludi malplenajn ĉelojn.

Kiel vi povas facile diveni, ni simple enigos la funkcion ISTEXT en nian distingan formulon de Excel-kalkulo:

Kaj jen reala vivoekzemplo de formulo:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Formulo por kalkuli apartajn nombrojn

Por kalkuli apartajn nombrajn valorojn (nombroj, datoj kaj tempoj), uzu la funkcion ISNUM:

Ekzemple, por nombri ĉiujn malsamajn nombrojn en intervalo A2:A10, uzu la jenan formulon:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Nombri uskle-distingajn distingajn valorojn en Excel

Simile al kalkuli uskle-distintajn unikajn valorojn, la plej facila maniero. kalkuli uskle-distingajn distingajn valorojn estas aldoni helpan kolumnon kun la tabelformulo kiu identigas unikajn valorojn inkluzive de unuaj duplikataj okazoj. La formulo estas esence la sama kiel tiu, kiun ni uzis por kalkuli uskle-distintajn unikajn valorojn, kun unu malgranda ŝanĝo en ĉela referenco kiu faras grandan diferencon:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

Kiel vi memoras, ĉiuj tabelaj formuloj en Excel postulas premadon Ctrl + Shift + Enter .

Post la supra formulo estas finita, vi povas kalkuli "distingajn" valorojn kun kutima COUNTIF formulo kiel ĉi tiu:

=COUNTIF(B2:B10, "distinct")

Se vi neniel povas aldoni helpan kolumnon al via laborfolio, vi povas uzi la jenan kompleksan tabelformulo por nombri uskle-distingajn distingajn valorojn sen kreante plian kolumnon:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

Nombri unikajn kaj apartajn vicojn en Excel

Nombri unikajn/distingajn vicojn en Excel similas al nombri unikajn kaj apartajn valorojn, kun la sola diferencoke vi uzu la funkcion COUNTIFS anstataŭ COUNTIF, kiu ebligas al vi specifi plurajn kolumnojn por kontroli unikajn valorojn.

Ekzemple, por kalkuli unikajn aŭ apartajn nomojn surbaze de la valoroj en kolumnoj A (Prenunomo) kaj B. (Familinomo), uzu unu el la jenaj formuloj:

Formulo por kalkuli unikajn vicojn:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Formulo por kalkuli distingajn vicoj:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Nature, vi ne estas limigita al kalkulo de unikaj vicoj bazitaj nur sur du kolumnoj, la Excel COUNTIFS-funkcio povas procesi supren. al 127 intervalo/kriteriaj paroj.

Nombri apartajn valorojn en Excel uzante Pivotabelon

La plej novaj versioj de Excel 2013 kaj Excel 2016 havas speciala funkcio, kiu permesas aŭtomate nombri apartajn valorojn en pivottabelo. La sekva ekrankopio donas ideon pri kiel aspektas la Excel Distinga Nombro :

Por krei pivotan tabelon kun la klara kalkulo por certa kolumno, faru la sekvajn paŝojn.

1. Elektu la datumojn inkluditajn en pivottabelo, ŝanĝu al la langeto Enmeti , grupon Tabeloj kaj alklaku la . 4>Pivottabulo -butono.
2. En la dialogo Krei Pivottabulo , elektu ĉu meti vian pivottabelon en novan aŭ ekzistantan laborfolion, kaj nepre elektu la Aldoni ĉi tiujn datumojn al la markobutono de Datuma Modelo .

Vi ankaŭ povas doni propran nomon al via Distinga Kalkulo se vi volas.

Fine! La lastatempe kreita pivottabelo montros la klaran nombron kiel montrite en la unua ekrankopio en ĉi tiu sekcio.

Konsilo. Post ĝisdatigi viajn fontajn datumojn, memoru ĝisdatigi la Pivottablon por ĝisdatigi la distingan kalkulon. Por refreŝigi pivottabelon, simple alklaku la butonon Refreŝigi sur la langeto Analizi , en la grupo Datumoj .

Jen kiel vi kalkulas. distingaj kaj unikaj valoroj en Excel. Se iu volas pli detale rigardi la formulojn diskutitajn en ĉi tiu lernilo, vi bonvenas elŝuti la ekzemplan Excel Count Unique laborlibron.

Mi dankas vin pro legado kaj esperas revidi vin venontsemajne. En la sekva artikolo, ni diskutos diversajn manierojn trovi, filtri, ĉerpi kaj reliefigi unikajn valorojn en Excel. Bonvolu