Selles õpetuses saate teada, kuidas lugeda unikaalseid väärtusi Excelis valemite abil ja kuidas saada automaatne erinevate väärtuste loendus pivot-tabelis. Samuti arutame mitmeid valemite näiteid unikaalsete nimede, tekstide, numbrite, kastitundlike unikaalsete väärtuste ja muude väärtuste loendamiseks.

Kui töötate Excelis suure andmekogumiga, võib teil sageli olla vaja teada, kui palju duplikaat ja unikaalne väärtused on olemas. Ja mõnikord võib soovida loendada ainult erinevad (erinevad) väärtused.

Kui olete seda blogi regulaarselt põhiliselt külastanud, siis teate juba Exceli valemit duplikaatide loendamiseks. Ja täna uurime erinevaid võimalusi unikaalsete väärtuste loendamiseks Excelis. Aga selguse huvides defineerime kõigepealt mõisted.

• Unikaalne väärtused - need on väärtused, mis ilmuvad loetelus ainult üks kord.
• Eristatav väärtused - need on kõik erinevad väärtused nimekirjas, st unikaalsed väärtused pluss dubleerivate väärtuste 1. esinemine.

Järgnev ekraanipilt näitab erinevust:

Ja nüüd vaatame, kuidas saab Excelis lugeda unikaalseid ja erinevaid väärtusi, kasutades valemeid ja PivotTable'i funktsioone.

Kuidas lugeda unikaalseid väärtusi Excelis

Siin on tavaline ülesanne, mida kõik Exceli kasutajad peavad aeg-ajalt täitma. Teil on andmete nimekiri ja teil on vaja välja selgitada, kui palju on selles nimekirjas unikaalseid väärtusi. Kuidas seda teha? Lihtsam kui te ehk arvate :) Allpool leiate mõned valemid, millega saab lugeda eri tüüpi unikaalseid väärtusi.

Unikaalsete väärtuste loendamine veerus

Oletame, et teil on Exceli töölehel nimede veerg ja teil on vaja loendada selles veerus olevaid unikaalseid nimesid. Lahendus on kasutada funktsiooni SUM koos IF ja COUNTIF funktsiooniga:

Märkus See on massiivi valem, seega vajutage kindlasti Ctrl + Shift + Enter, et seda lõpule viia. Kui te seda teete, siis Excel lisab valemi automaatselt {sõõrdsulgudesse}, nagu alloleval ekraanipildil. Mitte mingil juhul ei tohi te käsitsüksi sõõrdsulgusid sisestada, see ei toimi.

Selles näites loendame unikaalseid nimesid vahemikus A2:A10, nii et meie valem võtab järgmise kuju:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Edasi arutame selles õpetuses veel käputäie valemeid, et lugeda eri tüüpi unikaalseid väärtusi. Ja kuna kõik need valemid on Exceli unikaalsete väärtuste põhivalemi variatsioonid, on mõistlik eespool toodud valemit lahti mõtestada, et saaksite täielikult aru, kuidas see töötab, ja seda oma andmete jaoks kohandada. Kui keegi ei ole tehnilistest üksikasjadest huvitatud, võite kohe edasi minna.järgmine valemiga seotud näide.

Kuidas Exceli unikaalsete väärtuste loendamise valem töötab

Nagu näete, kasutatakse meie unikaalsete väärtuste valemis 3 erinevat funktsiooni - SUMM, IF ja COUNTIF. Vaadates seestpoolt välja, on siin, mida iga funktsioon teeb:

• Funktsioon COUNTIF loeb, mitu korda iga üksikväärtus määratud vahemikus esineb.

  Selles näites, COUNTIF(A2:A10,A2:A10) tagastab massiivi {1;2;2;1;2;2;2;1;2} .

• Funktsioon IF hindab iga väärtust COUNTIFi poolt tagastatud massiivis, säilitab kõik 1-d (unikaalsed väärtused) ja asendab kõik muud väärtused nullidega.

  Niisiis, funktsioon IF(COUNTIF(A2:A10,A2:A10)=1,1,0) muutub IF(1;2;2;1;2;2;2;2;1;2) = 1,1,0, mis muutub massiivi {1;0;0;1;0;0;0;1;0} kus 1 on unikaalne väärtus ja 0 on dubleeriv väärtus.

• Lõpuks liidab funktsioon SUM väärtused IF-i poolt tagastatud massiivis kokku ja väljastab unikaalsete väärtuste koguarvu, mis on täpselt see, mida me tahtsime.

Näpunäide. Selleks, et näha, milleks teie Exceli unikaalsete väärtuste valemi konkreetne osa hinnatakse, valige see osa valemiribal ja vajutage klahvi F9.

Lugege unikaalseid tekstiväärtusi Excelis

