Во ова упатство, ќе научите како да броите единствени вредности во Excel со формули и како да добиете автоматско броење на различни вредности во стожерна табела. Ќе разговараме и за голем број примери на формули за броење единствени имиња, текстови, броеви, уникатни вредности чувствителни на букви и многу повеќе.

Кога работите со голема база на податоци во Excel, честопати ќе треба да знаете колку дупликат и уникатни вредности има. И понекогаш, можеби ќе сакате да ги броите само различни (различни) вредности.

Ако сте го посетувале овој блог редовно, веќе ја знаете формулата на Excel за броење дупликати. И денес, ќе истражиме различни начини за броење единствени вредности во Excel. Но, за јасност, прво да ги дефинираме поимите.

• Единствени вредности - тоа се вредностите што се појавуваат во списокот само еднаш.
• Различни вредности - сите овие се различни вредности во списокот, т.е. уникатни вредности плус првата појава на дупликат вредности.

Следната слика од екранот ја покажува разликата:

И сега, ајде да видиме како можете да броите единствени и различни вредности во Excel користејќи формули и карактеристики на PivotTable.

Како да броите единствени вредности во Excel

Еве вообичаена задача што сите корисници на Excel треба да ја извршуваат одвреме-навреме. Имате листа на податоци и треба да го дознаете бројот на единствени вредности во тоаостанете во тек!

Бротајте единствени вредности во колона

Да претпоставиме дека имате колона со имиња во вашиот Excel работен лист и треба да броите единствени имиња во таа колона. Решението е да се користи функцијата SUM во комбинација со IF и COUNTIF:

Забелешка . Ова е формула за низа, па не заборавајте да притиснете Ctrl + Shift + Enter за да ја завршите. Откако ќе го направите ова, Excel автоматски ќе ја приложи формулата во {кадрави загради} како на сликата од екранот подолу. Во никој случај не треба рачно да ги пишувате кадравите загради, тоа нема да функционира.

Во овој пример, ние броиме единствени имиња во опсегот A2:A10, така што нашата формула ја има следната форма:

Понатаму во ова упатство, ќе разговараме за неколку други формули за броење единствени вредности од различни типови. И бидејќи сите тие формули се варијации на основната формула за уникатни вредности на Excel, има смисла да се разложи горната формула, за да можете целосно да разберете како функционира и да ја прилагодите за вашите податоци. Ако некој не е заинтересиран за техничките работи, можете да прескокнете директно на следниот пример на формула.

Како функционира формулата Excel count уникатни вредности

Како што гледате, 3 различни функции се користат во нашата единствена формула за вредности - СУМ, АКОи COUNTIF. Гледајќи од внатре кон надвор, еве што прави секоја функција:

• Функцијата COUNTIF брои колку пати секоја поединечна вредност се појавува во наведениот опсег.

  Во овој пример, COUNTIF(A2:A10,A2:A10) ја враќа низата {1;2;2;1;2;2;2;1;2} .

• Функцијата IF ја проценува секоја вредност во низата вратена од COUNTIF, ги задржува сите 1 (уникатни вредности) и ги заменува сите други вредности со нули .

  Значи, функцијата IF(COUNTIF(A2:A10,A2:A10)=1,1,0) станува IF(1;2;2;1;2;2;2;1;2) = 1,1,0, која се претвора во низата {1;0;0;1;0;0;0;1;0} каде 1 е единствена вредност, а 0 е дупликат вредност.

• Конечно, функцијата SUM ги собира вредностите во низата вратени од IF и го дава вкупниот број на единствени вредности, што е токму она што го сакавме.

Совет . За да видите на што се оценува одреден дел од формулата за уникатни вредности на Excel, изберете го тој дел во лентата со формули и притиснете го копчето F9.

Бротајте единствени текстуални вредности во Excel

