Dans ce tutoriel, vous apprendrez comment compter les valeurs uniques dans Excel à l'aide de formules, et comment obtenir un compte automatique de valeurs distinctes dans un tableau croisé dynamique. Nous aborderons également un certain nombre d'exemples de formules pour compter les noms uniques, les textes, les nombres, les valeurs uniques sensibles à la casse, etc.

Lorsque vous travaillez avec un grand ensemble de données dans Excel, vous avez souvent besoin de savoir combien d'utilisateurs ont été affectés à une tâche. duplicate et unique Et parfois, vous pouvez vouloir ne compter que les valeurs distinct (différentes) valeurs.

Si vous visitez régulièrement ce blog, vous connaissez déjà la formule Excel pour compter les doublons. Et aujourd'hui, nous allons explorer différentes façons de compter les valeurs uniques dans Excel. Mais pour plus de clarté, définissons d'abord les termes.

• Unique en son genre valeurs - ce sont les valeurs qui n'apparaissent qu'une seule fois dans la liste.
• Distinct valeurs - ce sont toutes les valeurs différentes de la liste, c'est-à-dire les valeurs uniques plus les 1ères occurrences des valeurs dupliquées.

La capture d'écran suivante montre la différence :

Voyons maintenant comment vous pouvez compter les valeurs uniques et distinctes dans Excel à l'aide de formules et des fonctionnalités de PivotTable.

Comment compter les valeurs uniques dans Excel

Voici une tâche commune que tous les utilisateurs d'Excel doivent effectuer de temps en temps. Vous avez une liste de données et vous devez trouver le nombre de valeurs uniques dans cette liste. Comment le faire ? Plus facile que vous ne le pensez :) Vous trouverez ci-dessous quelques formules pour compter les valeurs uniques de différents types.

Compter les valeurs uniques dans une colonne

Supposons que vous ayez une colonne de noms dans votre feuille de calcul Excel, et que vous ayez besoin de compter les noms uniques dans cette colonne. La solution est d'utiliser la fonction SUM en combinaison avec IF et COUNTIF :

Note Il s'agit d'une formule de type tableau, assurez-vous donc d'appuyer sur Ctrl + Shift + Enter pour la compléter. Une fois que vous aurez fait cela, Excel entourera automatiquement la formule d'accolades comme dans la capture d'écran ci-dessous. En aucun cas vous ne devez taper les accolades manuellement, cela ne fonctionnera pas.

Dans cet exemple, nous comptons les noms uniques dans la plage A2:A10, notre formule prend donc la forme suivante :

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Plus loin dans ce tutoriel, nous allons aborder une poignée d'autres formules permettant de compter les valeurs uniques de différents types. Et comme toutes ces formules sont des variations de la formule Excel de base des valeurs uniques, il est logique de décomposer la formule ci-dessus, afin que vous puissiez comprendre pleinement son fonctionnement et l'adapter à vos données. Si vous n'êtes pas intéressé par les détails techniques, vous pouvez passer directement à la page suivantel'exemple de formule suivant.

Comment fonctionne la formule Excel de comptage des valeurs uniques

Comme vous le voyez, trois fonctions différentes sont utilisées dans notre formule de valeurs uniques : SUM, IF et COUNTIF. En regardant de l'intérieur, voici ce que fait chaque fonction :

• La fonction COUNTIF compte combien de fois chaque valeur individuelle apparaît dans la plage spécifiée.

  Dans cet exemple, COUNTIF(A2:A10,A2:A10) retourne le tableau {1;2;2;1;2;2;2;1;2} .

• La fonction IF évalue chaque valeur du tableau retourné par COUNTIF, conserve tous les 1 (valeurs uniques) et remplace toutes les autres valeurs par des zéros.

  Ainsi, la fonction IF(COUNTIF(A2:A10,A2:A10)=1,1,0) devient SI(1;2;2;1;2;2;2;2;1;2) = 1,1,0, qui se transforme en un tableau {1;0;0;1;0;0;0;1;0} où 1 est une valeur unique et 0 une valeur dupliquée.

• Enfin, la fonction SUM additionne les valeurs du tableau retourné par IF et donne le nombre total de valeurs uniques, ce qui est exactement ce que nous voulions.

Conseil : pour voir à quoi correspond une partie spécifique de votre formule Excel de valeurs uniques, sélectionnez cette partie dans la barre de formule et appuyez sur la touche F9.

Compter les valeurs de texte uniques dans Excel

Si votre liste Excel contient à la fois des valeurs numériques et des valeurs textuelles, et que vous souhaitez compter uniquement les valeurs textuelles uniques, ajoutez la fonction ISTEXT à la formule de tableau présentée ci-dessus :

