Bu dərslikdə siz Excel-də düsturlarla unikal dəyərləri saymağı və pivot cədvəldə fərqli dəyərlərin avtomatik hesabını necə əldə etməyi öyrənəcəksiniz. Biz eyni zamanda unikal adların, mətnlərin, nömrələrin, kiçik ölçülü unikal dəyərlərin və s. hesablanması üçün bir sıra düstur nümunələrini müzakirə edəcəyik.

Excel-də böyük verilənlər toplusu ilə işləyərkən sizə tez-tez ehtiyac yarana bilər. neçə dublikat və unikal dəyərlərin olduğunu bilin. Və bəzən siz yalnız fərqli (fərqli) dəyərləri saymaq istəyə bilərsiniz.

Əgər siz bu bloqu müntəzəm olaraq ziyarət edirsinizsə, dublikatları saymaq üçün Excel düsturunu artıq bilirsiniz. Və bu gün biz Excel-də unikal dəyərləri saymağın müxtəlif yollarını araşdıracağıq. Ancaq aydınlıq üçün əvvəlcə şərtləri müəyyən edək.

• Unikal dəyərlər - bunlar siyahıda yalnız bir dəfə görünən dəyərlərdir.
• Fərqli dəyərlər - bunların hamısı siyahıdakı fərqli dəyərlərdir, yəni unikal dəyərlər və təkrarlanan dəyərlərin 1-ci halları.

Aşağıdakı skrinşot fərqi nümayiş etdirir:

İndi isə düsturlar və Pivot Cədvəl funksiyalarından istifadə edərək Excel-də unikal və fərqli dəyərləri necə hesablaya biləcəyinizi görək.

Excel-də unikal dəyərləri necə saymaq olar

Budur, bütün Excel istifadəçilərinin vaxtaşırı yerinə yetirməli olduğu ümumi tapşırıq. Sizin məlumatların siyahısı var və oradakı unikal dəyərlərin sayını öyrənməlisinizbizi izləyin!

Sütundakı unikal dəyərləri saymaq

Fərz edək ki, Excel-də adlar sütunu var. iş vərəqi və siz həmin sütundakı unikal adları saymalısınız. Həll yolu ƏGƏR və COUNTIF ilə birlikdə SUM funksiyasından istifadə etməkdir:

Qeyd . Bu massiv düsturudur, ona görə də tamamlamaq üçün Ctrl + Shift + Enter düymələrini sıxdığınızdan əmin olun. Siz bunu etdikdən sonra Excel aşağıdakı skrinşotdakı kimi düsturu avtomatik olaraq {qıvrımlı mötərizələr} içərisinə daxil edəcək. Heç bir halda əyri mötərizələri əl ilə yazmamalısınız, bu işləməyəcək.

Bu nümunədə biz A2:A10 diapazonunda unikal adları hesablayırıq, ona görə də düsturumuz aşağıdakı formanı alır:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Daha sonra bu dərslikdə müxtəlif növlərin unikal dəyərlərini hesablamaq üçün bir neçə başqa düsturları müzakirə edəcəyik. Və bütün bu düsturlar əsas Excel unikal dəyərlər düsturunun variasiyaları olduğuna görə yuxarıdakı düsturları parçalamaq mənasızdır, beləliklə siz onun necə işlədiyini tam başa düşə və onu məlumatlarınız üçün düzəldə bilərsiniz. Kimsə texniki məsələlərlə maraqlanmırsa, siz birbaşa növbəti düstur nümunəsinə keçə bilərsiniz.

Excel unikal dəyərləri hesablayır formulu necə işləyir

Gördüyünüz kimi, bizim unikal proqramımızda 3 fərqli funksiya istifadə olunur. dəyərlər düsturu - SUM, IFvə COUNTIF. İçəridən xaricdən baxsaq, hər bir funksiyanın gördüyü işlər bunlardır:

• COUNTIF funksiyası hər bir fərdi dəyərin müəyyən edilmiş diapazonda neçə dəfə göründüyünü hesablayır.

  Bu misalda COUNTIF(A2:A10,A2:A10) {1;2;2;1;2;2;2;1;2} massivini qaytarır.

