У овом водичу ћете научити како да пребројите јединствене вредности у Екцел-у помоћу формула и како да добијете аутоматски број различитих вредности у заокретној табели. Такође ћемо разговарати о бројним примерима формула за бројање јединствених имена, текстова, бројева, јединствених вредности осетљивих на мала слова и још много тога.

Када радите са великим скупом података у Екцел-у, можда ћете често морати да знати колико дуплираних и јединствених вредности постоји. А понекад, можда ћете желети да бројите само различите (различите) вредности.

Ако сте редовно посећивали овај блог, већ знате Екцел формулу за бројање дупликата. А данас ћемо истражити различите начине бројања јединствених вредности у Екцел-у. Али ради јасноће, хајде да прво дефинишемо појмове.

• Јединствене вредности – ово су вредности које се појављују на листи само једном.
• Различите вредности – ово су све различите вредности на листи, тј. јединствене вредности плус 1. појављивања дупликата вредности.

Следећи снимак екрана показује разлику:

А сада, хајде да видимо како можете да бројите јединствене и различите вредности у Екцел-у користећи формуле и функције изведене табеле.

Како да пребројите јединствене вредности у Екцел-у

Ево уобичајеног задатка који сви корисници Екцел-а морају с времена на време да обаве. Имате листу података и потребно је да сазнате број јединствених вредности у њојостаните са нама!

Пребројите јединствене вредности у колони

Претпоставимо да имате колону имена у свом Екцел-у радни лист и потребно је да бројите јединствена имена у тој колони. Решење је да користите функцију СУМ у комбинацији са ИФ и ЦОУНТИФ:

Напомена . Ово је формула низа, па обавезно притисните Цтрл + Схифт + Ентер да бисте је довршили. Једном када то урадите, Екцел ће аутоматски ставити формулу у {вирдзасте заграде} као на слици испод. Ни у ком случају не би требало ручно да куцате витичасте заграде, то неће функционисати.

У овом примеру, бројимо јединствена имена у опсегу А2:А10, тако да наша формула има следећи облик:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Даље, у овом водичу, разговараћемо о неколицини других формула за бројање јединствених вредности различитих типова. И пошто су све те формуле варијације основне формуле за јединствене вредности Екцел-а, има смисла разложити горњу формулу, тако да можете у потпуности разумети како функционише и прилагодити је за своје податке. Ако некога не занимају технички детаљи, можете прескочити право на следећи пример формуле.

Како функционише Екцел формула за бројање јединствених вредности

Као што видите, 3 различите функције се користе у нашој јединственој формула вредности - ЗБИР, АКОи ЦОУНТИФ. Гледајући изнутра ка споља, ево шта свака функција ради:

• Функција ЦОУНТИФ броји колико пута се свака појединачна вредност појављује у наведеном опсегу.

  У овом примеру, COUNTIF(A2:A10,A2:A10) враћа низ {1;2;2;1;2;2;2;1;2} .

• Функција ИФ процењује сваку вредност у низу коју враћа ЦОУНТИФ, задржава све 1 (јединствене вредности) и замењује све остале вредности нулама .

  Дакле, функција IF(COUNTIF(A2:A10,A2:A10)=1,1,0) постаје IF(1;2;2;1;2;2;2;1;2) = 1,1,0, која се претвара у низ {1;0;0;1;0;0;0;1;0} где је 1 јединствена вредност, а 0 дуплирана вредност.

• Коначно, функција СУМ сабира вредности у низу које враћа ИФ и даје укупан број јединствених вредности, што је управо оно што смо желели.

Савет . Да бисте видели шта одређени део ваше формуле јединствених вредности Екцел вреди, изаберите тај део на траци формула и притисните тастер Ф9.

Број јединствених текстуалних вредности у Екцел-у