=SOMME(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Comme vous le savez, la fonction Excel ISTEXT renvoie VRAI si une valeur évaluée est du texte, FAUX sinon. Comme l'astérisque (*) fonctionne comme l'opérateur AND dans les formules de tableau, la fonction IF renvoie 1 uniquement si une valeur est à la fois du texte et unique, 0 sinon. Et après que la fonction SUM ait additionné tous les 1, vous obtiendrez un compte des valeurs de texte uniques dans la plage spécifiée.

N'oubliez pas d'appuyer sur Ctrl + Shift + Enter pour entrer correctement la formule du tableau, et vous obtiendrez un résultat similaire à celui-ci :

Comme vous pouvez le voir dans la capture d'écran ci-dessus, la formule renvoie le nombre total de valeurs de texte uniques, à l'exclusion des cellules vides, des chiffres, des valeurs logiques de VRAI et FAUX et des erreurs.

Compter les valeurs numériques uniques dans Excel

Pour compter les numéros uniques dans une liste de données, utilisez une formule de tableau comme celle que nous venons d'utiliser pour compter les valeurs uniques de texte, à la seule différence que vous intégrez ISNUMBER au lieu de ISTEXT dans votre formule de valeurs uniques :

=SOMME(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Remarque : comme Microsoft Excel enregistre les dates et les heures sous forme de numéros de série, elles sont également comptées.

Compter les valeurs uniques sensibles à la casse dans Excel

Si votre tableau contient des données sensibles à la casse, le moyen le plus simple de compter les valeurs uniques consiste à créer une colonne d'aide avec la formule de tableau suivante pour identifier les éléments doubles et uniques :

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1, "Unique", "Dupe")

Et ensuite, utilisez une simple fonction COUNTIF pour compter les valeurs uniques :

=COUNTIF(B2:B10, "unique")

Compter les valeurs distinctes dans Excel (occurrences uniques et 1er doublon)

Pour obtenir le nombre de valeurs distinctes dans une liste, utilisez la formule suivante :

N'oubliez pas qu'il s'agit d'une formule de tableau et que vous devez donc utiliser le raccourci Ctrl + Shift + Enter au lieu de la touche Enter habituelle.

Vous pouvez également utiliser la fonction SUMPRODUCT et compléter la formule de la manière habituelle en appuyant sur la touche Entrée :

Par exemple, pour compter les valeurs distinctes dans la plage A2:A10, vous pouvez utiliser l'une des deux méthodes suivantes :

=SOMME(1/COUNTIF(A2:A10,A2:A10))

Ou

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Comment fonctionne la formule distincte d'Excel

Comme vous le savez déjà, nous utilisons la fonction COUNTIF pour savoir combien de fois chaque valeur individuelle apparaît dans la plage spécifiée. Dans l'exemple ci-dessus, le résultat de la fonction COUNTIF est le tableau suivant : {2;2;3;1;2;2;3;1;3} .

Ensuite, un certain nombre d'opérations de division sont effectuées, où chaque valeur du tableau est utilisée comme diviseur avec 1 comme dividende. Cela transforme toutes les valeurs dupliquées en nombres fractionnaires correspondant au nombre d'occurrences dupliquées. Par exemple, si une valeur apparaît 2 fois dans la liste, cela génère 2 éléments dans le tableau avec une valeur de 0,5 (1/2=0,5). Et si une valeur apparaît 3 fois, cela génère une valeur de 0,5.produit 3 éléments dans le tableau avec une valeur de 0.3(3). Dans notre exemple, le résultat de la commande 1/COUNTIF(A2:A10,A2:A10)) est le tableau {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Cela n'a pas beaucoup de sens jusqu'à présent ? C'est parce que nous n'avons pas encore appliqué la fonction SUM / SUMPRODUCT. Lorsqu'une de ces fonctions additionne les valeurs du tableau, la somme de tous les nombres fractionnaires pour chaque élément individuel donne toujours 1, quel que soit le nombre d'occurrences de cet élément dans la liste. Et parce que toutes les valeurs uniques apparaissent dans le tableau comme des 1 (1/1=1), le résultat final renvoyé par la fonctionest le nombre total de toutes les valeurs différentes de la liste.

Formules pour compter des valeurs distinctes de différents types

Comme pour le comptage des valeurs uniques dans Excel, vous pouvez utiliser des variantes de la formule Excel de base count distinct pour traiter des types de valeurs spécifiques tels que les nombres, le texte et les valeurs sensibles à la casse.

N'oubliez pas que toutes les formules ci-dessous sont des formules de tableau et qu'il faut appuyer sur Ctrl + Shift + Enter .

Compter les valeurs distinctes en ignorant les cellules vides

Si une colonne dans laquelle vous souhaitez compter les valeurs distinctes est susceptible de contenir des cellules vides, vous devez ajouter une fonction IF qui vérifiera l'absence de blancs dans la plage spécifiée (la formule Excel distincte de base présentée ci-dessus renverrait l'erreur #DIV/0 dans ce cas) :

Par exemple, pour compter les valeurs distinctes dans la plage A2:A10, utilisez la formule de tableau suivante :

=SOMME(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Formule pour compter les valeurs de texte distinctes

Pour compter les valeurs de texte distinctes dans une colonne, nous allons utiliser la même approche que celle que nous venons d'utiliser pour exclure les cellules vides.

Comme vous pouvez facilement le deviner, nous allons simplement intégrer la fonction ISTEXT dans notre formule Excel de comptage distinct :

Et voici un exemple concret de formule :

=SOMME(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Formule pour compter les nombres distincts

Pour compter des valeurs numériques distinctes (nombres, dates et heures), utilisez la fonction ISNUMBER :

Par exemple, pour compter tous les nombres différents dans la plage A2:A10, utilisez la formule suivante :

=SOMME(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10), ""))

Compter les valeurs distinctes sensibles à la casse dans Excel

Comme pour le comptage des valeurs uniques sensibles à la casse, le moyen le plus simple de compter les valeurs distinctes sensibles à la casse est d'ajouter une colonne d'aide avec la formule du tableau qui identifie les valeurs uniques, y compris les premières occurrences en double. La formule est fondamentalement la même que celle que nous avons utilisée pour compter les valeurs uniques sensibles à la casse, avec une petite modification dans une référence de cellule qui fait une grande différence :

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1, "Distinct","")

