Neste titorial, aprenderá a contar valores únicos en Excel con fórmulas e a obter un reconto automático de distintos valores nunha táboa dinámica. Tamén comentaremos unha serie de exemplos de fórmulas para contar nomes únicos, textos, números, valores únicos sensibles a maiúsculas de minúsculas e moito máis.

Ao traballar cun conxunto de datos grande en Excel, é posible que a miúdo necesites saber cantos valores duplicados e únicos hai. E ás veces, pode querer contar só os valores distintos (diferentes).

Se estiveches visitando este blog de forma habitual, xa coñeces a fórmula de Excel para contar duplicados. E hoxe, imos explorar diferentes formas de contar valores únicos en Excel. Pero por motivos de claridade, definamos primeiro os termos.

• Valores únicos : estes son os valores que só aparecen na lista unha vez.
• Valores distintos: todos son valores diferentes da lista, é dicir, valores únicos máis as primeiras aparicións de valores duplicados.

A seguinte captura de pantalla mostra a diferenza:

E agora, vexamos como pode contar valores únicos e distintos en Excel usando fórmulas e funcións de táboa dinámica.

Como contar valores únicos en Excel

Aquí está unha tarefa común que todos os usuarios de Excel teñen que realizar de cando en vez. Tes unha lista de datos e necesitas descubrir o número de valores únicos nelaestade atentos!

Contar valores únicos nunha columna

Supoño que tes unha columna de nomes no teu Excel folla de traballo e cómpre contar os nomes únicos nesa columna. A solución é usar a función SUMA en combinación con SE e CONTARSE:

Nota . Esta é unha fórmula matricial, así que asegúrate de premer Ctrl + Maiús + Intro para completala. Unha vez que fagas isto, Excel encerrará automaticamente a fórmula entre {llaves} como na captura de pantalla a continuación. En ningún caso debes escribir manualmente as chaves, que non funcionarán.

Neste exemplo, contamos nomes únicos no rango A2:A10, polo que a nosa fórmula toma a seguinte forma:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Máis adiante neste tutorial, imos discutir un puñado doutras fórmulas para contar valores únicos de diferentes tipos. E porque todas esas fórmulas son variacións da fórmula básica de valores únicos de Excel, ten sentido desglosar a fórmula anterior, para que poida comprender completamente como funciona e axustala para os seus datos. Se alguén non está interesado nos aspectos técnicos, pode pasar directamente ao seguinte exemplo de fórmula.

Como funciona a fórmula de conta de valores únicos de Excel

Como ves, úsanse 3 funcións diferentes na nosa fórmula única. fórmula de valores - SUMA, SEe COUNTIF. Mirando desde dentro para fóra, aquí tes o que fai cada función:

• A función COUNTIF conta cantas veces aparece cada valor individual no intervalo especificado.

  Neste exemplo, COUNTIF(A2:A10,A2:A10) devolve a matriz {1;2;2;1;2;2;2;1;2} .

• A función SE avalía cada valor da matriz devolta por COUNTIF, mantén todos os 1 (valores únicos) e substitúe todos os demais valores por ceros. .

  Entón, a función IF(COUNTIF(A2:A10,A2:A10)=1,1,0) pasa a ser IF(1;2;2;1;2;2;2;1;2) = 1,1,0, que se transforma na matriz {1;0;0;1;0;0;0;1;0} onde 1 é un valor único e 0 é un valor duplicado.

• Finalmente, a función SUMA suma os valores da matriz devoltos por SE e mostra o número total de valores únicos, que é exactamente o que queriamos.

Consello . Para ver a que avalía unha parte específica da súa fórmula de valores únicos de Excel, seleccione esa parte na barra de fórmulas e prema a tecla F9.

Conta valores de texto únicos en Excel

Se a túa lista de Excel contén valores numéricos e de texto e queres contar só valores de texto únicos, engade a función ISTEXT á fórmula de matriz descrita anteriormente:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Como sabes, a función ISTEXT de Excel devolve VERDADEIRO se un valor avaliado é texto, FALSO en caso contrario. Dado que o asterisco (*) funciona como o operador AND nas fórmulas matriciales, a función SE devolve 1 só se un valor é texto e único, 0 en caso contrario. E despois de que a función SUMA sume todos os 1, obterás un reconto de valores de texto únicos nointervalo.

