În acest tutorial, veți învăța cum să numărați valorile unice în Excel cu ajutorul formulelor și cum să obțineți o numărătoare automată a valorilor distincte într-un tabel pivot. De asemenea, vom discuta o serie de exemple de formule pentru numărarea numelor unice, a textelor, a numerelor, a valorilor unice cu majuscule și a altora.

Atunci când lucrați cu un set de date de mari dimensiuni în Excel, este posibil să aveți adesea nevoie să știți câte duplicat și unic Și, uneori, este posibil să doriți să numărați doar valorile distinct (diferite) valori.

Dacă ați vizitat acest blog în mod regulat, cunoașteți deja formula Excel pentru a număra duplicatele. Iar astăzi vom explora diferite modalități de a număra valorile unice în Excel. Dar, pentru claritate, să definim mai întâi termenii.

• Unic valori - acestea sunt valorile care apar o singură dată în listă.
• Distinct valori - acestea sunt toate valorile diferite din listă, adică valorile unice plus prima apariție a valorilor duplicate.

Următoarea captură de ecran demonstrează diferența:

Și acum, să vedem cum puteți număra valorile unice și distincte în Excel folosind formule și funcții PivotTable.

Cum să numărați valorile unice în Excel

Iată o sarcină comună pe care toți utilizatorii Excel trebuie să o îndeplinească din când în când. Aveți o listă de date și trebuie să aflați numărul de valori unice din acea listă. Cum faceți acest lucru? Mai ușor decât credeți :) Mai jos veți găsi câteva formule pentru a număra valorile unice de diferite tipuri.

Numără valorile unice dintr-o coloană

Să presupunem că aveți o coloană de nume în foaia de calcul Excel și că trebuie să numărați numele unice din acea coloană. Soluția este să utilizați funcția SUM în combinație cu IF și COUNTIF:

Notă Aceasta este o formulă de tip array, așa că nu uitați să apăsați Ctrl + Shift + Enter pentru a o completa. Odată ce ați făcut acest lucru, Excel va include automat formula în {între paranteze curbe}, ca în captura de ecran de mai jos. În niciun caz nu trebuie să introduceți manual parantezele curbe, deoarece nu va funcționa.

În acest exemplu, numărăm numele unice din intervalul A2:A10, astfel încât formula noastră are următoarea formă:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Mai departe în acest tutorial, vom discuta despre o mână de alte formule pentru a număra valori unice de diferite tipuri. Și pentru că toate aceste formule sunt variații ale formulei de bază Excel pentru valori unice, are sens să defalcăm formula de mai sus, astfel încât să puteți înțelege pe deplin cum funcționează și să o adaptați pentru datele dvs. Dacă cineva nu este interesat de detalii tehnice, puteți trece direct laurmătorul exemplu de formulă.

Cum funcționează formula Excel de numărare a valorilor unice

După cum vedeți, în formula noastră de valori unice sunt utilizate 3 funcții diferite - SUM, IF și COUNTIF. Privind din interior, iată ce face fiecare funcție:

• Funcția COUNTIF numără de câte ori apare fiecare valoare individuală în intervalul specificat.

  În acest exemplu, COUNTIF(A2:A10,A2:A10) returnează matricea {1;2;2;1;2;2;2;1;2} .

• Funcția IF evaluează fiecare valoare din matricea returnată de COUNTIF, păstrează toate valorile 1 (valori unice) și înlocuiește toate celelalte valori cu zerouri.

  Deci, funcția IF(COUNTIF(A2:A10,A2:A10)=1,1,0) devine IF(1;2;2;2;1;2;2;2;2;1;2) = 1,1,0, care se transformă în matricea {1;0;0;1;0;0;0;1;0} unde 1 este o valoare unică și 0 este o valoare duplicată.

• În cele din urmă, funcția SUM însumează valorile din matricea returnată de IF și afișează numărul total de valori unice, ceea ce este exact ceea ce am dorit.

Sfat. Pentru a vedea la ce se evaluează o anumită parte a formulei Excel cu valori unice, selectați partea respectivă în bara de formule și apăsați tasta F9.

Numărați valorile text unice în Excel

Dacă lista Excel conține atât valori numerice, cât și valori text și doriți să numărați numai valorile text unice, adăugați funcția ISTEXT la formula de matrice discutată mai sus:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

