V tomto učebnom texte sa dozviete, ako počítať jedinečné hodnoty v programe Excel pomocou vzorcov a ako získať automatické počítanie jedinečných hodnôt v otočnej tabuľke. Budeme tiež diskutovať o niekoľkých príkladoch vzorcov na počítanie jedinečných mien, textov, čísel, jedinečných hodnôt citlivých na veľkosť písmen a ďalších.

Pri práci s veľkým súborom údajov v programe Excel môžete často potrebovať vedieť, koľko duplikát a jedinečné A niekedy môžete chcieť počítať len s hodnotami zreteľné (rôzne) hodnoty.

Ak ste tento blog navštevovali pravidelne na základnej úrovni, vzorec Excelu na počítanie duplikátov už poznáte. A dnes sa budeme venovať rôznym spôsobom počítania jedinečných hodnôt v programe Excel. Kvôli prehľadnosti si však najprv zadefinujme pojmy.

• Jedinečné hodnoty - ide o hodnoty, ktoré sa v zozname zobrazia iba raz.
• Výrazné hodnoty - ide o všetky rôzne hodnoty v zozname, t. j. jedinečné hodnoty plus 1. výskyt duplicitných hodnôt.

Nasledujúca snímka obrazovky demonštruje tento rozdiel:

A teraz sa pozrieme, ako môžete v programe Excel počítať jedinečné a odlišné hodnoty pomocou vzorcov a funkcií PivotTable.

Ako počítať jedinečné hodnoty v programe Excel

Tu je bežná úloha, ktorú musia raz za čas vykonať všetci používatelia programu Excel. Máte zoznam údajov a potrebujete zistiť počet jedinečných hodnôt v tomto zozname. Ako to urobíte? Jednoduchšie, ako si možno myslíte :) Nižšie nájdete niekoľko vzorcov na počítanie jedinečných hodnôt rôznych typov.

Počítanie jedinečných hodnôt v stĺpci

Predpokladajme, že máte v pracovnom hárku programu Excel stĺpec s menami a potrebujete spočítať jedinečné mená v tomto stĺpci. Riešením je použitie funkcie SUM v kombinácii s funkciami IF a COUNTIF:

Poznámka . Toto je vzorec poľa, preto nezabudnite stlačiť klávesovú skratku Ctrl + Shift + Enter, aby ste ho dokončili. Keď to urobíte, Excel automaticky uzavrie vzorec do {vlnitých zátvoriek}, ako je to na snímke nižšie. V žiadnom prípade by ste nemali písať vlnité zátvorky ručne, to nebude fungovať.

V tomto príklade počítame jedinečné názvy v rozsahu A2:A10, takže náš vzorec má nasledujúci tvar:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Ďalej v tomto návode budeme diskutovať o niekoľkých ďalších vzorcoch na počítanie jedinečných hodnôt rôznych typov. A keďže všetky tieto vzorce sú variáciami základného vzorca na počítanie jedinečných hodnôt v programe Excel, má zmysel rozobrať vyššie uvedený vzorec, aby ste mohli plne pochopiť, ako funguje, a upraviť ho pre svoje údaje. Ak niekoho nezaujímajú technické detaily, môžete preskočiť priamo naďalší príklad vzorca.

Ako funguje vzorec programu Excel na počítanie jedinečných hodnôt

Ako vidíte, v našom vzorci pre jedinečné hodnoty sa používajú 3 rôzne funkcie - SUM, IF a COUNTIF. Ak sa na to pozrieme zvnútra, uvedieme, čo jednotlivé funkcie robia:

• Funkcia COUNTIF počíta, koľkokrát sa jednotlivé hodnoty objavia v zadanom rozsahu.

  V tomto príklade, COUNTIF(A2:A10,A2:A10) vráti pole {1;2;2;1;2;2;2;1;2} .

• Funkcia IF vyhodnotí každú hodnotu v poli vrátenom funkciou COUNTIF, ponechá všetky 1 (jedinečné hodnoty) a všetky ostatné hodnoty nahradí nulami.

  Takže funkcia IF(COUNTIF(A2:A10,A2:A10)=1,1,0) sa stáva IF(1;2;2;1;2;2;2;1;2) = 1,1,0, ktorý sa zmení na pole {1;0;0;1;0;0;0;1;0} kde 1 je jedinečná hodnota a 0 je duplicitná hodnota.

• Nakoniec funkcia SUM sčíta hodnoty v poli vrátenom funkciou IF a vypíše celkový počet jedinečných hodnôt, čo je presne to, čo sme chceli.

Tip: Ak chcete zistiť, na čo sa vyhodnocuje konkrétna časť vzorca jedinečných hodnôt programu Excel, vyberte túto časť na paneli vzorcov a stlačte kláves F9.

Počítanie jedinečných textových hodnôt v programe Excel