• ƏGƏR funksiyası COUNTIF tərəfindən qaytarılan massivdəki hər bir dəyəri qiymətləndirir, bütün 1-ləri (unikal dəyərlər) saxlayır və bütün digər dəyərləri sıfırlarla əvəz edir. .

  Beləliklə, IF(COUNTIF(A2:A10,A2:A10)=1,1,0) funksiyası IF(1;2;2;1;2;2;2;1;2) = 1,1,0, -ə çevrilir və {1;0;0;1;0;0;0;1;0} massivinə çevrilir, burada 1 unikal dəyər və 0 dublikat dəyərdir.

• Nəhayət, SUM funksiyası IF tərəfindən qaytarılan massivdəki dəyərləri əlavə edir və unikal dəyərlərin ümumi sayını çıxarır, bu da bizim istədiyimizdir.

İpucu. . Excel unikal dəyərlər düsturunuzun xüsusi hissəsinin nə ilə qiymətləndirildiyini görmək üçün düstur çubuğunda həmin hissəni seçin və F9 düyməsini basın.

Excel-də unikal mətn dəyərlərini hesablayın

Excel siyahınız həm ədədi, həm də mətn dəyərlərini ehtiva edirsə və siz yalnız unikal mətn dəyərlərini saymaq istəyirsinizsə, yuxarıda müzakirə olunan massiv düsturuna ISTEXT funksiyasını əlavə edin:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Bildiyiniz kimi, qiymətləndirilən dəyər mətndirsə, Excel ISTEXT funksiyası TRUE, əks halda YANLIŞ qaytarır. Ulduz işarəsi (*) massiv düsturlarında VƏ operatoru kimi işlədiyi üçün ƏGƏR funksiyası yalnız dəyər həm mətn, həm də unikal olduqda 1, əks halda isə 0 qaytarır. SUM funksiyası bütün 1-ləri əlavə etdikdən sonra, siz göstərilən mətndə unikal mətn dəyərlərinin sayını alacaqsınız.diapazon.

Massiv düsturunu düzgün daxil etmək üçün Ctrl + Shift + Enter düymələrini sıxmağı unutmayın və buna bənzər bir nəticə əldə edəcəksiniz:

Yuxarıdakı ekran görüntüsündə gördüyünüz kimi, formula boş xanalar, rəqəmlər, DOĞRU və YANLIŞ məntiqi dəyərləri və xətalar istisna olmaqla, unikal mətn dəyərlərinin ümumi sayını qaytarır.

Excel-də unikal rəqəmli dəyərləri sayın

Məlumat siyahısındakı unikal nömrələri saymaq üçün unikal mətn dəyərlərini hesablamaq üçün istifadə etdiyimiz kimi massiv düsturundan istifadə edin, yeganə fərq sizin unikal dəyərlər düsturunuzda ISTEXT əvəzinə ISNUMBER-ni yerləşdirməyinizdir:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Qeyd. Microsoft Excel tarixləri və vaxtları seriya nömrələri kimi saxladığından, onlar da sayılır.

Excel-də hərf hərfinə həssas unikal dəyərləri hesablayın

Cədvəlinizdə böyük hərflərə həssas məlumatlar varsa, saymağın ən asan yolu unikal dəyərlər dublikat və unikal elementləri müəyyən etmək üçün aşağıdakı massiv düsturu ilə köməkçi sütun yaratmaq olardı:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

Və sonra unikal dəyərləri saymaq üçün sadə COUNTIF funksiyasından istifadə edin:

=COUNTIF(B2:B10, "unique")

Excel-də fərqli dəyərləri hesablayın (unikal və 1-ci dublikat hadisələr)

Siyahıdakı fərqli dəyərlərin sayını əldə etmək üçün aşağıdakılardan istifadə edin formula:

Unutmayın, bu massiv düsturudur və buna görə də Ctrl + Shift + Enter düymələrini sıxmalısınız adi Enter əvəzinə qısayoldüyməni basmaq.

Alternativ olaraq, SUMPRODUCT funksiyasından istifadə edə və Enter düyməsini sıxmaqla düsturu adi şəkildə tamamlaya bilərsiniz:

Məsələn, A2:A10 diapazonunda fərqli dəyərləri saymaq üçün aşağıdakılardan birinə keçə bilərsiniz:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Ya da

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Excel fərqli düsturu necə işləyir

Bildiyiniz kimi, biz hər bir fərdi dəyərin neçə dəfə göründüyünü öyrənmək üçün COUNTIF funksiyasından istifadə edirik. müəyyən diapazon. Yuxarıdakı misalda COUNTIF funksiyasının nəticəsi aşağıdakı massivdir: {2;2;3;1;2;2;3;1;3} .

Bundan sonra bir sıra bölmə əməliyyatları yerinə yetirilir, burada massivin hər bir dəyəri 1 ilə bölən kimi istifadə olunur. dividend. Bu, dublikatların sayına uyğun gələn bütün dublikat dəyərləri kəsirli ədədlərə çevirir. Məsələn, əgər dəyər siyahıda 2 dəfə görünürsə, o, massivdə dəyəri 0,5 (1/2=0,5) olan 2 element yaradır. Əgər dəyər 3 dəfə görünsə, o, 0.3(3) dəyəri ilə massivdə 3 element çıxarır. Bizim nümunəmizdə 1/COUNTIF(A2:A10,A2:A10)) -in nəticəsi {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} massividir.

İndiyə qədər çox mənası yoxdur? Bunun səbəbi, biz hələ SUM / SUMPRODUCT funksiyasını tətbiq etməmişik. Bu funksiyalardan biri massivdəki dəyərləri topladıqda, siyahıda həmin elementin neçə dəfə olmasından asılı olmayaraq, hər bir fərdi element üçün bütün kəsr ədədlərinin cəmi həmişə 1 verir. Vəbütün unikal dəyərlər massivdə 1 (1/1=1) kimi göründüyü üçün düsturla qaytarılan yekun nəticə siyahıdakı bütün müxtəlif dəyərlərin ümumi sayıdır.

Fərqli dəyərlərin fərqli dəyərlərini hesablamaq üçün düsturlar növlər

Excel-də unikal dəyərlərin sayılması ilə bağlı olduğu kimi, siz rəqəmlər, mətn və hərf hərfinə həssas dəyərlər kimi xüsusi dəyər növlərini idarə etmək üçün əsas Excel sayma fərqli düsturunun variasiyalarından istifadə edə bilərsiniz.

Xahiş edirik unutmayın ki, aşağıdakı düsturların hamısı massiv düsturlarıdır və Ctrl + Shift + Enter düymələrini basmağı tələb edir.

Boş xanalara məhəl qoymadan fərqli dəyərləri sayın

