في هذا البرنامج التعليمي ، ستتعلم كيفية حساب القيم الفريدة في Excel باستخدام الصيغ ، وكيفية الحصول على حساب تلقائي للقيم المميزة في جدول محوري. سنناقش أيضًا عددًا من أمثلة الصيغ لحساب الأسماء الفريدة والنصوص والأرقام والقيم الفريدة الحساسة للحالة والمزيد.

عند العمل مع مجموعة بيانات كبيرة في Excel ، قد تحتاج غالبًا إلى تعرف على عدد القيمتين المكررة و الفريدة الموجودة. وأحيانًا ، قد ترغب في حساب قيم المميزة (مختلفة) فقط.

إذا كنت تزور هذه المدونة بشكل أساسي عادي ، فأنت تعرف بالفعل صيغة Excel لحساب التكرارات. واليوم ، سنستكشف طرقًا مختلفة لحساب القيم الفريدة في Excel. ولكن من أجل الوضوح ، دعنا نحدد المصطلحات أولاً.

• قيم فريدة - هذه هي القيم التي تظهر في القائمة مرة واحدة فقط.
• قيم مميزة - هذه كلها قيم مختلفة في القائمة ، أي قيم فريدة بالإضافة إلى التكرارات الأولى للقيم المكررة.

توضح لقطة الشاشة التالية الفرق:

والآن ، دعنا نرى كيف يمكنك حساب القيم الفريدة والمميزة في Excel باستخدام الصيغ وميزات PivotTable.

كيفية حساب القيم الفريدة في Excel

هذه مهمة شائعة يجب على جميع مستخدمي Excel القيام بها من حين لآخر. لديك قائمة بالبيانات وتحتاج إلى معرفة عدد القيم الفريدة في ذلكترقبوا!

عد القيم الفريدة في عمود

بافتراض أن لديك عمود أسماء في Excel ورقة العمل ، وتحتاج إلى حساب الأسماء الفريدة في هذا العمود. الحل هو استخدام الدالة SUM مع IF و COUNTIF:

ملاحظة . هذه صيغة صفيف ، لذا تأكد من الضغط على Ctrl + Shift + Enter لإكمالها. بمجرد القيام بذلك ، سيقوم Excel تلقائيًا بتضمين الصيغة {curly braces} كما في لقطة الشاشة أدناه. لا يجب عليك بأي حال من الأحوال كتابة الأقواس المتعرجة يدويًا ، فلن يعمل ذلك.

في هذا المثال ، نحسب الأسماء الفريدة في النطاق A2: A10 ، لذلك تأخذ صيغتنا الشكل التالي:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

في هذا البرنامج التعليمي ، سنناقش عددًا قليلاً من الصيغ الأخرى لحساب القيم الفريدة لأنواع مختلفة. ونظرًا لأن كل هذه الصيغ عبارة عن أشكال مختلفة من صيغة القيم الفريدة الأساسية لـ Excel ، فمن المنطقي تقسيم الصيغة أعلاه ، حتى تتمكن من فهم كيفية عملها تمامًا وتعديلها لبياناتك. إذا لم يكن شخص ما مهتمًا بالجوانب الفنية ، فيمكنك التخطي مباشرة إلى مثال الصيغة التالي.

كيف تعمل صيغة القيم الفريدة في Excel

كما ترى ، يتم استخدام 3 وظائف مختلفة في موقعنا الفريد صيغة القيم - SUM ، IFو COUNTIF. بالنظر من الداخل إلى الخارج ، إليك ما تفعله كل وظيفة:

• تحسب الدالة COUNTIF عدد المرات التي تظهر فيها كل قيمة فردية في النطاق المحدد.

  في هذا المثال ، تُرجع COUNTIF(A2:A10,A2:A10) المصفوفة {1;2;2;1;2;2;2;1;2} .

