ਇਸ ਟਿਊਟੋਰਿਅਲ ਵਿੱਚ, ਤੁਸੀਂ ਸਿੱਖੋਗੇ ਕਿ ਐਕਸਲ ਵਿੱਚ ਫਾਰਮੂਲੇ ਦੇ ਨਾਲ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਿਵੇਂ ਕਰਨੀ ਹੈ, ਅਤੇ ਇੱਕ ਧਰੁਵੀ ਸਾਰਣੀ ਵਿੱਚ ਵੱਖਰੇ ਮੁੱਲਾਂ ਦੀ ਸਵੈਚਲਿਤ ਗਿਣਤੀ ਕਿਵੇਂ ਪ੍ਰਾਪਤ ਕਰਨੀ ਹੈ। ਅਸੀਂ ਵਿਲੱਖਣ ਨਾਵਾਂ, ਲਿਖਤਾਂ, ਸੰਖਿਆਵਾਂ, ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਵਿਲੱਖਣ ਮੁੱਲਾਂ, ਅਤੇ ਹੋਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਕਈ ਫਾਰਮੂਲਾ ਉਦਾਹਰਨਾਂ 'ਤੇ ਵੀ ਚਰਚਾ ਕਰਾਂਗੇ।

ਐਕਸਲ ਵਿੱਚ ਇੱਕ ਵੱਡੇ ਡੇਟਾਸੈਟ ਨਾਲ ਕੰਮ ਕਰਦੇ ਸਮੇਂ, ਤੁਹਾਨੂੰ ਅਕਸਰ ਜਾਣੋ ਕਿ ਕਿੰਨੇ ਡੁਪਲੀਕੇਟ ਅਤੇ ਵਿਲੱਖਣ ਮੁੱਲ ਹਨ। ਅਤੇ ਕਈ ਵਾਰ, ਤੁਸੀਂ ਸਿਰਫ਼ ਵੱਖਰੇ (ਵੱਖ-ਵੱਖ) ਮੁੱਲਾਂ ਨੂੰ ਗਿਣਨਾ ਚਾਹ ਸਕਦੇ ਹੋ।

ਜੇਕਰ ਤੁਸੀਂ ਇਸ ਬਲੌਗ ਨੂੰ ਨਿਯਮਤ ਮੂਲ 'ਤੇ ਦੇਖ ਰਹੇ ਹੋ, ਤਾਂ ਤੁਸੀਂ ਡੁਪਲੀਕੇਟ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਐਕਸਲ ਫਾਰਮੂਲਾ ਪਹਿਲਾਂ ਹੀ ਜਾਣਦੇ ਹੋ। ਅਤੇ ਅੱਜ, ਅਸੀਂ ਐਕਸਲ ਵਿੱਚ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਦੇ ਵੱਖ-ਵੱਖ ਤਰੀਕਿਆਂ ਦੀ ਪੜਚੋਲ ਕਰਨ ਜਾ ਰਹੇ ਹਾਂ। ਪਰ ਸਪਸ਼ਟਤਾ ਦੀ ਖ਼ਾਤਰ, ਆਓ ਪਹਿਲਾਂ ਸ਼ਬਦਾਂ ਨੂੰ ਪਰਿਭਾਸ਼ਿਤ ਕਰੀਏ।

• ਵਿਲੱਖਣ ਮੁੱਲ - ਇਹ ਉਹ ਮੁੱਲ ਹਨ ਜੋ ਸੂਚੀ ਵਿੱਚ ਸਿਰਫ਼ ਇੱਕ ਵਾਰ ਦਿਖਾਈ ਦਿੰਦੇ ਹਨ।
• ਵੱਖਰੇ ਮੁੱਲ - ਇਹ ਸੂਚੀ ਵਿੱਚ ਸਾਰੇ ਵੱਖ-ਵੱਖ ਮੁੱਲ ਹਨ, ਜਿਵੇਂ ਕਿ ਵਿਲੱਖਣ ਮੁੱਲ ਅਤੇ ਡੁਪਲੀਕੇਟ ਮੁੱਲਾਂ ਦੀ ਪਹਿਲੀ ਮੌਜੂਦਗੀ।

ਹੇਠ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ੌਟ ਅੰਤਰ ਨੂੰ ਦਰਸਾਉਂਦੇ ਹਨ:

ਅਤੇ ਹੁਣ, ਆਓ ਦੇਖੀਏ ਕਿ ਤੁਸੀਂ ਫਾਰਮੂਲੇ ਅਤੇ PivotTable ਵਿਸ਼ੇਸ਼ਤਾਵਾਂ ਦੀ ਵਰਤੋਂ ਕਰਕੇ Excel ਵਿੱਚ ਵਿਲੱਖਣ ਅਤੇ ਵੱਖਰੇ ਮੁੱਲਾਂ ਨੂੰ ਕਿਵੇਂ ਗਿਣ ਸਕਦੇ ਹੋ।

ਐਕਸਲ ਵਿੱਚ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਿਵੇਂ ਕਰੀਏ

ਇੱਥੇ ਇੱਕ ਆਮ ਕੰਮ ਹੈ ਜੋ ਸਾਰੇ ਐਕਸਲ ਉਪਭੋਗਤਾਵਾਂ ਨੂੰ ਇੱਕ ਸਮੇਂ ਵਿੱਚ ਇੱਕ ਵਾਰ ਕਰਨਾ ਹੁੰਦਾ ਹੈ। ਤੁਹਾਡੇ ਕੋਲ ਡੇਟਾ ਦੀ ਇੱਕ ਸੂਚੀ ਹੈ ਅਤੇ ਤੁਹਾਨੂੰ ਉਸ ਵਿੱਚ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਦਾ ਪਤਾ ਲਗਾਉਣ ਦੀ ਲੋੜ ਹੈਬਣੇ ਰਹੋ!