Ak váš zoznam v programe Excel obsahuje číselné aj textové hodnoty a chcete počítať len jedinečné textové hodnoty, pridajte do vyššie uvedeného vzorca poľa funkciu ISTEXT:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Ako viete, funkcia ISTEXT programu Excel vracia TRUE, ak je vyhodnocovaná hodnota textom, v opačnom prípade FALSE. Keďže hviezdička (*) funguje ako operátor AND vo vzorcoch poľa, funkcia IF vracia 1 len vtedy, ak je hodnota textom a zároveň jedinečná, v opačnom prípade 0. A po sčítaní všetkých 1 funkciou SUM získate počet jedinečných textových hodnôt v zadanom rozsahu.

Nezabudnite stlačiť klávesovú skratku Ctrl + Shift + Enter, aby ste správne zadali vzorec poľa, a dostanete podobný výsledok:

Ako vidíte na obrázku vyššie, vzorec vracia celkový počet jedinečných textových hodnôt bez prázdnych buniek, čísel, logických hodnôt TRUE a FALSE a chýb.

Počítanie jedinečných číselných hodnôt v programe Excel

Ak chcete spočítať jedinečné čísla v zozname údajov, použite vzorec poľa, ktorý sme práve použili na počítanie jedinečných textových hodnôt, len s tým rozdielom, že do vzorca pre jedinečné hodnoty vložíte ISNUMBER namiesto ISTEXT:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Poznámka: Keďže Microsoft Excel ukladá dátumy a časy ako poradové čísla, sú tiež započítané.

Počítanie jedinečných hodnôt v programe Excel s rozlišovaním veľkých a malých písmen

Ak vaša tabuľka obsahuje údaje citlivé na veľkosť písmen, najjednoduchším spôsobom počítania jedinečných hodnôt by bolo vytvorenie pomocného stĺpca s nasledujúcim vzorcom poľa na identifikáciu duplicitných a jedinečných položiek:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1, "Unikátny", "Duplikát")

A potom použite jednoduchú funkciu COUNTIF na počítanie jedinečných hodnôt:

=COUNTIF(B2:B10, "unique")

Spočítajte odlišné hodnoty v programe Excel (jedinečné a 1. duplicitné výskyty)

Ak chcete získať počet rôznych hodnôt v zozname, použite nasledujúci vzorec:

Nezabudnite, že ide o vzorec poľa, a preto by ste namiesto bežného stlačenia klávesu Enter mali stlačiť klávesovú skratku Ctrl + Shift + Enter.

Prípadne môžete použiť funkciu SUMPRODUCT a vzorec dokončiť obvyklým spôsobom stlačením klávesu Enter:

Ak chcete napríklad spočítať rôzne hodnoty v rozsahu A2:A10, môžete použiť buď:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Alebo

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Ako funguje výrazný vzorec programu Excel

Ako už viete, pomocou funkcie COUNTIF zistíme, koľkokrát sa jednotlivé hodnoty vyskytujú v zadanom rozsahu. V uvedenom príklade je výsledkom funkcie COUNTIF nasledujúce pole: {2;2;3;1;2;2;3;1;3} .

Potom sa vykoná niekoľko operácií delenia, pri ktorých sa každá hodnota poľa použije ako deliteľ a ako dividenda sa použije 1. Tým sa všetky duplicitné hodnoty zmenia na zlomkové čísla zodpovedajúce počtu duplicitných výskytov. Napríklad, ak sa hodnota v zozname vyskytne 2-krát, vytvoria sa 2 položky v poli s hodnotou 0,5 (1/2=0,5). A ak sa hodnota vyskytne 3-krát, vytvorí savytvorí 3 položky v poli s hodnotou 0,3(3). V našom príklade je výsledkom 1/COUNTIF(A2:A10,A2:A10)) je pole {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Že to zatiaľ nedáva zmysel? Je to preto, že sme ešte nepoužili funkciu SUM / SUMPRODUCT. Keď jedna z týchto funkcií sčíta hodnoty v poli, súčet všetkých zlomkových čísel pre každú jednotlivú položku dáva vždy 1, bez ohľadu na to, koľko výskytov danej položky v zozname existuje. A pretože všetky jedinečné hodnoty sa v poli zobrazujú ako 1 (1/1=1), konečný výsledok vrátený funkciouvzorec je celkový počet všetkých rôznych hodnôt v zozname.

Vzorce na počítanie rozdielnych hodnôt rôznych typov

Podobne ako v prípade počítania jedinečných hodnôt v programe Excel môžete použiť variácie základného vzorca programu Excel pre počítanie odlišných hodnôt na spracovanie konkrétnych typov hodnôt, ako sú čísla, text a hodnoty s rozlišovaním veľkých a malých písmen.

Nezabudnite, že všetky nižšie uvedené vzorce sú vzorce poľa a vyžadujú stlačenie klávesovej skratky Ctrl + Shift + Enter .

Počítanie rozdielnych hodnôt bez ohľadu na prázdne bunky

Ak stĺpec, v ktorom chcete počítať odlišné hodnoty, môže obsahovať prázdne bunky, mali by ste pridať funkciu IF, ktorá skontroluje zadaný rozsah na prítomnosť prázdnych buniek (základný vzorec Excelu pre odlišné hodnoty, o ktorom sme hovorili vyššie, by v tomto prípade vrátil chybu #DIV/0):

Ak chcete napríklad spočítať rôzne hodnoty v rozsahu A2:A10, použite nasledujúci vzorec:

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Vzorec na počítanie odlišných textových hodnôt

Na počítanie odlišných textových hodnôt v stĺpci použijeme rovnaký prístup, aký sme práve použili na vylúčenie prázdnych buniek.

Ako si môžete ľahko domyslieť, funkciu ISTEXT jednoducho vložíme do nášho vzorca na rozlišovanie počtu v programe Excel:

A tu je príklad skutočného vzorca:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Vzorec na počítanie rôznych čísel

Ak chcete spočítať rôzne číselné hodnoty (čísla, dátumy a časy), použite funkciu ISNUMBER:

Ak chcete napríklad spočítať všetky rôzne čísla v rozsahu A2:A10, použite nasledujúci vzorec:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Počítanie rozdielnych hodnôt s rozlišovaním veľkých a malých písmen v programe Excel

Podobne ako pri počítaní jedinečných hodnôt citlivých na veľkosť písmen je najjednoduchším spôsobom počítania jedinečných hodnôt citlivých na veľkosť písmen pridanie pomocného stĺpca so vzorcom poľa, ktorý identifikuje jedinečné hodnoty vrátane prvých duplicitných výskytov. Vzorec je v podstate rovnaký ako vzorec, ktorý sme použili na počítanie jedinečných hodnôt citlivých na veľkosť písmen, s jednou malou zmenou v odkaze na bunku, ktorá predstavuje veľký rozdiel:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1, "Rozdielne",")

Ako si pamätáte, všetky vzorce polí v programe Excel vyžadujú stlačenie klávesovej skratky Ctrl + Shift + Enter .

Po dokončení vyššie uvedeného vzorca môžete spočítať "rozdielne" hodnoty pomocou bežného vzorca COUNTIF takto:

=COUNTIF(B2:B10, "distinct")

Ak nie je možné pridať pomocný stĺpec do pracovného hárku, môžete použiť nasledujúci zložitý vzorec poľa na počítanie rozdielnych hodnôt s rozlišovaním veľkých a malých písmen bez vytvorenia ďalšieho stĺpca:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0)))