Ако ваша Екцел листа садржи и нумеричке и текстуалне вредности, а желите да бројите само јединствене текстуалне вредности, додајте функцију ИСТЕКСТ у формулу низа о којој је горе дискутовано:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Као што знате, Екцел функција ИСТЕКСТ враћа ТРУЕ ако је процењена вредност текст, а у супротном ФАЛСЕ. Пошто звездица (*) функционише као оператор И у формулама низа, функција ИФ враћа 1 само ако је вредност и текстуална и јединствена, 0 у супротном. А након што функција СУМ сабере све 1, добићете број јединствених текстуалних вредности у наведеномопсег.

Не заборавите да притиснете Цтрл + Схифт + Ентер да правилно унесете формулу низа и добићете резултат сличан овоме:

Као што можете видети на слици изнад, формула враћа укупан број јединствених текстуалних вредности, искључујући празне ћелије, бројеве, логичке вредности ТРУЕ и ФАЛСЕ и грешке.

Пребројите јединствене нумеричке вредности у Екцел-у

Да бисте пребројали јединствене бројеве на листи података, користите формулу низа какву смо управо користили за бројање јединствених текстуалних вредности, са једином разликом што у своју формулу јединствених вредности уграђујете ИСНУМБЕР уместо ИСТЕКСТ:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Напомена. Пошто Мицрософт Екцел чува датуме и времена као серијске бројеве, они се такође броје.

Избројите јединствене вредности које су осетљиве на велика и мала слова у Екцел-у

Ако ваша табела садржи податке осетљиве на велика и мала слова, најлакши начин за бројање јединствене вредности би биле прављење помоћне колоне са следећом формулом низа за идентификацију дупликата и јединствених ставки:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

А затим користите једноставну функцију ЦОУНТИФ да бисте пребројали јединствене вредности:

=COUNTIF(B2:B10, "unique")

Број различитих вредности у Екцел-у (јединствена и 1. дуплирана појављивања)

Да бисте добили број различитих вредности на листи, користите следеће формула:

Запамтите, то је формула низа и зато треба да притиснете Цтрл + Схифт + Ентер пречица уместо уобичајеног Ентерпритисак на тастер.

Алтернативно, можете користити функцију СУМПРОДУЦТ и допунити формулу на уобичајен начин притиском на тастер Ентер:

На пример, да бисте пребројали различите вредности у опсегу А2:А10, можете ићи са:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Или

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Како функционише Екцел посебна формула

Као што већ знате, користимо функцију ЦОУНТИФ да бисмо сазнали колико пута се свака појединачна вредност појављује у наведени опсег. У горњем примеру, резултат функције ЦОУНТИФ је следећи низ: {2;2;3;1;2;2;3;1;3} .

