In hierdie tutoriaal sal jy leer hoe om unieke waardes in Excel met formules te tel, en hoe om 'n outomatiese telling van afsonderlike waardes in 'n spiltabel te kry. Ons sal ook 'n aantal formule-voorbeelde bespreek vir die tel van unieke name, tekste, getalle, hooflettersensitiewe unieke waardes, en meer.

Wanneer jy met 'n groot datastel in Excel werk, sal jy dalk dikwels nodig hê om weet hoeveel duplikaat en unieke waardes daar is. En soms wil jy dalk net die afsonderlike (verskillende) waardes tel.

As jy hierdie blog op 'n gereelde basis besoek het, ken jy reeds die Excel-formule om duplikate te tel. En vandag gaan ons verskillende maniere ondersoek om unieke waardes in Excel te tel. Maar ter wille van duidelikheid, kom ons definieer eers die terme.

• Unieke waardes - dit is die waardes wat net een keer in die lys verskyn.
• Afsonderlike waardes - dit is almal verskillende waardes in die lys, dit wil sê unieke waardes plus 1ste voorkoms van duplikaatwaardes.

Die volgende skermkiekie demonstreer die verskil:

En nou, kom ons kyk hoe jy unieke en duidelike waardes in Excel kan tel deur formules en draaitabelkenmerke te gebruik.

Hoe om unieke waardes in Excel te tel

Hier is 'n algemene taak wat alle Excel-gebruikers af en toe moet uitvoer. Jy het 'n lys van data en jy moet die aantal unieke waardes daarin uitvindbly ingeskakel!

Tel unieke waardes in 'n kolom

Gestel jy het 'n kolom met name in jou Excel werkblad, en jy moet unieke name in daardie kolom tel. Die oplossing is om die SOM-funksie te gebruik in kombinasie met IF en COUNTIF:

Let wel . Dit is 'n skikkingsformule, so maak seker dat u Ctrl + Shift + Enter druk om dit te voltooi. Sodra jy dit gedoen het, sal Excel outomaties die formule in {krulhakies} omsluit soos in die skermkiekie hieronder. In geen geval moet jy die krulhakies handmatig tik nie, dit sal nie werk nie.

In hierdie voorbeeld tel ons unieke name in reeks A2:A10, so ons formule neem die volgende vorm aan:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Verder in hierdie tutoriaal gaan ons 'n handvol ander formules bespreek om unieke waardes van verskillende tipes te tel. En omdat al daardie formules variasies van die basiese Excel-formule vir unieke waardes is, maak dit sin om die bogenoemde formule af te breek, sodat jy ten volle kan verstaan ​​hoe dit werk en dit vir jou data kan aanpas. As iemand nie in tegniese aspekte belangstel nie, kan jy reguit na die volgende formulevoorbeeld oorslaan.

Hoe die Excel-tel unieke waardes-formule werk

Soos jy sien, word 3 verskillende funksies in ons unieke gebruik waardes formule - SOM, IFen COUNTIF. As jy van binne na buite kyk, is dit wat elke funksie doen:

• Die COUNTIF-funksie tel hoeveel keer elke individuele waarde in die gespesifiseerde reeks verskyn.

  In hierdie voorbeeld gee COUNTIF(A2:A10,A2:A10) die skikking {1;2;2;1;2;2;2;1;2} terug.

• Die IF-funksie evalueer elke waarde in die skikking wat deur COUNTIF teruggestuur word, hou al 1'e (unieke waardes), en vervang alle ander waardes met nulle .

  Dus, die funksie IF(COUNTIF(A2:A10,A2:A10)=1,1,0) word IF(1;2;2;1;2;2;2;1;2) = 1,1,0, wat verander in die skikking {1;0;0;1;0;0;0;1;0} waar 1 'n unieke waarde is en 0 'n duplikaatwaarde is.

• Laastens tel die SUM-funksie die waardes in die skikking wat deur IF teruggestuur word bymekaar en voer die totale aantal unieke waardes uit, wat presies is wat ons wou hê.

Wenk . Om te sien wat 'n spesifieke deel van jou Excel unieke waardes-formule evalueer, kies daardie deel in die formulebalk en druk die F9-sleutel.

Tel unieke tekswaardes in Excel

As jou Excel-lys beide numeriese en tekswaardes bevat, en jy wil net unieke tekswaardes tel, voeg die ISTEXT-funksie by die skikkingsformule wat hierbo bespreek is:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Soos jy weet, gee die Excel ISTEXT-funksie WAAR as 'n geëvalueerde waarde teks is, anders ONWAAR. Aangesien die asterisk (*) as die EN-operateur in skikkingsformules werk, gee die IF-funksie slegs 1 terug as 'n waarde beide teks en uniek is, anders 0. En nadat die SUM-funksie al 1'e bymekaargetel het, sal jy 'n telling van unieke tekswaardes in die gespesifiseerdereeks.