Fərqli dəyərləri saymaq istədiyiniz sütun varsa boş xanalar ola bilər, siz boşluqlar üçün göstərilən diapazonu yoxlayacaq ƏGƏR funksiyası əlavə etməlisiniz (yuxarıda müzakirə edilən əsas Excel fərqli düstur bu halda #DIV/0 xətası qaytaracaq):

Məsələn, A2:A10 diapazonunda fərqli dəyərləri saymaq üçün istifadə edin aşağıdakı massiv düsturu :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Fərqli mətn dəyərlərini saymaq üçün düstur

Sütundakı fərqli mətn dəyərlərini saymaq üçün biz istifadə edəcəyik boş xanaları xaric etmək üçün indicə istifadə etdiyimiz eyni yanaşma.

Asanlıqla təxmin edə bildiyiniz kimi, biz sadəcə olaraq ISTEXT funksiyasını Excel saymaq üçün fərqli düsturumuza yerləşdirəcəyik:

Və burada real həyat vardüstur nümunəsi:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Fərqli ədədləri hesablamaq üçün düstur

Fərqli rəqəmli dəyərləri (rəqəmlər, tarixlər və vaxtlar) hesablamaq üçün ISNUMBER funksiyasından istifadə edin:

Məsələn, bütün müxtəlif ədədləri saymaq üçün A2:A10 diapazonunda aşağıdakı düsturdan istifadə edin:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Excel-də hərflərə həssas fərqli dəyərləri saymaq

Ən asan yol böyük hərflərə həssas fərqli dəyərləri saymaq, ilk təkrarlanan hadisələr də daxil olmaqla unikal dəyərləri müəyyən edən massiv düsturuna köməkçi sütun əlavə etməkdir. Düstur, böyük fərq yaradan xana istinadında kiçik bir dəyişikliklə, hərf-həssas unikal dəyərləri saymaq üçün istifadə etdiyimiz düsturla əsasən eynidir:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

Xatırladığınız kimi, Excel-dəki bütün massiv düsturları Ctrl + Shift + Enter düymələrini sıxmağı tələb edir.

Yuxarıdakı düstur tamamlandıqdan sonra siz adi COUNTIF düsturu ilə "fərqli" dəyərləri aşağıdakı kimi saya bilərsiniz:

=COUNTIF(B2:B10, "distinct")

Əgər iş vərəqinizə köməkçi sütun əlavə etmək imkanı yoxdursa, hərflərə həssas fərqli dəyərləri saymaq üçün aşağıdakı kompleks massiv düsturundan istifadə edə bilərsiniz. əlavə sütun yaratmaq:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

Excel-də unikal və fərqli cərgələri saymaq

Excel-də unikal/fərqli cərgələri saymaq unikal və fərqli dəyərləri hesablamağa bənzəyir. fərqunikal dəyərləri yoxlamaq üçün bir neçə sütun təyin etməyə imkan verən COUNTIF əvəzinə COUNTIFS funksiyasından istifadə edirsiniz.

Məsələn, A (Ad) və B sütunlarındakı dəyərlər əsasında unikal və ya fərqli adları saymaq üçün (Soyad), aşağıdakı düsturlardan birini istifadə edin:

Unikal sıraları saymaq üçün düstur:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Fərqli saymaq üçün düstur sətirlər:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Təbii ki, siz yalnız iki sütuna əsaslanan unikal sətirləri saymaqla məhdudlaşmırsınız, Excel COUNTIFS funksiyası emal edə bilər 127 diapazon/kriteriya cütünə qədər.

Pivot Cədvəldən istifadə edərək Excel-də fərqli dəyərləri hesablayın

Excel 2013 və Excel 2016 ən son versiyalarında pivot cədvəldə fərqli dəyərləri avtomatik saymağa imkan verən xüsusi xüsusiyyət. Aşağıdakı ekran görüntüsü Excel Fərqli Say -ın necə göründüyü barədə fikir verir:

Müəyyən bir sütun üçün fərqli say ilə pivot cədvəli yaratmaq üçün, aşağıdakı addımları yerinə yetirin.

1. Pivot cədvəlinə daxil ediləcək məlumatları seçin, Daxil et nişanına, Cədvəllər qrupuna keçin və Pivot Cədvəl düyməsi.
2. Pivot Cədvəli Yarat dialoq qutusunda pivot cədvəlinizi yeni və ya mövcud iş vərəqinə yerləşdirməyi seçin və Əlavə et seçin. bu məlumatları Data Modeli qeyd qutusuna qoyun.

İstəsəniz, Fərqli Sayınıza fərdi ad da verə bilərsiniz.

Bitti! Yeni yaradılmış pivot cədvəli bu bölmənin ilk skrinşotunda göstərildiyi kimi fərqli sayları göstərəcək.

İpucu. Mənbə məlumatlarınızı yenilədikdən sonra fərqli hesablamaları yeniləmək üçün Pivot Cədvəli yeniləməyi unutmayın. Pivot cədvəlini yeniləmək üçün Məlumat qrupunda Təhlil nişanında Yenilə düyməsini klikləyin.

Siz hesablama qaydası belədir. Excel-də fərqli və unikal dəyərlər. Əgər kimsə bu dərslikdə müzakirə olunan düsturlara daha yaxından baxmaq istəyirsə, siz Excel Count Unique iş kitabının nümunəsini yükləyə bilərsiniz.

Oxuduğunuz üçün sizə təşəkkür edirəm və növbəti həftə sizinlə yenidən görüşməyə ümid edirəm. Növbəti məqalədə biz Excel-də unikal dəyərləri tapmaq, filtrləmək, çıxarmaq və vurğulamaq üçün müxtəlif yolları müzakirə edəcəyik. Zəhmət olmasa