Non esquezas premer Ctrl + Maiús + Intro para introducir correctamente a fórmula matricial e obterás un resultado semellante a este:

Como podes ver na captura de pantalla anterior, a fórmula devolve o número total de valores de texto únicos, excluíndo as celas en branco, os números, os valores lóxicos de VERDADEIRO e FALSO e os erros.

Conta os valores numéricos únicos en Excel

Para contar números únicos nunha lista de datos, utiliza unha fórmula matricial como a que acabamos de usar para contar valores de texto únicos, coa única diferenza de que incrustas ISNUMBER en lugar de ISTEXT na túa fórmula de valores únicos:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Nota. Dado que Microsoft Excel almacena as datas e as horas como números de serie, tamén se contan.

Conta os valores únicos que distinguen entre maiúsculas e minúsculas en Excel

Se a túa táboa contén datos que distinguen entre maiúsculas e minúsculas, a forma máis sinxela de contar valores únicos serían crear unha columna auxiliar coa seguinte fórmula matricial para identificar elementos únicos e duplicados:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

E, a continuación, use unha función simple COUNTIF para contar valores únicos:

=COUNTIF(B2:B10, "unique")

Contar distintos valores en Excel (únicas e primeiras ocorrencias duplicadas)

Para obter un reconto de distintos valores nunha lista, use o seguinte fórmula:

Lembra que é unha fórmula matricial e, polo tanto, debes premer Ctrl + Maiús + Intro atallo en lugar do habitual Entertecla.

Como alternativa, pode usar a función SUMAPRODUTO e completar a fórmula do xeito habitual premendo a tecla Intro:

Por exemplo, para contar os distintos valores do intervalo A2:A10, pode ir con:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Ou

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Como funciona a fórmula distinta de Excel

Como xa sabes, utilizamos a función COUNTIF para saber cantas veces aparece cada valor individual no rango especificado. No exemplo anterior, o resultado da función COUNTIF é a seguinte matriz: {2;2;3;1;2;2;3;1;3} .

