Энэ зааварт та Excel-ийн өвөрмөц утгуудыг томъёогоор хэрхэн тоолох, мөн пивот хүснэгтэд ялгаатай утгуудын автомат тоололыг хэрхэн авах талаар сурах болно. Мөн бид өвөрмөц нэр, бичвэр, тоо, жижиг жижиг жижиг утгууд болон бусад зүйлийг тоолох хэд хэдэн томъёоны жишээг авч үзэх болно.

Excel дээр том өгөгдлийн багцтай ажиллахдаа та ихэвчлэн шаардлагатай байж болно. давхардсан ба өвөрмөц утгууд хэр их байгааг мэдэх. Заримдаа та зөвхөн ялгаатай (өөр) утгуудыг тоолохыг хүсэж болох юм.

Хэрэв та энэ блогт байнга зочилж байсан бол давхардсан тоолох Excel томъёог аль хэдийн мэддэг болсон. Өнөөдөр бид Excel-ийн өвөрмөц утгыг тоолох янз бүрийн аргыг судлах болно. Гэхдээ ойлгомжтой болгох үүднээс эхлээд нэр томьёог тодорхойлъё.

• Өвөрмөц утгууд - эдгээр нь жагсаалтад нэг л удаа харагдах утгууд юм.
• Ялгаатай утгууд - эдгээр нь бүгд жагсаалтад байгаа өөр өөр утгууд, өөрөөр хэлбэл давтагдсан утгуудын 1 дэхь давтагдах утгууд.

Дараах дэлгэцийн агшин ялгааг харуулж байна:

Тэгээд одоо томъёо болон пивот хүснэгтийн функцуудыг ашиглан Excel-ийн өвөрмөц, ялгаатай утгуудыг хэрхэн тоолж болохыг харцгаая.

Excel-ийн өвөрмөц утгыг хэрхэн тоолохыг

Эдгээр Excel-ийн бүх хэрэглэгчид хааяа нэг удаа хийх ёстой нийтлэг даалгавар байна. Танд өгөгдлийн жагсаалт байгаа бөгөөд түүн доторх өвөрмөц утгуудын тоог олох хэрэгтэйХамтдаа байгаарай!

Багананд өвөрмөц утгуудыг тоолох

Таны Excel-д нэрний багана байгаа гэж бодъё. ажлын хуудас бөгөөд та тэр баганад байгаа өвөрмөц нэрийг тоолох хэрэгтэй. Үүний шийдэл нь SUM функцийг IF болон COUNTIF-тэй хослуулан ашиглах явдал юм:

Тэмдэглэл . Энэ бол массивын томьёо тул Ctrl + Shift + Enter дарж дуусгана уу. Үүнийг хийсний дараа Excel нь доорх дэлгэцийн зурган дээрх шиг томьёог автоматаар {буржгар хаалтанд} хавсаргана. Ямар ч тохиолдолд та буржгар хаалтуудыг гараар бичиж болохгүй, энэ нь ажиллахгүй.

Энэ жишээнд бид A2:A10 муж дахь өвөрмөц нэрийг тоолж байгаа тул бидний томъёо дараах хэлбэртэй байна:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Цаашид энэ зааварт бид өөр өөр төрлийн өвөрмөц утгыг тоолох цөөн хэдэн томъёог авч үзэх болно. Эдгээр бүх томьёо нь Excel-ийн үндсэн өвөрмөц утгуудын томьёоны хувилбарууд тул дээрх томьёог задлах нь зүйтэй бөгөөд ингэснээр та энэ нь хэрхэн ажилладагийг бүрэн ойлгож, өөрийн өгөгдөлд тохируулан өөрчлөх боломжтой болно. Хэрэв хэн нэгэн техникийн талаар сонирхдоггүй бол та дараагийн томьёоны жишээ рүү шууд алгасаж болно.

Excel өвөрмөц утгыг тоолох томьёо хэрхэн ажилладаг вэ

Таны харж байгаагаар манай өвөрмөц программд 3 өөр функц ашиглагдаж байна. утгын томъёо - SUM, IFболон COUNTIF. Дотор талаас нь харахад функц бүр юу хийдэг вэ:

• COUNTIF функц нь тус бүрийн утга заасан мужид хэдэн удаа гарч ирэхийг тооцдог.

  Энэ жишээнд COUNTIF(A2:A10,A2:A10) нь {1;2;2;1;2;2;2;1;2} массивыг буцаана.

