या ट्युटोरियलमध्ये, तुम्ही एक्सेलमध्ये फॉर्म्युलासह युनिक व्हॅल्यूज कसे मोजायचे आणि पिव्होट टेबलमध्ये वेगळ्या व्हॅल्यूजची स्वयंचलित गणना कशी करायची ते शिकाल. अनन्य नावे, मजकूर, संख्या, केस-संवेदनशील अद्वितीय मूल्ये आणि बरेच काही मोजण्यासाठी आम्ही अनेक सूत्र उदाहरणांवर देखील चर्चा करू.

एक्सेलमध्ये मोठ्या डेटासेटसह कार्य करताना, तुम्हाला अनेकदा तेथे किती डुप्लिकेट आणि युनिक मूल्ये आहेत ते जाणून घ्या. आणि काहीवेळा, तुम्हाला फक्त विशिष्ट (भिन्न) मूल्ये मोजायची असतील.

तुम्ही या ब्लॉगला नियमितपणे भेट देत असाल, तर तुम्हाला डुप्लिकेट मोजण्यासाठी एक्सेल सूत्र आधीच माहित आहे. आणि आज, आपण एक्सेलमध्ये अद्वितीय मूल्ये मोजण्याचे विविध मार्ग शोधणार आहोत. परंतु स्पष्टतेसाठी, प्रथम संज्ञा परिभाषित करूया.

• अद्वितीय मूल्ये - ही अशी मूल्ये आहेत जी सूचीमध्ये फक्त एकदाच दिसतात.
• स्पष्ट मूल्ये - ही सूचीमधील सर्व भिन्न मूल्ये आहेत, उदा. अद्वितीय मूल्ये आणि डुप्लिकेट मूल्यांची पहिली घटना.

खालील स्क्रीनशॉट फरक दर्शवितो:

आणि आता, सूत्रे आणि पिव्होटटेबल वैशिष्ट्यांचा वापर करून तुम्ही Excel मध्ये अद्वितीय आणि वेगळी मूल्ये कशी मोजू शकता ते पाहू.

एक्सेलमध्ये अद्वितीय मूल्ये कशी मोजायची<12

येथे एक सामान्य कार्य आहे जे सर्व एक्सेल वापरकर्त्यांना वेळोवेळी पार पाडावे लागते. तुमच्याकडे डेटाची एक सूची आहे आणि तुम्हाला त्यातील अद्वितीय मूल्यांची संख्या शोधण्याची आवश्यकता आहेसंपर्कात रहा!

यादी तुम्ही ते कसे करता? तुम्हाला वाटेल त्यापेक्षा सोपे :) खाली तुम्हाला वेगवेगळ्या प्रकारची अनन्य मूल्ये मोजण्यासाठी काही सूत्रे सापडतील.

स्तंभात अद्वितीय मूल्ये मोजा

समजा तुमच्या Excel मध्ये नावांचा स्तंभ आहे. वर्कशीट, आणि तुम्हाला त्या स्तंभातील अद्वितीय नावे मोजण्याची आवश्यकता आहे. उपाय म्हणजे SUM फंक्शन IF आणि COUNTIF च्या संयोजनात वापरणे:

टीप . हे अॅरे फॉर्म्युला आहे, त्यामुळे ते पूर्ण करण्यासाठी Ctrl + Shift + Enter दाबण्याची खात्री करा. एकदा तुम्ही हे केल्यावर, Excel खालील स्क्रीनशॉटप्रमाणे {कर्ली ब्रेसेस} मध्ये सूत्र आपोआप संलग्न करेल. कोणत्याही परिस्थितीत तुम्ही कुरळे ब्रेसेस मॅन्युअली टाइप करू नयेत, ते काम करणार नाही.

या उदाहरणात, आम्ही A2:A10 श्रेणीमध्ये अद्वितीय नावे मोजत आहोत, त्यामुळे आमचे सूत्र खालील आकार घेते:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

