В този урок ще научите как да броите уникални стойности в Excel с помощта на формули и как да получавате автоматично броене на уникални стойности в таблица с въртящи се елементи. Ще обсъдим и редица примери за формули за броене на уникални имена, текстове, числа, уникални стойности с чувствителни към големи букви и др.

Когато работите с голям набор от данни в Excel, често ви се налага да знаете колко дублиране на и уникален А понякога може да искате да преброите само отделен (различни) стойности.

Ако редовно посещавате този блог, вече знаете формулата на Excel за броене на дубликати. А днес ще разгледаме различни начини за броене на уникални стойности в Excel. Но за по-голяма яснота нека първо дефинираме термините.

• Уникален стойности - това са стойностите, които се появяват в списъка само веднъж.
• Отличителен стойности - това са всички различни стойности в списъка, т.е. уникалните стойности плюс първите срещания на дублиращи се стойности.

Следната снимка на екрана показва разликата:

А сега нека видим как можете да преброите уникалните и различни стойности в Excel, като използвате формули и функции на PivotTable.

Как да преброите уникалните стойности в Excel

Ето една често срещана задача, която всички потребители на Excel трябва да изпълняват от време на време. Имате списък с данни и трябва да откриете броя на уникалните стойности в този списък. Как да направите това? По-лесно, отколкото си мислите :) По-долу ще намерите няколко формули за преброяване на уникални стойности от различни типове.

Преброяване на уникалните стойности в дадена колона

Да предположим, че имате колона с имена в работния лист на Excel и трябва да преброите уникалните имена в тази колона. Решението е да използвате функцията SUM в комбинация с IF и COUNTIF:

Забележка . Това е формула за масив, така че не забравяйте да натиснете Ctrl + Shift + Enter, за да я завършите. След като направите това, Excel автоматично ще затвори формулата в {къдрави скоби}, както на снимката по-долу. В никакъв случай не трябва да въвеждате къдравите скоби ръчно, това няма да работи.

В този пример преброяваме уникалните имена в диапазона A2:A10, така че формулата ни придобива следната форма:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

По-нататък в този урок ще обсъдим няколко други формули за броене на уникални стойности от различни типове. И тъй като всички тези формули са разновидности на основната формула за уникални стойности на Excel, има смисъл да разнищим горната формула, за да можете напълно да разберете как работи и да я настроите за вашите данни. Ако някой не се интересува от технически подробности, може да прескочи направо къмследващия пример за формула.

Как работи формулата за броене на уникални стойности в Excel

Както виждате, в нашата формула за уникални стойности се използват 3 различни функции - SUM, IF и COUNTIF. Ако погледнем отвътре навън, ето какво прави всяка функция:

• Функцията COUNTIF преброява колко пъти всяка отделна стойност се появява в зададения диапазон.

  В този пример, COUNTIF(A2:A10,A2:A10) връща масива {1;2;2;1;2;2;2;1;2} .

• Функцията IF оценява всяка стойност в масива, върнат от COUNTIF, запазва всички 1 (уникални стойности) и заменя всички останали стойности с нули.

  Така че функцията IF(COUNTIF(A2:A10,A2:A10)=1,1,0) става IF(1;2;2;1;2;2;2;1;2) = 1,1,0, който се превръща в масив {1;0;0;1;0;0;0;1;0} където 1 е уникална стойност, а 0 е дублирана стойност.

• Накрая функцията SUM сумира стойностите в масива, върнат от IF, и извежда общия брой уникални стойности, което е точно това, което искахме.

Съвет: За да видите до какво се оценява определена част от формулата за уникални стойности на Excel, изберете тази част в лентата с формули и натиснете клавиша F9.

Преброяване на уникалните текстови стойности в Excel

Ако списъкът ви в Excel съдържа както цифрови, така и текстови стойности и искате да преброите само уникалните текстови стойности, добавете функцията ISTEXT към формулата за масива, разгледана по-горе:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Както знаете, функцията ISTEXT на Excel връща TRUE, ако оценяваната стойност е текст, FALSE в противен случай. Тъй като звездичката (*) работи като оператор AND във формулите за масиви, функцията IF връща 1 само ако стойността е едновременно текст и уникална, 0 в противен случай. И след като функцията SUM събере всички 1, ще получите брой на уникалните текстови стойности в посочения диапазон.

