Katika somo hili, utajifunza jinsi ya kuhesabu thamani za kipekee katika Excel kwa kutumia fomula, na jinsi ya kupata hesabu ya kiotomatiki ya thamani mahususi katika jedwali la egemeo. Pia tutajadili idadi ya mifano ya fomula ya kuhesabu majina ya kipekee, maandishi, nambari, thamani za kipekee ambazo ni nyeti kwa ukubwa, na zaidi.

Unapofanya kazi na mkusanyiko mkubwa wa data katika Excel, mara nyingi huenda ukahitajika kufanya hivyo. fahamu ni thamani ngapi za duplicate na kipekee ziko. Na wakati mwingine, unaweza kutaka kuhesabu tu thamani tofauti (tofauti).

Ikiwa umekuwa ukitembelea blogu hii kwa misingi ya kawaida, tayari unajua fomula ya Excel ya kuhesabu nakala. Na leo, tutachunguza njia tofauti za kuhesabu maadili ya kipekee katika Excel. Lakini kwa ajili ya uwazi, hebu tufafanue masharti kwanza.

• Thamani za kipekee - hizi ni thamani zinazoonekana kwenye orodha mara moja tu.
• Thamani tofauti - hizi zote ni thamani tofauti katika orodha, yaani, thamani za kipekee pamoja na matukio ya 1 ya thamani zilizorudiwa.

Picha ya skrini ifuatayo inaonyesha tofauti:

Na sasa, hebu tuone jinsi unavyoweza kuhesabu thamani za kipekee na mahususi katika Excel kwa kutumia fomula na vipengele vya Jedwali la Pivot.

Jinsi ya kuhesabu thamani za kipekee katika Excel

Hili hapa ni kazi ya kawaida ambayo watumiaji wote wa Excel wanapaswa kutekeleza mara moja baada ya nyingine. Una orodha ya data na unahitaji kujua idadi ya maadili ya kipekee katika hiyoendelea kufuatilia!

Hesabu thamani za kipekee katika safu

Tuseme una safu wima ya majina katika Excel yako. laha ya kazi, na unahitaji kuhesabu majina ya kipekee kwenye safu hiyo. Suluhisho ni kutumia chaguo za kukokotoa za SUM pamoja na IF na COUNTIF:

Kumbuka . Hii ni fomula ya safu, kwa hivyo hakikisha unabonyeza Ctrl + Shift + Enter ili kuikamilisha. Ukishafanya hivi, Excel itaambatanisha kiotomatiki fomula katika {curly braces} kama kwenye picha ya skrini iliyo hapa chini. Kwa hali yoyote usichape brashi zilizojipinda wewe mwenyewe, hiyo haitafanya kazi.

Katika mfano huu, tunahesabu majina ya kipekee katika safu A2:A10, kwa hivyo fomula yetu inachukua umbo lifuatalo:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Zaidi katika somo hili, tutajadili kanuni chache za kuhesabu thamani za kipekee za aina tofauti. Na kwa sababu fomula hizo zote ni tofauti za fomula ya msingi ya maadili ya kipekee ya Excel, inaleta maana kugawa fomula iliyo hapo juu, ili uweze kuelewa kikamilifu jinsi inavyofanya kazi na kuibadilisha kwa data yako. Ikiwa mtu hatavutiwa na ufundi, unaweza kuruka kulia hadi kwenye mfano wa fomula ifuatayo.

Jinsi fomula ya thamani za kipekee ya Excel inavyofanya kazi

Kama unavyoona, vitendaji 3 tofauti vinatumika katika kipekee yetu. fomula ya maadili - SUM, IFna COUNTIF. Ukiangalia kutoka ndani kwenda nje, hivi ndivyo kila chaguo la kukokotoa hufanya:

• Kitendakazi cha COUNTIF huhesabu ni mara ngapi kila thamani ya mtu binafsi inaonekana katika safu maalum.

  Katika mfano huu, COUNTIF(A2:A10,A2:A10) inarejesha safu {1;2;2;1;2;2;2;1;2} .