Comme vous vous en souvenez, toutes les formules de tableau dans Excel nécessitent d'appuyer sur Ctrl + Shift + Enter .

Une fois la formule ci-dessus terminée, vous pouvez compter les valeurs "distinctes" avec une formule COUNTIF habituelle comme celle-ci :

=COUNTIF(B2:B10, "distinct")

S'il n'est pas possible d'ajouter une colonne d'aide à votre feuille de calcul, vous pouvez utiliser le complexe suivant formule matricielle pour compter les valeurs distinctes sensibles à la casse sans créer de colonne supplémentaire :

=SOMME(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0)))

Compter les lignes uniques et distinctes dans Excel

Le comptage des lignes uniques / distinctes dans Excel s'apparente au comptage des valeurs uniques et distinctes, à la seule différence que vous utilisez la fonction COUNTIFS au lieu de COUNTIF, qui vous permet de spécifier plusieurs colonnes pour vérifier les valeurs uniques.

Par exemple, pour compter les noms uniques ou distincts en fonction des valeurs des colonnes A (Prénom) et B (Nom), utilisez l'une des formules suivantes :

Formule pour compter les rangs uniques :

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Formule pour compter les lignes distinctes :

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Naturellement, vous n'êtes pas limité à compter les lignes uniques sur la base de deux colonnes seulement, la fonction COUNTIFS d'Excel peut traiter jusqu'à 127 paires plage/critères.

Compter les valeurs distinctes dans Excel à l'aide d'un tableau croisé dynamique (PivotTable)

Les dernières versions de Excel 2013 et Excel 2016 ont une fonction spéciale qui permet de compter automatiquement les valeurs distinctes dans un tableau croisé dynamique. La capture d'écran suivante donne une idée de la manière dont le logiciel Excel Compte Distinct ressemble :

Pour créer un tableau croisé dynamique avec le compte distinct pour une certaine colonne, effectuez les étapes suivantes.

1. Sélectionnez les données à inclure dans un tableau croisé dynamique, passez à l'écran d'accueil. Insérer onglet, Tableaux et cliquez sur le bouton Tableau croisé dynamique bouton.
2. Dans le Créer un tableau croisé dynamique choisissez de placer votre tableau croisé dynamique dans une nouvelle feuille de calcul ou dans une feuille de calcul existante, et assurez-vous de sélectionner l'onglet Ajouter ces données au modèle de données la case à cocher.

Vous pouvez également donner un nom personnalisé à votre compte Distinct si vous le souhaitez.

Le tableau croisé dynamique nouvellement créé affichera le nombre de distinctions comme indiqué dans la toute première capture d'écran de cette section.

Conseil : après avoir mis à jour vos données sources, n'oubliez pas de mettre à jour le tableau croisé dynamique pour actualiser le nombre de distinctions. Pour actualiser un tableau croisé dynamique, il suffit de cliquer sur l'icône Rafraîchir sur le bouton Analysez dans l'onglet Données groupe.

Si vous souhaitez examiner de plus près les formules présentées dans ce tutoriel, vous pouvez télécharger le classeur Excel Count Unique.

Je vous remercie de votre lecture et j'espère vous revoir la semaine prochaine. Dans le prochain article, nous aborderons différentes manières de trouver, filtrer, extraire et mettre en évidence des valeurs uniques dans Excel. Restez à l'écoute !