U ovom vodiču naučit ćete kako prebrojati jedinstvene vrijednosti u Excelu s formulama i kako dobiti automatski broj različitih vrijednosti u zaokretnoj tablici. Također ćemo raspravljati o brojnim primjerima formula za brojanje jedinstvenih imena, tekstova, brojeva, jedinstvenih vrijednosti osjetljivih na velika i mala slova i više.

Kada radite s velikim skupom podataka u Excelu, možda ćete često morati znati koliko ima dupliciranih i jedinstvenih vrijednosti. A ponekad ćete možda htjeti brojati samo različite (različite) vrijednosti.

Ako ste redovito posjećivali ovaj blog, već znate formulu programa Excel za brojanje duplikata. A danas ćemo istražiti različite načine brojanja jedinstvenih vrijednosti u Excelu. Ali radi jasnoće, prvo definirajmo pojmove.

• Jedinstvene vrijednosti - to su vrijednosti koje se pojavljuju na popisu samo jednom.
• Različite vrijednosti - sve su to različite vrijednosti na popisu, tj. jedinstvene vrijednosti plus prvo pojavljivanje dupliciranih vrijednosti.

Sljedeći snimak zaslona pokazuje razliku:

A sada, da vidimo kako možete prebrojati jedinstvene i različite vrijednosti u Excelu pomoću formula i značajki zaokretne tablice.

Kako prebrojati jedinstvene vrijednosti u Excelu

Evo uobičajenog zadatka koji svi korisnici programa Excel s vremena na vrijeme moraju izvršiti. Imate popis podataka i morate saznati broj jedinstvenih vrijednosti u njemuostanite s nama!

Brojanje jedinstvenih vrijednosti u stupcu

Pretpostavimo da imate stupac imena u svom Excelu radni list, a vi morate prebrojati jedinstvena imena u tom stupcu. Rješenje je korištenje funkcije SUM u kombinaciji s IF i COUNTIF:

Napomena . Ovo je formula polja, pa svakako pritisnite Ctrl + Shift + Enter da biste je dovršili. Nakon što to učinite, Excel će automatski staviti formulu u {vitičaste zagrade} kao na slici ispod. Ni u kojem slučaju ne biste trebali ručno upisivati ​​vitičaste zagrade, to neće raditi.

U ovom primjeru brojimo jedinstvena imena u rasponu A2:A10, tako da naša formula ima sljedeći oblik:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Dalje u ovom vodiču, raspravljat ćemo o nekolicini drugih formula za brojanje jedinstvenih vrijednosti različitih vrsta. Budući da su sve te formule varijacije osnovne formule jedinstvenih vrijednosti programa Excel, ima smisla raščlaniti gornju formulu kako biste u potpunosti razumjeli kako funkcionira i prilagodili je za svoje podatke. Ako nekoga ne zanimaju tehničke detalje, možete prijeći odmah na sljedeći primjer formule.

Kako radi formula za brojanje jedinstvenih vrijednosti programa Excel

Kao što vidite, 3 različite funkcije koriste se u našoj jedinstvenoj formula vrijednosti - SUM, IFi COUNTIF. Gledajući iznutra prema van, evo što svaka funkcija radi:

• Funkcija COUNTIF broji koliko se puta svaka pojedinačna vrijednost pojavljuje u navedenom rasponu.

  U ovom primjeru, COUNTIF(A2:A10,A2:A10) vraća niz {1;2;2;1;2;2;2;1;2} .

• Funkcija IF procjenjuje svaku vrijednost u nizu koju vraća COUNTIF, zadržava sve 1 (jedinstvene vrijednosti) i zamjenjuje sve ostale vrijednosti nulama .

  Dakle, funkcija IF(COUNTIF(A2:A10,A2:A10)=1,1,0) postaje IF(1;2;2;1;2;2;2;1;2) = 1,1,0, koja se pretvara u polje {1;0;0;1;0;0;0;1;0} gdje je 1 jedinstvena vrijednost, a 0 duplikat vrijednosti.

• Konačno, funkcija SUM zbraja vrijednosti u nizu koje vraća IF i ispisuje ukupan broj jedinstvenih vrijednosti, što je upravo ono što smo htjeli.

Savjet . Da biste vidjeli na što se procjenjuje određeni dio vaše formule jedinstvenih vrijednosti programa Excel, odaberite taj dio na traci formule i pritisnite tipku F9.

Brojanje jedinstvenih tekstualnih vrijednosti u programu Excel