Ако вашата листа на Excel содржи и нумерички и текстуални вредности и сакате да броите само уникатни текстуални вредности, додајте ја функцијата ISTEXT во формулата за низа дискутирана погоре:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Како што знаете, функцијата Excel ISTEXT враќа TRUE ако проценетата вредност е текст, во спротивно FALSE. Бидејќи ѕвездичката (*) работи како AND оператор во формулите на низата, функцијата IF враќа 1 само ако вредноста е и текстуална и единствена, инаку 0. И откако функцијата SUM ќе ги собере сите 1, ќе добиете број на единствени текстуални вредности во наведенотоопсег.

Не заборавајте да притиснете Ctrl + Shift + Enter за правилно да ја внесете формулата на низата и ќе добиете резултат сличен на овој:

Како што можете да видите на сликата од екранот погоре, формулата го враќа вкупниот број на единствени текстуални вредности, исклучувајќи ги празните ќелии, броевите, логичките вредности на TRUE и FALSE и грешките.

Бротајте единствени нумерички вредности во Excel

За да броите уникатни броеви во списокот на податоци, користете формула за низа како што сега користевме за броење уникатни вредности на текст, со единствената разлика што вградувате ISNUMBER наместо ISTEXT во формулата за уникатни вредности:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Забелешка. Бидејќи Microsoft Excel ги складира датумите и времињата како сериски броеви, тие исто така се бројат.

Бротајте уникатни вредности чувствителни на големи букви во Excel

Ако вашата табела содржи податоци чувствителни на букви, најлесниот начин за броење единствени вредности би биле создавање помошна колона со следнава формула за низа за да се идентификуваат дупликати и единствени ставки:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

И потоа, користете едноставна функција COUNTIF за броење единствени вредности:

=COUNTIF(B2:B10, "unique")

Бротајте различни вредности во Excel (уникатни и 1-ви дупликат појави)

За да добиете број на различни вредности во списокот, користете го следново формула:

Запомнете, тоа е формула за низа и затоа треба да притиснете Ctrl + Shift + Enter кратенка наместо вообичаеното Enterпритискање на тастатурата.

Алтернативно, можете да ја користите функцијата SUMPRODUCT и да ја комплетирате формулата на вообичаен начин со притискање на копчето Enter:

На пример, за да ги броите различните вредности во опсегот A2:A10, можете да одите со:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Или

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Како функционира различната формула на Excel

Како што веќе знаете, ја користиме функцијата COUNTIF за да откриеме колку пати секоја поединечна вредност се појавува во одреден опсег. Во горниот пример, резултатот од функцијата COUNTIF е следнава низа: {2;2;3;1;2;2;3;1;3} .