ਇੱਕ ਕਾਲਮ ਵਿੱਚ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰੋ

ਮੰਨ ਲਓ ਕਿ ਤੁਹਾਡੇ ਐਕਸਲ ਵਿੱਚ ਨਾਮਾਂ ਦਾ ਇੱਕ ਕਾਲਮ ਹੈ ਵਰਕਸ਼ੀਟ, ਅਤੇ ਤੁਹਾਨੂੰ ਉਸ ਕਾਲਮ ਵਿੱਚ ਵਿਲੱਖਣ ਨਾਮਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਦੀ ਲੋੜ ਹੈ। ਹੱਲ ਹੈ SUM ਫੰਕਸ਼ਨ ਨੂੰ IF ਅਤੇ COUNTIF ਦੇ ਸੁਮੇਲ ਵਿੱਚ ਵਰਤਣਾ:

ਨੋਟ । ਇਹ ਇੱਕ ਐਰੇ ਫਾਰਮੂਲਾ ਹੈ, ਇਸਲਈ ਇਸਨੂੰ ਪੂਰਾ ਕਰਨ ਲਈ Ctrl + Shift + Enter ਦੱਬਣਾ ਯਕੀਨੀ ਬਣਾਓ। ਇੱਕ ਵਾਰ ਜਦੋਂ ਤੁਸੀਂ ਅਜਿਹਾ ਕਰ ਲੈਂਦੇ ਹੋ, ਤਾਂ Excel ਆਪਣੇ ਆਪ ਫਾਰਮੂਲੇ ਨੂੰ ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ੌਟ ਵਾਂਗ {ਕਰਲੀ ਬਰੇਸ} ਵਿੱਚ ਨੱਥੀ ਕਰ ਦੇਵੇਗਾ। ਕਿਸੇ ਵੀ ਸਥਿਤੀ ਵਿੱਚ ਤੁਹਾਨੂੰ ਕਰਲੀ ਬਰੇਸ ਨੂੰ ਹੱਥੀਂ ਟਾਈਪ ਨਹੀਂ ਕਰਨਾ ਚਾਹੀਦਾ, ਇਹ ਕੰਮ ਨਹੀਂ ਕਰੇਗਾ।

ਇਸ ਉਦਾਹਰਨ ਵਿੱਚ, ਅਸੀਂ ਰੇਂਜ A2:A10 ਵਿੱਚ ਵਿਲੱਖਣ ਨਾਮਾਂ ਦੀ ਗਿਣਤੀ ਕਰ ਰਹੇ ਹਾਂ, ਇਸਲਈ ਸਾਡਾ ਫਾਰਮੂਲਾ ਹੇਠਾਂ ਦਿੱਤੀ ਸ਼ਕਲ ਲੈਂਦਾ ਹੈ:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

ਅੱਗੇ ਇਸ ਟਿਊਟੋਰਿਅਲ ਵਿੱਚ, ਅਸੀਂ ਵੱਖ-ਵੱਖ ਕਿਸਮਾਂ ਦੇ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਕੁਝ ਹੋਰ ਫਾਰਮੂਲਿਆਂ ਦੀ ਚਰਚਾ ਕਰਨ ਜਾ ਰਹੇ ਹਾਂ। ਅਤੇ ਕਿਉਂਕਿ ਉਹ ਸਾਰੇ ਫਾਰਮੂਲੇ ਮੂਲ ਐਕਸਲ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੇ ਫਾਰਮੂਲੇ ਦੀਆਂ ਭਿੰਨਤਾਵਾਂ ਹਨ, ਇਸ ਲਈ ਉਪਰੋਕਤ ਫਾਰਮੂਲੇ ਨੂੰ ਤੋੜਨਾ ਸਮਝਦਾਰੀ ਹੈ, ਤਾਂ ਜੋ ਤੁਸੀਂ ਪੂਰੀ ਤਰ੍ਹਾਂ ਸਮਝ ਸਕੋ ਕਿ ਇਹ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ ਅਤੇ ਇਸਨੂੰ ਤੁਹਾਡੇ ਡੇਟਾ ਲਈ ਟਵੀਕ ਕਰਦਾ ਹੈ। ਜੇਕਰ ਕਿਸੇ ਨੂੰ ਤਕਨੀਕੀਆਂ ਵਿੱਚ ਦਿਲਚਸਪੀ ਨਹੀਂ ਹੈ, ਤਾਂ ਤੁਸੀਂ ਅਗਲੇ ਫਾਰਮੂਲੇ ਦੀ ਉਦਾਹਰਨ 'ਤੇ ਜਾ ਸਕਦੇ ਹੋ।

ਐਕਸਲ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਿਵੇਂ ਕਰਦਾ ਹੈ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ

ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਦੇਖਦੇ ਹੋ, ਸਾਡੇ ਵਿਲੱਖਣ ਵਿੱਚ 3 ਵੱਖ-ਵੱਖ ਫੰਕਸ਼ਨਾਂ ਦੀ ਵਰਤੋਂ ਕੀਤੀ ਜਾਂਦੀ ਹੈ ਮੁੱਲ ਫਾਰਮੂਲਾ - SUM, IFਅਤੇ COUNTIF। ਅੰਦਰੋਂ ਬਾਹਰੋਂ ਦੇਖਦੇ ਹੋਏ, ਇੱਥੇ ਹਰ ਫੰਕਸ਼ਨ ਕੀ ਕਰਦਾ ਹੈ:

• COUNTIF ਫੰਕਸ਼ਨ ਇਹ ਗਿਣਦਾ ਹੈ ਕਿ ਨਿਰਧਾਰਤ ਰੇਂਜ ਵਿੱਚ ਹਰੇਕ ਵਿਅਕਤੀਗਤ ਮੁੱਲ ਕਿੰਨੀ ਵਾਰ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ।

  ਇਸ ਉਦਾਹਰਨ ਵਿੱਚ, COUNTIF(A2:A10,A2:A10) ਐਰੇ {1;2;2;1;2;2;2;1;2} ਵਾਪਸ ਕਰਦਾ ਹੈ।