पुढे या ट्युटोरियलमध्ये, आपण विविध प्रकारच्या युनिक व्हॅल्यूज मोजण्यासाठी इतर मूठभर सूत्रांची चर्चा करणार आहोत. आणि ती सर्व सूत्रे बेसिक एक्सेल युनिक व्हॅल्यूज फॉर्म्युलाची भिन्नता असल्यामुळे, वरील सूत्र तोडण्यात अर्थ आहे, जेणेकरून ते कसे कार्य करते ते तुम्ही पूर्णपणे समजून घेऊ शकता आणि तुमच्या डेटासाठी त्यात बदल करू शकता. जर एखाद्याला तांत्रिक गोष्टींमध्ये स्वारस्य नसेल, तर तुम्ही थेट पुढील सूत्र उदाहरणाकडे जाऊ शकता.

एक्सेल अद्वितीय मूल्यांची गणना कशी करते हे सूत्र कसे कार्य करते

तुम्ही पाहिल्याप्रमाणे, आमच्या अद्वितीय मध्ये 3 भिन्न कार्ये वापरली जातात मूल्य सूत्र - SUM, IFआणि COUNTIF. आतून बाहेरून पाहता, प्रत्येक फंक्शन काय करते ते येथे आहे:

• COUNTIF फंक्शन निर्दिष्ट श्रेणीमध्ये प्रत्येक वैयक्तिक मूल्य किती वेळा दिसले याची गणना करते.

  या उदाहरणात, COUNTIF(A2:A10,A2:A10) अॅरे {1;2;2;1;2;2;2;1;2} परत करतो.

• IF फंक्शन COUNTIF द्वारे मिळवलेल्या अॅरेमधील प्रत्येक मूल्याचे मूल्यांकन करते, सर्व 1 (अद्वितीय मूल्ये) ठेवते आणि इतर सर्व मूल्यांना शून्याने बदलते .

  तर, फंक्शन IF(COUNTIF(A2:A10,A2:A10)=1,1,0) IF(1;2;2;1;2;2;2;1;2) = 1,1,0, बनते जे अॅरे {1;0;0;1;0;0;0;1;0} मध्ये बदलते जेथे 1 एक अद्वितीय मूल्य आहे आणि 0 डुप्लिकेट मूल्य आहे.

• शेवटी, SUM फंक्शन IF द्वारे परत केलेल्या अॅरेमधील मूल्ये जोडते आणि अद्वितीय मूल्यांची एकूण संख्या आउटपुट करते, जे आम्हाला हवे होते.

टीप . तुमच्या एक्सेल युनिक व्हॅल्यूज फॉर्म्युलाचा विशिष्ट भाग कशासाठी मूल्यमापन करतो हे पाहण्यासाठी, फॉर्म्युला बारमधील तो भाग निवडा आणि F9 की दाबा.

Excel मध्ये अद्वितीय मजकूर मूल्ये मोजा

तुमच्या Excel सूचीमध्ये अंकीय आणि मजकूर दोन्ही मूल्ये असतील आणि तुम्हाला फक्त अद्वितीय मजकूर मूल्ये मोजायची असतील, तर वर चर्चा केलेल्या अॅरे सूत्रामध्ये ISTEXT फंक्शन जोडा:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

तुम्हाला माहिती आहे की, एक्सेल ISTEXT फंक्शन जर मूल्यमापन केलेले मूल्य मजकूर असेल तर TRUE मिळवते, अन्यथा FALSE. अ‍ॅरे फॉर्म्युलामध्ये तारांकन (*) AND ऑपरेटर म्हणून काम करत असल्याने, IF फंक्शन फक्त 1 मिळवते जर एखादे मूल्य मजकूर आणि अद्वितीय दोन्ही असेल, अन्यथा 0. आणि SUM फंक्शनने सर्व 1 जोडल्यानंतर, तुम्हाला विशिष्ट मजकूर मूल्यांची संख्या मिळेल.श्रेणी.

अ‍ॅरे फॉर्म्युला अचूकपणे एंटर करण्यासाठी Ctrl + Shift + Enter दाबायला विसरू नका, आणि तुम्हाला यासारखाच परिणाम मिळेल:

जसे तुम्ही वरील स्क्रीनशॉटमध्ये पाहू शकता, फॉर्म्युला रिक्त सेल, संख्या, सत्य आणि असत्य ची तार्किक मूल्ये आणि त्रुटी वगळता अद्वितीय मजकूर मूल्यांची एकूण संख्या मिळवते.