Не забравяйте да натиснете Ctrl + Shift + Enter, за да въведете правилно формулата на масива, и ще получите резултат, подобен на този:

Както можете да видите на горната снимка, формулата връща общия брой уникални текстови стойности, като не включва празни клетки, числа, логически стойности TRUE и FALSE и грешки.

Преброяване на уникални числови стойности в Excel

За да преброите уникалните числа в списък с данни, използвайте формула за масиви, каквато току-що използвахме за преброяване на уникални текстови стойности, с единствената разлика, че във формулата за уникални стойности вграждате ISNUMBER вместо ISTEXT:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Забележка: Тъй като Microsoft Excel съхранява датите и часовете като серийни номера, те също се отчитат.

Преброяване на уникални стойности с отчитане на малкия и големия размер на буквите в Excel

Ако таблицата ви съдържа данни, чувствителни към малки и големи букви, най-лесният начин за преброяване на уникалните стойности е да създадете помощна колона със следната формула за масиви, за да идентифицирате дублиращите се и уникалните елементи:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1, "Уникален", "Двойник")

След това използвайте проста функция COUNTIF, за да преброите уникалните стойности:

=COUNTIF(B2:B10, "unique")

Преброяване на различни стойности в Excel (уникални и първи дублиращи се случаи)

За да получите брой на отделните стойности в списък, използвайте следната формула:

Не забравяйте, че това е формула за масив и затова трябва да натиснете клавишната комбинация Ctrl + Shift + Enter вместо обичайната клавишна комбинация Enter.

Като алтернатива можете да използвате функцията SUMPRODUCT и да завършите формулата по обичайния начин, като натиснете клавиша Enter:

Например, за да преброите различните стойности в диапазона A2:A10, можете да използвате:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Или

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Как работи различната формула на Excel

Както вече знаете, използваме функцията COUNTIF, за да разберем колко пъти всяка отделна стойност се появява в зададения диапазон. В горния пример резултатът от функцията COUNTIF е следният масив: {2;2;3;1;2;2;3;1;3} .