Ako vaš Excel popis sadrži i numeričke i tekstualne vrijednosti, a želite brojati samo jedinstvene tekstualne vrijednosti, dodajte funkciju ISTEXT u formulu polja o kojoj je gore bilo riječi:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Kao što znate, funkcija Excel ISTEXT vraća TRUE ako je procijenjena vrijednost tekst, FALSE u suprotnom. Budući da zvjezdica (*) funkcionira kao operator AND u formulama polja, funkcija IF vraća 1 samo ako je vrijednost i tekstualna i jedinstvena, a 0 u suprotnom. Nakon što funkcija SUM zbroji sve 1, dobit ćete broj jedinstvenih tekstualnih vrijednosti u navedenomraspon.

Ne zaboravite pritisnuti Ctrl + Shift + Enter za ispravan unos formule polja i dobit ćete rezultat sličan ovome:

Kao što možete vidjeti na gornjoj snimci zaslona, ​​formula vraća ukupan broj jedinstvenih tekstualnih vrijednosti, isključujući prazne ćelije, brojeve, logičke vrijednosti TRUE i FALSE i pogreške.

Broj jedinstvenih numeričkih vrijednosti u Excelu

Da biste prebrojali jedinstvene brojeve na popisu podataka, upotrijebite formulu polja kao što smo upravo upotrijebili za prebrojavanje jedinstvenih tekstualnih vrijednosti, s jedinom razlikom što ćete u svoju formulu jedinstvenih vrijednosti ugraditi ISNUMBER umjesto ISTEXT:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Napomena. Budući da Microsoft Excel pohranjuje datume i vremena kao serijske brojeve, oni se također broje.

Brojte jedinstvene vrijednosti koje razlikuju velika i mala slova u Excelu

Ako vaša tablica sadrži podatke koji razlikuju velika i mala slova, najlakši je način brojanja jedinstvene vrijednosti bile bi stvaranje pomoćnog stupca sa sljedećom formulom polja za identifikaciju duplikata i jedinstvenih stavki:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

A zatim upotrijebite jednostavnu funkciju COUNTIF za brojanje jedinstvenih vrijednosti:

=COUNTIF(B2:B10, "unique")

Broj različite vrijednosti u Excelu (jedinstvene i prve duple pojave)

Da biste dobili broj različitih vrijednosti na popisu, upotrijebite sljedeće formula:

Zapamtite, to je formula polja i stoga biste trebali pritisnuti Ctrl + Shift + Enter prečac umjesto uobičajenog Enterapritisak tipke.

Alternativno, možete koristiti funkciju SUMPROIZVOD i dovršiti formulu na uobičajeni način pritiskom na tipku Enter:

Na primjer, za brojanje različitih vrijednosti u rasponu A2:A10, možete ići s bilo kojim:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Ili

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Kako funkcionira posebna formula programa Excel

Kao što već znate, koristimo se funkcijom COUNTIF kako bismo saznali koliko se puta svaka pojedinačna vrijednost pojavljuje u navedeni raspon. U gornjem primjeru, rezultat funkcije COUNTIF je sljedeći niz: {2;2;3;1;2;2;3;1;3} .