Moenie vergeet om Ctrl + Shift + Enter te druk om die skikkingsformule korrek in te voer nie, en jy sal 'n resultaat soortgelyk aan hierdie kry:

Soos jy in die skermkiekie hierbo kan sien, gee die formule die totale aantal unieke tekswaardes terug, uitgesluit leë selle, getalle, logiese waardes van WAAR en ONWAAR, en foute.

Tel unieke numeriese waardes in Excel

Om unieke getalle in 'n lys data te tel, gebruik 'n skikkingsformule soos ons pas gebruik het vir die tel van unieke tekswaardes, met die enigste verskil dat jy ISNUMBER in plaas van ISTEXT in jou unieke waardes formule insluit:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Let wel. Aangesien Microsoft Excel datums en tye as reeksnommers stoor, word dit ook getel.

Tel hooflettersensitiewe unieke waardes in Excel

As jou tabel hooflettersensitiewe data bevat, is die maklikste manier om te tel unieke waardes sou 'n helperkolom skep met die volgende skikkingsformule om duplikaat- en unieke items te identifiseer:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

En gebruik dan 'n eenvoudige COUNTIF-funksie om unieke waardes te tel:

=COUNTIF(B2:B10, "unique")

Tel afsonderlike waardes in Excel (unieke en 1ste duplikaatvoorvalle)

Om 'n telling van afsonderlike waardes in 'n lys te kry, gebruik die volgende formule:

Onthou, dit is 'n skikkingsformule, en daarom moet jy die Ctrl + Shift + Enter druk kortpad in plaas van die gewone Entertoetsaanslag.

Alternatiewelik kan jy die SUMPRODUCT-funksie gebruik en die formule op die gewone manier voltooi deur die Enter-sleutel te druk:

Om byvoorbeeld die afsonderlike waardes in reeks A2:A10 te tel, kan jy met óf gaan:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Of

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Hoe die Excel-afsonderlike formule werk

Soos jy reeds weet, gebruik ons ​​die COUNTIF-funksie om uit te vind hoeveel keer elke individuele waarde in die gespesifiseerde reeks. In die bostaande voorbeeld is die resultaat van die COUNTIF-funksie die volgende skikking: {2;2;3;1;2;2;3;1;3} .