• IF функц нь COUNTIF-ийн буцаасан массив дахь утга бүрийг үнэлж, бүх 1-ийг (өвөрмөц утгуудыг) хадгалж, бусад бүх утгыг тэгээр солино. .

  Тиймээс IF(COUNTIF(A2:A10,A2:A10)=1,1,0) функц нь IF(1;2;2;1;2;2;2;1;2) = 1,1,0, болж {1;0;0;1;0;0;0;1;0} массив болж хувирдаг бөгөөд 1 нь өвөрмөц утга, 0 нь давхардсан утга юм.

• Эцэст нь SUM функц нь IF-ын буцаасан массив дахь утгуудыг нэмж, өвөрмөц утгуудын нийт тоог гаргадаг бөгөөд энэ нь яг бидний хүссэн зүйл юм.

Зөвлөгөө. . Excel-ийн өвөрмөц утгуудын томъёоны тодорхой хэсэг юунд үнэлэгдэж байгааг харахын тулд томъёоны мөрөнд тухайн хэсгийг сонгоод F9 товчийг дарна уу.

Excel дээрх өвөрмөц текстийн утгыг тоолоорой

Хэрэв таны Excel жагсаалт тоон болон текстийн утгыг хоёуланг нь агуулж байгаа бөгөөд та зөвхөн өвөрмөц текстийн утгыг тоолохыг хүсвэл дээр дурдсан массивын томъёонд ISTEXT функцийг нэмнэ үү:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Таны мэдэж байгаагаар Excel-ийн ISTEXT функц нь хэрэв үнэлэгдсэн утга нь текст байвал ҮНЭН, үгүй ​​бол ХУДАЛ буцаана. Од (*) нь массивын томьёонд БА операторын үүрэг гүйцэтгэдэг тул хэрэв утга нь текст болон өвөрмөц байвал IF функц нь 1-ийг буцаана, үгүй ​​бол 0-ийг буцаана. SUM функц нь бүх 1-ийг нэмсний дараа та заасан текстийн өвөрмөц утгуудын тоог авах болно.муж.

Масивын томьёог зөв оруулахын тулд Ctrl + Shift + Enter дарахаа бүү мартаарай, тэгвэл та үүнтэй төстэй үр дүнг авах болно:

Дээрх дэлгэцийн зургаас харж байгаагаар томьёо нь хоосон нүд, тоо, ҮНЭН ба ХУДАЛ гэсэн логик утга, алдааг оруулаагүй өвөрмөц текстийн утгуудын нийт тоог буцаана.

Excel дээрх өвөрмөц тоон утгыг тоолоорой

Өгөгдлийн жагсаалт дахь давтагдашгүй тоонуудыг тоолохын тулд бидний дөнгөж сая давтагдашгүй текстийн утгыг тоолоход ашигласан шиг массивын томьёог ашиглана уу. Та өөрийн өвөрмөц утгуудын томъёонд ISTEXT-ийн оронд ISNUMBER-г оруулах цорын ганц ялгаа нь:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Тайлбар. Microsoft Excel нь огноо, цагийг серийн дугаар болгон хадгалдаг тул тэдгээрийг мөн тоолдог.

Excel-д том жижиг үсгээр ялгах өвөрмөц утгыг тоолно

Хэрэв таны хүснэгтэнд том жижиг үсгээр хамаарах өгөгдөл байгаа бол тоолох хамгийн хялбар арга. өвөрмөц утгууд нь давхардсан болон давтагдашгүй зүйлсийг тодорхойлохын тулд дараах массив томьёотой туслах багана үүсгэх болно:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

Дараа нь энгийн COUNTIF функцийг ашиглан өвөрмөц утгыг тоолно уу:

=COUNTIF(B2:B10, "unique")

Excel-д ялгаатай утгуудыг тоолох (өвөрмөц болон 1-р давхцал)

Жагсаалт дахь ялгаатай утгуудын тоог авахын тулд дараахийг ашиглана уу. томъёо:

Энэ бол массив томьёо тул Ctrl + Shift + Enter дарах хэрэгтэй гэдгийг санаарай. ердийн Enter-ийн оронд товчлолтовч дарна уу.

Үүнээс гадна та SUMPRODUCT функцийг ашиглаж Enter товчийг дарж ердийн аргаар томьёог бөглөж болно:

Жишээ нь, A2:A10 муж дахь ялгаатай утгуудыг тоолохын тулд та:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Эсвэл