Nakon toga se izvodi nekoliko operacija dijeljenja, gdje se svaka vrijednost niza koristi kao djelitelj s 1 kao djeliteljom dividenda. Ovo pretvara sve duplicirane vrijednosti u razlomke koji odgovaraju broju dupliciranih pojavljivanja. Na primjer, ako se vrijednost pojavi 2 puta na popisu, generira 2 stavke u nizu s vrijednošću 0,5 (1/2=0,5). A ako se vrijednost pojavi 3 puta, proizvodi 3 stavke u nizu s vrijednošću 0,3(3). U našem primjeru, rezultat od 1/COUNTIF(A2:A10,A2:A10)) je polje {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Za sada nema smisla? To je zato što još nismo primijenili funkciju SUM / SUMPRODUCT. Kada jedna od ovih funkcija zbroji vrijednosti u nizu, zbroj svih razlomačkih brojeva za svaku pojedinačnu stavku uvijek daje 1, bez obzira koliko pojavljivanja te stavke postoji na popisu. Ibudući da se sve jedinstvene vrijednosti pojavljuju u nizu kao 1 (1/1=1), konačni rezultat koji vraća formula je ukupan broj svih različitih vrijednosti na popisu.

Formule za brojanje različitih vrijednosti različitih tipovi

Kao što je slučaj s prebrojavanjem jedinstvenih vrijednosti u Excelu, možete koristiti varijacije osnovne Excelove formule za različito brojanje za rukovanje određenim vrstama vrijednosti kao što su brojevi, tekst i vrijednosti osjetljive na velika i mala slova.

Zapamtite da su sve donje formule formule polja i zahtijevaju pritisak Ctrl + Shift + Enter .

Brojte različite vrijednosti zanemarujući prazne ćelije

Ako je stupac u kojem želite brojati različite vrijednosti može sadržavati prazne ćelije, trebali biste dodati funkciju IF koja će provjeriti navedeni raspon za praznine (osnovna posebna Excel formula o kojoj je gore bilo riječi vratila bi pogrešku #DIV/0 u ovom slučaju):

Na primjer, za brojanje različitih vrijednosti u rasponu A2:A10, koristite sljedeća formula niza :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Formula za brojanje različitih tekstualnih vrijednosti

Da bismo brojali različite tekstualne vrijednosti u stupcu, koristit ćemo isti pristup koji smo upravo upotrijebili za izuzimanje praznih ćelija.

Kao što lako možete pogoditi, jednostavno ćemo ugraditi funkciju ISTEXT u našu posebnu formulu za brojanje u Excelu:

I evo stvarnog životaprimjer formule:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Formula za brojanje različitih brojeva

Za brojanje različitih numeričkih vrijednosti (brojeva, datuma i vremena), koristite funkciju ISNUMBER:

Na primjer, za brojanje svih različitih brojeva u rasponu A2:A10 upotrijebite sljedeću formulu:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Broj različite vrijednosti osjetljive na velika i mala slova u Excelu

Slično brojanju jedinstvenih vrijednosti osjetljivih na velika i mala slova, najlakši način brojati različite vrijednosti koje razlikuju velika i mala slova znači dodati pomoćni stupac s formulom polja koja identificira jedinstvene vrijednosti uključujući prve duplikate. Formula je u osnovi ista kao ona koju smo koristili za brojanje jedinstvenih vrijednosti osjetljivih na velika i mala slova, s jednom malom promjenom u referenci ćelije koja čini veliku razliku:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

Kao što se sjećate, sve formule niza u Excelu zahtijevaju pritiskanje Ctrl + Shift + Enter .

Nakon što je gornja formula gotova, možete brojati "različite" vrijednosti uobičajenom formulom COUNTIF poput ove:

=COUNTIF(B2:B10, "distinct")

Ako ne možete dodati pomoćni stupac na svoj radni list, možete upotrijebiti sljedeću složenu formulu niza za brojanje različitih vrijednosti koje razlikuju velika i mala slova bez stvaranje dodatnog stupca:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

Brojenje jedinstvenih i različitih redaka u Excelu

Brojenje jedinstvenih/različitih redaka u Excelu slično je brojanju jedinstvenih i različitih redaka, sa samo razlikada koristite funkciju COUNTIFS umjesto COUNTIF, koja vam omogućuje navođenje nekoliko stupaca za provjeru jedinstvenih vrijednosti.

Na primjer, za brojanje jedinstvenih ili različitih imena na temelju vrijednosti u stupcima A (Ime) i B (Prezime), koristite jednu od sljedećih formula:

Formula za brojanje jedinstvenih redaka:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Formula za brojanje različitih redaka redaka:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Naravno, niste ograničeni na brojanje jedinstvenih redaka na temelju samo dva stupca, funkcija Excel COUNTIFS može obraditi do 127 parova raspona/kriterija.

Prebrojite različite vrijednosti u Excelu pomoću zaokretne tablice

Posljednje verzije programa Excel 2013 i Excel 2016 imaju posebna značajka koja omogućuje automatsko brojanje različitih vrijednosti u zaokretnoj tablici. Sljedeća snimka zaslona daje ideju o tome kako Excel Različiti broj izgleda:

Da biste stvorili zaokretnu tablicu s različitim zbrojem za određeni stupac, izvršite sljedeće korake.

1. Odaberite podatke koji će biti uključeni u zaokretnu tablicu, prebacite se na karticu Umetni , grupu Tablice i kliknite Gumb zaokretne tablice .
2. U dijaloškom okviru Stvori zaokretnu tablicu odaberite hoćete li svoju zaokretnu tablicu smjestiti u novi ili postojeći radni list i svakako odaberite Dodaj ove podatke u potvrdni okvir Data Model .

Također možete dati prilagođeni naziv vašem posebnom broju ako to želite.

Gotovo! Novostvorena zaokretna tablica prikazat će poseban broj kao što je prikazano na prvoj snimci zaslona u ovom odjeljku.

Savjet. Nakon ažuriranja izvornih podataka, ne zaboravite ažurirati zaokretnu tablicu kako biste ažurirali različiti broj. Da biste osvježili zaokretnu tablicu, samo kliknite gumb Osvježi na kartici Analiziraj , u grupi Podaci .

Ovako brojite različite i jedinstvene vrijednosti u Excelu. Ako netko želi pobliže pogledati formule o kojima se govori u ovom vodiču, slobodno možete preuzeti oglednu radnu knjigu Excel Count Unique.

Zahvaljujem vam na čitanju i nadam se da se ponovno vidimo sljedeći tjedan. U sljedećem članku raspravljat ćemo o različitim načinima pronalaženja, filtriranja, izdvajanja i isticanja jedinstvenih vrijednosti u Excelu. Molim