Daarna word 'n aantal delingbewerkings uitgevoer, waar elke waarde van die skikking as 'n deler gebruik word met 1 as die dividend. Dit verander alle duplikaatwaardes in breukgetalle wat ooreenstem met die aantal duplikaatvoorvalle. Byvoorbeeld, as 'n waarde 2 keer in die lys verskyn, genereer dit 2 items in die skikking met 'n waarde van 0.5 (1/2=0.5). En as 'n waarde 3 keer verskyn, produseer dit 3 items in die skikking met 'n waarde van 0.3(3). In ons voorbeeld is die resultaat van 1/COUNTIF(A2:A10,A2:A10)) die skikking {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Maak tot dusver nie veel sin nie? Dit is omdat ons nog nie die SUM / SUMPRODUCT-funksie toegepas het nie. Wanneer een van hierdie funksies die waardes in die skikking bymekaartel, lewer die som van alle breukgetalle vir elke individuele item altyd 1, maak nie saak hoeveel voorkomste van daardie item in die lys bestaan ​​nie. Enomdat alle unieke waardes in die skikking as 1's (1/1=1) verskyn, is die finale resultaat wat deur die formule teruggegee word die totale aantal van alle verskillende waardes in die lys.

Formules om verskillende waardes van verskillende te tel. tipes

Soos die geval is met die tel van unieke waardes in Excel, kan jy variasies van die basiese Excel-telling-duidelike formule gebruik om spesifieke waardetipes soos getalle, teks en hooflettersensitiewe waardes te hanteer.

Onthou asseblief dat al die onderstaande formules skikkingsformules is en vereis dat Ctrl + Shift + Enter gedruk moet word.

Tel afsonderlike waardes wat leë selle ignoreer

As 'n kolom waar jy verskillende waardes wil tel leë selle kan bevat, moet jy 'n IF-funksie byvoeg wat die gespesifiseerde reeks vir spasies sal kontroleer (die basiese Excel-eienlike formule hierbo bespreek sal die #DIV/0-fout in hierdie geval terugstuur):

Om byvoorbeeld duidelike waardes in reeks A2:A10 te tel, gebruik die volgende skikkingsformule :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Formule om afsonderlike tekswaardes te tel

Om afsonderlike tekswaardes in 'n kolom te tel, sal ons die dieselfde benadering as wat ons sopas gebruik het om leë selle uit te sluit.

Soos jy maklik kan raai, sal ons eenvoudig die ISTEXT-funksie in ons Excel-telling-duidelike formule insluit:

En hier is 'n werklike leweformule voorbeeld:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Formule om duidelike getalle te tel

Om duidelike numeriese waardes (getalle, datums en tye) te tel, gebruik die ISNUMBER-funksie:

Byvoorbeeld, om alle verskillende getalle te tel in reeks A2:A10, gebruik die volgende formule:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Tel hooflettersensitiewe afsonderlike waardes in Excel

Net soos om hooflettersensitiewe unieke waardes te tel, die maklikste manier om hooflettersensitiewe afsonderlike waardes te tel, is om 'n helperkolom by te voeg met die skikkingsformule wat unieke waardes identifiseer, insluitend eerste duplikaatvoorvalle. Die formule is basies dieselfde as die een wat ons gebruik het om hooflettersensitiewe unieke waardes te tel, met een klein verandering in 'n selverwysing wat 'n groot verskil maak:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

Soos jy onthou, alle skikkingsformules in Excel vereis om Ctrl + Shift + Enter te druk.

Nadat die formule hierbo voltooi is, kan jy "afsonderlike" waardes tel met 'n gewone COUNTIF formule soos hierdie:

=COUNTIF(B2:B10, "distinct")

As daar geen manier is waarop jy 'n helperkolom by jou werkblad kan voeg nie, kan jy die volgende komplekse skikkingformule gebruik om hooflettersensitiewe afsonderlike waardes te tel sonder skep 'n addisionele kolom:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

Tel unieke en afsonderlike rye in Excel

Om unieke / afsonderlike rye in Excel te tel is soortgelyk aan die tel van unieke en afsonderlike waardes, met die enigste verskildat jy die COUNTIFS-funksie gebruik in plaas van COUNTIF, waarmee jy verskeie kolomme kan spesifiseer om vir unieke waardes na te gaan.

Byvoorbeeld, om unieke of afsonderlike name te tel gebaseer op die waardes in kolomme A (Voornaam) en B (Vannaam), gebruik een van die volgende formules:

Formule om unieke rye te tel:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Formule om onderskeid te tel rye:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

U is natuurlik nie beperk tot die tel van unieke rye wat slegs op twee kolomme gebaseer is nie, die Excel COUNTIFS-funksie kan opwerk tot 127 reeks/kriteria-pare.

Tel afsonderlike waardes in Excel deur 'n draaitabel te gebruik

Die nuutste weergawes van Excel 2013 en Excel 2016 het 'n spesiale kenmerk wat dit moontlik maak om afsonderlike waardes outomaties in 'n spilpunttabel te tel. Die volgende skermkiekie gee 'n idee van hoe die Excel Distinct Count lyk:

Om 'n spiltabel te skep met die duidelike telling vir 'n sekere kolom, voer die volgende stappe uit.

1. Kies die data wat in 'n spilpunttabel ingesluit moet word, skakel oor na die Voeg in -oortjie, Tabelle -groep, en klik die Draaitabel -knoppie.
2. In die Skep Spiltabel -dialoog, kies of jy jou spiltabel in 'n nuwe of bestaande werkblad wil plaas, en maak seker dat jy die Voeg by hierdie data na die Data Model -merkblokkie.

Jy kan ook 'n pasgemaakte naam aan jou Distinct Count gee as jy wil.

Klaar! Die nuutgeskepte spiltabel sal die duidelike telling vertoon soos in die heel eerste skermkiekie in hierdie afdeling.

Wenk. Nadat u u brondata opgedateer het, onthou om die draaitabel op te dateer om die duidelike telling op datum te bring. Om 'n spiltabel te verfris, klik net die Verfris -knoppie op die Analiseer -oortjie, in die Data -groep.

Dit is hoe jy tel duidelike en unieke waardes in Excel. As iemand die formules wat in hierdie tutoriaal bespreek word van nader wil bekyk, is jy welkom om die voorbeeld Excel Count Unieke werkboek af te laai.

Ek bedank jou vir die lees en hoop om jou volgende week weer te sien. In die volgende artikel gaan ons verskeie maniere bespreek om unieke waardes in Excel te vind, te filter, te onttrek en uit te lig. Asseblief