Die tutoriaal verduidelik hoe om leë spasies in Excel te verwyder deur formules en die Text Toolkit-nutsding te gebruik. Jy sal leer hoe om voorste en agterste spasies in 'n sel uit te vee, ekstra spasies tussen woorde uit te skakel, ontslae te raak van nie-brekende wit spasies en nie-druk karakters.

Wat is die grootste probleem met spasies? Hulle is dikwels onsigbaar vir die menslike oog. 'n Oplettende gebruiker kan soms 'n voorste spasie voor die teks of 'n paar ekstra spasies tussen woorde opvang. Maar daar is geen manier om agterste spasies raak te sien nie, dié wat aan die einde van selle buite sig bly.

Dit sal nie veel van 'n probleem wees as ekstra spasies net rondlê nie, maar dit bemors jou formules. Die punt is dat twee selle wat dieselfde teks met en sonder spasies bevat, selfs al is dit so min as 'n enkele spasiekarakter, as verskillende waardes beskou word. So, jy is dalk besig om jou brein te probeer om uit te vind hoekom 'n ooglopend korrekte formule nie twee oënskynlik identiese inskrywings kan pas nie.

Noudat jy ten volle bewus is van die probleem, is dit tyd om te werk 'n oplossing uit. Daar is verskeie maniere om spasies uit string te verwyder, en hierdie tutoriaal sal jou help om die tegniek te kies wat die beste geskik is vir jou spesifieke taak en die datatipe waarmee jy werk.

Hoe om leeg te verwyder spasies in Excel - voor, agter, tussen woorde

As jou datastel oortollige spasies bevat, sal die ExcelTRIM-funksie kan jou help om hulle almal in een slag uit te vee - voor-, agter- en veelvuldige tussen-in spasies, behalwe vir 'n enkele spasie-karakter tussen woorde.

'n Gereelde TRIM-formule is so eenvoudig soos hierdie:

=TRIM(A2)

Waar A2 die sel is waaruit jy spasies wil uitvee.

Soos in die volgende skermkiekie getoon, het die Excel TRIM-formule ook alle spasies voor en na die teks suksesvol uitgeskakel as opeenvolgende spasies in die middel van 'n string.

En nou hoef jy net waardes in die oorspronklike kolom met geknipte waardes te vervang. Die maklikste manier om dit te doen is om Plak Spesiale > Waardes te gebruik, die gedetailleerde instruksies kan hier gevind word: Hoe om waardes in Excel te kopieer.

Boonop kan jy kan die Excel TRIM-funksie gebruik om slegs voorste spasies te verwyder, en hou alle spasies in die middel van 'n teksstring ongeskonde. Die formule-voorbeeld is hier: Hoe om voorste spasies in Excel te snoei (Linksknip).

Hoe om lynbreuke en karakters wat nie te druk word uit te vee nie

Wanneer jy data van eksterne bronne invoer, is dit nie net ekstra spasies wat saamkom, maar ook verskeie nie-drukkarakters soos koetretoer, lyntoevoer, vertikale of horisontale tab, ens.

Die TRIM-funksie kan van wit spasies ontslae raak, maar dit kan nie nie-drukende karakters uitskakel . Tegnies is Excel TRIM ontwerp om slegs waarde 32 in die 7-bis ASCII-stelsel uit te vee, wat die spasie iskarakter.

Om spasies en nie-druk karakters in 'n string te verwyder, gebruik TRIM in kombinasie met die SKOON funksie. Soos die name aandui, is CLEAN bedoel vir die skoonmaak van data, en dit kan enige en al die eerste 32 nie-drukkarakters in die 7-bis ASCII-stel (waardes 0 tot 31) uitvee, insluitend reëlbreuk ( waarde 10).

As die data wat skoongemaak moet word in sel A2 is, is die formule soos volg:

=TRIM(CLEAN(A2))

As die Trim/ Skoon formule voeg by die inhoud van veelvuldige reëls sonder spasies, jy kan dit regmaak deur een van hierdie tegnieke te gebruik:

• Gebruik die "Vervang alles"-kenmerk van Excel: in die "Vind wat"-blokkie, voer in 'n karretoer deur die Ctrl+J-kortpad te druk; en in die "Vervang met" boks, tik 'n spasie. Deur op die Vervang alles -knoppie te klik, sal alle reëlbreuke in die geselekteerde reeks vir spasies omruil.
• Gebruik die volgende formule om Karakters vir Carriage Return (waarde 13) en Line Feed (waarde 10) te vervang met spasies:

  =SUBSTITUTE(SUBSTITUTE(A2, CHAR(13)," "), CHAR(10), " ")

Vir meer inligting, sien asseblief Hoe om koets-terugsendings (reëlbreuke) in Excel te verwyder.

Hoe om nie-breek spasies te verwyder in Excel

As na die gebruik van die TRIM & SKOON formule sommige hardnekkige spasies is nog steeds daar, heel waarskynlik het jy die data van iewers gekopieer/geplak en 'n paar nie-breek spasies het ingesluip.

Om ontslae te raak van nie-breek spasies (html karakter ), vervang hulle met gewonespasies, en laat die TRIM-funksie dit dan verwyder:

=TRIM(SUBSTITUTE(A2, CHAR(160), " "))

Om die logika beter te verstaan, kom ons breek die formule af:

• 'n Nie-brekende karakter het waarde 160 in die 7-bis ASCII-stelsel, so jy kan dit definieer deur die CHAR(160)-formule te gebruik.
• Die SUBSTITUTE-funksie word gebruik om nie-brekende spasies in gereelde spasies te verander.
• En laastens, sluit jy die SUBSTITUTE-stelling in die TRIM-funksie in om die omgeskakelde spasies te verwyder.

As jou werkblad ook nie-drukende karakters bevat, gebruik die CLEAN-funksie saam met TRIM en SUBSTITUTE om te kry ontslae te raak van spasies en ongewenste simbole in een klap:

=TRIM(CLEAN((SUBSTITUTE(A2,CHAR(160)," "))))

Die volgende skermskoot demonstreer die verskil:

Hoe om 'n spesifieke nie- drukkarakter

As die skakeling van 3 funksies wat in die voorbeeld hierbo bespreek is (TRIM, CLEAN en SUBSTITUTE) nie spasies of nie-drukkarakters in jou blad kon uitskakel nie, beteken dit dat daardie karakters ASCII-waardes anders as 0 tot 3 2 (nie-druk karakters) of 160 (nie-breek spasie).

In hierdie geval, gebruik die KODE-funksie om die karakterwaarde te identifiseer, en gebruik dan SUBSTITUT om dit met 'n gewone spasie te vervang en TRIM om verwyder die spasie.

As aanvaar word dat die spasies of ander ongewenste karakters waarvan jy ontslae wil raak in sel A2 is, skryf jy 2 formules:

1. In sel B2, bespeur die problematiekkarakterwaarde deur een van die volgende KODE-funksies te gebruik:
   • Voorloopspasie of nie-drukende karakter aan die begin van die string:

     =CODE(LEFT(A2,1))

   • Topspasie of nie-druk karakter aan die einde van die string:

     =CODE(RIGHT(A2,1))

   • Spasie of nie-druk karakter in die middel van die string, waar n die posisie van die problematiese karakter is:

     =CODE(MID(A2, n , 1)))

   In hierdie voorbeeld het ons 'n onbekende nie-drukkarakter in die middel van die teks, in die 4de posisie, en ons vind die waarde daarvan uit met hierdie formule:

   =CODE(MID(A2,4,1))

   Die KODE-funksie gee waarde 127 terug (sien asseblief die skermkiekie hieronder).

2. In sel C2 vervang jy CHAR(127) met 'n gewone spasie (" "), en sny dan daardie spasie af:

   =TRIM(SUBSTITUTE(A2, CHAR(127), " "))

Die resultaat behoort iets soortgelyk soos hierdie te lyk:

As jou data 'n paar verskillende nie-druktekens sowel as nie-breekspasies bevat, kan jy twee of meer SUBSTITUT-funksies nes om te verwyder alle ongewenste karakterkodes op 'n slag:

=TRIM(SUBSTITUTE(SUBSTITUTE(A2, CHAR(127), " "), CHAR(160), " ")))