După cum știți, funcția Excel ISTEXT returnează TRUE dacă o valoare evaluată este text, FALSE în caz contrar. Deoarece asterisc (*) funcționează ca operator AND în formulele de matrice, funcția IF returnează 1 numai dacă o valoare este atât text, cât și unică, 0 în caz contrar. Și după ce funcția SUM însumează toți cei 1, veți obține un număr de valori text unice în intervalul specificat.

Nu uitați să apăsați Ctrl + Shift + Enter pentru a introduce corect formula de matrice și veți obține un rezultat similar cu acesta:

După cum puteți vedea în captura de ecran de mai sus, formula returnează numărul total de valori text unice, excluzând celulele goale, numerele, valorile logice TRUE și FALSE și erorile.

Numărați valorile numerice unice în Excel

Pentru a număra numerele unice dintr-o listă de date, utilizați o formulă de matrice, așa cum tocmai am folosit pentru numărarea valorilor text unice, cu singura diferență că în formula valorilor unice includeți ISNUMBER în loc de ISTEXT:

=SUMA(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Notă: Deoarece Microsoft Excel stochează datele și orele ca numere de serie, acestea sunt, de asemenea, numărate.

Numărați valorile unice sensibile la majuscule și minuscule în Excel

Dacă tabelul dvs. conține date sensibile la majuscule și minuscule, cel mai simplu mod de a număra valorile unice ar fi crearea unei coloane ajutătoare cu următoarea formulă de matrice pentru a identifica elementele duplicate și unice:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1, "Unic", "Dublu")

Apoi, utilizați o funcție COUNTIF simplă pentru a număra valorile unice:

=COUNTIF(B2:B10, "unique")

Numărați valorile distincte în Excel (apariții unice și primele duplicate)

Pentru a obține o numărătoare a valorilor distincte dintr-o listă, utilizați următoarea formulă:

Nu uitați că este o formulă de matrice și, prin urmare, trebuie să apăsați comanda rapidă Ctrl + Shift + Enter în loc de tasta Enter obișnuită.

Alternativ, puteți utiliza funcția SUMPRODUCT și puteți completa formula în mod obișnuit, apăsând tasta Enter:

De exemplu, pentru a număra valorile distincte din intervalul A2:A10, puteți folosi oricare dintre următoarele variante:

=SUMA(1/COUNTIF(A2:A10,A2:A10))

Sau

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Cum funcționează formula Excel distinctă

După cum știți deja, folosim funcția COUNTIF pentru a afla de câte ori apare fiecare valoare individuală în intervalul specificat. În exemplul de mai sus, rezultatul funcției COUNTIF este următoarea matrice: {2;2;3;1;2;2;3;1;3} .

După aceea, se efectuează o serie de operații de împărțire, în care fiecare valoare din tablou este utilizată ca divizor, cu 1 ca dividend. Acest lucru transformă toate valorile duplicate în numere fracționare corespunzătoare numărului de apariții duplicate. De exemplu, dacă o valoare apare de 2 ori în listă, aceasta generează 2 elemente în tablou cu valoarea 0,5 (1/2=0,5). Iar dacă o valoare apare de 3 ori, aceastaproduce 3 elemente în matrice cu valoarea 0.3(3). În exemplul nostru, rezultatul operației 1/COUNTIF(A2:A10,A2:A10)) este matricea {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Nu are prea mult sens până acum? Asta pentru că nu am aplicat încă funcția SUM / SUMPRODUCT. Atunci când una dintre aceste funcții însumează valorile din tablou, suma tuturor numerelor fracționare pentru fiecare element în parte dă întotdeauna 1, indiferent de câte apariții ale acelui element există în listă. Și pentru că toate valorile unice apar în tablou ca 1 (1/1=1), rezultatul final returnat de funcțiaeste numărul total al tuturor valorilor diferite din listă.

Formule pentru a număra valori distincte de diferite tipuri

Ca și în cazul numărării valorilor unice în Excel, puteți utiliza variații ale formulei de bază Excel count distinct pentru a gestiona tipuri de valori specifice, cum ar fi numere, text și valori care țin cont de majuscule și minuscule.

Vă rugăm să rețineți că toate formulele de mai jos sunt formule de matrice și necesită apăsarea Ctrl + Shift + Enter .

Numără valorile distincte ignorând celulele goale

Dacă o coloană în care doriți să numărați valorile distincte ar putea conține celule goale, trebuie să adăugați o funcție IF care va verifica intervalul specificat pentru spații goale (formula de bază Excel distinctă discutată mai sus ar returna eroarea #DIV/0 în acest caz):

De exemplu, pentru a număra valorile distincte din intervalul A2:A10, utilizați următoarea formulă de matrice:

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0)))

