In deze handleiding leert u hoe u unieke waarden kunt tellen in Excel met formules, en hoe u een automatische telling van unieke waarden in een draaitabel krijgt. We bespreken ook een aantal formulevoorbeelden voor het tellen van unieke namen, teksten, getallen, unieke waarden met een hoofdletter en meer.

Wanneer u met een grote dataset in Excel werkt, moet u vaak weten hoeveel dubbel en uniek waarden zijn. En soms wil je misschien alleen de verschillende (verschillende) waarden.

Als u deze blog regelmatig bezoekt, kent u al de Excel-formule om duplicaten te tellen. En vandaag gaan we verschillende manieren verkennen om unieke waarden te tellen in Excel. Maar laten we voor de duidelijkheid eerst de begrippen definiëren.

• Uniek waarden - dit zijn de waarden die slechts eenmaal in de lijst voorkomen.
• Onderscheidend waarden - dit zijn alle verschillende waarden in de lijst, d.w.z. unieke waarden plus 1e voorkomens van dubbele waarden.

De volgende schermafbeelding toont het verschil:

Laten we nu eens kijken hoe u unieke en afzonderlijke waarden kunt tellen in Excel met behulp van formules en draaitabellen.

Hoe unieke waarden tellen in Excel

Hier is een veelvoorkomende taak die alle Excel-gebruikers af en toe moeten uitvoeren. U hebt een lijst met gegevens en u moet het aantal unieke waarden in die lijst bepalen. Hoe doet u dat? Gemakkelijker dan u misschien denkt :) Hieronder vindt u een paar formules om unieke waarden van verschillende typen te tellen.

Tellen van unieke waarden in een kolom

Stel, u hebt een kolom met namen in uw Excel-werkblad, en u moet unieke namen in die kolom tellen. De oplossing is het gebruik van de SUM-functie in combinatie met IF en COUNTIF:

Opmerking Dit is een matrixformule, dus druk op Ctrl + Shift + Enter om de formule te voltooien. Zodra u dit doet, zal Excel de formule automatisch omsluiten met {curly braces} zoals in de schermafbeelding hieronder. In geen geval moet u de accolades handmatig typen, dat werkt niet.

In dit voorbeeld tellen we unieke namen in het bereik A2:A10, dus neemt onze formule de volgende vorm aan:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Verderop in deze handleiding gaan we een handvol andere formules bespreken om unieke waarden van verschillende types te tellen. En omdat al die formules variaties zijn van de basisformule voor unieke waarden in Excel, is het zinvol om de bovenstaande formule uit te splitsen, zodat u volledig kunt begrijpen hoe ze werkt en haar kunt aanpassen aan uw gegevens. Als iemand niet geïnteresseerd is in technische details, kunt u meteen doorgaan naarhet volgende formulevoorbeeld.

Hoe de formule voor het tellen van unieke waarden in Excel werkt

Zoals u ziet, worden 3 verschillende functies gebruikt in onze formule met unieke waarden - SUM, IF en COUNTIF. Van binnen naar buiten kijkend, ziet u hier wat elke functie doet:

• De functie COUNTIF telt hoe vaak elke individuele waarde voorkomt in het opgegeven bereik.

  In dit voorbeeld, COUNTIF(A2:A10,A2:A10) geeft de matrix {1;2;2;1;2;2;2;1;2} .

• De IF-functie evalueert elke waarde in de door COUNTIF geretourneerde array, behoudt alle 1's (unieke waarden), en vervangt alle andere waarden door nullen.

  Dus, de functie IF(COUNTIF(A2:A10,A2:A10)=1,1,0) wordt IF(1;2;2;1;2;2;2;1;2) = 1,1,0, die overgaat in de array {1;0;0;1;0;0;0;1;0} waarbij 1 een unieke waarde is en 0 een dubbele waarde.

• Ten slotte telt de SUM-functie de waarden in de door IF geretourneerde array op en geeft het totale aantal unieke waarden, precies wat we wilden.

Tip: Om te zien wat een bepaald deel van uw Excel-formule met unieke waarden doet, selecteert u dat deel in de formulebalk en drukt u op de F9-toets.

Unieke tekstwaarden tellen in Excel

Indien uw Excel-lijst zowel numerieke als tekstwaarden bevat, en u wilt alleen unieke tekstwaarden tellen, voeg dan de ISTEXT-functie toe aan de hierboven besproken matrixformule:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Zoals u weet, geeft de Excel ISTEXT-functie WAAR als een geëvalueerde waarde tekst is, en anders ONWAAR. Aangezien het sterretje (*) werkt als de EN-operator in matrixformules, geeft de IF-functie alleen 1 terug als een waarde zowel tekst als uniek is, en 0 anders. En nadat de SUM-functie alle 1's heeft opgeteld, krijgt u een telling van unieke tekstwaarden in het opgegeven bereik.

