Trong hướng dẫn này, bạn sẽ tìm hiểu cách đếm các giá trị duy nhất trong Excel bằng công thức và cách nhận số lượng tự động các giá trị riêng biệt trong bảng tổng hợp. Chúng ta cũng sẽ thảo luận về một số ví dụ về công thức để đếm các tên, văn bản, số, giá trị duy nhất phân biệt chữ hoa chữ thường và hơn thế nữa.

Khi làm việc với một tập dữ liệu lớn trong Excel, bạn có thể thường xuyên cần phải biết có bao nhiêu giá trị duplicate và unique . Và đôi khi, bạn có thể chỉ muốn đếm các giá trị khác biệt (khác nhau).

Nếu bạn thường xuyên truy cập blog này, thì bạn đã biết công thức Excel để đếm các giá trị trùng lặp. Và hôm nay, chúng ta sẽ khám phá những cách khác nhau để đếm các giá trị duy nhất trong Excel. Nhưng để rõ ràng, trước tiên chúng ta hãy xác định các thuật ngữ.

• Giá trị duy nhất - đây là những giá trị chỉ xuất hiện trong danh sách một lần.
• Các giá trị khác biệt - đây là tất cả các giá trị khác nhau trong danh sách, tức là các giá trị duy nhất cộng với lần xuất hiện đầu tiên của các giá trị trùng lặp.

Ảnh chụp màn hình sau đây cho thấy sự khác biệt:

Và bây giờ, hãy xem cách bạn có thể đếm các giá trị riêng biệt và duy nhất trong Excel bằng cách sử dụng các công thức và tính năng PivotTable.

Cách đếm các giá trị duy nhất trong Excel

Đây là một nhiệm vụ phổ biến mà thỉnh thoảng tất cả người dùng Excel phải thực hiện. Bạn có một danh sách dữ liệu và bạn cần tìm ra số lượng giá trị duy nhất trong đóhãy chú ý theo dõi!

Đếm các giá trị duy nhất trong một cột

Giả sử bạn có một cột tên trong Excel của mình bảng tính và bạn cần đếm các tên duy nhất trong cột đó. Giải pháp là sử dụng hàm SUM kết hợp với IF và COUNTIF:

Lưu ý . Đây là một công thức mảng, vì vậy hãy chắc chắn nhấn Ctrl + Shift + Enter để hoàn thành nó. Sau khi bạn thực hiện việc này, Excel sẽ tự động đặt công thức trong {dấu ngoặc nhọn} như trong ảnh chụp màn hình bên dưới. Trong mọi trường hợp, bạn không nên nhập dấu ngoặc nhọn theo cách thủ công, điều đó sẽ không hoạt động.

Trong ví dụ này, chúng tôi đang đếm các tên duy nhất trong phạm vi A2:A10, vì vậy công thức của chúng tôi có dạng như sau:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Hơn nữa trong hướng dẫn này, chúng ta sẽ thảo luận về một số công thức khác để đếm các giá trị duy nhất thuộc các loại khác nhau. Và bởi vì tất cả các công thức đó là các biến thể của công thức giá trị duy nhất cơ bản của Excel, nên bạn nên chia nhỏ công thức trên để bạn có thể hiểu đầy đủ cách thức hoạt động của nó và điều chỉnh nó cho dữ liệu của mình. Nếu ai đó không quan tâm đến các vấn đề kỹ thuật, bạn có thể chuyển sang ngay ví dụ về công thức tiếp theo.

Cách thức hoạt động của công thức đếm giá trị duy nhất trong Excel

Như bạn thấy, 3 hàm khác nhau được sử dụng trong công thức duy nhất của chúng tôi công thức giá trị - SUM, IFvà COUNTIF. Nhìn từ trong ra ngoài, đây là chức năng của từng hàm:

• Hàm COUNTIF đếm số lần mỗi giá trị riêng lẻ xuất hiện trong phạm vi đã chỉ định.

  Trong ví dụ này, COUNTIF(A2:A10,A2:A10) trả về mảng {1;2;2;1;2;2;2;1;2} .