-ийн аль нэгээр нь явж болно. =SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Excel-ийн ялгаатай томьёо хэрхэн ажилладаг вэ

Та аль хэдийн мэдэж байгаачлан бид COUNTIF функцийг ашиглан тус бүрийн утга тус бүр хэдэн удаа гарч ирснийг мэдэхийн тулд ашигладаг. заасан хүрээ. Дээрх жишээн дээр COUNTIF функцийн үр дүн дараах массив байна: {2;2;3;1;2;2;3;1;3} .

Үүний дараа хэд хэдэн хуваах үйлдлүүд хийгдэх бөгөөд массивын утга бүрийг хуваагч болгон 1-ээр ашиглана. ногдол ашиг. Энэ нь бүх давхардсан утгыг давхардсан тохиолдлын тоотой харгалзах бутархай тоо болгон хувиргадаг. Жишээлбэл, жагсаалтад утга 2 удаа гарч ирвэл массив дахь 0.5 (1/2=0.5) утгатай 2 зүйлийг үүсгэдэг. Хэрэв утга 3 удаа гарч ирвэл массив дахь 0.3(3) утгатай 3 зүйлийг үүсгэдэг. Бидний жишээн дээр 1/COUNTIF(A2:A10,A2:A10)) -ийн үр дүн нь {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} массив байна.

Одоогоор тийм ч утгагүй байна уу? Учир нь бид SUM / SUMPRODUCT функцийг хараахан хэрэглээгүй байна. Эдгээр функцүүдийн аль нэг нь массив дахь утгуудыг нэмэхэд тухайн зүйл жагсаалтад хэдэн удаа тохиолдсоноос үл хамааран тус бүрийн зүйл бүрийн бутархай тоонуудын нийлбэр нь үргэлж 1-ийг гаргана. Тэгээдучир нь бүх өвөрмөц утгууд массив дотор 1-ийн (1/1=1) хэлбэрээр гарч ирдэг тул томъёогоор буцаасан эцсийн үр дүн нь жагсаалт дахь бүх өөр утгуудын нийт тоо юм.

Өөр өөр утгуудыг тоолох томьёо. төрлүүд

Excel-д давтагдашгүй утгуудыг тоолохын нэгэн адил та тоо, текст, жижиг үсгийн мэдрэмж зэрэг тодорхой утгын төрлүүдийг зохицуулахын тулд Excel-ийн үндсэн тоолох томьёоны хувилбаруудыг ашиглаж болно.

Доорх бүх томьёо нь массив томьёо бөгөөд Ctrl + Shift + Enter товчийг дарах шаардлагатай гэдгийг санаарай.

Хоосон нүдийг үл тоомсорлон ялгаатай утгуудыг тоолох