Vergeet niet op Ctrl + Shift + Enter te drukken om de matrixformule correct in te voeren, en je krijgt een resultaat dat lijkt op dit:

Zoals u in de bovenstaande schermafbeelding kunt zien, geeft de formule het totale aantal unieke tekstwaarden, exclusief lege cellen, getallen, logische waarden TRUE en FALSE, en fouten.

Unieke numerieke waarden tellen in Excel

Om unieke getallen in een lijst met gegevens te tellen, gebruikt u een matrixformule zoals we zojuist hebben gebruikt voor het tellen van unieke tekstwaarden, met als enige verschil dat u ISNUMBER in plaats van ISTEXT in uw formule voor unieke waarden opneemt:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Opmerking. Aangezien Microsoft Excel datums en tijden opslaat als volgnummers, worden deze ook meegeteld.

Hoofdlettergevoelige unieke waarden tellen in Excel

Als uw tabel hoofdlettergevoelige gegevens bevat, is de eenvoudigste manier om unieke waarden te tellen het maken van een hulpkolom met de volgende matrixformule om dubbele en unieke items te identificeren:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

En gebruik dan een eenvoudige COUNTIF-functie om unieke waarden te tellen:

=COUNTIF(B2:B10, "unique")

Verschillende waarden tellen in Excel (unieke en 1e dubbele waarden)

Gebruik de volgende formule om het aantal afzonderlijke waarden in een lijst te tellen:

Vergeet niet dat het een matrixformule is, en dat u daarom de sneltoets Ctrl + Shift + Enter moet indrukken in plaats van de gebruikelijke Enter-toets.

U kunt ook de SUMPRODUCT-functie gebruiken en de formule op de gebruikelijke manier invullen door op de Enter-toets te drukken:

Bijvoorbeeld, om de verschillende waarden in het bereik A2:A10 te tellen, kunt u kiezen uit:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Of

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Hoe de Excel onderscheidende formule werkt

Zoals u al weet, gebruiken we de functie COUNTIF om na te gaan hoe vaak elke individuele waarde voorkomt in het opgegeven bereik. In het bovenstaande voorbeeld is het resultaat van de functie COUNTIF de volgende matrix: {2;2;3;1;2;2;3;1;3} .

Daarna wordt een aantal delingen uitgevoerd, waarbij elke waarde van de matrix wordt gebruikt als deler met 1 als dividend. Dit verandert alle dubbele waarden in fractionele getallen die overeenkomen met het aantal keren dat ze voorkomen. Bijvoorbeeld, als een waarde 2 keer voorkomt in de lijst, genereert het 2 items in de matrix met een waarde van 0,5 (1/2=0,5). En als een waarde 3 keer voorkomt, wordt hetproduceert 3 items in de array met een waarde van 0.3(3). In ons voorbeeld is het resultaat van 1/COUNTIF(A2:A10,A2:A10)) is de matrix {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Dat komt omdat we de SUM / SUMPRODUCT functie nog niet hebben toegepast. Wanneer een van deze functies de waarden in de array optelt, levert de som van alle fractionele getallen voor elk individueel item altijd 1 op, ongeacht het aantal voorkomens van dat item in de lijst. En omdat alle unieke waarden in de array verschijnen als 1's (1/1=1), is het eindresultaat dat wordt teruggegeven door deformule is het totale aantal van alle verschillende waarden in de lijst.

Formules om verschillende waarden van verschillende types te tellen

Net als bij het tellen van unieke waarden in Excel, kunt u variaties van de basisformule voor het tellen van verschillende waarden in Excel gebruiken om specifieke typen waarden te verwerken, zoals getallen, tekst en hoofdlettergevoelige waarden.

Denk eraan dat alle onderstaande formules matrixformules zijn en dat u daarvoor op Ctrl + Shift + Enter moet drukken.

Verschillende waarden tellen die lege cellen negeren

Indien een kolom waarin u verschillende waarden wilt tellen lege cellen kan bevatten, moet u een IF-functie toevoegen die het opgegeven bereik controleert op lege cellen (de hierboven besproken basisformule van Excel zou in dit geval de fout #DIV/0 opleveren):

Om bijvoorbeeld afzonderlijke waarden in het bereik A2:A10 te tellen, gebruikt u de volgende matrixformule:

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Formule om verschillende tekstwaarden te tellen

Om afzonderlijke tekstwaarden in een kolom te tellen, gebruiken we dezelfde aanpak die we zojuist hebben gebruikt om lege cellen uit te sluiten.

Zoals u gemakkelijk kunt raden, zullen wij de ISTEXT-functie eenvoudigweg opnemen in onze Excel-formule voor afzonderlijke tellingen:

En hier is een voorbeeld van een echte formule:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Formule om verschillende getallen te tellen

Gebruik de functie ISNUMBER om afzonderlijke numerieke waarden (getallen, datums en tijden) te tellen:

Om bijvoorbeeld alle verschillende getallen in het bereik A2:A10 te tellen, gebruikt u de volgende formule:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Hoofdlettergevoelige afzonderlijke waarden tellen in Excel

De eenvoudigste manier om hoofdlettergevoelige unieke waarden te tellen, is het toevoegen van een hulpkolom met de matrixformule die unieke waarden identificeert, inclusief de eerste dubbele voorkomens. De formule is in principe dezelfde als die we gebruikten om hoofdlettergevoelige unieke waarden te tellen, met één kleine wijziging in een celverwijzing die een groot verschil maakt:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct",")

Zoals u zich herinnert, moeten voor alle matrixformules in Excel Ctrl + Shift + Enter worden ingedrukt.

Nadat de bovenstaande formule is voltooid, kunt u de "verschillende" waarden tellen met een gebruikelijke COUNTIF-formule als deze:

=COUNTIF(B2:B10, "distinct")

Als u op geen enkele manier een hulpkolom aan uw werkblad kunt toevoegen, kunt u het volgende complex gebruiken matrixformule om hoofdlettergevoelige afzonderlijke waarden te tellen zonder een extra kolom aan te maken:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), 0), 0)).