• Hàm IF đánh giá từng giá trị trong mảng do COUNTIF trả về, giữ tất cả giá trị 1 (giá trị duy nhất) và thay thế tất cả giá trị khác bằng số không .

  Vì vậy, hàm IF(COUNTIF(A2:A10,A2:A10)=1,1,0) trở thành IF(1;2;2;1;2;2;2;1;2) = 1,1,0, biến thành mảng {1;0;0;1;0;0;0;1;0} trong đó 1 là giá trị duy nhất và 0 là giá trị trùng lặp.

• Cuối cùng, hàm SUM cộng các giá trị trong mảng do hàm IF trả về và xuất ra tổng số giá trị duy nhất, chính xác như những gì chúng ta muốn.

Mẹo . Để xem phần cụ thể của công thức giá trị duy nhất trong Excel của bạn ước tính giá trị gì, hãy chọn phần đó trong thanh công thức và nhấn phím F9.

Đếm các giá trị văn bản duy nhất trong Excel

Nếu danh sách Excel của bạn chứa cả giá trị số và văn bản và bạn chỉ muốn đếm các giá trị văn bản duy nhất, hãy thêm hàm ISTEXT vào công thức mảng đã thảo luận ở trên:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Như bạn đã biết, hàm ISTEXT trong Excel trả về TRUE nếu giá trị được đánh giá là văn bản, FALSE nếu không. Vì dấu hoa thị (*) hoạt động như toán tử AND trong công thức mảng nên hàm IF chỉ trả về 1 nếu một giá trị vừa là văn bản vừa là duy nhất, nếu không thì trả về 0. Và sau khi hàm SUM cộng tất cả các số 1, bạn sẽ nhận được một số giá trị văn bản duy nhất trong chỉ địnhphạm vi.

Đừng quên nhấn Ctrl + Shift + Enter để nhập chính xác công thức mảng và bạn sẽ nhận được kết quả tương tự như sau:

Như bạn có thể thấy trong ảnh chụp màn hình ở trên, công thức trả về tổng số giá trị văn bản duy nhất, không bao gồm ô trống, số, giá trị lô-gic TRUE và FALSE cũng như lỗi.

Đếm giá trị số duy nhất trong Excel

Để đếm các số duy nhất trong danh sách dữ liệu, hãy sử dụng công thức mảng như chúng ta vừa sử dụng để đếm các giá trị văn bản duy nhất, với điểm khác biệt duy nhất là bạn nhúng ISNUMBER thay vì ISTEXT trong công thức giá trị duy nhất của mình:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Lưu ý. Vì Microsoft Excel lưu trữ ngày và giờ dưới dạng số sê-ri nên chúng cũng được tính.

Đếm các giá trị duy nhất phân biệt chữ hoa chữ thường trong Excel

Nếu bảng của bạn chứa dữ liệu phân biệt chữ hoa chữ thường, cách dễ nhất để đếm các giá trị duy nhất sẽ tạo cột trợ giúp với công thức mảng sau để xác định các mục trùng lặp và duy nhất:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

Sau đó, sử dụng hàm COUNTIF đơn giản để đếm các giá trị duy nhất:

=COUNTIF(B2:B10, "unique")

Đếm các giá trị riêng biệt trong Excel (lần xuất hiện duy nhất và trùng lặp đầu tiên)

Để đếm số lượng giá trị riêng biệt trong danh sách, hãy sử dụng cách sau công thức:

Hãy nhớ rằng, đó là một công thức mảng, do đó bạn nên nhấn Ctrl + Shift + Enter phím tắt thay vì Enter thông thườnggõ phím.

Ngoài ra, bạn có thể sử dụng hàm TÓM TẮT và hoàn thành công thức theo cách thông thường bằng cách nhấn phím Enter:

Ví dụ: để đếm các giá trị riêng biệt trong phạm vi A2:A10, bạn có thể sử dụng:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Hoặc

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Cách thức hoạt động của công thức riêng trong Excel