एक्सेलमध्ये अद्वितीय अंकीय मूल्ये मोजा

डेटा सूचीमध्ये अद्वितीय संख्या मोजण्यासाठी, अॅरे फॉर्म्युला वापरा जसे की आम्ही नुकतीच युनिक टेक्स्ट व्हॅल्यू मोजण्यासाठी वापरले आहे, फक्त फरक आहे की तुम्ही तुमच्या युनिक व्हॅल्यूज फॉर्म्युलामध्ये ISTEXT ऐवजी ISNUMBER एम्बेड करता:<3

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

टीप. Microsoft Excel तारखा आणि वेळा अनुक्रमांक म्हणून संग्रहित करत असल्याने, ते देखील मोजले जातात.

Excel मध्ये केस-संवेदनशील अद्वितीय मूल्ये मोजा

तुमच्या टेबलमध्ये केस-संवेदी डेटा असल्यास, मोजण्याचा सर्वात सोपा मार्ग युनिक व्हॅल्यूज डुप्लिकेट आणि युनिक आयटम ओळखण्यासाठी खालील अॅरे फॉर्म्युलासह हेल्पर कॉलम तयार करेल:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

आणि नंतर, युनिक व्हॅल्यू मोजण्यासाठी एक साधे COUNTIF फंक्शन वापरा:

=COUNTIF(B2:B10, "unique")

एक्सेलमधील भिन्न मूल्यांची गणना करा (अद्वितीय आणि प्रथम डुप्लिकेट घटना)

सूचीमधील भिन्न मूल्यांची गणना करण्यासाठी, खालील वापरा सूत्र:

लक्षात ठेवा, हे अॅरे फॉर्म्युला आहे आणि म्हणून तुम्ही Ctrl + Shift + Enter दाबले पाहिजे. नेहमीच्या एंटरऐवजी शॉर्टकटकीस्ट्रोक.

वैकल्पिकपणे, तुम्ही SUMPRODUCT फंक्शन वापरू शकता आणि एंटर की दाबून नेहमीच्या पद्धतीने सूत्र पूर्ण करू शकता:

उदाहरणार्थ, श्रेणी A2:A10 मधील भिन्न मूल्ये मोजण्यासाठी, तुम्ही यापैकी एकासह जाऊ शकता:

=SUM(1/COUNTIF(A2:A10,A2:A10))

किंवा

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

एक्सेल वेगळे सूत्र कसे कार्य करते

तुम्हाला आधीच माहित आहे की, प्रत्येक वैयक्तिक मूल्य किती वेळा दिसून येते हे शोधण्यासाठी आम्ही COUNTIF फंक्शन वापरतो निर्दिष्ट श्रेणी. वरील उदाहरणात, COUNTIF फंक्शनचा परिणाम खालील अॅरे आहे: {2;2;3;1;2;2;3;1;3} .

त्यानंतर, अनेक डिव्हिजन ऑपरेशन्स केल्या जातात, जेथे अॅरेचे प्रत्येक मूल्य 1 सह भाजक म्हणून वापरले जाते लाभांश हे सर्व डुप्लिकेट मूल्ये डुप्लिकेट घटनांच्या संख्येशी संबंधित अपूर्णांकात बदलते. उदाहरणार्थ, सूचीमध्ये मूल्य 2 वेळा दिसल्यास, ते 0.5 (1/2=0.5) च्या मूल्यासह अॅरेमध्ये 2 आयटम व्युत्पन्न करते. आणि जर एखादे मूल्य 3 वेळा दिसले, तर ते 0.3(3) च्या मूल्यासह अॅरेमध्ये 3 आयटम तयार करते. आमच्या उदाहरणात, 1/COUNTIF(A2:A10,A2:A10)) चा परिणाम अॅरे {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} आहे.