Hoe om alle spasies in Excel te verwyder

In sommige situasies wil jy dalk absoluut verwyder alle wit spasies in 'n sel, insluitend enkele spasies tussen woorde of getalle. Byvoorbeeld, wanneer jy 'n numeriese kolom ingevoer het waar spasies as duisende skeiers gebruik word, wat dit makliker maak om groot getalle te lees, maar jou formules verhoed om te bereken.

Om alle spasies te skrapin een slag, gebruik SUBSTITUT soos verduidelik in die vorige voorbeeld, met die enigste verskil dat jy die spasiekarakter wat deur CHAR(32) teruggestuur word vervang met niks (""):

=SUBSTITUTE(A2, CHAR(32), "")

Of , jy kan eenvoudig die spasie (" ") in die formule tik, soos volg:

=SUBSTITUTE(A2," ","")

Vervang daarna formules met waardes en jou getalle sal behoorlik bereken word .

Hoe om spasies in Excel te tel

Voordat jy spasies uit 'n sekere sel verwyder, is jy dalk nuuskierig om te weet hoeveel van hulle werklik daar is.

Om die totale aantal spasies in 'n sel, doen die volgende:

• Bereken die hele stringlengte deur die LEN-funksie te gebruik: LEN(A2)
• Vervang alle spasies met niks: SUBSTITUTE(A2) ," ","")
• Bereken die lengte van die string sonder spasies: LEN(SUBSTITUTE(A2," ",""))
• Trek die "spasievrye" stringlengte af vanaf die totale lengte.

As die oorspronklike teksstring in sel A2 is, gaan die volledige formule soos volg:

=LEN(A2)-LEN(SUBSTITUTE(A2," ",""))

Om uit te vind hoeveel uitb ra spasies in die sel is, kry die tekslengte sonder ekstra spasies en trek dit dan af van die totale stringlengte:

=LEN(A2)-LEN(TRIM(A2))

Die volgende skermkiekie demonstreer beide formules in aksie:

Nou dat jy weet hoeveel spasies elke sel bevat, kan jy veilig ekstra spasies uitvee deur die TRIM-formule te gebruik.

Formulevrye manier om spasies te verwyder en data skoon te maak

Soos jy reedsweet, baie ekstra spasies en ander onwelkome karakters kan ongemerk in jou blaaie skuil, veral as jy jou data van eksterne bronne invoer. Jy weet ook hoe om spasies in Excel uit te vee met 'n formule. Natuurlik is die aanleer van 'n handvol formules 'n goeie oefening om jou vaardighede op te skerp, maar dit kan tydrowend wees.

Excel-gebruikers wat hul tyd waardeer en gemak waardeer, kan voordeel trek uit die teksnutsgoed wat by ons ingesluit is. Ultimate Suite vir Excel. Een van hierdie handige nutsgoed maak dit moontlik om spasies en karakters wat nie druk nie te verwyder met 'n knoppie-klik.

Sodra dit geïnstalleer is, voeg Ultimate Suite verskeie nuttige knoppies by jou Excel-lint soos Sny spasies , Verwyder karakters , Skakel teks om , Vee formatering uit , en 'n paar meer.

Wanneer jy leë spasies in wil verwyder jou Excel-blaaie, voer hierdie 4 vinnige stappe uit:

1. Kies die selle (reeks, hele kolom of ry) waar jy ekstra spasies wil uitvee.
2. Klik die Snoei Spasies -knoppie op die Ablebits Data -oortjie.
3. Kies een of meer opsies:
   • Verwyder voorste en volgende spasies
   • Sny ekstra spasies tussen woorde tot een
   • Vee nie-breek spasies uit ( )
4. Klik op die Snoei -knoppie.

Klaar! Alle ekstra spasies word met een klik uitgevee.

Dit is hoe jy spasies vinnig kan verwyderin Excel-selle. As jy nuuskierig is om ander vermoëns te verken, is jy baie welkom om 'n evalueringsweergawe van die Ultimate Suite af te laai. Ek bedank jou vir die lees en sien uit daarna om jou volgende week op ons blog te sien!