Tutorial honetan, Excel-en balio esklusiboak nola zenbatzen ikasiko duzu formulekin, eta nola lortu balio desberdinen zenbaketa automatikoa taula dinamiko batean. Izen esklusiboak, testuak, zenbakiak, maiuskulak eta minuskulak bereizten dituzten balio esklusiboak eta gehiago zenbatzeko formula-adibide batzuk ere aztertuko ditugu.

Excel-en datu-multzo handi batekin lan egiten duzunean, baliteke sarritan egin behar izatea. jakin zenbat bikoiztu eta bakar balio dauden. Eta batzuetan, baliteke bereizgarriak (desberdinak) balioak soilik zenbatu nahi izatea.

Blog hau ohiko oinarrizko moduan bisitatu baduzu, dagoeneko ezagutzen duzu bikoiztuak zenbatzeko Excel formula. Eta gaur, Excel-en balio bereziak zenbatzeko modu desberdinak aztertuko ditugu. Baina argitasunagatik, defini ditzagun terminoak lehenik.

• Balio bakarrak - zerrendan behin bakarrik agertzen diren balioak dira.
• Balio bereizgarriak - hauek guztiak zerrendako balio desberdinak dira, hau da, balio bakarrak gehi balio bikoiztuen lehen agerraldiak.

Ondoko pantaila-argazkiak aldea erakusten du:

Eta orain, ikus dezagun nola zenbatu ditzakezun balio bereziak eta bereiziak Excel-en formulak eta taula dinamikoaren funtzioak erabiliz.

Nola zenbatu ditzakezun balio bakarrak Excel-en

Hona hemen Excel erabiltzaile guztiek noizean behin egin behar duten zeregin arrunt bat. Datu-zerrenda bat duzu eta bertan dauden balio esklusiboen kopurua aurkitu behar duzuegon adi!

Zutabe batean balio bakarrak zenbatu

Demagun zure Excel-en izenen zutabe bat duzula. lan-orria, eta zutabe horretan izen bereziak zenbatu behar dituzu. Irtenbidea SUM funtzioa IF eta COUNTIF-ekin konbinatuta erabiltzea da:

Oharra . Hau array formula bat da, beraz, ziurtatu Ctrl + Shift + Sartu sakatu duzula osatzeko. Hori egin ondoren, Excel-ek automatikoki sartuko du formula {giltza kizkurren artean} beheko pantaila-argazkian bezala. Inola ere ez dituzu eskuz idatzi behar giltza kizkurrak, horrek ez du funtzionatuko.

Adibide honetan, A2:A10 barrutian izen esklusiboak zenbatzen ari gara, beraz, gure formulak forma hau hartzen du:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Tutorial honetan aurrerago, mota ezberdinetako balio bakarrak zenbatzeko beste formula batzuk eztabaidatuko ditugu. Eta formula horiek guztiak Excel oinarrizko balio esklusiboen formularen aldakuntzak direnez, zentzuzkoa da goiko formula haustea, nola funtzionatzen duen guztiz uler dezazun eta zure datuetarako doitzeko. Norbaiti ez bazaio teknifikazioak interesatzen, hurrengo formula adibidera joan zaitezke.

Nola funtzionatzen duen Excel balio esklusiboak zenbatzen dituen formula

Ikusten duzun bezala, 3 funtzio ezberdin erabiltzen dira gure bakarrean. balioen formula - SUM, IFeta COUNTIF. Barrutik begiratuta, hona hemen funtzio bakoitzak zer egiten duen:

• ZENBATU BATEN funtzioak balio indibidual bakoitza zenbat aldiz agertzen den zenbatzen du zehaztutako barrutian.

  Adibide honetan, COUNTIF(A2:A10,A2:A10) -k {1;2;2;1;2;2;2;1;2} array-a itzultzen du.

• IF funtzioak COUNTIF-ek itzultzen duen arrayko balio bakoitza ebaluatzen du, 1 guztiak gordetzen ditu (balio bakarrak) eta gainerako balio guztiak zeroekin ordezkatzen ditu. .

  Beraz, IF(COUNTIF(A2:A10,A2:A10)=1,1,0) funtzioa IF(1;2;2;1;2;2;2;1;2) = 1,1,0, bihurtzen da eta {1;0;0;1;0;0;0;1;0} array bihurtzen da non 1 balio bakarra den eta 0 balio bikoiztua den.

• Azkenik, SUM funtzioak IF-ek itzultzen dituen arrayko balioak batzen ditu eta balio esklusiboen kopuru osoa ateratzen du, hau da, guk nahi genuena.

Aholkua . Excel balio esklusiboen formularen zati zehatz batek zer balio duen ikusteko, hautatu zati hori formula-barran eta sakatu F9 tekla.

Testu-balio bakarrak zenbatu Excel-en