• Chaguo za kukokotoa za IF hutathmini kila thamani katika safu iliyorejeshwa na COUNTIF, huweka 1 zote (thamani za kipekee), na kubadilisha thamani zingine zote kwa sufuri. .

  Kwa hivyo, chaguo la kukokotoa IF(COUNTIF(A2:A10,A2:A10)=1,1,0) inakuwa IF(1;2;2;1;2;2;2;1;2) = 1,1,0, ambayo inageuka kuwa safu {1;0;0;1;0;0;0;1;0} ambapo 1 ni thamani ya kipekee na 0 ni dhamana ya nakala.

• Mwishowe, chaguo za kukokotoa za SUM huongeza thamani katika safu iliyorejeshwa na IF na kutoa jumla ya nambari za kipekee, ambayo ndiyo hasa tuliyotaka.

Kidokezo . Ili kuona sehemu mahususi ya fomula yako ya thamani ya kipekee ya Excel inatathmini nini, chagua sehemu hiyo kwenye upau wa fomula na ubonyeze kitufe cha F9.

Hesabu thamani za maandishi ya kipekee katika Excel

Ikiwa orodha yako ya Excel ina thamani za nambari na maandishi, na ungependa kuhesabu tu thamani za maandishi za kipekee, ongeza kitendakazi cha ISTEXT kwenye fomula ya mkusanyiko iliyojadiliwa hapo juu:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Kama unavyojua, chaguo za kukokotoa za Excel ISTEXT hurejesha TRUE ikiwa thamani iliyotathminiwa ni maandishi, FALSE vinginevyo. Kwa kuwa kinyota (*) hufanya kazi kama AND opereta katika fomula za mkusanyiko, chaguo za kukokotoa za IF hurejesha 1 ikiwa tu thamani ni ya maandishi na ya kipekee, 0 vinginevyo. Na baada ya kitendakazi cha SUM kuongeza 1 zote, utapata hesabu ya maadili ya kipekee ya maandishi katika maalummasafa.

Usisahau kubonyeza Ctrl + Shift + Enter ili kuingiza kwa usahihi fomula ya safu, na utapata matokeo sawa na haya:

Kama unavyoona kwenye picha ya skrini iliyo hapo juu, fomula hurejesha jumla ya nambari za thamani za kipekee za maandishi, bila kujumuisha visanduku tupu, nambari, thamani za kimantiki za TRUE na FALSE, na makosa.

Hesabu thamani za kipekee za nambari katika Excel

Ili kuhesabu nambari za kipekee katika orodha ya data, tumia fomula ya mkusanyiko kama vile tumetumia hivi punde kuhesabu thamani za kipekee za maandishi, na tofauti pekee ambayo umepachika ISNUMBER badala ya ISTEXT katika fomula yako ya kipekee ya thamani:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Kumbuka. Kwa kuwa Microsoft Excel huhifadhi tarehe na nyakati kama nambari za mfululizo, pia huhesabiwa.

Hesabu thamani za kipekee ambazo ni nyeti kwa ukubwa katika Excel

Ikiwa jedwali lako lina data nyeti, njia rahisi zaidi ya kuhesabu. thamani za kipekee zitakuwa zinaunda safu wima kisaidizi yenye fomula ifuatayo ya kubainisha vipengee nakala na vya kipekee:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

Na kisha, tumia chaguo rahisi la kukokotoa COUNTIF kuhesabu thamani za kipekee:

=COUNTIF(B2:B10, "unique")

Hesabu thamani tofauti katika Excel (tukio la kipekee na la 1)

Ili kupata hesabu ya thamani tofauti katika orodha, tumia zifuatazo. formula:

Kumbuka, ni fomula ya mkusanyiko, na kwa hivyo unapaswa kubonyeza Ctrl + Shift + Enter njia ya mkato badala ya Enter ya kawaidakitufe.

Vinginevyo, unaweza kutumia kitendakazi cha SUMPRODUCT na ukamilishe fomula kwa njia ya kawaida kwa kubonyeza kitufe cha Ingiza:

Kwa mfano, ili kuhesabu thamani tofauti katika safu A2:A10, unaweza kwenda na:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Au

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Jinsi fomula mahususi ya Excel inavyofanya kazi