Kui teie Exceli loend sisaldab nii arv- kui ka tekstiväärtusi ja soovite lugeda ainult unikaalseid tekstiväärtusi, lisage eespool käsitletud massiivi valemile funktsioon ISTEXT:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Nagu te teate, tagastab Exceli funktsioon ISTEXT TRUE, kui hinnatud väärtus on tekst, muidu FALSE. Kuna tärn (*) toimib massiivi valemites AND-operaatorina, siis IF funktsioon tagastab 1 ainult siis, kui väärtus on nii tekst kui ka unikaalne, muidu 0. Ja pärast funktsiooni SUM liidetakse kõik 1-d kokku, saadakse määratud vahemikus olevate unikaalsete tekstiväärtuste arv.

Ärge unustage vajutada Ctrl + Shift + Enter, et sisestada massiivi valem õigesti, ja te saate tulemuse, mis sarnaneb sellele:

Nagu ülaltoodud ekraanipildil näha, annab valem tagasi unikaalsete tekstiväärtuste koguarvu, välja arvatud tühjad lahtrid, numbrid, loogilised väärtused TRUE ja FALSE ning vead.

Unikaalsete numbriliste väärtuste loendamine Excelis

Unikaalsete numbrite loendamiseks andmete loetelus kasutage massiivi valemit, nagu me just kasutasime unikaalsete tekstiväärtuste loendamiseks, ainukese erinevusega, et lisate ISNUMBER asemel ISTEXT oma unikaalsete väärtuste valemisse:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Märkus. Kuna Microsoft Excel salvestab kuupäevi ja kellaaegu seerianumbritena, siis loetakse ka neid.

Lugege Exceli suur- ja väiketähtedega unikaalseid väärtusi

Kui teie tabel sisaldab suurustundlikke andmeid, on lihtsaim viis unikaalsete väärtuste loendamiseks luua abisammas järgmise massiivi valemiga, et tuvastada dubleerivaid ja unikaalseid elemente:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1, "Unique", "Dupe")

Ja seejärel kasutage unikaalsete väärtuste loendamiseks lihtsat funktsiooni COUNTIF:

=COUNTIF(B2:B10, "unique")

Lugege Excelis erinevaid väärtusi (unikaalsed ja 1. dubleerivad esinemised).

Nimekirjas olevate erinevate väärtuste arvu saamiseks kasutage järgmist valemit:

Pea meeles, et tegemist on massiivi valemiga ja seetõttu tuleb tavapärase Enter-klahvi asemel vajutada Ctrl + Shift + Enter klahvikombinatsiooni.

Teise võimalusena võite kasutada funktsiooni SUMPRODUCT ja täita valemit tavapärasel viisil, vajutades Enter-klahvi:

Näiteks, kui soovite lugeda erinevaid väärtusi vahemikus A2:A10, võite kasutada kas:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Või

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Kuidas Exceli erinev valem töötab

Nagu te juba teate, kasutame funktsiooni COUNTIF, et leida, mitu korda iga üksikväärtus määratud vahemikus esineb. Ülaltoodud näites on funktsiooni COUNTIF tulemus järgmine massiivi: {2;2;3;1;2;2;3;1;3} .