Formula pentru a număra valorile distincte ale textului

Pentru a număra valorile distincte ale textului dintr-o coloană, vom folosi aceeași abordare pe care tocmai am folosit-o pentru a exclude celulele goale.

După cum puteți ghici cu ușurință, vom încorpora pur și simplu funcția ISTEXT în formula noastră distinctă de numărare din Excel:

Și iată un exemplu de formulă din viața reală:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),"")))

Formula de numărare a numerelor distincte

Pentru a număra valori numerice distincte (numere, date și ore), utilizați funcția ISNUMBER:

De exemplu, pentru a număra toate numerele diferite din intervalul A2:A10, utilizați următoarea formulă:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),"")))

Numărați valorile distincte sensibile la majuscule și minuscule în Excel

În mod similar cu numărarea valorilor unice cu majuscule și minuscule, cel mai simplu mod de a număra valorile distincte cu majuscule și minuscule este de a adăuga o coloană de ajutor cu formula de matrice care identifică valorile unice, inclusiv primele apariții duplicate. Formula este practic aceeași cu cea pe care am folosit-o pentru a număra valorile unice cu majuscule și minuscule, cu o mică schimbare într-o referință de celulă care face o mare diferență:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1, "Distinct","")

După cum vă amintiți, toate formulele de matrice din Excel necesită apăsarea Ctrl + Shift + Enter .

După ce formula de mai sus este finalizată, puteți număra valorile "distincte" cu o formulă COUNTIF obișnuită ca aceasta:

=COUNTIF(B2:B10, "distinct")

Dacă nu există nicio modalitate de a adăuga o coloană de ajutor la foaia de calcul, puteți utiliza următorul complex formula matricei pentru a număra valorile distincte care țin cont de majuscule și minuscule fără a crea o coloană suplimentară:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0), 0)))

Numărați rândurile unice și distincte în Excel

Numărarea rândurilor unice / distincte în Excel este asemănătoare cu numărarea valorilor unice și distincte, cu singura diferență că se utilizează funcția COUNTIFS în loc de COUNTIF, care vă permite să specificați mai multe coloane pentru a verifica dacă există valori unice.

De exemplu, pentru a număra numele unice sau distincte pe baza valorilor din coloanele A (First Name) și B (Last Name), utilizați una dintre următoarele formule:

Formulă pentru a număra rândurile unice:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Formulă pentru a număra rândurile distincte:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Firește, nu sunteți limitat la numărarea rândurilor unice pe baza a doar două coloane, funcția Excel COUNTIFS poate procesa până la 127 de perechi interval/criteriu.

Numărați valorile distincte în Excel utilizând un PivotTable

Cele mai recente versiuni ale Excel 2013 și Excel 2016 dispun de o funcție specială care permite numărarea automată a valorilor distincte într-un tabel pivot. Următoarea captură de ecran oferă o idee despre modul în care Excel Număr distinct se pare că:

Pentru a crea un tabel pivot cu numărul distinct pentru o anumită coloană, efectuați următorii pași.

1. Selectați datele care urmează să fie incluse într-un tabel pivot, treceți la Introduceți tab, Tabele și faceți clic pe butonul PivotTable buton.
2. În Creați tabelul pivotant alegeți dacă doriți să plasați tabelul pivot într-o foaie de lucru nouă sau existentă și nu uitați să selectați opțiunea Adăugați aceste date la modelul de date caseta de selectare.

De asemenea, dacă doriți, puteți da un nume personalizat pentru Distinct Count.

Tabelul pivot nou creat va afișa numărul distinct, așa cum se arată în prima captură de ecran din această secțiune.

Sfat: După ce ați actualizat datele sursă, nu uitați să actualizați tabelul pivot pentru a aduce la zi numărul distinct. Pentru a actualiza un tabel pivot, faceți clic pe butonul Reîmprospătare de pe butonul Analizați în fila Date grup.

Acesta este modul în care numărați valorile distincte și unice în Excel. Dacă cineva dorește să arunce o privire mai atentă asupra formulelor discutate în acest tutorial, este binevenit să descarce exemplul de registru de lucru Excel Count Unique.

Vă mulțumesc pentru lectură și sper să ne revedem săptămâna viitoare. În articolul următor, vom discuta despre diverse modalități de a găsi, filtra, extrage și evidenția valori unice în Excel. Vă rugăm să rămâneți pe recepție!