• IF ਫੰਕਸ਼ਨ COUNTIF ਦੁਆਰਾ ਵਾਪਸ ਕੀਤੇ ਗਏ ਐਰੇ ਵਿੱਚ ਹਰੇਕ ਮੁੱਲ ਦਾ ਮੁਲਾਂਕਣ ਕਰਦਾ ਹੈ, ਸਾਰੇ 1 (ਵਿਲੱਖਣ ਮੁੱਲ) ਰੱਖਦਾ ਹੈ, ਅਤੇ ਬਾਕੀ ਸਾਰੇ ਮੁੱਲਾਂ ਨੂੰ ਜ਼ੀਰੋ ਨਾਲ ਬਦਲਦਾ ਹੈ। .

  ਇਸ ਲਈ, ਫੰਕਸ਼ਨ IF(COUNTIF(A2:A10,A2:A10)=1,1,0) IF(1;2;2;1;2;2;2;1;2) = 1,1,0, ਬਣ ਜਾਂਦਾ ਹੈ ਜੋ ਐਰੇ {1;0;0;1;0;0;0;1;0} ਵਿੱਚ ਬਦਲ ਜਾਂਦਾ ਹੈ ਜਿੱਥੇ 1 ਇੱਕ ਵਿਲੱਖਣ ਮੁੱਲ ਹੈ ਅਤੇ 0 ਇੱਕ ਡੁਪਲੀਕੇਟ ਮੁੱਲ ਹੈ।

• ਅੰਤ ਵਿੱਚ, SUM ਫੰਕਸ਼ਨ IF ਦੁਆਰਾ ਵਾਪਸ ਕੀਤੇ ਗਏ ਐਰੇ ਵਿੱਚ ਮੁੱਲਾਂ ਨੂੰ ਜੋੜਦਾ ਹੈ ਅਤੇ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਕੁੱਲ ਸੰਖਿਆ ਨੂੰ ਆਊਟਪੁੱਟ ਕਰਦਾ ਹੈ, ਜੋ ਬਿਲਕੁਲ ਉਹੀ ਹੈ ਜੋ ਅਸੀਂ ਚਾਹੁੰਦੇ ਸੀ।

ਟਿਪ . ਇਹ ਦੇਖਣ ਲਈ ਕਿ ਤੁਹਾਡੇ Excel ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੇ ਫਾਰਮੂਲੇ ਦਾ ਇੱਕ ਖਾਸ ਹਿੱਸਾ ਕਿਸ ਤਰ੍ਹਾਂ ਦਾ ਮੁਲਾਂਕਣ ਕਰਦਾ ਹੈ, ਫਾਰਮੂਲਾ ਬਾਰ ਵਿੱਚ ਉਸ ਹਿੱਸੇ ਨੂੰ ਚੁਣੋ ਅਤੇ F9 ਕੁੰਜੀ ਦਬਾਓ।

ਐਕਸਲ ਵਿੱਚ ਵਿਲੱਖਣ ਟੈਕਸਟ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰੋ

ਜੇਕਰ ਤੁਹਾਡੀ ਐਕਸਲ ਸੂਚੀ ਵਿੱਚ ਸੰਖਿਆਤਮਕ ਅਤੇ ਟੈਕਸਟ ਮੁੱਲ ਦੋਵੇਂ ਹਨ, ਅਤੇ ਤੁਸੀਂ ਸਿਰਫ਼ ਵਿਲੱਖਣ ਟੈਕਸਟ ਮੁੱਲਾਂ ਨੂੰ ਗਿਣਨਾ ਚਾਹੁੰਦੇ ਹੋ, ਤਾਂ ਉੱਪਰ ਦੱਸੇ ਗਏ ਐਰੇ ਫਾਰਮੂਲੇ ਵਿੱਚ ISTEXT ਫੰਕਸ਼ਨ ਸ਼ਾਮਲ ਕਰੋ:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਜਾਣਦੇ ਹੋ, ਐਕਸਲ ISTEXT ਫੰਕਸ਼ਨ TRUE ਦਿੰਦਾ ਹੈ ਜੇਕਰ ਇੱਕ ਮੁਲਾਂਕਣ ਮੁੱਲ ਟੈਕਸਟ ਹੈ, ਨਹੀਂ ਤਾਂ FALSE। ਕਿਉਂਕਿ ਤਾਰਾ (*) ਐਰੇ ਫਾਰਮੂਲੇ ਵਿੱਚ AND ਆਪਰੇਟਰ ਦੇ ਤੌਰ ਤੇ ਕੰਮ ਕਰਦਾ ਹੈ, IF ਫੰਕਸ਼ਨ ਸਿਰਫ 1 ਦਿੰਦਾ ਹੈ ਜੇਕਰ ਇੱਕ ਮੁੱਲ ਟੈਕਸਟ ਅਤੇ ਵਿਲੱਖਣ ਦੋਵੇਂ ਹੋਵੇ, ਨਹੀਂ ਤਾਂ 0। ਅਤੇ SUM ਫੰਕਸ਼ਨ ਦੇ ਸਾਰੇ 1 ਨੂੰ ਜੋੜਨ ਤੋਂ ਬਾਅਦ, ਤੁਹਾਨੂੰ ਨਿਸ਼ਚਿਤ ਵਿੱਚ ਵਿਲੱਖਣ ਟੈਕਸਟ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਮਿਲੇਗੀਰੇਂਜ।