आतापर्यंत फारसा अर्थ नाही का? कारण आम्ही अद्याप SUM / SUMPRODUCT फंक्शन लागू केलेले नाही. जेव्हा यापैकी एक फंक्शन अॅरेमधील मूल्ये जोडते, तेव्हा प्रत्येक वैयक्तिक आयटमसाठी सर्व अपूर्णांक संख्यांची बेरीज नेहमी 1 मिळते, सूचीमध्ये त्या आयटमच्या कितीही घटना अस्तित्वात असल्या तरीही. आणिकारण सर्व अनन्य मूल्ये 1 च्या (1/1=1) म्हणून अॅरेमध्ये दिसतात, सूत्राद्वारे मिळालेला अंतिम परिणाम म्हणजे सूचीतील सर्व भिन्न मूल्यांची एकूण संख्या.

वेगवेगळ्या मूल्यांची गणना करण्यासाठी सूत्रे प्रकार

एक्सेलमध्ये युनिक व्हॅल्यूज गणनेच्या बाबतीत, तुम्ही एक्सेलच्या बेसिक व्हॅल्यूजच्या फरकाचा वापर करू शकता. 0>कृपया लक्षात ठेवा की खालील सर्व सूत्रे अ‍ॅरे सूत्रे आहेत आणि त्यासाठी Ctrl + Shift + Enter दाबणे आवश्यक आहे.

रिक्त सेलकडे दुर्लक्ष करून भिन्न मूल्ये मोजा