Despois diso, realízanse unha serie de operacións de división, onde cada valor da matriz se usa como divisor con 1 como o dividendo. Isto converte todos os valores duplicados en números fraccionarios correspondentes ao número de ocorrencias duplicadas. Por exemplo, se un valor aparece 2 veces na lista, xera 2 elementos na matriz cun valor de 0,5 (1/2=0,5). E se un valor aparece 3 veces, produce 3 elementos na matriz cun valor de 0,3(3). No noso exemplo, o resultado de 1/COUNTIF(A2:A10,A2:A10)) é a matriz {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Non ten moito sentido ata agora? Isto é porque aínda non aplicamos a función SUMA / SUMAPRODUTO. Cando unha destas funcións suma os valores da matriz, a suma de todos os números fraccionarios de cada elemento individual sempre dá 1, sen importar cantas ocorrencias dese elemento existan na lista. Eporque todos os valores únicos aparecen na matriz como 1 (1/1=1), o resultado final que devolve a fórmula é o número total de todos os valores diferentes da lista.

Fórmulas para contar valores distintos de diferentes valores. tipos

Como é o caso de contar valores únicos en Excel, pode usar variacións da fórmula básica de conta de Excel para manexar tipos de valores específicos, como números, texto e valores que distinguen entre maiúsculas e minúsculas.

Lembre que todas as fórmulas seguintes son fórmulas de matriz e requiren premer Ctrl + Maiús + Intro .

Contar distintos valores ignorando as celas baleiras

Se unha columna onde quere contar valores distintos pode conter celas en branco, debería engadir unha función IF que comprobará o intervalo especificado de espazos en branco (a fórmula básica de Excel distinta discutida anteriormente devolvería o erro #DIV/0 neste caso):

Por exemplo, para contar valores distintos no intervalo A2:A10, use o seguinte fórmula matricial :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Fórmula para contar distintos valores de texto

Para contar distintos valores de texto nunha columna, usaremos o mesmo enfoque que acabamos de utilizar para excluír celas baleiras.

Como podes adiviñar facilmente, simplemente incorporaremos a función ISTEXT na nosa fórmula distinta de conta de Excel:

E aquí tes unha vida realexemplo de fórmula:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Fórmula para contar distintos números

Para contar distintos valores numéricos (números, datas e horas), use a función ISNUMBER:

Por exemplo, para contar todos os números diferentes no intervalo A2:A10, use a seguinte fórmula:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Conta os valores distintos que distinguen entre maiúsculas e minúsculas en Excel

Do mesmo xeito que para contar os valores únicos que distinguen entre maiúsculas e minúsculas, o xeito máis sinxelo contar os valores distintos que distinguen entre maiúsculas e minúsculas é engadir unha columna auxiliar coa fórmula matricial que identifique valores únicos, incluíndo as primeiras ocorrencias duplicadas. A fórmula é basicamente a mesma que usamos para contar os valores únicos que distinguen entre maiúsculas e minúsculas, cun pequeno cambio na referencia dunha cela que marca unha gran diferenza:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

Como lembras, todas as fórmulas de matriz en Excel requiren premer Ctrl + Maiús + Intro.

Despois de rematar a fórmula anterior, pode contar os valores "distintos" cunha fórmula habitual COUNTIF como esta:

=COUNTIF(B2:B10, "distinct")

Se non hai forma de engadir unha columna auxiliar á súa folla de traballo, pode utilizar a seguinte complexa fórmula matricial para contar os valores distintos que distinguen entre maiúsculas e minúsculas sen creando unha columna adicional:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

Contar filas únicas e distintas en Excel

Contar filas únicas/diferentes en Excel é semellante a contar valores únicos e distintos, co único diferenzaque use a función COUNTIFS en lugar de COUNTIF, que lle permite especificar varias columnas para comprobar os valores únicos.

Por exemplo, para contar nomes únicos ou distintos en función dos valores das columnas A (Nome) e B (Apelidos), use unha das seguintes fórmulas:

Fórmula para contar filas únicas:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Fórmula para contar distintas filas:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Naturalmente, non está limitado a contar filas únicas baseadas só en dúas columnas, a función de Excel COUNTIFS pode procesar a 127 pares intervalo/criterio.

Conta distintos valores en Excel mediante unha táboa dinámica

As últimas versións de Excel 2013 e Excel 2016 teñen un característica especial que permite contar valores distintos automaticamente nunha táboa dinámica. A seguinte captura de pantalla dá unha idea de como se ve o Recuento distinto de Excel:

Para crear unha táboa dinámica co reconto distinto para unha determinada columna, realice os seguintes pasos.

1. Seleccione os datos que se incluirán nunha táboa dinámica, cambie á pestana Inserir , grupo Táboas e faga clic no botón Botón Táboa dinámica .
2. No diálogo Crear táboa dinámica , escolla se quere colocar a súa táboa dinámica nunha folla de traballo nova ou existente e asegúrese de seleccionar a opción Engadir estes datos á caixa de verificación Modelo de datos .

Tamén podes darlle un nome personalizado ao teu Distinct Count se queres.

Feito! A táboa dinámica recentemente creada mostrará o reconto distinto como se mostra na primeira captura de pantalla desta sección.

Consello. Despois de actualizar os datos de orixe, recorda actualizar a táboa dinámica para actualizar o reconto distinto. Para actualizar unha táboa dinámica, só tes que facer clic no botón Actualizar da pestana Analizar , no grupo Datos .

Así contas. valores distintos e únicos en Excel. Se alguén quere ver as fórmulas que se comentan neste titorial, podes descargar o libro de traballo único de conta de Excel de exemplo.

Grazas por ler e espero verte de novo a próxima semana. No seguinte artigo, imos discutir varias formas de atopar, filtrar, extraer e resaltar valores únicos en Excel. Por favor