ਐਰੇ ਫਾਰਮੂਲੇ ਨੂੰ ਸਹੀ ਢੰਗ ਨਾਲ ਦਾਖਲ ਕਰਨ ਲਈ Ctrl + Shift + Enter ਨੂੰ ਦਬਾਉਣ ਲਈ ਨਾ ਭੁੱਲੋ, ਅਤੇ ਤੁਹਾਨੂੰ ਇਸ ਤਰ੍ਹਾਂ ਦਾ ਨਤੀਜਾ ਮਿਲੇਗਾ:

ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਉੱਪਰ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ੌਟ ਵਿੱਚ ਦੇਖ ਸਕਦੇ ਹੋ, ਫਾਰਮੂਲਾ ਖਾਲੀ ਸੈੱਲਾਂ, ਨੰਬਰਾਂ, ਸਹੀ ਅਤੇ ਗਲਤ ਦੇ ਲਾਜ਼ੀਕਲ ਮੁੱਲਾਂ ਅਤੇ ਗਲਤੀਆਂ ਨੂੰ ਛੱਡ ਕੇ ਵਿਲੱਖਣ ਟੈਕਸਟ ਮੁੱਲਾਂ ਦੀ ਕੁੱਲ ਸੰਖਿਆ ਵਾਪਸ ਕਰਦਾ ਹੈ।

ਐਕਸਲ ਵਿੱਚ ਵਿਲੱਖਣ ਸੰਖਿਆਤਮਕ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰੋ

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

ਨੋਟ। ਕਿਉਂਕਿ Microsoft Excel ਮਿਤੀਆਂ ਅਤੇ ਸਮੇਂ ਨੂੰ ਸੀਰੀਅਲ ਨੰਬਰਾਂ ਵਜੋਂ ਸਟੋਰ ਕਰਦਾ ਹੈ, ਉਹਨਾਂ ਨੂੰ ਵੀ ਗਿਣਿਆ ਜਾਂਦਾ ਹੈ।

ਐਕਸਲ ਵਿੱਚ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰੋ

ਜੇਕਰ ਤੁਹਾਡੀ ਸਾਰਣੀ ਵਿੱਚ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਡੇਟਾ ਹੈ, ਤਾਂ ਗਿਣਤੀ ਕਰਨ ਦਾ ਸਭ ਤੋਂ ਆਸਾਨ ਤਰੀਕਾ ਹੈ। ਵਿਲੱਖਣ ਮੁੱਲ ਡੁਪਲੀਕੇਟ ਅਤੇ ਵਿਲੱਖਣ ਆਈਟਮਾਂ ਦੀ ਪਛਾਣ ਕਰਨ ਲਈ ਹੇਠਾਂ ਦਿੱਤੇ ਐਰੇ ਫਾਰਮੂਲੇ ਨਾਲ ਇੱਕ ਸਹਾਇਕ ਕਾਲਮ ਬਣਾਉਣਗੇ:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

ਅਤੇ ਫਿਰ, ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਇੱਕ ਸਧਾਰਨ COUNTIF ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰੋ:

=COUNTIF(B2:B10, "unique")

ਐਕਸਲ ਵਿੱਚ ਵੱਖਰੇ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰੋ (ਵਿਲੱਖਣ ਅਤੇ ਪਹਿਲੀ ਡੁਪਲੀਕੇਟ ਘਟਨਾਵਾਂ)

ਸੂਚੀ ਵਿੱਚ ਵੱਖਰੇ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ, ਹੇਠਾਂ ਦਿੱਤੀ ਵਰਤੋਂ ਕਰੋ ਫਾਰਮੂਲਾ:

ਯਾਦ ਰੱਖੋ, ਇਹ ਇੱਕ ਐਰੇ ਫਾਰਮੂਲਾ ਹੈ, ਅਤੇ ਇਸਲਈ ਤੁਹਾਨੂੰ Ctrl + Shift + Enter ਦਬਾਉ। ਆਮ ਐਂਟਰ ਦੀ ਬਜਾਏ ਸ਼ਾਰਟਕੱਟਕੀਸਟ੍ਰੋਕ।

ਵਿਕਲਪਿਕ ਤੌਰ 'ਤੇ, ਤੁਸੀਂ SUMPRODUCT ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ ਅਤੇ ਐਂਟਰ ਕੁੰਜੀ ਨੂੰ ਦਬਾ ਕੇ ਆਮ ਤਰੀਕੇ ਨਾਲ ਫਾਰਮੂਲੇ ਨੂੰ ਪੂਰਾ ਕਰ ਸਕਦੇ ਹੋ:

ਉਦਾਹਰਨ ਲਈ, ਰੇਂਜ A2:A10 ਵਿੱਚ ਵੱਖਰੇ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ, ਤੁਸੀਂ ਇਹਨਾਂ ਵਿੱਚੋਂ ਕਿਸੇ ਇੱਕ ਨਾਲ ਜਾ ਸਕਦੇ ਹੋ:

=SUM(1/COUNTIF(A2:A10,A2:A10))

ਜਾਂ

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

ਐਕਸਲ ਵੱਖਰਾ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ

ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਪਹਿਲਾਂ ਹੀ ਜਾਣਦੇ ਹੋ, ਅਸੀਂ ਇਹ ਪਤਾ ਕਰਨ ਲਈ COUNTIF ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹਾਂ ਕਿ ਹਰੇਕ ਵਿਅਕਤੀਗਤ ਮੁੱਲ ਵਿੱਚ ਕਿੰਨੀ ਵਾਰ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ ਨਿਰਧਾਰਤ ਸੀਮਾ. ਉਪਰੋਕਤ ਉਦਾਹਰਨ ਵਿੱਚ, COUNTIF ਫੰਕਸ਼ਨ ਦਾ ਨਤੀਜਾ ਹੇਠ ਦਿੱਤੀ ਐਰੇ ਹੈ: {2;2;3;1;2;2;3;1;3} ।

