Bilangin ang natatangi at natatanging mga halaga sa Excel gamit ang formula o pivot table

Michael Brown

16-05-2023 Excel
  • Ibahagi Ito
Michael Brown

Sa tutorial na ito, matututunan mo kung paano magbilang ng mga natatanging value sa Excel gamit ang mga formula, at kung paano makakuha ng awtomatikong pagbilang ng mga natatanging value sa isang pivot table. Tatalakayin din natin ang ilang halimbawa ng formula para sa pagbibilang ng mga natatanging pangalan, text, numero, cased-sensitive na natatanging value, at higit pa.

Kapag nagtatrabaho sa isang malaking dataset sa Excel, maaaring kailanganin mong madalas na alamin kung gaano karaming duplicate at natatanging value ang naroon. At kung minsan, maaaring gusto mong bilangin lamang ang natatanging (iba't ibang) mga halaga.

Kung binibisita mo ang blog na ito nang regular, alam mo na ang Excel formula sa pagbibilang ng mga duplicate. At ngayon, tutuklasin natin ang iba't ibang paraan upang mabilang ang mga natatanging halaga sa Excel. Ngunit para sa kalinawan, tukuyin muna natin ang mga termino.

  • Natatangi na mga value - ito ang mga value na isang beses lang lumalabas sa listahan.
  • Nakakaibang na mga value - lahat ito ay iba't ibang value sa listahan, ibig sabihin, mga natatanging value kasama ang mga unang paglitaw ng mga duplicate na value.

Ipinapakita ng sumusunod na screenshot ang pagkakaiba:

At ngayon, tingnan natin kung paano mo mabibilang ang natatangi at natatanging mga value sa Excel gamit ang mga formula at feature ng PivotTable.

    Paano magbilang ng mga natatanging value sa Excel

    Narito ang isang karaniwang gawain na kailangang gampanan ng lahat ng mga user ng Excel paminsan-minsan. Mayroon kang listahan ng data at kailangan mong malaman ang bilang ng mga natatanging halaga doonmanatiling nakatutok!

    listahan. Paano mo gagawin iyon? Mas madali kaysa sa iniisip mo :) Sa ibaba ay makakahanap ka ng ilang mga formula upang mabilang ang mga natatanging halaga ng iba't ibang uri.

    Bilangin ang mga natatanging halaga sa isang column

    Ipagpalagay na mayroon kang column ng mga pangalan sa iyong Excel worksheet, at kailangan mong bilangin ang mga natatanging pangalan sa column na iyon. Ang solusyon ay ang paggamit ng SUM function kasama ng IF at COUNTIF:

    =SUM(IF(COUNTIF( range, range)=1,1,0))

    Tandaan . Isa itong array formula, kaya siguraduhing pindutin ang Ctrl + Shift + Enter upang makumpleto ito. Kapag nagawa mo na ito, awtomatikong isasama ng Excel ang formula sa {curly braces} tulad ng sa screenshot sa ibaba. Sa anumang kaso, dapat mong i-type nang manu-mano ang mga kulot na brace, hindi iyon gagana.

    Sa halimbawang ito, binibilang namin ang mga natatanging pangalan sa hanay na A2:A10, kaya ang aming formula ay may sumusunod na hugis:

    =SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

    Higit pa sa tutorial na ito, tatalakayin natin ang ilang iba pang mga formula upang mabilang ang mga natatanging halaga ng iba't ibang uri. At dahil ang lahat ng mga formula na iyon ay mga variation ng pangunahing Excel unique values ​​formula, makatuwirang hatiin ang formula sa itaas, para lubos mong maunawaan kung paano ito gumagana at i-tweak ito para sa iyong data. Kung ang isang tao ay hindi interesado sa mga teknikalidad, maaari kang lumaktaw sa susunod na halimbawa ng formula.

    Paano gumagana ang Excel count unique values ​​formula

    Sa nakikita mo, 3 iba't ibang function ang ginagamit sa aming natatanging formula ng mga halaga - SUM, IFat COUNTIF. Kung titingnan mula sa loob palabas, narito ang ginagawa ng bawat function:

    • Binibilang ng COUNTIF function kung ilang beses lalabas ang bawat indibidwal na value sa tinukoy na hanay.

      Sa halimbawang ito, ibinabalik ng COUNTIF(A2:A10,A2:A10) ang array na {1;2;2;1;2;2;2;1;2} .

    • Sinusuri ng IF function ang bawat value sa array na ibinalik ng COUNTIF, pinapanatili ang lahat ng 1 (natatanging value), at pinapalitan ang lahat ng iba pang value ng mga zero .

      Kaya, ang function na IF(COUNTIF(A2:A10,A2:A10)=1,1,0) ay nagiging IF(1;2;2;1;2;2;2;1;2) = 1,1,0, na nagiging array {1;0;0;1;0;0;0;1;0} kung saan ang 1 ay isang natatanging halaga at ang 0 ay isang duplicate na halaga.

    • Sa wakas, ang SUM function ay nagdaragdag ng mga halaga sa array na ibinalik ng IF at naglalabas ng kabuuang bilang ng mga natatanging value, na kung ano mismo ang gusto namin.

    Tip . Upang makita kung saan sinusuri ng isang partikular na bahagi ng iyong Excel unique values ​​formula, piliin ang bahaging iyon sa formula bar at pindutin ang F9 key.

    Bilangin ang mga natatanging text value sa Excel

    Kung ang iyong listahan ng Excel ay naglalaman ng parehong numerical at text value, at gusto mong bilangin lamang ang mga natatanging text value, idagdag ang ISTEXT function sa array formula na tinalakay sa itaas:

    =SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

    Tulad ng alam mo, ang Excel ISTEXT function ay nagbabalik ng TRUE kung ang isang nasuri na halaga ay text, FALSE kung hindi. Dahil ang asterisk (*) ay gumagana bilang AND operator sa array formula, ang IF function ay nagbabalik lamang ng 1 kung ang isang value ay parehong text at unique, 0 kung hindi. At pagkatapos idagdag ng SUM function ang lahat ng 1, makakakuha ka ng bilang ng mga natatanging halaga ng teksto sa tinukoy narange.

    Huwag kalimutang pindutin ang Ctrl + Shift + Enter upang maipasok nang tama ang array formula, at makakakuha ka ng resultang katulad nito:

    Tulad ng nakikita mo sa screenshot sa itaas, ibinabalik ng formula ang kabuuang bilang ng mga natatanging value ng text, hindi kasama ang mga blangkong cell, numero, lohikal na value ng TRUE at FALSE, at mga error.

    Bilangin ang mga natatanging numeric value sa Excel

    Upang magbilang ng mga natatanging numero sa isang listahan ng data, gumamit ng array formula tulad ng kakagamit lang namin sa pagbibilang ng mga natatanging value ng text, na may pagkakaiba lang na ini-embed mo ang ISNUMBER sa halip na ISTEXT sa iyong unique values ​​formula:

    =SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

    Tandaan. Dahil ang Microsoft Excel ay nag-iimbak ng mga petsa at oras bilang mga serial number, binibilang din ang mga ito.

    Bilangin ang mga case-sensitive na natatanging value sa Excel

    Kung ang iyong talahanayan ay naglalaman ng case-sensitive na data, ang pinakamadaling paraan upang mabilang ang mga natatanging value ay gagawa ng helper column na may sumusunod na array formula para matukoy ang mga duplicate at natatanging item:

    =IF(SUM((--EXACT($A$2:$A$10,A2)))=1,"Unique","Dupe")

    At pagkatapos, gumamit ng simpleng COUNTIF function para mabilang ang mga natatanging value:

    =COUNTIF(B2:B10, "unique")

    Bilangin ang mga natatanging value sa Excel (natatangi at unang mga duplicate na pangyayari)

    Upang makakuha ng bilang ng mga natatanging value sa isang listahan, gamitin ang sumusunod formula:

    =SUM(1/COUNTIF( range , range ))

    Tandaan, isa itong array formula, at samakatuwid dapat mong pindutin ang Ctrl + Shift + Enter shortcut sa halip na ang karaniwang Enterkeystroke.

    Bilang kahalili, maaari mong gamitin ang function na SUMPRODUCT at kumpletuhin ang formula sa karaniwang paraan sa pamamagitan ng pagpindot sa Enter key:

    =SUMPRODUCT(1/COUNTIF( range , range ))

    Halimbawa, para mabilang ang mga natatanging value sa range A2:A10, maaari kang pumunta sa alinman sa:

    =SUM(1/COUNTIF(A2:A10,A2:A10))

    O

    =SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

    Paano gumagana ang natatanging formula ng Excel

    Tulad ng alam mo na, ginagamit namin ang function na COUNTIF para malaman kung ilang beses lumilitaw ang bawat indibidwal na value sa tinukoy na saklaw. Sa halimbawa sa itaas, ang resulta ng function na COUNTIF ay ang sumusunod na array: {2;2;3;1;2;2;3;1;3} .

    Pagkatapos nito, isinasagawa ang ilang operasyon ng paghahati, kung saan ginagamit ang bawat value ng array bilang isang divisor na may 1 bilang ang dibidendo. Ginagawa nitong mga fractional na numero ang lahat ng duplicate na value na tumutugma sa bilang ng mga duplicate na paglitaw. Halimbawa, kung 2 beses na lumabas ang isang value sa listahan, bubuo ito ng 2 item sa array na may value na 0.5 (1/2=0.5). At kung ang isang halaga ay lilitaw nang 3 beses, ito ay gumagawa ng 3 mga item sa array na may halaga na 0.3(3). Sa aming halimbawa, ang resulta ng 1/COUNTIF(A2:A10,A2:A10)) ay ang array na {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

    Hindi pa ba gaanong makabuluhan sa ngayon? Iyon ay dahil hindi pa namin nailalapat ang function na SUM / SUMPRODUCT. Kapag ang isa sa mga function na ito ay nagdagdag ng mga halaga sa array, ang kabuuan ng lahat ng fractional na numero para sa bawat indibidwal na item ay palaging magbubunga ng 1, gaano man karaming mga paglitaw ng item na iyon ang umiiral sa listahan. Atdahil lumilitaw ang lahat ng natatanging value sa array bilang 1's (1/1=1), ang huling resulta na ibinalik ng formula ay ang kabuuang bilang ng lahat ng iba't ibang value sa listahan.

    Mga formula para mabilang ang mga natatanging value ng iba't ibang value. type

    Katulad ng kaso sa pagbibilang ng mga natatanging value sa Excel, maaari mong gamitin ang mga variation ng basic Excel count unique formula para pangasiwaan ang mga partikular na uri ng value gaya ng mga numero, text, at case-sensitive na value.

    Pakitandaan na ang lahat ng mga formula sa ibaba ay mga array formula at nangangailangan ng pagpindot sa Ctrl + Shift + Enter .

    Bilangin ang mga natatanging value na binabalewala ang mga walang laman na cell

    Kung isang column kung saan mo gustong magbilang ng mga natatanging value Maaaring naglalaman ng mga blangkong cell, dapat kang magdagdag ng function na IF na susuri sa tinukoy na hanay para sa mga blangko (ang pangunahing Excel na natatanging formula na tinalakay sa itaas ay magbabalik ng #DIV/0 error sa kasong ito):

    =SUM(IF( range "",1/COUNTIF( range , range ), 0))

    Halimbawa, para mabilang ang mga natatanging value sa range A2:A10, gamitin ang sumusunod na formula ng array :

    =SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

    Formula para mabilang ang mga natatanging value ng text

    Upang bilangin ang mga natatanging value ng text sa isang column, gagamitin namin ang parehong diskarte na ginamit namin upang ibukod ang mga walang laman na cell.

    Bilang madali mong mahulaan, i-embed lang namin ang ISTEXT function sa aming Excel count unique formula:

    =SUM(IF(ISTEXT( range ),1/COUNTIF( range , range ),""))

    At narito ang totoong buhayhalimbawa ng formula:

    =SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

    Formula para mabilang ang mga natatanging numero

    Upang bilangin ang mga natatanging halaga ng numero (mga numero, petsa at oras), gamitin ang function na ISNUMBER:

    =SUM (IF(ISNUMBER( range ),1/COUNTIF( range , range ),""))

    Halimbawa, para mabilang ang lahat ng iba't ibang numero sa hanay na A2:A10, gamitin ang sumusunod na formula:

    =SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

    Bilangin ang mga case-sensitive na natatanging value sa Excel

    Katulad ng pagbibilang ng mga case-sensitive na natatanging value, ang pinakamadaling paraan upang mabilang ang mga case-sensitive na natatanging value ay ang pagdaragdag ng helper column na may array formula na tumutukoy sa mga natatanging value kasama ang mga unang duplicate na paglitaw. Ang formula ay karaniwang kapareho ng ginamit namin upang mabilang ang mga case-sensitive na natatanging halaga, na may isang maliit na pagbabago sa isang cell reference na gumagawa ng malaking pagkakaiba:

    =IF(SUM((--EXACT($A$2:$A2,$A2)))=1,"Distinct","")

    Sa naaalala mo, lahat ng array formula sa Excel ay nangangailangan ng pagpindot sa Ctrl + Shift + Enter .

    Pagkatapos ng formula sa itaas, maaari mong bilangin ang mga "distinct" na value na may karaniwang COUNTIF formula na tulad nito:

    =COUNTIF(B2:B10, "distinct")

    Kung walang paraan na maaari kang magdagdag ng column ng helper sa iyong worksheet, maaari mong gamitin ang sumusunod na kumplikadong array formula upang mabilang ang mga case-sensitive na natatanging value nang walang paggawa ng karagdagang column:

    =SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

    Bilangin ang natatangi at natatanging mga row sa Excel

    Ang pagbibilang ng natatangi / natatanging mga row sa Excel ay katulad ng pagbibilang ng natatangi at natatanging mga value, na may tanging pagkakaibana ginagamit mo ang function na COUNTIFS sa halip na COUNTIF, na nagbibigay-daan sa iyong tumukoy ng ilang column para tingnan ang mga natatanging value.

    Halimbawa, para magbilang ng natatangi o natatanging mga pangalan batay sa mga value sa column A (First Name) at B (Apelyido), gamitin ang isa sa mga sumusunod na formula:

    Formula upang mabilang ang mga natatanging row:

    =SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

    Formula upang mabilang ang natatanging mga row:

    =SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

    Natural, hindi ka limitado sa pagbibilang ng mga natatanging row batay lamang sa dalawang column, ang Excel COUNTIFS function ay maaaring magproseso ng up hanggang 127 na mga pares ng hanay/pamantayan.

    Bilangin ang mga natatanging value sa Excel gamit ang isang PivotTable

    Ang mga pinakabagong bersyon ng Excel 2013 at Excel 2016 ay may espesyal na feature na nagbibigay-daan sa awtomatikong pagbilang ng mga natatanging value sa isang pivot table. Ang sumusunod na screenshot ay nagbibigay ng ideya kung ano ang hitsura ng Excel Distinct Count :

    Upang gumawa ng pivot table na may natatanging bilang para sa isang partikular na column, gawin ang mga sumusunod na hakbang.

    1. Piliin ang data na isasama sa isang pivot table, lumipat sa tab na Insert , Tables group, at i-click ang PivotTable na button.
    2. Sa dialog na Gumawa ng PivotTable , piliin kung ilalagay ang iyong pivot table sa bago o umiiral nang worksheet, at tiyaking piliin ang Add ang data na ito sa Data Model checkbox.

  • Kapag bumukas ang iyong pivot table, ayusin ang mga Rows, Column at Values ​​na mga lugar saparaang gusto mo. Kung wala kang gaanong karanasan sa mga Excel pivot table, maaaring makatulong ang mga sumusunod na detalyadong alituntunin: Paglikha ng PivotTable sa Excel.
  • Ilipat ang field na may natatanging bilang na gusto mong kalkulahin ( Item field sa halimbawang ito) sa Values area, i-click ito, at piliin ang Field Value Settings... mula sa drop-down na menu:

  • Magbubukas ang dialog window ng Mga Setting ng Value Field , mag-scroll ka pababa sa Distinct Count , na siyang pinakahuling opsyon sa listahan, piliin ito at i-click ang OK .

    • Maaari ka ring magbigay ng custom na pangalan sa iyong Distinct Count kung gusto mo.

    Tapos na! Ipapakita ng bagong likhang pivot table ang natatanging bilang tulad ng ipinapakita sa pinakaunang screenshot sa seksyong ito.

    Tip. Pagkatapos i-update ang iyong source data, tandaan na i-update ang PivotTable para mapapanahon ang natatanging bilang. Upang mag-refresh ng pivot table, i-click lang ang button na I-refresh sa tab na Analyze , sa grupong Data .

    Ganito ka magbibilang natatanging at natatanging mga halaga sa Excel. Kung may gustong tingnang mabuti ang mga formula na tinalakay sa tutorial na ito, malugod kang i-download ang sample na Excel Count Unique workbook.

    Nagpapasalamat ako sa iyo sa pagbabasa at umaasa akong makita kang muli sa susunod na linggo. Sa susunod na artikulo, tatalakayin natin ang iba't ibang paraan upang mahanap, i-filter, i-extract at i-highlight ang mga natatanging halaga sa Excel. Pakiusap

    Nakaraang post Paano tingnan, baguhin, alisin ang mga katangian ng dokumento ng Excel
    Susunod na post Lagda sa Outlook: kung paano lumikha, gumamit at magbago

    Si Michael Brown ay isang dedikadong mahilig sa teknolohiya na may hilig sa pagpapasimple ng mga kumplikadong proseso gamit ang mga tool sa software. Sa higit sa isang dekada ng karanasan sa industriya ng tech, hinasa niya ang kanyang mga kasanayan sa Microsoft Excel at Outlook, pati na rin ang Google Sheets at Docs. Ang blog ni Michael ay nakatuon sa pagbabahagi ng kanyang kaalaman at kadalubhasaan sa iba, na nagbibigay ng madaling sundan na mga tip at mga tutorial para sa pagpapabuti ng pagiging produktibo at kahusayan. Isa ka mang batikang propesyonal o baguhan, nag-aalok ang blog ni Michael ng mahahalagang insight at praktikal na payo para masulit ang mahahalagang software tool na ito.