Потоа, се вршат голем број операции за делење, каде што секоја вредност на низата се користи како делител со 1 како дивиденда. Ова ги претвора сите вредности на дупликати во фракциони броеви што одговараат на бројот на дупликати појави. На пример, ако некоја вредност се појавува 2 пати во списокот, таа генерира 2 ставки во низата со вредност од 0,5 (1/2=0,5). И ако една вредност се појавува 3 пати, таа произведува 3 ставки во низата со вредност од 0,3(3). Во нашиот пример, резултатот од 1/COUNTIF(A2:A10,A2:A10)) е низата {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Нема многу смисла досега? Тоа е затоа што сè уште не сме ја примениле функцијата SUM / SUMPRODUCT. Кога една од овие функции ги собира вредностите во низата, збирот на сите дробни броеви за секоја поединечна ставка секогаш дава 1, без разлика колку појавувања на таа ставка постојат во списокот. Ибидејќи сите единствени вредности се појавуваат во низата како 1 (1/1=1), конечниот резултат вратен со формулата е вкупниот број на сите различни вредности во листата.

Формули за броење различни вредности на различни типови

Како што е случај со броењето единствени вредности во Excel, можете да користите варијации на основната формула за броење на Excel за да се справите со специфични типови вредности како што се броеви, текст и вредности чувствителни на букви.

Запомнете дека сите долунаведени формули се формули на низа и бараат притискање на Ctrl + Shift + Enter .

Бротајте различни вредности игнорирајќи ги празните ќелии

Ако колона сакате да броите различни вредности може да содржи празни ќелии, треба да додадете функција IF која ќе го провери наведениот опсег за празни места (основната посебна формула на Excel дискутирана погоре ќе ја врати грешката #DIV/0 во овој случај):

На пример, за броење различни вредности во опсегот A2:A10, користете го следнава формула за низа :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Формула за броење различни текстуални вредности

За броење различни текстуални вредности во колона, ќе ги користиме истиот пристап кој штотуку го користевме за да ги исклучиме празните ќелии.

Како што можете лесно да погодите, едноставно ќе ја вградиме функцијата ISTEXT во нашата посебна формула за броење на Excel:

И еве еден реален животпример на формула:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Формула за броење различни броеви

За броење различни нумерички вредности (броеви, датуми и времиња), користете ја функцијата ISNUMBER:

На пример, за броење на сите различни броеви во опсегот A2:A10, користете ја следнава формула:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Бротајте различни вредности чувствителни на големи букви во Excel

Слично како и броењето уникатни вредности чувствителни на големи букви, најлесниот начин да се избројат различните вредности чувствителни на големи букви значи да се додаде помошна колона со формулата на низата што ги идентификува единствените вредности вклучувајќи ги првите дупликати појави. Формулата е во основа иста како онаа што ја користевме за броење единствени вредности чувствителни на големи букви, со една мала промена во референцата на ќелијата што прави голема разлика:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

Како што се сеќавате, сите формули на низи во Excel бараат притискање на Ctrl + Shift + Enter .

По завршувањето на горната формула, можете да броите „различни“ вредности со вообичаена формула COUNTIF како оваа:

=COUNTIF(B2:B10, "distinct")

Ако не можете да додадете помошна колона на вашиот работен лист, можете да ја користите следнава сложена формула за низа за да броите различни вредности чувствителни на големи букви без создавање дополнителна колона:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

Брота уникатни и различни редови во Excel

Броењето единствени / различни редови во Excel е слично на броење единствени и различни вредности, со единствена разликадека ја користите функцијата COUNTIFS наместо COUNTIF, што ви овозможува да наведете неколку колони за проверка на единствени вредности.

На пример, да броите единствени или различни имиња врз основа на вредностите во колоните A (Име) и B (Презиме), користете една од следниве формули:

Формула за броење единствени редови:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Формула за броење различни редови:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Нормално, не сте ограничени на броење единствени редови базирани само на две колони, функцијата Excel COUNTIFS може да обработи до 127 парови опсег/критериум.

Бротајте различни вредности во Excel користејќи PivotTable

Најновите верзии на Excel 2013 и Excel 2016 имаат специјална карактеристика што овозможува автоматско броење на различни вредности во стожерна табела. Следната слика од екранот дава идеја за тоа како изгледа Excel Distinct Count :

За да креирате стожерна табела со различен број за одредена колона, направете ги следните чекори.

1. Изберете ги податоците што ќе се вклучат во стожерната табела, префрлете се на јазичето Вметни , групата Табели и кликнете на <Копче 4>Стажната табела .
2. Во дијалогот Креирај стожерна табела , изберете дали да ја поставите вашата стожерна табела во нов или постоечки работен лист и погрижете се да изберете Додај овие податоци во полето за избор на податочен модел .

Можете и да му дадете приспособено име на вашиот различен број ако сакате.

Готово! Новосоздадената стожерна табела ќе го прикаже различниот број како што е прикажано на првата слика од екранот во овој дел.

Совет. Откако ќе ги ажурирате вашите изворни податоци, не заборавајте да ја ажурирате Стожерната табела за да го ажурирате различниот број. За да освежите стожерна табела, само кликнете на копчето Освежи на картичката Анализа , во групата Податоци .

Вака броите различни и единствени вредности во Excel. Ако некој сака подетално да ги погледне формулите дискутирани во ова упатство, добредојдени сте да ја преземете примерокот на работната книга Excel Count Unique.

Ви благодарам што прочитавте и се надевам дека ќе се видиме повторно следната недела. Во следната статија, ќе разговараме за различни начини за наоѓање, филтрирање, екстракција и истакнување единствени вредности во Excel. Ве молам