Pärast seda tehakse hulk jagamisoperatsioone, kus iga massiivi väärtust kasutatakse jagajaks ja dividendiks on 1. See muudab kõik dubleeritud väärtused murdarvudeks, mis vastavad dubleeritud esinemiste arvule. Näiteks kui väärtus esineb loetelus 2 korda, tekitab see massiivi 2 elementi väärtusega 0,5 (1/2=0,5). Ja kui väärtus esineb 3 korda, siis seeannab 3 elementi massiivi väärtusega 0.3(3). Meie näites on tulemus 1/COUNTIF(A2:A10,A2:A10)) on massiivi {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Kas see ei ole siiani mõistlik? See on sellepärast, et me ei ole veel rakendanud funktsiooni SUM / SUMPRODUCT. Kui üks neist funktsioonidest liidab massiivi väärtused kokku, annab kõigi murdarvude summa iga üksiku elemendi kohta alati 1, olenemata sellest, kui mitu korda see element loetelus esineb. Ja kuna kõik unikaalsed väärtused esinevad massiivi 1-dena (1/1=1), on lõpptulemus, mille tagastab funktsioon SUMPRODUCT.valem on kõigi erinevate väärtuste koguarv loetelus.

Valemid eri tüüpi väärtuste loendamiseks

Nagu Excelis unikaalsete väärtuste loendamisel, saate kasutada Exceli põhivalemi count distinct variante, et käsitleda konkreetseid väärtustüüpe, näiteks numbreid, teksti ja suur- ja väiketähendusega väärtusi.

Pidage meeles, et kõik allpool esitatud valemid on massiivi valemid ja nõuavad Ctrl + Shift + Enter .

Loendatakse erinevaid väärtusi, ignoreerides tühje lahtreid

Kui veerg, kus soovite lugeda erinevaid väärtusi, võib sisaldada tühje lahtreid, peaksite lisama IF-funktsiooni, mis kontrollib määratud vahemikku tühjade leidmiseks (eespool käsitletud Exceli põhivalem tagastaks sellisel juhul vea #DIV/0):

Näiteks, et lugeda erinevaid väärtusi vahemikus A2:A10, kasutage järgmist massiivi valemit:

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Erinevate tekstiväärtuste loendamise valem

Selleks, et lugeda veerus olevaid erinevaid tekstiväärtusi, kasutame sama lähenemisviisi, mida kasutasime just tühjade lahtrite väljaarvamiseks.

Nagu võite hõlpsasti arvata, me lihtsalt integreerime ISTEXT-funktsiooni meie Exceli loendusvormelisse:

Ja siin on näide reaalsest elust:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Erinevate arvude loendamise valem

Erinevate numbriliste väärtuste (numbrid, kuupäevad ja ajad) loendamiseks kasutage funktsiooni ISNUMBER:

Näiteks, et lugeda kõiki erinevaid numbreid vahemikus A2:A10, kasutage järgmist valemit:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Lugege Excelis suur- ja väiketähtedega eristatavad väärtused

Sarnaselt suur- ja väiketähendusega unikaalsete väärtuste loendamisele on lihtsaim viis suur- ja väiketähendusega eristuvate väärtuste loendamiseks lisada abisammas koos massiivi valemiga, mis tuvastab unikaalsed väärtused, sealhulgas esimesed dubleerivad esinemised. Valem on põhimõtteliselt sama, mida kasutasime suur- ja väiketähendusega unikaalsete väärtuste loendamiseks, ühe väikese muudatusega lahtriviites, mis teeb suure erinevuse:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1, "Distinct","")

Nagu te mäletate, nõuavad kõik Exceli massiivi valemid Ctrl + Shift + Enter .

Pärast ülaltoodud valemi lõpetamist saate lugeda "erinevaid" väärtusi tavalise COUNTIF-valemi abil, näiteks järgmiselt:

=COUNTIF(B2:B10, "distinct")

Kui te ei saa kuidagi oma töölehele abisammast lisada, võite kasutada järgmist kompleksset massiivi valem loendamiseks ilma täiendavat veergu loomata:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10))), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)))), 0), 0)))

Unikaalsete ja eristatavate ridade loendamine Excelis

Ainulaadsete / erinevate ridade loendamine Excelis on sarnane unikaalsete ja erinevate väärtuste loendamisele, ainsa erinevusega, et te kasutate funktsiooni COUNTIFS asemel COUNTIF, mis võimaldab teil määrata mitu veergu, mida kontrollida unikaalsete väärtuste suhtes.

Näiteks selleks, et lugeda unikaalseid või erinevaid nimesid veergude A (eesnimi) ja B (perekonnanimi) väärtuste põhjal, kasutage ühte järgmistest valemitest:

Valem unikaalsete ridade loendamiseks:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Valem erinevate ridade lugemiseks:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Loomulikult ei ole te piiratud ainult kahe veeru põhjal unikaalsete ridade lugemisega, Exceli funktsioon COUNTIFS võib töödelda kuni 127 vahemiku/kriteeriumi paari.

Erinevate väärtuste lugemine Excelis, kasutades PivotTable'i

Viimased versioonid Excel 2013 ja Excel 2016 on eriline funktsioon, mis võimaldab pivot-tabelis automaatselt erinevaid väärtusi loendada. Järgnev ekraanipilt annab ülevaate, kuidas Exceli Eristuv arv näeb välja:

Teatud veergu eristava loendiga pivot-tabeli loomiseks tehke järgmised sammud.

1. Valige andmed, mida tahetakse lisada pivot-tabelisse, lülitage Sisesta vahekaart, Tabelid gruppi ja klõpsake nuppu PivotTable nupp.
2. In the Loo PivotTable valige, kas paigutada oma pivot-tabel uuele või olemasolevale töölehele, ja valige kindlasti ka valik Lisage need andmed andmemudelisse märkeruut.

Soovi korral võite anda oma eristatavale loendajale ka kohandatud nime.

Valmis! Äsja loodud pivot-tabel kuvab eraldi arvu, nagu on näidatud selle jaotise esimesel ekraanipildil.

Vihje. Pärast lähteandmete ajakohastamist ärge unustage PivotTable'i uuendada, et viia eristatav arv ajakohaseks. PivotTable'i uuendamiseks klõpsake lihtsalt nuppu Värskenda nuppu Analüüsi vahekaardil Andmed rühm.

Nii loete Excelis erinevaid ja unikaalseid väärtusi. Kui keegi soovib selles õpetuses käsitletud valemeid lähemalt uurida, on teil võimalik alla laadida Exceli töövihiku "Count Unique" näidis.

Tänan teid lugemise eest ja loodan, et näeme teid järgmisel nädalal uuesti. Järgmises artiklis arutame erinevaid võimalusi, kuidas leida, filtreerida, ekstraheerida ja esile tõsta unikaalseid väärtusi Excelis. Palun jääge kursis!