Počítanie jedinečných a odlišných riadkov v programe Excel

Počítanie jedinečných/odlišných riadkov v programe Excel je podobné počítaniu jedinečných a odlišných hodnôt, len s tým rozdielom, že namiesto funkcie COUNTIFS používate funkciu COUNTIF, ktorá umožňuje zadať niekoľko stĺpcov na kontrolu jedinečných hodnôt.

Ak chcete napríklad spočítať jedinečné alebo odlišné mená na základe hodnôt v stĺpcoch A (Krstné meno) a B (Priezvisko), použite jeden z nasledujúcich vzorcov:

Vzorec na počítanie jedinečných riadkov:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Vzorec na počítanie odlišných riadkov:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Samozrejme, nie ste obmedzení na počítanie jedinečných riadkov len na základe dvoch stĺpcov, funkcia Excel COUNTIFS dokáže spracovať až 127 dvojíc rozsah/kritérium.

Počítanie rôznych hodnôt v programe Excel pomocou PivotTable

Najnovšie verzie Excel 2013 a Excel 2016 majú špeciálnu funkciu, ktorá umožňuje automatické počítanie rozdielnych hodnôt v otočnej tabuľke. Nasledujúca snímka obrazovky poskytuje predstavu o tom, ako Excel Odlišný počet vyzerá takto:

Ak chcete vytvoriť otočnú tabuľku s odlišným počtom pre určitý stĺpec, vykonajte nasledujúce kroky.

1. Vyberte údaje, ktoré sa majú zahrnúť do otočnej tabuľky, prepnite na Vložte tab, Tabuľky a kliknite na PivotTable tlačidlo.
2. V Vytvoriť tabuľku PivotTable vyberte, či chcete otočnú tabuľku umiestniť do nového alebo existujúceho pracovného hárka, a nezabudnite vybrať Pridanie týchto údajov do dátového modelu zaškrtávacie políčko.

Ak chcete, môžete svojmu rozlíšiteľnému počtu priradiť aj vlastný názov.

Hotovo! Novovytvorená otočná tabuľka zobrazí odlišný počet, ako je znázornené na prvom obrázku v tejto časti.

Tip. Po aktualizácii zdrojových údajov nezabudnite aktualizovať pivotnú tabuľku, aby sa aktualizoval počet rozdielov. Ak chcete aktualizovať pivotnú tabuľku, stačí kliknúť na tlačidlo Obnoviť tlačidlo na Analyzujte na karte Údaje skupina.

Takto sa v programe Excel počítajú odlišné a jedinečné hodnoty. Ak sa chce niekto bližšie pozrieť na vzorce, o ktorých sa hovorí v tomto návode, môže si stiahnuť vzorový zošit programu Excel Count Unique (Počítať jedinečné hodnoty).

Ďakujem vám za prečítanie a dúfam, že sa uvidíme opäť budúci týždeň. V ďalšom článku sa budeme venovať rôznym spôsobom vyhľadávania, filtrovania, extrahovania a zvýrazňovania jedinečných hodnôt v programe Excel. Prosím, zostaňte naladení!