Zure Excel-en zerrendak zenbakizko balioak eta testu-balioak baditu eta testu-balio bakarrak bakarrik zenbatu nahi badituzu, gehitu ISTEXT funtzioa goian azaldutako matrize-formulari:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Dakizuenez, Excel ISTEXT funtzioak EGIA ematen du ebaluatutako balio bat testua bada, GEZURRA bestela. Izartxoak (*) matrize-formuletan AND eragile gisa funtzionatzen duenez, IF funtzioak 1 itzultzen du balio bat testua eta bakarra bada, 0 bestela. Eta SUM funtzioak 1 guztiak batu ondoren, testu-balio esklusiboen zenbaketa jasoko duzu zehaztutakobarrutia.

Ez ahaztu Ctrl + Shift + Sartu sakatzea matrizearen formula zuzen sartzeko, eta honen antzeko emaitza lortuko duzu:

Goiko pantaila-argazkian ikus dezakezun bezala, formulak testu-balio esklusiboen kopuru osoa itzultzen du, gelaxka hutsak, zenbakiak, TRUE eta FALSE balio logikoak eta akatsak kenduta.

Zentatu zenbakizko balio bakarra Excel-en

Datu-zerrenda bateko zenbaki esklusiboak zenbatzeko, erabili testu-balio esklusiboak zenbatzeko erabili berri dugun matrize-formula bat, desberdintasun bakarrarekin ISNUMBER-ren ordez ISTEXT txertatzen duzula balio esklusiboen formulan:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Oharra. Microsoft Excel-ek datak eta orduak serie-zenbaki gisa gordetzen dituenez, hauek ere zenbatzen dira.

Mauskulak eta minuskulak bereizten dituzten balio esklusibak Excel-en zenbatu

Zure taulak maiuskulak eta minuskulak bereizten dituen datuak baditu, zenbatzeko modurik errazena. balio esklusiboek zutabe laguntzaile bat sortuko lukete matrize-formula honekin, elementu bikoiztuak eta bakarrak identifikatzeko:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

Eta, gero, erabili COUNTIF funtzio soil bat balio esklusiboak zenbatzeko:

=COUNTIF(B2:B10, "unique")

Kontatu balio desberdinak Excel-en (bakarrik eta bikoiztutako lehen agerraldi)

Zerrenda bateko balio ezberdinen zenbaketa lortzeko, erabili honako hau formula:

Gogoratu matrize formula bat dela, eta, beraz, Ctrl + Shift + Sartu sakatu beharko zenuke Sartu ohiko lasterbidea ordeztekla sakatzea.

Bestela, SUMPRODUCT funtzioa erabil dezakezu eta formula ohiko moduan osa dezakezu Sartu tekla sakatuz:

Adibidez, A2:A10 barrutian dauden balio desberdinak zenbatzeko, honako hauekin joan zaitezke:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Edo

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Nola funtzionatzen duen Excel formula desberdina

Dagoeneko dakizuenez, ZENBATZENBIDE funtzioa erabiltzen dugu balio indibidual bakoitza zenbat aldiz agertzen den jakiteko. zehaztutako tartea. Goiko adibidean, COUNTIF funtzioaren emaitza honako array hau da: {2;2;3;1;2;2;3;1;3} .

Ondoren, zatiketa-eragiketa batzuk egiten dira, non matrizearen balio bakoitza zatitzaile gisa erabiltzen den 1 gisa. dibidendua. Honek bikoiztutako balio guztiak agerraldi bikoiztuen kopuruari dagozkion zatiki-zenbaki bihurtzen ditu. Adibidez, balio bat zerrendan 2 aldiz agertzen bada, 0,5 balioarekin (1/2=0,5) 2 elementu sortzen ditu matrizean. Eta balio bat 3 aldiz agertzen bada, 0,3(3) balioa duten 3 elementu sortzen ditu arrayan. Gure adibidean, 1/COUNTIF(A2:A10,A2:A10)) -ren emaitza {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} array-a da.

Orain arte ez du zentzu handirik? Hori da oraindik ez dugulako SUM / SUMPRODUCT funtzioa aplikatu. Funtzio horietako batek matrizeko balioak batzen dituenean, elementu bakoitzaren zatiki-zenbaki guztien baturak beti ematen du 1, elementu horren zenbat agerraldi dauden zerrendan. Etabalio esklusibo guztiak matrizean 1 gisa agertzen direnez (1/1=1), formulak itzultzen duen azken emaitza zerrendako balio ezberdin guztien kopurua da.

Formulak desberdinen balio desberdinak zenbatzeko. motak

Excel-en balio esklusiboak zenbatzearekin gertatzen den bezala, oinarrizko Excel-en zenbaketa formula ezberdinaren aldaerak erabil ditzakezu balio mota zehatzak kudeatzeko, hala nola zenbakiak, testua eta maiuskulak eta minuskulak bereizten dituzten balioak.

Mesedez, gogoratu beheko formula guztiak matrize formulak direla eta Ctrl + Shift + Sartu sakatu behar direla.

Balio desberdinak zenbatu gelaxka hutsak alde batera utzita