След това се извършват редица операции за деление, при които всяка стойност от масива се използва като делител, а като дивидент се използва 1. Това превръща всички дублиращи се стойности в дробни числа, съответстващи на броя на дублиращите се случаи. Например, ако дадена стойност се появи 2 пъти в списъка, тя генерира 2 елемента в масива със стойност 0,5 (1/2=0,5). Ако пък дадена стойност се появи 3 пъти, тядава 3 елемента в масива със стойност 0.3(3). В нашия пример резултатът от 1/COUNTIF(A2:A10,A2:A10)) е масивът {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Това е така, защото все още не сме приложили функцията SUM / SUMPRODUCT. Когато някоя от тези функции сумира стойностите в масива, сборът от всички дробни числа за всеки отделен елемент винаги дава 1, независимо от това колко срещания на този елемент има в списъка. И тъй като всички уникални стойности се появяват в масива като 1 (1/1=1), крайният резултат, върнат от функциятаформулата е общият брой на всички различни стойности в списъка.

Формули за броене на различни стойности от различни типове

Както и при броенето на уникални стойности в Excel, можете да използвате варианти на основната формула на Excel за броене на различни стойности, за да обработвате специфични типове стойности, като числа, текст и стойности, чувствителни към малки и големи букви.

Не забравяйте, че всички формули по-долу са формули за масиви и изискват натискане на Ctrl + Shift + Enter .

Преброяване на различни стойности, като се игнорират празните клетки

Ако колоната, в която искате да преброите различни стойности, може да съдържа празни клетки, трябва да добавите функция IF, която ще провери посочения диапазон за празни клетки (основната формула за различни стойности на Excel, разгледана по-горе, ще върне грешка #DIV/0 в този случай):

Например, за да преброите различни стойности в диапазона A2:A10, използвайте следната формула за масиви:

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Формула за преброяване на различни текстови стойности

За да преброим отделните текстови стойности в колона, ще използваме същия подход, който току-що използвахме за изключване на празните клетки.

Както можете лесно да се досетите, ние просто ще вградим функцията ISTEXT в нашата формула за различаване на броя на Excel:

Ето и пример за формула от реалния живот:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Формула за броене на различни числа

За да преброите отделни числови стойности (числа, дати и времена), използвайте функцията ISNUMBER:

Например, за да преброите всички различни числа в диапазона A2:A10, използвайте следната формула:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Преброяване на различни стойности с отчитане на големи и малки букви в Excel

Подобно на броенето на уникални стойности, чувствителни към малкия и големия размер на буквите, най-лесният начин за броене на уникални стойности, чувствителни към малкия и големия размер на буквите, е да се добави помощна колона с формула за масиви, която идентифицира уникалните стойности, включително първите дублиращи се случаи. Формулата е основно същата като тази, която използвахме за броене на уникални стойности, чувствителни към малкия и големия размер на буквите, с една малка промяна в препратката към клетката, която прави голяма разлика:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1, "Distinct","")

Както си спомняте, всички формули за масиви в Excel изискват натискане на Ctrl + Shift + Enter .

След като горната формула е завършена, можете да преброите "различните" стойности с обичайната формула COUNTIF по следния начин:

=COUNTIF(B2:B10, "distinct")

Ако няма как да добавите помощна колона към работния си лист, можете да използвате следния комплекс формула за масив за преброяване на различими стойности с отчитане на големи и малки букви, без да се създава допълнителна колона:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), 0), 0)))

Преброяване на уникални и отделни редове в Excel

Броенето на уникални/различни редове в Excel е подобно на броенето на уникални и различни стойности, с единствената разлика, че използвате функцията COUNTIFS вместо COUNTIF, която ви позволява да посочите няколко колони за проверка за уникални стойности.

Например, за да преброите уникалните или различни имена въз основа на стойностите в колони A (Име) и B (Фамилия), използвайте една от следните формули:

Формула за броене на уникални редове:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Формула за броене на отделни редове:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Естествено, не сте ограничени до преброяване на уникални редове само въз основа на две колони - функцията COUNTIFS на Excel може да обработва до 127 двойки обхват/критерии.

Преброяване на различни стойности в Excel с помощта на PivotTable

Най-новите версии на Excel 2013 и Excel 2016 има специална функция, която позволява автоматично преброяване на различни стойности в таблицата за завъртане. Следващата екранна снимка дава представа за това как Excel Брой на различията изглежда така:

За да създадете въртяща се таблица с различния брой за определена колона, изпълнете следните стъпки.

1. Изберете данните, които да бъдат включени в таблицата за завъртане, преминете към Вмъкване на таб, Таблици и щракнете върху PivotTable бутон.
2. В Създаване на PivotTable изберете дали да поставите таблицата в нов или в съществуващ работен лист и не забравяйте да изберете Добавяне на тези данни към модела на данните квадратчето за отметка.

Ако желаете, можете също така да дадете персонализирано име на своя Distinct Count.

Готово! Новосъздадената въртяща се таблица ще покаже броя на различията, както е показано на първата снимка на екрана в този раздел.

Съвет. След като актуализирате изходните данни, не забравяйте да актуализирате таблицата Pivot, за да актуализирате броя на различията. За да актуализирате таблицата Pivot, просто щракнете върху Обновяване на бутона Анализирайте в раздела Данни група.

Така можете да преброите различни и уникални стойности в Excel. Ако някой иска да разгледа по-подробно формулите, разгледани в този урок, може да изтегли примерната работна книга на Excel Count Unique.

Благодаря ви, че прочетохте, и се надявам да се видим отново следващата седмица. В следващата статия ще обсъдим различни начини за намиране, филтриране, извличане и подчертаване на уникални стойности в Excel. Моля, останете на линия!