Unieke en afzonderlijke rijen tellen in Excel

Het tellen van unieke / afzonderlijke rijen in Excel is vergelijkbaar met het tellen van unieke en afzonderlijke waarden, met als enige verschil dat u de functie COUNTIFS gebruikt in plaats van COUNTIF, waarmee u verschillende kolommen kunt opgeven om te controleren op unieke waarden.

Als u bijvoorbeeld unieke of afzonderlijke namen wilt tellen op basis van de waarden in de kolommen A (Voornaam) en B (Achternaam), gebruikt u een van de volgende formules:

Formule om unieke rijen te tellen:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Formule om verschillende rijen te tellen:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Uiteraard bent u niet beperkt tot het tellen van unieke rijen op basis van slechts twee kolommen, de Excel COUNTIFS functie kan tot 127 bereik/criteria paren verwerken.

Verschillende waarden tellen in Excel met behulp van een draaitabel

De laatste versies van Excel 2013 en Excel 2016 hebben een speciale functie waarmee afzonderlijke waarden in een draaitabel automatisch kunnen worden geteld. De volgende schermafbeelding geeft een idee van hoe Excel Onderscheidende telling lijkt erop:

Voer de volgende stappen uit om een draaitabel te maken met de afzonderlijke telling voor een bepaalde kolom.

1. Selecteer de gegevens die in een draaitabel moeten worden opgenomen, schakel over naar de Plaats tab, Tabellen groep, en klik op de Draaitabel knop.
2. In de Kruistabel maken dialoogvenster, kies of u uw draaitabel in een nieuw of een bestaand werkblad wilt plaatsen, en zorg ervoor dat u de optie Deze gegevens toevoegen aan het gegevensmodel checkbox.

U kunt ook een aangepaste naam geven aan uw Distinct Count als u dat wilt.

De nieuw aangemaakte draaitabel toont de afzonderlijke aantallen, zoals in de eerste schermafbeelding in dit deel.

Tip: Nadat u uw brongegevens hebt bijgewerkt, mag u niet vergeten de draaitabel bij te werken om de afzonderlijke telling te actualiseren. Om een draaitabel te vernieuwen, klikt u op de knop Vernieuwen knop op de Analyseer tabblad, in de Gegevens groep.

Dit is hoe u afzonderlijke en unieke waarden telt in Excel. Als iemand de formules die in deze handleiding worden besproken nader wil bekijken, kunt u de voorbeeldwerkmap Excel Count Unique downloaden.

Ik dank u voor het lezen en hoop u volgende week weer te zien. In het volgende artikel gaan we verschillende manieren bespreken om unieke waarden in Excel te vinden, te filteren, te extraheren en te markeren. Blijf kijken!