• تقوم الدالة IF بتقييم كل قيمة في المصفوفة التي تم إرجاعها بواسطة COUNTIF ، وتحتفظ بكل قيم 1 (قيم فريدة) ، وتستبدل جميع القيم الأخرى بالأصفار .

  إذن ، الدالة IF(COUNTIF(A2:A10,A2:A10)=1,1,0) تصبح IF(1;2;2;1;2;2;2;1;2) = 1,1,0, والتي تتحول إلى مصفوفة {1;0;0;1;0;0;0;1;0} حيث 1 قيمة فريدة و 0 قيمة مكررة.

• أخيرًا ، تضيف الدالة SUM القيم في المصفوفة التي تم إرجاعها بواسطة IF وتخرج العدد الإجمالي للقيم الفريدة ، وهو بالضبط ما أردناه.

نصيحة . لمعرفة ما يتم تقييمه لجزء معين من صيغة القيم الفريدة في Excel ، حدد هذا الجزء في شريط الصيغة واضغط على المفتاح F9.

عد القيم النصية الفريدة في Excel

إذا كانت قائمة Excel تحتوي على قيم رقمية ونصية ، وتريد حساب القيم النصية الفريدة فقط ، فقم بإضافة دالة ISTEXT إلى صيغة الصفيف الموضحة أعلاه:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

كما تعلم ، ترجع الدالة Excel ISTEXT TRUE إذا كانت القيمة التي تم تقييمها نصًا ، أو FALSE بخلاف ذلك. نظرًا لأن العلامة النجمية (*) تعمل كعامل التشغيل AND في صيغ الصفيف ، فإن الدالة IF ترجع 1 فقط إذا كانت القيمة نصية وفريدة من نوعها ، وتعيد القيمة 0 بخلاف ذلك. وبعد أن تجمع الدالة SUM كل 1 ، ستحصل على عدد من القيم النصية الفريدة في المحددالنطاق.

لا تنس الضغط على Ctrl + Shift + Enter لإدخال صيغة الصفيف بشكل صحيح ، وستحصل على نتيجة مشابهة لهذه:

كما ترى في لقطة الشاشة أعلاه ، تُرجع الصيغة العدد الإجمالي للقيم النصية الفريدة ، باستثناء الخلايا الفارغة والأرقام والقيم المنطقية لـ TRUE و FALSE والأخطاء.

عد القيم الرقمية الفريدة في Excel

لحساب الأرقام الفريدة في قائمة البيانات ، استخدم صيغة صفيف مثل التي استخدمناها للتو لحساب القيم النصية الفريدة ، مع الاختلاف الوحيد الذي قمت بتضمينه ISNUMBER بدلاً من ISTEXT في صيغة القيم الفريدة الخاصة بك:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

ملاحظة. نظرًا لأن Microsoft Excel يخزن التواريخ والأوقات كأرقام تسلسلية ، يتم حسابها أيضًا.

عد القيم الفريدة الحساسة لحالة الأحرف في Excel

إذا كان الجدول الخاص بك يحتوي على بيانات حساسة لحالة الأحرف ، فإن أسهل طريقة للعد ستنشئ القيم الفريدة عمودًا مساعدًا باستخدام صيغة الصفيف التالية لتحديد العناصر المكررة والفريدة:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

وبعد ذلك ، استخدم دالة COUNTIF بسيطة لحساب القيم الفريدة:

=COUNTIF(B2:B10, "unique")

عد القيم المميزة في Excel (تكرار فريد وأول تكرار)

للحصول على عدد القيم المميزة في قائمة ، استخدم ما يلي الصيغة:

تذكر ، إنها صيغة صفيف ، وبالتالي يجب عليك الضغط على Ctrl + Shift + Enter الاختصار بدلاً من إدخال المعتادضغط المفتاح.

بدلاً من ذلك ، يمكنك استخدام وظيفة SUMPRODUCT وإكمال الصيغة بالطريقة المعتادة عن طريق الضغط على مفتاح Enter:

على سبيل المثال ، لحساب القيم المميزة في النطاق A2: A10 ، يمكنك استخدام إما:

=SUM(1/COUNTIF(A2:A10,A2:A10))