Хэрэв та өөр утгуудыг тоолохыг хүссэн багана бол хоосон нүднүүдийг агуулж болох юм бол та заасан хүрээн дэх хоосон зайг шалгах IF функцийг нэмэх хэрэгтэй (дээр хэлэлцсэн Excel-ийн үндсэн томъёо нь энэ тохиолдолд #DIV/0 алдааг буцаана):

Жишээ нь, A2:A10 муж дахь ялгаатай утгуудыг тоолохын тулд Дараах массив томъёо :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Текстийн ялгаатай утгыг тоолох томьёо

Багананд байгаа өөр өөр текстийн утгыг тоолохын тулд бид дараахыг ашиглана. Хоосон нүднүүдийг хасахын тулд бидний саяхан ашигласан арга барилтай ижил арга барил.

Таны таамаглаж байгаагаар бид ISTEXT функцийг Excel-ийн тодорхой томьёонд оруулах болно:

Мөн энд бодит амьдрал байнатомьёоны жишээ:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Ялгаатай тоог тоолох томьёо

Ялгаатай тоон утгыг (тоо, огноо, цаг) тоолохын тулд ISNUMBER функцийг ашиглана уу:

Жишээ нь, бүх өөр тоог тоолох A2:A10 мужид дараах томьёог ашиглана уу:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Excel дээр том жижиг үсгээр ялгагдах утгуудыг тоолох

Хамгийн хялбар арга Том жижиг үсгээр ялгагдах утгуудыг тоолох нь эхний давхардсан тохиолдлуудыг багтаасан өвөрмөц утгуудыг тодорхойлдог массивын томьёотой туслах багана нэмэх явдал юм. Томьёо нь үндсэндээ бидний хэрэглэж байсан том жижиг жижиг үсгээр ялгах өвөрмөц утгуудыг тоолоход ашигладагтай ижил бөгөөд нүдний лавлагаанд нэг жижиг өөрчлөлт орсон нь ихээхэн ялгаатай:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

Таны санаж байгаагаар, Excel дээрх бүх массив томьёо нь Ctrl + Shift + Enter товчлуурыг дарах шаардлагатай.

Дээрх томьёог дуусгасны дараа та "ялгаатай" утгыг ердийн COUNTIF томъёогоор дараах байдлаар тоолж болно:

=COUNTIF(B2:B10, "distinct")

Хэрэв та ажлын хуудсандаа туслах багана нэмэх боломжгүй бол дараах нийлмэл массивийн томьёог ашиглан том жижиг жижиг үсгээр ялгах утгыг тоолох боломжтой. нэмэлт багана үүсгэх:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

Excel дээрх өвөрмөц, ялгаатай мөрүүдийг тоолох

Excel дээр өвөрмөц / ялгаатай мөрүүдийг тоолох нь цорын ганц, өвөрмөц, ялгаатай утгуудыг тоолохтой адил юм. ялгааТа COUNTIF-ийн оронд COUNTIFS функцийг ашигладаг бөгөөд энэ нь танд өвөрмөц утгыг шалгахын тулд хэд хэдэн баганыг зааж өгөх боломжийг олгодог.

Жишээ нь, A (Нэр) ба В баганын утгууд дээр үндэслэн өвөрмөц эсвэл ялгаатай нэрийг тоолох. (Овог нэр), дараах томъёоны аль нэгийг ашиглана уу:

Өвөрмөц мөрийг тоолох томьёо:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Ялгаатай тоолох томъёо мөрүүд:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Мэдээж та зөвхөн хоёр баганад тулгуурласан өвөрмөц мөрүүдийг тоолохоор хязгаарлагдахгүй, Excel-ийн COUNTIFS функцийг боловсруулах боломжтой. 127 муж/шалгуур хос болно.

Excel-д пивот хүснэгт ашиглан ялгаатай утгуудыг тоолох

Excel 2013 ба Excel 2016 -ийн сүүлийн хувилбарууд нь Пивот хүснэгтэд тодорхой утгыг автоматаар тоолох боломжийг олгодог тусгай функц. Дараах дэлгэцийн агшинд Excel Ялгаатай тоо хэрхэн харагдахыг харуулсан:

Тодорхой баганын тодорхой тоо бүхий пивот хүснэгт үүсгэхийн тулд, дараах алхмуудыг хийгээрэй.

1. Пивот хүснэгтэд оруулах өгөгдлийг сонгоод Оруулах таб, Хүснэгт бүлэг рүү шилжиж, <дээр дарна уу. 4>Пивот хүснэгт товч.
2. Пивот хүснэгт үүсгэх харилцах цонхонд пивот хүснэгтээ шинэ эсвэл одоо байгаа ажлын хуудсанд байрлуулах эсэхээ сонгоод Нэмэх товчийг сонгохоо мартуузай. энэ өгөгдлийг Өгөгдлийн загвар шалгах хайрцагт хийнэ үү.

Хэрэв та хүсвэл өөрийн Тооллогоо өөрчлөн нэр өгч болно.

Боллоо! Шинээр үүсгэсэн пивот хүснэгт нь энэ хэсгийн хамгийн эхний дэлгэцийн агшинд үзүүлсэн шиг тодорхой тоог харуулах болно.

Зөвлөгөө. Эх өгөгдлөө шинэчилсний дараа тодорхой тооллогыг шинэчлэхийн тулд Пивот хүснэгтийг шинэчлэхээ бүү мартаарай. Пивот хүснэгтийг сэргээхийн тулд Өгөгдөл бүлгийн Шинжилгээ таб дээрх Сэргээх товчийг дарахад л хангалттай.

Та ингэж тооцдог. Excel-ийн өвөрмөц, өвөрмөц утгууд. Хэрэв хэн нэгэн энэ зааварт хэлэлцсэн томьёотой танилцахыг хүсвэл Excel Count Unique програмын жишээг татаж авч болно.

Уншсанд баярлалаа, дараа долоо хоногт дахин уулзана гэж найдаж байна. Дараагийн өгүүллээр бид Excel-ийн өвөрмөц утгыг олох, шүүх, задлах, тодруулах янз бүрийн аргуудыг хэлэлцэх болно. Гуйя