ਉਸ ਤੋਂ ਬਾਅਦ, ਕਈ ਡਿਵੀਜ਼ਨ ਓਪਰੇਸ਼ਨ ਕੀਤੇ ਜਾਂਦੇ ਹਨ, ਜਿੱਥੇ ਐਰੇ ਦੇ ਹਰੇਕ ਮੁੱਲ ਨੂੰ 1 ਦੇ ਨਾਲ ਇੱਕ ਭਾਜਕ ਵਜੋਂ ਵਰਤਿਆ ਜਾਂਦਾ ਹੈ। ਲਾਭਅੰਸ਼ ਇਹ ਸਾਰੇ ਡੁਪਲੀਕੇਟ ਮੁੱਲਾਂ ਨੂੰ ਡੁਪਲੀਕੇਟ ਘਟਨਾਵਾਂ ਦੀ ਸੰਖਿਆ ਦੇ ਅਨੁਸਾਰੀ ਅੰਸ਼ਕ ਸੰਖਿਆਵਾਂ ਵਿੱਚ ਬਦਲ ਦਿੰਦਾ ਹੈ। ਉਦਾਹਰਨ ਲਈ, ਜੇਕਰ ਸੂਚੀ ਵਿੱਚ ਇੱਕ ਮੁੱਲ 2 ਵਾਰ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ, ਤਾਂ ਇਹ ਐਰੇ ਵਿੱਚ 0.5 (1/2=0.5) ਦੇ ਮੁੱਲ ਨਾਲ 2 ਆਈਟਮਾਂ ਬਣਾਉਂਦਾ ਹੈ। ਅਤੇ ਜੇਕਰ ਕੋਈ ਮੁੱਲ 3 ਵਾਰ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ, ਤਾਂ ਇਹ 0.3(3) ਦੇ ਮੁੱਲ ਨਾਲ ਐਰੇ ਵਿੱਚ 3 ਆਈਟਮਾਂ ਪੈਦਾ ਕਰਦਾ ਹੈ। ਸਾਡੀ ਉਦਾਹਰਨ ਵਿੱਚ, 1/COUNTIF(A2:A10,A2:A10)) ਦਾ ਨਤੀਜਾ ਐਰੇ {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} ਹੈ।

ਕੀ ਹੁਣ ਤੱਕ ਬਹੁਤਾ ਅਰਥ ਨਹੀਂ ਹੈ? ਅਜਿਹਾ ਇਸ ਲਈ ਕਿਉਂਕਿ ਅਸੀਂ ਅਜੇ ਤੱਕ SUM / SUMPRODUCT ਫੰਕਸ਼ਨ ਨੂੰ ਲਾਗੂ ਨਹੀਂ ਕੀਤਾ ਹੈ। ਜਦੋਂ ਇਹਨਾਂ ਵਿੱਚੋਂ ਕੋਈ ਇੱਕ ਫੰਕਸ਼ਨ ਐਰੇ ਵਿੱਚ ਮੁੱਲਾਂ ਨੂੰ ਜੋੜਦਾ ਹੈ, ਤਾਂ ਹਰੇਕ ਵਿਅਕਤੀਗਤ ਆਈਟਮ ਲਈ ਸਾਰੀਆਂ ਫ੍ਰੈਕਸ਼ਨਲ ਸੰਖਿਆਵਾਂ ਦਾ ਜੋੜ ਹਮੇਸ਼ਾ 1 ਦਿੰਦਾ ਹੈ, ਭਾਵੇਂ ਸੂਚੀ ਵਿੱਚ ਉਸ ਆਈਟਮ ਦੀਆਂ ਕਿੰਨੀਆਂ ਵੀ ਘਟਨਾਵਾਂ ਮੌਜੂਦ ਹੋਣ। ਅਤੇਕਿਉਂਕਿ ਸਾਰੇ ਵਿਲੱਖਣ ਮੁੱਲ ਐਰੇ ਵਿੱਚ 1 ਦੇ (1/1=1) ਦੇ ਰੂਪ ਵਿੱਚ ਦਿਖਾਈ ਦਿੰਦੇ ਹਨ, ਫਾਰਮੂਲੇ ਦੁਆਰਾ ਦਿੱਤਾ ਗਿਆ ਅੰਤਮ ਨਤੀਜਾ ਸੂਚੀ ਵਿੱਚ ਸਾਰੇ ਵੱਖ-ਵੱਖ ਮੁੱਲਾਂ ਦੀ ਕੁੱਲ ਸੰਖਿਆ ਹੈ।

ਵੱਖ-ਵੱਖ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਫਾਰਮੂਲੇ ਕਿਸਮਾਂ

ਜਿਵੇਂ ਕਿ ਐਕਸਲ ਵਿੱਚ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਦਾ ਮਾਮਲਾ ਹੈ, ਤੁਸੀਂ ਖਾਸ ਮੁੱਲ ਕਿਸਮਾਂ ਜਿਵੇਂ ਕਿ ਸੰਖਿਆਵਾਂ, ਟੈਕਸਟ, ਅਤੇ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਮੁੱਲਾਂ ਨੂੰ ਸੰਭਾਲਣ ਲਈ ਮੂਲ ਐਕਸਲ ਕਾਉਂਟ ਵੱਖਰੇ ਫਾਰਮੂਲੇ ਦੀਆਂ ਭਿੰਨਤਾਵਾਂ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ।

ਕਿਰਪਾ ਕਰਕੇ ਯਾਦ ਰੱਖੋ ਕਿ ਹੇਠਾਂ ਦਿੱਤੇ ਸਾਰੇ ਫਾਰਮੂਲੇ ਐਰੇ ਫਾਰਮੂਲੇ ਹਨ ਅਤੇ ਉਹਨਾਂ ਨੂੰ Ctrl + Shift + Enter ਦਬਾਉਣ ਦੀ ਲੋੜ ਹੈ।