Kama unavyojua tayari, tunatumia chaguo la kukokotoa la COUNTIF ili kujua ni mara ngapi kila thamani huonekana kwenye masafa maalum. Katika mfano ulio hapo juu, matokeo ya chaguo za kukokotoa za COUNTIF ni safu ifuatayo: {2;2;3;1;2;2;3;1;3} .

Baada ya hapo, idadi ya shughuli za mgawanyiko hufanywa, ambapo kila thamani ya safu inatumiwa kama kigawanyiko na 1 kama gawio. Hii inageuza thamani zote zilizorudiwa kuwa nambari za sehemu zinazolingana na idadi ya matukio yanayorudiwa. Kwa mfano, ikiwa thamani inaonekana mara 2 kwenye orodha, inazalisha vitu 2 katika safu na thamani ya 0.5 (1/2=0.5). Na ikiwa thamani inaonekana mara 3, hutoa vitu 3 katika safu na thamani ya 0.3 (3). Katika mfano wetu, matokeo ya 1/COUNTIF(A2:A10,A2:A10)) ni safu {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Je, haileti maana sana hadi sasa? Hiyo ni kwa sababu bado hatujatumia chaguo za kukokotoa za SUM / SUMPRODUCT. Wakati mojawapo ya chaguo hizi za kukokotoa inapojumlisha thamani katika safu, jumla ya nambari zote za sehemu kwa kila kipengee mahususi daima hutoa 1, haijalishi ni matukio mangapi ya kipengee hicho yapo kwenye orodha. Nakwa sababu thamani zote za kipekee huonekana katika safu kama 1 (1/1=1), matokeo ya mwisho yanayorejeshwa na fomula ni jumla ya idadi ya thamani zote tofauti katika orodha.

Mfumo wa kuhesabu thamani tofauti za tofauti. type

Kama ilivyo kwa kuhesabu thamani za kipekee katika Excel, unaweza kutumia utofauti wa fomula ya msingi ya hesabu ya Excel kushughulikia aina mahususi za thamani kama vile nambari, maandishi na thamani nyeti kwa kadiri.

Tafadhali kumbuka kwamba fomula zote zilizo hapa chini ni fomula za mkusanyiko na zinahitaji kubonyeza Ctrl + Shift + Enter .

Hesabu thamani tofauti ukipuuza seli tupu

Kama safu wima ambapo ungependa kuhesabu thamani tofauti. inaweza kuwa na seli tupu, unapaswa kuongeza kitendakazi cha IF ambacho kitaangalia safu maalum kwa nafasi zilizo wazi (fomula ya msingi ya Excel iliyojadiliwa hapo juu itarudisha hitilafu ya #DIV/0 katika kesi hii):

Kwa mfano, ili kuhesabu thamani tofauti katika safu A2:A10, tumia kufuata fomula ya safu :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Mfumo wa kuhesabu thamani tofauti za maandishi

Ili kuhesabu thamani tofauti za maandishi katika safu wima, tutakuwa tukitumia mbinu ile ile ambayo tumetumia hivi punde kutenga seli tupu.

Kama unavyoweza kukisia kwa urahisi, tutapachika tu chaguo la kukokotoa la ISTEXT kwenye fomula yetu mahususi ya hesabu ya Excel:

Na hapa kuna maisha halisimfano wa fomula:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Mfumo wa kuhesabu nambari tofauti

Ili kuhesabu thamani tofauti za nambari (nambari, tarehe na nyakati), tumia chaguo la kukokotoa la ISNUMBER:

Kwa mfano, kuhesabu nambari zote tofauti katika safu A2:A10, tumia fomula ifuatayo:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Hesabu thamani tofauti ambazo ni nyeti kadiri katika Excel

Sawa na kuhesabu thamani za kipekee ambazo ni nyeti kwa kesi, njia rahisi zaidi. kuhesabu thamani tofauti ambazo ni nyeti kwa kesi ni kuongeza safu wima kisaidizi yenye fomula ya mkusanyiko inayobainisha thamani za kipekee ikiwa ni pamoja na matukio ya nakala ya kwanza. Kimsingi fomula ni sawa na ile tuliyotumia kuhesabu thamani za kipekee ambazo ni nyeti kwa kadiri, kukiwa na badiliko moja dogo katika marejeleo ya seli ambayo hufanya tofauti kubwa:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

Kama unavyokumbuka, fomula zote za safu katika Excel zinahitaji kubonyeza Ctrl + Shift + Enter .

Baada ya fomula iliyo hapo juu kukamilika, unaweza kuhesabu thamani "tofauti" kwa fomula ya kawaida COUNTIF kama hii:

=COUNTIF(B2:B10, "distinct")

Ikiwa hakuna njia unaweza kuongeza safu wima ya usaidizi kwenye lahakazi yako, unaweza kutumia fomula changamano ifuatayo ili kuhesabu thamani tofauti ambazo ni nyeti kwa kesi bila kuunda safu wima ya ziada:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

Hesabu safu mlalo za kipekee na bainifu katika Excel

Kuhesabu safu mlalo za kipekee/tofauti katika Excel ni sawa na kuhesabu thamani za kipekee na tofauti, kwa kutumia pekee. tofautikwamba unatumia kitendakazi cha COUNTIFS badala ya COUNTIF, ambayo hukuruhusu kubainisha safu wima kadhaa ili kuangalia thamani za kipekee.

Kwa mfano, kuhesabu majina ya kipekee au tofauti kulingana na thamani katika safu wima A (Jina la Kwanza) na B. (Jina la Ukoo), tumia mojawapo ya fomula zifuatazo:

Mfumo wa kuhesabu safu mlalo za kipekee:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Mfumo wa kuhesabu tofauti. safu mlalo:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Kwa kawaida, huna kikomo cha kuhesabu safu mlalo za kipekee kulingana na safu wima mbili pekee, chaguo la kukokotoa la Excel COUNTIFS linaweza kuchakata. hadi 127 anuwai/vigezo jozi.

Hesabu thamani tofauti katika Excel kwa kutumia Jedwali la Pivot

Matoleo ya hivi punde ya Excel 2013 na Excel 2016 yana kipengele maalum kinachoruhusu kuhesabu thamani tofauti kiotomatiki katika jedwali badilifu. Picha ya skrini ifuatayo inatoa wazo la jinsi Excel Hesabu Distinct inaonekana kama:

Ili kuunda jedwali la egemeo lenye hesabu tofauti ya safu wima fulani, tekeleza hatua zifuatazo.

1. Chagua data itakayojumuishwa katika jedwali egemeo, badilisha hadi Ingiza kichupo, Majedwali kikundi, na ubofye Kitufe cha Jedwali Egemeo .
2. Katika kidirisha cha Unda Jedwali Egemeo , chagua ikiwa utaweka jedwali lako la egemeo katika laha kazi mpya au iliyopo, na uhakikishe kuwa umechagua Ongeza. data hii kwenye kisanduku cha kuteua cha Modeli ya Data .

29>

Unaweza pia kutoa jina maalum kwa Hesabu yako Tofauti ukitaka.

Nimemaliza! Jedwali jipya la egemeo litaonyesha idadi tofauti kama inavyoonyeshwa kwenye picha ya skrini ya kwanza kabisa katika sehemu hii.

Kidokezo. Baada ya kusasisha data yako ya chanzo, kumbuka kusasisha PivotTable ili kusasisha hesabu mahususi. Ili kuonyesha upya jedwali la egemeo, bofya tu kitufe cha Onyesha upya kwenye kichupo cha Changanua , katika kikundi cha Data .

Hivi ndivyo unavyohesabu. maadili tofauti na ya kipekee katika Excel. Iwapo mtu anataka kuangalia kwa karibu fomula zilizojadiliwa katika somo hili, unakaribishwa kupakua sampuli ya kitabu cha kazi cha Kipekee cha Hesabu ya Excel.

Ninakushukuru kwa kusoma na natumai kukuona tena wiki ijayo. Katika makala inayofuata, tutajadili njia mbalimbali za kupata, kuchuja, kutoa na kuangazia maadili ya kipekee katika Excel. Tafadhali