Như bạn đã biết, chúng tôi sử dụng hàm COUNTIF để tìm hiểu xem mỗi giá trị riêng lẻ xuất hiện bao nhiêu lần trong phạm vi quy định. Trong ví dụ trên, kết quả của hàm COUNTIF là mảng sau: {2;2;3;1;2;2;3;1;3} .

Sau đó, một số phép chia được thực hiện, trong đó mỗi giá trị của mảng được sử dụng làm ước số với 1 là cổ tức. Điều này biến tất cả các giá trị trùng lặp thành các số phân số tương ứng với số lần xuất hiện trùng lặp. Ví dụ: nếu một giá trị xuất hiện 2 lần trong danh sách, nó sẽ tạo ra 2 mục trong mảng có giá trị là 0,5 (1/2=0,5). Và nếu một giá trị xuất hiện 3 lần, nó sẽ tạo ra 3 mục trong mảng có giá trị là 0,3(3). Trong ví dụ của chúng tôi, kết quả của 1/COUNTIF(A2:A10,A2:A10)) là mảng {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Cho đến nay vẫn chưa có ý nghĩa gì? Đó là do chúng ta chưa áp dụng hàm SUM/SUMPRODUCT. Khi một trong các hàm này cộng các giá trị trong mảng, tổng của tất cả các số phân số cho từng mục riêng lẻ luôn cho kết quả là 1, bất kể có bao nhiêu lần xuất hiện của mục đó trong danh sách. Vàbởi vì tất cả các giá trị duy nhất xuất hiện trong mảng là 1 (1/1=1), nên kết quả cuối cùng mà công thức trả về là tổng số của tất cả các giá trị khác nhau trong danh sách.

Các công thức để đếm các giá trị riêng biệt của các giá trị khác nhau các loại

Giống như trường hợp đếm các giá trị duy nhất trong Excel, bạn có thể sử dụng các biến thể của công thức đếm riêng biệt cơ bản trong Excel để xử lý các loại giá trị cụ thể như số, văn bản và các giá trị phân biệt chữ hoa chữ thường.

Hãy nhớ rằng tất cả các công thức bên dưới đều là công thức mảng và yêu cầu nhấn Ctrl + Shift + Enter .

Đếm các giá trị riêng biệt bỏ qua các ô trống

Nếu một cột mà bạn muốn đếm các giá trị riêng biệt có thể chứa các ô trống, bạn nên thêm một hàm IF sẽ kiểm tra phạm vi đã chỉ định để tìm khoảng trống (công thức Excel cơ bản riêng biệt được thảo luận ở trên sẽ trả về lỗi #DIV/0 trong trường hợp này):

Ví dụ: để đếm các giá trị riêng biệt trong dải A2:A10, hãy sử dụng công thức mảng sau :

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Công thức đếm các giá trị văn bản riêng biệt

Để đếm các giá trị văn bản riêng biệt trong một cột, chúng ta sẽ sử dụng cùng một phương pháp mà chúng ta vừa sử dụng để loại trừ các ô trống.

Như bạn có thể dễ dàng đoán ra, chúng ta sẽ chỉ cần nhúng hàm ISTEXT vào công thức đếm riêng biệt trong Excel của mình:

Và đây là thực tếví dụ về công thức:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Công thức đếm các số riêng biệt

Để đếm các giá trị số riêng biệt (số, ngày và giờ), hãy sử dụng hàm ISNUMBER:

Ví dụ: để đếm tất cả các số khác nhau trong phạm vi A2:A10, hãy sử dụng công thức sau:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Đếm các giá trị riêng biệt phân biệt chữ hoa chữ thường trong Excel

Tương tự như đếm các giá trị duy nhất phân biệt chữ hoa chữ thường, cách dễ nhất để đếm các giá trị phân biệt có phân biệt chữ hoa chữ thường là thêm một cột trợ giúp có công thức mảng xác định các giá trị duy nhất bao gồm các lần xuất hiện trùng lặp đầu tiên. Về cơ bản, công thức này giống với công thức mà chúng tôi đã sử dụng để đếm các giá trị duy nhất phân biệt chữ hoa chữ thường, với một thay đổi nhỏ trong tham chiếu ô sẽ tạo ra sự khác biệt lớn:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

Như bạn còn nhớ, tất cả các công thức mảng trong Excel đều yêu cầu nhấn Ctrl + Shift + Enter .

Sau khi hoàn thành công thức trên, bạn có thể đếm các giá trị "khác biệt" bằng công thức COUNTIF thông thường như sau:

=COUNTIF(B2:B10, "distinct")

Nếu không thể thêm cột trợ giúp vào trang tính của mình, bạn có thể sử dụng công thức mảng phức tạp sau đây để đếm các giá trị phân biệt có phân biệt chữ hoa chữ thường mà không cần tạo một cột bổ sung:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

Đếm các hàng riêng biệt và duy nhất trong Excel

Đếm các hàng duy nhất/khác biệt trong Excel cũng giống như đếm các giá trị duy nhất và khác biệt, chỉ với Sự khác biệtrằng bạn sử dụng hàm COUNTIFS thay vì COUNTIF, hàm này cho phép bạn chỉ định một số cột để kiểm tra các giá trị duy nhất.

Ví dụ: để đếm các tên riêng biệt hoặc duy nhất dựa trên các giá trị trong cột A (Tên) và B (Last Name), sử dụng một trong các công thức sau:

Công thức đếm các hàng duy nhất:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Công thức đếm các hàng khác biệt rows:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Đương nhiên, bạn không bị giới hạn trong việc đếm các hàng duy nhất chỉ dựa trên hai cột, hàm COUNTIFS của Excel có thể xử lý đến 127 cặp phạm vi/tiêu chí.

Đếm các giá trị riêng biệt trong Excel bằng cách sử dụng PivotTable

Các phiên bản mới nhất của Excel 2013 và Excel 2016 có một tính năng đặc biệt cho phép tự động đếm các giá trị riêng biệt trong bảng tổng hợp. Ảnh chụp màn hình sau đây cung cấp ý tưởng về cách Số đếm khác biệt của Excel trông như thế nào:

Để tạo bảng tổng hợp với số đếm riêng biệt cho một cột nhất định, thực hiện các bước sau.

1. Chọn dữ liệu được đưa vào bảng tổng hợp, chuyển sang tab Chèn , nhóm Bảng và nhấp vào Nút PivotTable .
2. Trong hộp thoại Tạo PivotTable , hãy chọn đặt bảng tổng hợp của bạn vào trang tính mới hoặc trang tính hiện có và đảm bảo chọn Thêm dữ liệu này vào hộp kiểm Mô hình dữ liệu .

Bạn cũng có thể đặt tên tùy chỉnh cho Distinct Count của mình nếu muốn.

Hoàn tất! Bảng tổng hợp mới được tạo sẽ hiển thị số lượng riêng biệt như được hiển thị trong ảnh chụp màn hình đầu tiên trong phần này.

Mẹo. Sau khi cập nhật dữ liệu nguồn của bạn, hãy nhớ cập nhật PivotTable để cập nhật số lượng riêng biệt. Để làm mới bảng tổng hợp, chỉ cần nhấp vào nút Làm mới trên tab Phân tích , trong nhóm Dữ liệu .

Đây là cách bạn đếm các giá trị khác biệt và duy nhất trong Excel. Nếu ai đó muốn xem kỹ hơn các công thức được thảo luận trong hướng dẫn này, bạn có thể tải xuống sổ làm việc Excel Count Unique mẫu.

Tôi cảm ơn bạn đã đọc và hy vọng gặp lại bạn vào tuần tới. Trong bài viết tiếp theo, chúng ta sẽ thảo luận về nhiều cách khác nhau để tìm, lọc, trích xuất và đánh dấu các giá trị duy nhất trong Excel. Xin vui lòng