Balio desberdinak zenbatu nahi dituzun zutabe bat bada. gelaxka hutsak izan ditzake, IF funtzio bat gehitu beharko zenuke, zehaztutako tartea hutsuneen egiaztapena egingo duena (goian aztertutako oinarrizko Excel formula bereiziak kasu honetan #DIV/0 errorea itzuliko luke):

Adibidez, A2:A10 barrutian balio desberdinak zenbatzeko, erabili ondorengo array formula :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Testu-balio desberdinak zenbatzeko formula

Zutabe batean testu-balio desberdinak zenbatzeko, hau erabiliko dugu. Gelaxka hutsak baztertzeko erabili berri dugun ikuspegi bera.

Erraz asma dezakezun bezala, ISTEXT funtzioa gure Excel zenbaketa formula ezberdinean txertatuko dugu besterik gabe:

Eta hona hemen bizitza errealeko batformula adibidea:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Zenbaki desberdinak zenbatzeko formula

Zenbakizko balio desberdinak (zenbakiak, datak eta orduak) zenbatzeko, erabili ISNUMBER funtzioa:

Adibidez, hainbat zenbaki zenbatu A2:A10 barrutian, erabili formula hau:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Mauskulak eta minuskulak bereizten dituzten balioak Excel-en zenbatzea

Mauskulak eta minuskulak bereizten dituzten balio bakarrak zenbatzearen antzera, modurik errazena maiuskulak eta minuskulak bereizten dituzten balio desberdinak zenbatzea balio esklusiboak identifikatzen dituen matrize-formularekin zutabe laguntzaile bat gehitzea da, lehen agerraldi bikoiztuak barne. Formula, funtsean, maiuskulak eta minuskulak bereizten dituzten balio esklusiboak zenbatzeko erabili genuenaren berdina da, gelaxka-erreferentzian aldaketa txiki batekin alde handia egiten duena:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

Gogoratzen duzunez, Excel-eko matrize-formula guztiek Ctrl + Shift + Sartu sakatu behar dute.

Aurreko formula amaitu ondoren, balio "bereiztuak" zenbatu ditzakezu COUNTIF formula ohiko batekin:

=COUNTIF(B2:B10, "distinct")

Ez badago zure lan-orrian zutabe laguntzaile bat gehitzeko modurik, hurrengo array formula konplexua erabil dezakezu maiuskulak eta minuskulak bereizten dituzten balio desberdinak zenbatzeko. zutabe gehigarri bat sortzea:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

Excel-en errenkada bakarrak eta bereiziak zenbatzea

Excel-en errenkada bakarrak/berdinak zenbatzea balio bakarrak eta bereiziak zenbatzearen antzekoa da, bakarrarekin. aldeaCOUNTIFS funtzioa erabiltzen duzula COUNTIF-en ordez, eta horri esker, hainbat zutabe zehazten dituzu balio esklusiboak egiaztatzeko.

Adibidez, A (Izena) eta B zutabeetako balioetan oinarrituta izen esklusiboak edo desberdinak zenbatzeko. (Abizena), erabili formula hauetako bat:

Formula errenkada bakarrak zenbatzeko:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Formula bereiziak zenbatzeko errenkadak:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Noski, ez zaude bi zutabeetan soilik oinarritutako errenkada bakarrak kontatzera mugatzen, Excel COUNTIFS funtzioak prozesatu dezake. 127 barruti/irizpide bikotera.

Zentatu balio desberdinak Excel-en taula dinamikoa erabiliz

Excel 2013 eta Excel 2016 azken bertsioek bat dute. Taula dinamiko batean balio desberdinak automatikoki zenbatzea ahalbidetzen duen ezaugarri berezia. Hurrengo pantaila-argazkiak Excel Zenbaketa bereizgarria itxura nolakoa den ematen du:

Taula dinamiko bat sortzeko zutabe jakin baterako zenbaketa desberdina duena, egin urrats hauek.

1. Hautatu taula dinamiko batean sartu nahi dituzun datuak, aldatu Txertatu fitxara, Taulak taldera eta egin klik Taula dinamikoa botoia.
2. Sortu taula dinamikoa elkarrizketa-koadroan, aukeratu taula dinamikoa lan-orri berri batean edo lehendik dagoen batean kokatu nahi duzun, eta ziurtatu Gehitu aukeratzen duzula. datu hauek Datu-eredua kontrol-laukira.

Izen pertsonalizatu bat ere eman diezaiokezu zure Distinct Count-i nahi baduzu.

Eginda! Sortu berri den taula dinamikoak atal honetako lehen pantaila-argazkian erakusten den zenbaketa desberdina erakutsiko du.

Aholkua. Zure iturburu-datuak eguneratu ondoren, gogoratu taula dinamikoa eguneratzea zenbaketa desberdina eguneratzeko. Taula dinamiko bat freskatzeko, egin klik Freskatu botoian Aztertu fitxan, Datuak taldean.

Horrela zenbatzen duzu. balio bereiziak eta bakarrak Excel-en. Norbaitek tutoretza honetan aztertzen diren formulei hurbilagotik begiratu nahi badie, ongi etorriko zaizu Excel Count Unique lan-koadernoaren adibidea deskargatzea.

Eskerrik asko irakurtzeagatik eta hurrengo astean berriro ikustea espero dut. Hurrengo artikuluan Excel-en balio bereziak aurkitzeko, iragazteko, ateratzeko eta nabarmentzeko hainbat modu eztabaidatuko ditugu. Mesedez