Након тога се изводи низ операција дељења, где се свака вредност низа користи као делилац са 1 као дивиденда. Ово претвара све дупликате вредности у разломке који одговарају броју дупликата. На пример, ако се вредност појави 2 пута на листи, она генерише 2 ставке у низу са вредношћу 0,5 (1/2=0,5). А ако се вредност појави 3 пута, она производи 3 ставке у низу са вредношћу 0,3(3). У нашем примеру, резултат 1/COUNTIF(A2:A10,A2:A10)) је низ {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Зар нема много смисла за сада? То је зато што још увек нисмо применили функцију СУМ/СУМПРОДУЦТ. Када једна од ових функција сабере вредности у низу, збир свих разломака за сваку појединачну ставку увек даје 1, без обзира колико појављивања те ставке постоји на листи. Ипошто се све јединствене вредности појављују у низу као 1 (1/1=1), коначни резултат који даје формула је укупан број свих различитих вредности на листи.

Формуле за бројање различитих вредности различитих типови

Као што је случај са бројањем јединствених вредности у Екцел-у, можете да користите варијације основне формуле Екцел бројача да бисте руковали одређеним типовима вредности као што су бројеви, текст и вредности које разликују велика и мала слова.

Не заборавите да су све формуле низа и захтевају да притиснете Цтрл + Схифт + Ентер .

Пребројите различите вредности игноришући празне ћелије

Ако колона у којој желите да бројите различите вредности може садржати празне ћелије, требало би да додате ИФ функцију која ће проверити да ли у наведеном опсегу нема празнина (основна Екцелова различита формула о којој је било речи изнад би вратила грешку #ДИВ/0 у овом случају):

На пример, да бисте пребројали различите вредности у опсегу А2:А10, користите следећа формула низа :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Формула за бројање различитих текстуалних вредности

Да бисмо пребројали различите текстуалне вредности у колони, користићемо исти приступ који смо управо користили да искључимо празне ћелије.

Као што лако можете да претпоставите, једноставно ћемо уградити функцију ИСТЕКСТ у нашу различиту формулу за бројање Екцел-а:

И ево стварног животапример формуле:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Формула за бројање различитих бројева

Да бисте пребројали различите нумеричке вредности (бројеве, датуме и времена), користите функцију ИСНУМБЕР:

На пример, за бројање свих различитих бројева у опсегу А2:А10, користите следећу формулу:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Израчунајте различите вредности осетљиве на велика и мала слова у Екцел-у

Слично као код бројања јединствених вредности осетљивих на велика и мала слова, најлакши начин пребројавање различитих вредности које су осетљиве на велика и мала слова је додавање помоћне колоне са формулом низа која идентификује јединствене вредности укључујући прве дупликате појављивања. Формула је у основи иста као она коју смо користили за бројање јединствених вредности осетљивих на велика и мала слова, са једном малом променом у референци ћелије која чини велику разлику:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

Као што се сећате, све формуле низа у Екцел-у захтевају да притиснете Цтрл + Схифт + Ентер .

Након што се горња формула заврши, можете пребројати „различите“ вредности помоћу уобичајене формуле ЦОУНТИФ овако:

=COUNTIF(B2:B10, "distinct")

Ако не можете да додате помоћну колону свом радном листу, можете користити следећу сложену формулу низа да бисте пребројали различите вредности које су осетљиве на велика и мала слова без креирање додатне колоне:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

Број јединствених и различитих редова у Екцел-у

Пребројавање јединствених/различитих редова у Екцел-у је слично бројању јединствених и различитих вредности, са јединим разликада користите функцију ЦОУНТИФС уместо ЦОУНТИФ, која вам омогућава да наведете неколико колона за проверу јединствених вредности.

На пример, да бројите јединствена или различита имена на основу вредности у колонама А (Име) и Б (Презиме), користите једну од следећих формула:

Формула за бројање јединствених редова:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Формула за бројање различитих редови:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Наравно, нисте ограничени на бројање јединствених редова заснованих само на две колоне, функција Екцел ЦОУНТИФС може да обради до 127 парова опсега/критеријума.

Избројите различите вредности у Екцел-у користећи заокретну табелу

Најновије верзије Екцел 2013 и Екцел 2016 имају посебна карактеристика која омогућава аутоматско бројање различитих вредности у заокретној табели. Следећи снимак екрана даје идеју о томе како изгледа Екцел Дистинцт Цоунт :

Да бисте креирали изведену табелу са различитим бројем за одређену колону, извршите следеће кораке.

1. Изаберите податке који ће бити укључени у изведену табелу, пребаците се на картицу Убаци , групу Табеле и кликните на Дугме заокретна табела .
2. У дијалогу Креирај заокретну табелу , изаберите да ли да поставите своју изведену табелу у нови или постојећи радни лист и обавезно изаберите Додај ове податке у поље за потврду Модел података .

Такође можете дати прилагођено име свом Дистинцт Цоунт ако желите.

Готово! Новокреирана стожерна табела ће приказати различит број као што је приказано на првом снимку екрана у овом одељку.

Савет. Након ажурирања изворних података, не заборавите да ажурирате заокретну табелу да бисте ажурирали различити број. Да бисте освежили изведену табелу, само кликните на дугме Освежи на картици Анализа , у групи Подаци .

Овако рачунате различите и јединствене вредности у Екцел-у. Ако неко жели да изблиза погледа формуле о којима се говори у овом водичу, можете преузети пример Екцел Цоунт Уникуе радне свеске.

Захваљујем вам на читању и надам се да ћемо се видети поново следеће недеље. У следећем чланку ћемо разговарати о различитим начинима за проналажење, филтрирање, издвајање и истицање јединствених вредности у Екцел-у. Молимо вас