ज्या स्तंभात तुम्हाला वेगळी मूल्ये मोजायची असतील तर रिक्त सेल असू शकतात, तुम्ही IF फंक्शन जोडले पाहिजे जे रिक्त स्थानांसाठी निर्दिष्ट श्रेणी तपासेल (वर चर्चा केलेले मूलभूत एक्सेल वेगळे सूत्र या प्रकरणात #DIV/0 त्रुटी देईल):

उदाहरणार्थ, श्रेणी A2:A10 मध्ये भिन्न मूल्ये मोजण्यासाठी, वापरा खालील अॅरे सूत्र :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

विशिष्ट मजकूर मूल्ये मोजण्यासाठी सूत्र

स्तंभातील भिन्न मजकूर मूल्ये मोजण्यासाठी, आम्ही वापरणार आहोत रिकाम्या सेल वगळण्यासाठी आम्‍ही नुकताच वापरला आहे तोच दृष्टीकोन.

तुम्ही सहज अंदाज लावू शकता, आम्‍ही ISTEXT फंक्‍शनला आमच्या Excel गणनेच्‍या वेगळ्या फॉर्म्युलामध्‍ये एम्बेड करू:

आणि हे एक वास्तविक जीवन आहेसूत्र उदाहरण:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

विशिष्ट संख्या मोजण्यासाठी सूत्र

भिन्न संख्यात्मक मूल्ये (संख्या, तारखा आणि वेळा) मोजण्यासाठी, ISNUMBER फंक्शन वापरा:

उदाहरणार्थ, सर्व भिन्न संख्या मोजण्यासाठी श्रेणी A2:A10 मध्ये, खालील सूत्र वापरा:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Excel मध्ये केस-संवेदनशील भिन्न मूल्यांची गणना करा

तसेच केस-संवेदनशील अद्वितीय मूल्ये मोजण्यासाठी, सर्वात सोपा मार्ग केस-संवेदनशील भिन्न मूल्ये मोजणे म्हणजे प्रथम डुप्लिकेट घटनांसह अद्वितीय मूल्ये ओळखणार्‍या अॅरे सूत्रासह एक सहायक स्तंभ जोडणे. सूत्र मूलत: आम्ही केस-सेन्सिटिव्ह अनन्य मूल्ये मोजण्यासाठी वापरलेल्या सारखेच आहे, सेल संदर्भातील एका लहान बदलाने खूप फरक पडतो:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

तुम्हाला आठवत असेल, एक्सेलमधील सर्व अॅरे सूत्रांना Ctrl + Shift + Enter दाबणे आवश्यक आहे.

वरील सूत्र पूर्ण झाल्यानंतर, तुम्ही यासारख्या नेहमीच्या COUNTIF सूत्रासह "भिन्न" मूल्ये मोजू शकता:

=COUNTIF(B2:B10, "distinct") <3

तुम्ही तुमच्या वर्कशीटमध्ये मदतनीस स्तंभ जोडू शकत नसल्यास, तुम्ही केस-संवेदनशील भिन्न मूल्ये मोजण्यासाठी खालील जटिल अॅरे सूत्र वापरू शकता. अतिरिक्त स्तंभ तयार करणे:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

Excel मध्ये अद्वितीय आणि वेगळ्या पंक्ती मोजा

Excel मध्ये अद्वितीय/विशिष्ट पंक्ती मोजणे हे अद्वितीय आणि वेगळे मूल्य मोजण्यासारखे आहे, फक्त फरककी तुम्ही COUNTIF ऐवजी COUNTIFS फंक्शन वापरता, जे तुम्हाला अनन्य मूल्ये तपासण्यासाठी अनेक स्तंभ निर्दिष्ट करू देते.

उदाहरणार्थ, स्तंभ A (प्रथम नाव) आणि B मधील मूल्यांवर आधारित अद्वितीय किंवा वेगळी नावे मोजण्यासाठी (आडनाव), खालीलपैकी एक सूत्र वापरा:

अद्वितीय पंक्ती मोजण्यासाठी सूत्र:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

सूत्र वेगळे मोजण्यासाठी पंक्ती:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

साहजिकच, तुम्ही केवळ दोन स्तंभांवर आधारित अद्वितीय पंक्ती मोजण्यापुरते मर्यादित नाही, Excel COUNTIFS फंक्शन प्रक्रिया करू शकते 127 श्रेणी/निकष जोड्यांपर्यंत.

PivotTable वापरून Excel मध्ये भिन्न मूल्ये मोजा

Excel 2013 आणि Excel 2016 च्या नवीनतम आवृत्त्या आहेत विशेष वैशिष्ट्य जे मुख्य सारणीमध्ये भिन्न मूल्ये स्वयंचलितपणे मोजण्याची परवानगी देते. खालील स्क्रीनशॉट एक्सेल डिस्टिंक्ट काउंट कसा दिसतो याची कल्पना देतो:

विशिष्ट कॉलमसाठी विशिष्ट गणनेसह पिव्होट टेबल तयार करण्यासाठी, खालील पायऱ्या करा.

1. पिव्होट टेबलमध्ये समाविष्ट करण्यासाठी डेटा निवडा, इन्सर्ट टॅब, टेबल्स ग्रुपवर स्विच करा आणि <वर क्लिक करा 4>PivotTable बटण.
2. PivotTable तयार करा संवादामध्ये, तुमची मुख्य सारणी नवीन किंवा विद्यमान वर्कशीटमध्ये ठेवायची की नाही ते निवडा आणि जोडा निवडण्याचे सुनिश्चित करा हा डेटा डेटा मॉडेल चेकबॉक्समध्ये.

तुम्ही इच्छित असल्यास तुमच्या विशिष्ट गणाला एक सानुकूल नाव देखील देऊ शकता.

पूर्ण! नव्याने तयार केलेले पिव्होट टेबल या विभागातील पहिल्या स्क्रीनशॉटमध्ये दाखवल्याप्रमाणे वेगळी संख्या प्रदर्शित करेल.

टीप. तुमचा स्रोत डेटा अद्यतनित केल्यानंतर, विशिष्ट गणना अद्ययावत करण्यासाठी PivotTable अद्यतनित करण्याचे लक्षात ठेवा. मुख्य सारणी रीफ्रेश करण्यासाठी, फक्त डेटा गटातील विश्लेषण टॅबवरील रिफ्रेश बटणावर क्लिक करा.

तुम्ही अशा प्रकारे मोजता. एक्सेलमधील वेगळे आणि अद्वितीय मूल्ये. जर एखाद्याला या ट्युटोरियलमध्ये चर्चा केलेली सूत्रे जवळून पाहायची असतील तर, एक्सेल काउंट युनिक वर्कबुकचा नमुना डाउनलोड करण्यासाठी तुमचे स्वागत आहे.

मी वाचल्याबद्दल धन्यवाद आणि पुढच्या आठवड्यात पुन्हा भेटण्याची आशा करतो. पुढील लेखात, आपण एक्सेलमधील अद्वितीय मूल्ये शोधण्यासाठी, फिल्टर करण्यासाठी, काढण्यासाठी आणि हायलाइट करण्याच्या विविध मार्गांवर चर्चा करणार आहोत. कृपया