أو

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

كيف تعمل صيغة Excel المميزة

كما تعلم بالفعل ، نستخدم وظيفة COUNTIF لمعرفة عدد المرات التي تظهر فيها كل قيمة فردية في نطاق محدد. في المثال أعلاه ، تكون نتيجة الدالة COUNTIF هي المصفوفة التالية: {2;2;3;1;2;2;3;1;3} .

بعد ذلك ، يتم تنفيذ عدد من عمليات القسمة ، حيث يتم استخدام كل قيمة من المصفوفة كمقسوم مع 1 باعتباره ال توزيعات ارباح. يؤدي هذا إلى تحويل جميع القيم المكررة إلى أرقام كسرية تتوافق مع عدد التكرارات المكررة. على سبيل المثال ، إذا ظهرت قيمة مرتين في القائمة ، فإنها تنشئ عنصرين في المصفوفة بقيمة 0.5 (1/2 = 0.5). وإذا ظهرت قيمة 3 مرات ، فإنها تنتج 3 عناصر في المصفوفة بقيمة 0.3 (3). في مثالنا ، نتيجة 1/COUNTIF(A2:A10,A2:A10)) هي المصفوفة {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

هل لا معنى لها حتى الآن؟ هذا لأننا لم نطبق الدالة SUM / SUMPRODUCT حتى الآن. عندما تقوم إحدى هذه الوظائف بجمع القيم الموجودة في المصفوفة ، فإن مجموع كل الأرقام الكسرية لكل عنصر فردي ينتج عنه دائمًا 1 ، بغض النظر عن عدد تكرارات هذا العنصر في القائمة. ونظرًا لأن جميع القيم الفريدة تظهر في المصفوفة على أنها 1 (1/1 = 1) ، فإن النتيجة النهائية التي تُرجعها الصيغة هي العدد الإجمالي لجميع القيم المختلفة في القائمة.

الصيغ لحساب القيم المميزة لمختلف الأنواع

كما هو الحال مع حساب القيم الفريدة في Excel ، يمكنك استخدام أشكال مختلفة من الصيغة المميزة لحساب Excel الأساسي للتعامل مع أنواع قيم معينة مثل الأرقام والنص والقيم الحساسة لحالة الأحرف.

يرجى تذكر أن جميع الصيغ أدناه هي صيغ صفيف وتتطلب الضغط على Ctrl + Shift + Enter.

عد القيم المميزة مع تجاهل الخلايا الفارغة

إذا كان العمود الذي تريد حساب القيم المميزة فيه قد تحتوي على خلايا فارغة ، يجب عليك إضافة دالة IF التي ستتحقق من النطاق المحدد للفراغات (ستُرجع صيغة Excel المميزة الأساسية التي تمت مناقشتها أعلاه الخطأ # DIV / 0 في هذه الحالة):

على سبيل المثال ، لحساب القيم المميزة في النطاق A2: A10 ، استخدم صيغة الصفيف التالية :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

صيغة لحساب القيم النصية المميزة

لحساب القيم النصية المميزة في عمود ، سنستخدم نفس الطريقة التي استخدمناها للتو لاستبعاد الخلايا الفارغة.

كما يمكنك أن تخمن بسهولة ، سنقوم ببساطة بتضمين وظيفة ISTEXT في الصيغة المميزة لحساب Excel:

وإليك الحياة الواقعيةمثال على الصيغة:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

صيغة لحساب الأرقام المميزة

لحساب القيم الرقمية المميزة (الأرقام والتواريخ والأوقات) ، استخدم الدالة ISNUMBER:

على سبيل المثال ، لحساب جميع الأرقام المختلفة في النطاق A2: A10 ، استخدم الصيغة التالية:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

عد القيم المميزة الحساسة لحالة الأحرف في Excel

على غرار حساب القيم الفريدة الحساسة لحالة الأحرف ، أسهل طريقة لحساب القيم المميزة الحساسة لحالة الأحرف هو إضافة عمود مساعد باستخدام صيغة الصفيف التي تحدد القيم الفريدة بما في ذلك التكرارات الأولى. الصيغة في الأساس هي نفسها التي استخدمناها لحساب القيم الفريدة الحساسة لحالة الأحرف ، مع تغيير صغير واحد في مرجع خلية يحدث فرقًا كبيرًا:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

كما تتذكر ، تتطلب جميع صيغ الصفيف في Excel الضغط على Ctrl + Shift + Enter.

بعد الانتهاء من الصيغة أعلاه ، يمكنك حساب القيم "المميزة" باستخدام صيغة COUNTIF المعتادة مثل:

=COUNTIF(B2:B10, "distinct")

إذا لم تكن هناك طريقة يمكنك من خلالها إضافة عمود مساعد إلى ورقة العمل الخاصة بك ، فيمكنك استخدام صيغة الصفيف المعقدة التالية لحساب القيم المميزة الحساسة لحالة الأحرف بدون إنشاء عمود إضافي:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

حساب الصفوف الفريدة والمميزة في Excel

يعد حساب الصفوف الفريدة / المميزة في Excel أقرب إلى حساب القيم الفريدة والمميزة ، باستخدام فرقأنك تستخدم دالة COUNTIFS بدلاً من COUNTIF ، والتي تتيح لك تحديد عدة أعمدة للتحقق من القيم الفريدة.

على سبيل المثال ، لحساب الأسماء الفريدة أو المميزة بناءً على القيم الموجودة في العمودين A (الاسم الأول) و B (اسم العائلة) ، استخدم إحدى الصيغ التالية:

صيغة لحساب عدد الصفوف الفريدة:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

صيغة لحساب مميز الصفوف:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

بطبيعة الحال ، أنت لست مقيدًا بحساب الصفوف الفريدة استنادًا إلى عمودين فقط ، يمكن معالجة وظيفة Excel COUNTIFS إلى 127 زوجًا من النطاق / المعايير.

عد القيم المميزة في Excel باستخدام PivotTable

أحدث إصدارات Excel 2013 و Excel 2016 بها ميزة خاصة تتيح حساب القيم المميزة تلقائيًا في جدول محوري. تعطي لقطة الشاشة التالية فكرة عن كيفية ظهور Excel عدد مميز :

لإنشاء جدول محوري بعدد مميز لعمود معين ، نفذ الخطوات التالية.

1. حدد البيانات المراد تضمينها في جدول محوري ، انتقل إلى علامة التبويب إدراج ، جداول ، وانقر فوق زر PivotTable .
2. في مربع الحوار إنشاء PivotTable ، اختر ما إذا كنت تريد وضع الجدول المحوري في ورقة عمل جديدة أو موجودة ، وتأكد من تحديد إضافة هذه البيانات إلى مربع اختيار نموذج البيانات .

يمكنك أيضًا إعطاء اسم مخصص للعدد المميز الخاص بك إذا كنت تريد ذلك.

تم! سيعرض الجدول المحوري الذي تم إنشاؤه حديثًا العدد المميز كما هو موضح في أول لقطة شاشة في هذا القسم.

نصيحة. بعد تحديث بيانات المصدر ، تذكر تحديث PivotTable لتحديث العد المميز. لتحديث جدول محوري ، ما عليك سوى النقر فوق الزر تحديث في علامة التبويب تحليل ، في مجموعة البيانات .

هذه هي طريقة العد قيم مميزة وفريدة من نوعها في Excel. إذا أراد شخص ما إلقاء نظرة فاحصة على الصيغ التي تمت مناقشتها في هذا البرنامج التعليمي ، فنحن نرحب بك لتنزيل نموذج مصنف Excel Count الفريد.

أشكرك على القراءة وآمل أن أراك مرة أخرى الأسبوع المقبل. في المقالة التالية ، سنناقش طرقًا مختلفة للعثور على القيم الفريدة وتصفيتها واستخراجها وتسليط الضوء عليها في Excel. لو سمحت