ਖਾਲੀ ਸੈੱਲਾਂ ਨੂੰ ਨਜ਼ਰਅੰਦਾਜ਼ ਕਰਦੇ ਹੋਏ ਵੱਖਰੇ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰੋ

ਜੇ ਇੱਕ ਕਾਲਮ ਜਿੱਥੇ ਤੁਸੀਂ ਵੱਖਰੇ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨਾ ਚਾਹੁੰਦੇ ਹੋ ਖਾਲੀ ਸੈੱਲ ਸ਼ਾਮਲ ਹੋ ਸਕਦੇ ਹਨ, ਤੁਹਾਨੂੰ ਇੱਕ IF ਫੰਕਸ਼ਨ ਜੋੜਨਾ ਚਾਹੀਦਾ ਹੈ ਜੋ ਖਾਲੀ ਥਾਂਵਾਂ ਲਈ ਨਿਰਧਾਰਤ ਰੇਂਜ ਦੀ ਜਾਂਚ ਕਰੇਗਾ (ਉੱਪਰ ਦੱਸੇ ਗਏ ਮੂਲ ਐਕਸਲ ਵੱਖਰਾ ਫਾਰਮੂਲਾ ਇਸ ਕੇਸ ਵਿੱਚ #DIV/0 ਗਲਤੀ ਵਾਪਸ ਕਰੇਗਾ):

ਉਦਾਹਰਨ ਲਈ, ਰੇਂਜ A2:A10 ਵਿੱਚ ਵੱਖਰੇ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ, ਦੀ ਵਰਤੋਂ ਕਰੋ ਹੇਠ ਦਿੱਤੇ ਐਰੇ ਫਾਰਮੂਲੇ :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

ਵੱਖਰੇ ਟੈਕਸਟ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਫਾਰਮੂਲਾ

ਇੱਕ ਕਾਲਮ ਵਿੱਚ ਵੱਖਰੇ ਟੈਕਸਟ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ, ਅਸੀਂ ਇਸਦੀ ਵਰਤੋਂ ਕਰਾਂਗੇ ਉਹੀ ਪਹੁੰਚ ਜੋ ਅਸੀਂ ਹੁਣੇ ਖਾਲੀ ਸੈੱਲਾਂ ਨੂੰ ਬਾਹਰ ਕੱਢਣ ਲਈ ਵਰਤੀ ਹੈ।

ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਆਸਾਨੀ ਨਾਲ ਅੰਦਾਜ਼ਾ ਲਗਾ ਸਕਦੇ ਹੋ, ਅਸੀਂ ਸਿਰਫ਼ ISTEXT ਫੰਕਸ਼ਨ ਨੂੰ ਸਾਡੇ ਐਕਸਲ ਕਾਉਂਟ ਵੱਖਰੇ ਫਾਰਮੂਲੇ ਵਿੱਚ ਸ਼ਾਮਲ ਕਰਾਂਗੇ:

ਅਤੇ ਇੱਥੇ ਇੱਕ ਅਸਲ-ਜੀਵਨ ਹੈਫਾਰਮੂਲਾ ਉਦਾਹਰਨ:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

ਵੱਖ-ਵੱਖ ਸੰਖਿਆਵਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਫਾਰਮੂਲਾ

ਵੱਖ-ਵੱਖ ਸੰਖਿਆਤਮਕ ਮੁੱਲਾਂ (ਸੰਖਿਆਵਾਂ, ਮਿਤੀਆਂ ਅਤੇ ਸਮੇਂ) ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ, ISNUMBER ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰੋ:

ਉਦਾਹਰਨ ਲਈ, ਸਾਰੇ ਵੱਖ-ਵੱਖ ਨੰਬਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਰੇਂਜ A2:A10 ਵਿੱਚ, ਹੇਠਾਂ ਦਿੱਤੇ ਫਾਰਮੂਲੇ ਦੀ ਵਰਤੋਂ ਕਰੋ:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

ਐਕਸਲ ਵਿੱਚ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਵੱਖਰੇ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰੋ

ਇਸੇ ਤਰ੍ਹਾਂ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ, ਸਭ ਤੋਂ ਆਸਾਨ ਤਰੀਕਾ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਵੱਖਰੇ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਐਰੇ ਫਾਰਮੂਲੇ ਦੇ ਨਾਲ ਇੱਕ ਸਹਾਇਕ ਕਾਲਮ ਜੋੜਨਾ ਹੈ ਜੋ ਪਹਿਲੀ ਡੁਪਲੀਕੇਟ ਘਟਨਾਵਾਂ ਸਮੇਤ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਪਛਾਣ ਕਰਦਾ ਹੈ। ਫਾਰਮੂਲਾ ਮੂਲ ਰੂਪ ਵਿੱਚ ਉਹੀ ਹੈ ਜੋ ਅਸੀਂ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਵਰਤਿਆ ਸੀ, ਇੱਕ ਸੈੱਲ ਸੰਦਰਭ ਵਿੱਚ ਇੱਕ ਛੋਟੀ ਜਿਹੀ ਤਬਦੀਲੀ ਨਾਲ ਜੋ ਬਹੁਤ ਵੱਡਾ ਫ਼ਰਕ ਪਾਉਂਦਾ ਹੈ:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

ਜਿਵੇਂ ਕਿ ਤੁਹਾਨੂੰ ਯਾਦ ਹੈ, ਐਕਸਲ ਵਿੱਚ ਸਾਰੇ ਐਰੇ ਫਾਰਮੂਲਿਆਂ ਲਈ Ctrl + Shift + Enter ਦਬਾਉਣ ਦੀ ਲੋੜ ਹੁੰਦੀ ਹੈ।

ਉਪਰੋਕਤ ਫਾਰਮੂਲਾ ਪੂਰਾ ਹੋਣ ਤੋਂ ਬਾਅਦ, ਤੁਸੀਂ ਇਸ ਤਰ੍ਹਾਂ ਦੇ ਆਮ COUNTIF ਫਾਰਮੂਲੇ ਨਾਲ "ਵੱਖਰੇ" ਮੁੱਲਾਂ ਨੂੰ ਗਿਣ ਸਕਦੇ ਹੋ:

=COUNTIF(B2:B10, "distinct")

ਜੇਕਰ ਤੁਸੀਂ ਆਪਣੀ ਵਰਕਸ਼ੀਟ ਵਿੱਚ ਸਹਾਇਕ ਕਾਲਮ ਸ਼ਾਮਲ ਕਰਨ ਦਾ ਕੋਈ ਤਰੀਕਾ ਨਹੀਂ ਹੈ, ਤਾਂ ਤੁਸੀਂ ਬਿਨਾਂ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਵੱਖਰੇ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਹੇਠਾਂ ਦਿੱਤੇ ਕੰਪਲੈਕਸ ਐਰੇ ਫਾਰਮੂਲੇ ਦੀ ਵਰਤੋਂ ਕਰ ਸਕਦੇ ਹੋ ਇੱਕ ਵਾਧੂ ਕਾਲਮ ਬਣਾਉਣਾ:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

ਐਕਸਲ ਵਿੱਚ ਵਿਲੱਖਣ ਅਤੇ ਵੱਖਰੀਆਂ ਕਤਾਰਾਂ ਦੀ ਗਿਣਤੀ

ਐਕਸਲ ਵਿੱਚ ਵਿਲੱਖਣ / ਵੱਖਰੀਆਂ ਕਤਾਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨਾ ਵਿਲੱਖਣ ਅਤੇ ਵੱਖਰੇ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਦੇ ਸਮਾਨ ਹੈ, ਅੰਤਰਕਿ ਤੁਸੀਂ COUNTIF ਦੀ ਬਜਾਏ COUNTIFS ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹੋ, ਜੋ ਤੁਹਾਨੂੰ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਦੀ ਜਾਂਚ ਕਰਨ ਲਈ ਕਈ ਕਾਲਮਾਂ ਨੂੰ ਨਿਸ਼ਚਿਤ ਕਰਨ ਦਿੰਦਾ ਹੈ।

ਉਦਾਹਰਨ ਲਈ, ਕਾਲਮ A (ਪਹਿਲਾ ਨਾਮ) ਅਤੇ B ਵਿੱਚ ਮੁੱਲਾਂ ਦੇ ਆਧਾਰ 'ਤੇ ਵਿਲੱਖਣ ਜਾਂ ਵੱਖਰੇ ਨਾਮਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ (ਆਖਰੀ ਨਾਮ), ਹੇਠਾਂ ਦਿੱਤੇ ਫਾਰਮੂਲੇ ਵਿੱਚੋਂ ਕਿਸੇ ਇੱਕ ਦੀ ਵਰਤੋਂ ਕਰੋ:

ਵਿਲੱਖਣ ਕਤਾਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਫਾਰਮੂਲਾ:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

ਵੱਖਰੀ ਗਿਣਤੀ ਕਰਨ ਲਈ ਫਾਰਮੂਲਾ ਕਤਾਰਾਂ:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

ਕੁਦਰਤੀ ਤੌਰ 'ਤੇ, ਤੁਸੀਂ ਸਿਰਫ਼ ਦੋ ਕਾਲਮਾਂ ਦੇ ਆਧਾਰ 'ਤੇ ਵਿਲੱਖਣ ਕਤਾਰਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਤੱਕ ਸੀਮਿਤ ਨਹੀਂ ਹੋ, ਐਕਸਲ COUNTIFS ਫੰਕਸ਼ਨ ਪ੍ਰਕਿਰਿਆ ਕਰ ਸਕਦਾ ਹੈ। 127 ਰੇਂਜ/ਮਾਪਦੰਡ ਜੋੜਿਆਂ ਤੱਕ।

ਇੱਕ PivotTable ਦੀ ਵਰਤੋਂ ਕਰਕੇ Excel ਵਿੱਚ ਵੱਖਰੇ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰੋ

Excel 2013 ਅਤੇ Excel 2016 ਦੇ ਨਵੀਨਤਮ ਸੰਸਕਰਣਾਂ ਵਿੱਚ ਇੱਕ ਹੈ ਵਿਸ਼ੇਸ਼ ਵਿਸ਼ੇਸ਼ਤਾ ਜੋ ਇੱਕ ਧਰੁਵੀ ਸਾਰਣੀ ਵਿੱਚ ਆਪਣੇ ਆਪ ਹੀ ਵੱਖਰੇ ਮੁੱਲਾਂ ਦੀ ਗਿਣਤੀ ਕਰਨ ਦੀ ਆਗਿਆ ਦਿੰਦੀ ਹੈ। ਨਿਮਨਲਿਖਤ ਸਕ੍ਰੀਨਸ਼ੌਟ ਇੱਕ ਵਿਚਾਰ ਦਿੰਦਾ ਹੈ ਕਿ ਐਕਸਲ ਵੱਖਰੀ ਗਿਣਤੀ ਕਿਵੇਂ ਦਿਖਾਈ ਦਿੰਦੀ ਹੈ:

ਕਿਸੇ ਖਾਸ ਕਾਲਮ ਲਈ ਵੱਖਰੀ ਗਿਣਤੀ ਦੇ ਨਾਲ ਇੱਕ ਧਰੁਵੀ ਸਾਰਣੀ ਬਣਾਉਣ ਲਈ, ਹੇਠਾਂ ਦਿੱਤੇ ਕਦਮਾਂ ਨੂੰ ਪੂਰਾ ਕਰੋ।

1. ਪਿਵੋਟ ਟੇਬਲ ਵਿੱਚ ਸ਼ਾਮਲ ਕੀਤੇ ਜਾਣ ਵਾਲੇ ਡੇਟਾ ਨੂੰ ਚੁਣੋ, ਇਨਸਰਟ ਟੈਬ, ਟੇਬਲ ਗਰੁੱਪ ਵਿੱਚ ਸਵਿੱਚ ਕਰੋ, ਅਤੇ <ਤੇ ਕਲਿੱਕ ਕਰੋ। 4>PivotTable ਬਟਨ।
2. PivotTable ਬਣਾਓ ਡਾਇਲਾਗ ਵਿੱਚ, ਚੁਣੋ ਕਿ ਕੀ ਤੁਹਾਡੀ ਧਰੁਵੀ ਸਾਰਣੀ ਨੂੰ ਨਵੀਂ ਵਰਕਸ਼ੀਟ ਵਿੱਚ ਰੱਖਣਾ ਹੈ ਜਾਂ ਮੌਜੂਦਾ ਵਰਕਸ਼ੀਟ ਵਿੱਚ, ਅਤੇ ਸ਼ਾਮਲ ਕਰਨਾ ਯਕੀਨੀ ਬਣਾਓ। ਇਸ ਡੇਟਾ ਨੂੰ ਡੇਟਾ ਮਾਡਲ ਚੈਕਬਾਕਸ ਵਿੱਚ।

ਜੇ ਤੁਸੀਂ ਚਾਹੋ ਤਾਂ ਤੁਸੀਂ ਆਪਣੀ ਵੱਖਰੀ ਗਿਣਤੀ ਨੂੰ ਇੱਕ ਕਸਟਮ ਨਾਮ ਵੀ ਦੇ ਸਕਦੇ ਹੋ।

ਹੋ ਗਿਆ! ਨਵੀਂ ਬਣਾਈ ਗਈ ਧਰੁਵੀ ਸਾਰਣੀ ਵੱਖਰੀ ਗਿਣਤੀ ਨੂੰ ਪ੍ਰਦਰਸ਼ਿਤ ਕਰੇਗੀ ਜਿਵੇਂ ਕਿ ਇਸ ਭਾਗ ਵਿੱਚ ਪਹਿਲੇ ਸਕ੍ਰੀਨਸ਼ੌਟ ਵਿੱਚ ਦਿਖਾਇਆ ਗਿਆ ਹੈ।

ਸੁਝਾਅ। ਆਪਣੇ ਸਰੋਤ ਡੇਟਾ ਨੂੰ ਅੱਪਡੇਟ ਕਰਨ ਤੋਂ ਬਾਅਦ, ਵੱਖਰੀ ਗਿਣਤੀ ਨੂੰ ਅੱਪ ਟੂ ਡੇਟ ਲਿਆਉਣ ਲਈ PivotTable ਨੂੰ ਅੱਪਡੇਟ ਕਰਨਾ ਯਾਦ ਰੱਖੋ। ਇੱਕ ਧਰੁਵੀ ਸਾਰਣੀ ਨੂੰ ਤਾਜ਼ਾ ਕਰਨ ਲਈ, ਡੇਟਾ ਸਮੂਹ ਵਿੱਚ, ਵਿਸ਼ਲੇਸ਼ਣ ਟੈਬ 'ਤੇ ਰਿਫ੍ਰੈਸ਼ ਕਰੋ ਬਟਨ 'ਤੇ ਕਲਿੱਕ ਕਰੋ।

ਤੁਸੀਂ ਇਸ ਤਰ੍ਹਾਂ ਗਿਣਦੇ ਹੋ ਐਕਸਲ ਵਿੱਚ ਵੱਖਰੇ ਅਤੇ ਵਿਲੱਖਣ ਮੁੱਲ। ਜੇਕਰ ਕੋਈ ਵਿਅਕਤੀ ਇਸ ਟਿਊਟੋਰਿਅਲ ਵਿੱਚ ਦੱਸੇ ਗਏ ਫਾਰਮੂਲਿਆਂ ਨੂੰ ਨੇੜਿਓਂ ਦੇਖਣਾ ਚਾਹੁੰਦਾ ਹੈ, ਤਾਂ ਤੁਹਾਡਾ ਨਮੂਨਾ ਐਕਸਲ ਕਾਉਂਟ ਯੂਨੀਕ ਵਰਕਬੁੱਕ ਡਾਊਨਲੋਡ ਕਰਨ ਲਈ ਸਵਾਗਤ ਹੈ।

ਮੈਂ ਪੜ੍ਹਨ ਲਈ ਤੁਹਾਡਾ ਧੰਨਵਾਦ ਕਰਦਾ ਹਾਂ ਅਤੇ ਅਗਲੇ ਹਫ਼ਤੇ ਤੁਹਾਨੂੰ ਦੁਬਾਰਾ ਮਿਲਣ ਦੀ ਉਮੀਦ ਕਰਦਾ ਹਾਂ। ਅਗਲੇ ਲੇਖ ਵਿੱਚ, ਅਸੀਂ ਐਕਸਲ ਵਿੱਚ ਵਿਲੱਖਣ ਮੁੱਲਾਂ ਨੂੰ ਲੱਭਣ, ਫਿਲਟਰ ਕਰਨ, ਐਕਸਟਰੈਕਟ ਕਰਨ ਅਤੇ ਹਾਈਲਾਈਟ ਕਰਨ ਦੇ ਕਈ ਤਰੀਕਿਆਂ ਬਾਰੇ ਚਰਚਾ ਕਰਨ ਜਾ ਰਹੇ ਹਾਂ। ਕ੍ਰਿਪਾ ਕਰਕੇ