Vandag se blogplasing gaan alles daaroor om die verskil tussen twee datums in Google Blaaie uit te vind. Jy sal baie DATEDIF-formules sien om dae, maande en jare te tel, en leer hoe NETWORKDAYS gebruik word om slegs werksdae te tel, selfs al is jou vakansies op 'n pasgemaakte skedule gebaseer.

Baie sigblaaie wat gebruikers vind datums verwarrend, indien nie uiters moeilik nie, om te hanteer. Maar glo dit of nie, daar is 'n paar handige en eenvoudige funksies vir daardie doel. DATEDIF en NETWORKDAYS is 'n paar van hulle.

DATEDIF-funksie in Google Sheets

Soos dit met funksies gebeur, suggereer hul name die aksie. Dieselfde geld vir DATEDIF. Dit moet gelees word as datum verskil , nie gedateer as , en dit staan ​​vir datum verskil . Dus, DATEDIF in Google Blaaie bereken die datumverskil tussen twee datums.

Kom ons breek dit in stukke op. Die funksie vereis drie argumente:

• begindatum – 'n datum wat as 'n beginpunt gebruik word. Dit moet een van die volgende wees:
  • 'n datum self in dubbele aanhalingstekens: "8/13/2020"
  • 'n verwysing na 'n sel met 'n datum: A2
  • 'n formule wat 'n datum gee: DATE(2020, 8, 13)
  • 'n getal wat vir 'n spesifieke datum staan ​​en wat kan deur Google Sheets as 'n datum geïnterpreteer word, bv. 44056 verteenwoordig 13 Augustus 2020 .
• einddatum – 'n datum wat gebruik isas eindpunt. Dit moet van dieselfde formaat wees as die begindatum .
• eenheid – word gebruik om die funksie te vertel watter verskil om terug te gee. Hier is 'n volledige lys eenhede wat jy kan gebruik:
  • "D" – (kort vir dae ) gee die aantal dae tussen twee datums terug.
  • "M" – (maande) die aantal volle maande tussen twee datums.
  • "Y" – (jare) die aantal volle jare.
  • "MD" – (dae ignoreer maande) die aantal dae nadat hele maande afgetrek is.
  • "YD" – (dae wat jare ignoreer) die aantal dae na aftrekking van hele jare.
  • "YM" – (maande wat jare ignoreer) die aantal volledige maande nadat volle jare afgetrek is.

Let wel. Alle eenhede moet in formules geplaas word op dieselfde manier as wat hulle hierbo verskyn – in dubbele aanhalingstekens.

Kom ons sit nou al hierdie dele saam en kyk hoe DATEDIF-formules in Google Sheets werk.

Bereken dae tussen twee datums in Google Sheets

Voorbeeld 1. Tel alle dae

Ek het 'n klein tafel om 'n paar bestellings op te spoor. Almal van hulle is in die eerste helfte van Augustus verskeep – Versendingsdatum – wat my begindatum gaan wees. Daar is ook 'n benaderde afleweringsdatum – Vervaldatum .

Ek gaan dae bereken – "D" – tussen versending en sperdatums om te sien hoe lank dit neem vir items om te arriveer. Hier is die formule wat ek moet gebruik:

=DATEDIF(B2, C2, "D")

Ek voer dieDATEDIF-formule na D2 en kopieer dit dan in die kolom af om op ander rye toe te pas.

Wenk. Jy kan altyd die hele kolom gelyktydig met 'n enkele formule bereken deur ARRAYFORMULA te gebruik:

=ArrayFormula(DATEDIF(B2:B13, C2:C13, "D"))

Voorbeeld 2. Tel dae wat maande ignoreer

Stel jou daar voor is 'n paar maande tussen twee datums:

Hoe tel jy net dae asof dit aan dieselfde maand behoort? Dit is reg: deur volle maande wat verby is, te ignoreer. DATEDIF bereken dit outomaties wanneer jy die "MD" -eenheid gebruik:

=DATEDIF(A2, B2, "MD")

Die funksie trek verstreke maande af en tel oorblywende dae .

Voorbeeld 3. Tel dae wat jare ignoreer

'n Ander eenheid – "YD" – sal help wanneer datums meer as 'n jaar tussen hulle het:

=DATEDIF(A2, B2, "YD")

Die formule sal eers jare aftrek en dan oorblywende dae bereken asof hulle aan dieselfde jaar behoort.

Tel werksdae in Google Blaaie

Daar is 'n spesiale geval wanneer jy net werksdae in Google Sheets moet tel. DATEDIF-formules sal nie veel van 'n hulp hier wees nie. En ek glo jy sal saamstem dat dit nie die mees elegante opsie is om naweke met die hand af te trek nie.

Gelukkig het Google Sheets 'n paar nie-so-tower towerspreuke daarvoor :)

Voorbeeld 1. NETWORKDAYS-funksie

Die eerste een word NETWERKDAE genoem. Hierdie funksie bereken die aantal werksdae tussen twee datums uitgesluit naweke (Saterdag enSondag) en selfs vakansiedae indien nodig:

• begin_datum – 'n datum wat as 'n beginpunt gebruik word. Vereis.

  Let wel. Indien hierdie datum nie 'n vakansiedag is nie, word dit as 'n werksdag gereken.

• einddatum – 'n datum wat as 'n eindpunt gebruik word. Vereis.

  Let wel. Indien hierdie datum nie 'n vakansiedag is nie, word dit as 'n werksdag gereken.

• vakansies – hierdie een is opsioneel vir wanneer jy spesifieke vakansiedae moet uitwys. Dit moet 'n reeks datums of nommers wees wat datums verteenwoordig.

Om te illustreer hoe dit werk, sal ek 'n lys vakansiedae byvoeg wat tussen versending en sperdatums plaasvind:

Dus, kolom B is my begindatum, kolomme C – einddatum. Datums in kolom E is die vakansiedae om te oorweeg. Hier is hoe die formule moet lyk:

=NETWORKDAYS(B2, C2, $E$2:$E$4)

Wenk. As jy die formule na ander selle gaan kopieer, gebruik absolute selleverwysings vir vakansies om foute of verkeerde resultate te vermy. Of oorweeg dit om eerder 'n skikkingsformule te bou.

Het jy opgelet hoe die aantal dae afgeneem het in vergelyking met die DATEDIF-formules? Want nou trek die funksie outomaties alle Saterdae, Sondae en twee vakansiedae af wat op Vrydag en Maandag plaasvind.

Let wel. Anders as DATEDIF in Google Blaaie, tel NETWORKDAYS begin_dag en einddag as werksdae, tensy dit vakansiedae is. Gevolglik gee D7 1 terug.

Voorbeeld 2.NETWORKDAYS.INTL vir Google Sheets

As jy 'n pasgemaakte naweekskedule het, sal jy by 'n ander funksie baat: NETWORKDAYS.INTL. Dit laat jou werksdae in Google Blaaie tel op grond van persoonlik vasgestelde naweke:

• begin_datum – 'n datum gebruik as 'n beginpunt. Vereis.
• einddatum – 'n datum wat as 'n eindpunt gebruik word. Vereis.

  Let wel. NETWORKDAYS.INTL in Google Sheets tel ook begin_dag en einddag as werksdae, tensy dit vakansiedae is.

• naweek – hierdie een is opsioneel. As dit weggelaat word, word Saterdag en Sondag as naweke beskou. Maar jy kan dit op twee maniere verander:
  • Maskes .

    Wenk. Hierdie manier is perfek vir wanneer jou afdae oor die hele week versprei is.

    Masker is 'n sewesyferpatroon van 1'e en 0'e. 1 staan ​​vir 'n naweek, 0 vir 'n werksdag. Die eerste syfer in die patroon is altyd Maandag, die laaste een - Sondag.

    Byvoorbeeld, "1100110" beteken dat jy op Woensdag, Donderdag, Vrydag en Saterdag werk.

    Let wel. Die masker moet tussen dubbele aanhalingstekens geplaas word.

  • Nommers .

    Gebruik eensyfergetalle (1-7) wat 'n paar vasgestelde naweke aandui:

    Getal	Naweek
    1	Saterdag, Sondag
    2	Sondag, Maandag
    3	Maandag, Dinsdag
    4	Dinsdag,Woensdag
    5	Woensdag, Donderdag
    6	Donderdag, Vrydag
    7	Vrydag, Saterdag

    Of werk met tweesyfergetalle (11-17) wat een dag vir rus aandui binne 'n week:

    Getal	Naweekdag
    11	Sondag
    12	Maandag
    13	Dinsdag
    14	Woensdag
    15	Donderdag
    16	Vrydag
    17	Saterdag

• vakansies – dit is ook opsioneel en word gebruik om vakansiedae te spesifiseer.

Hierdie funksie mag dalk ingewikkeld lyk as gevolg van al daardie getalle, maar ek moedig jou aan om dit te probeer.

Eers, net kry 'n duidelike begrip van jou afdae. Kom ons maak dit Sondag en Maandag . Besluit dan op die pad om jou naweke aan te dui.

As jy met 'n masker gaan, sal dit so wees – 1000001 :

=NETWORKDAYS.INTL(B2, C2, "1000001")

Maar aangesien ek twee naweekdae in 'n ry het, kan ek 'n nommer uit die tabelle hierbo gebruik, 2 in my geval:

=NETWORKDAYS.INTL(B2, C2, 2)

Voeg dan eenvoudig die laaste argument – ​​verwys na vakansiedae in kolom E, en die formule is gereed:

=NETWORKDAYS.INTL(B2, C2, 2, $E$2:$E$4)

Google Sheets en datumverskil in maande

Soms maak maande meer saak as dae. As dit vir jou waar is en jy verkies om die datumverskil in maande eerder as dae te kry, laat Google Sheets toeDATEDIF doen die werk.

Voorbeeld 1. Die aantal volle maande tussen twee datums

Die dril is dieselfde: die begin_datum gaan eerste, gevolg deur die einddatum en "M" – wat vir maande staan ​​– as 'n laaste argument:

=DATEDIF(A2, B2, "M")

Wenk. Moenie vergeet van die ARRAUFORMULA-funksie wat jou kan help om maande op alle rye gelyktydig te tel nie:

=ARRAYFORMULA(DATEDIF(A2:A13, B2:B13, "M"))

Voorbeeld 2. Die aantal maande wat jare ignoreer

Jy hoef dalk nie tel maande deur alle jare tussen begin- en einddatums. En DATEDIF laat jou dit doen.

Gebruik net die "YM" -eenheid en die formule sal eers hele jare aftrek, en dan die aantal maande tussen datums tel:

=DATEDIF(A2, B2, "YM")

Bereken jare tussen twee datums in Google Sheets

Die laaste (maar nie die minste nie) ding om jou te wys is hoe Google Sheets DATEDIF die datum bereken verskil in jare.

Ek gaan die aantal jare wat paartjies getroud is bereken op grond van hul troudatums en vandag se datum:

Soos jy dalk al geraai het, sal ek die "Y" -eenheid daarvoor gebruik:

=DATEDIF(A2, B2, "Y")

Al hierdie DATEDIF-formules is die eerste om te probeer wanneer dit kom by die berekening van dae, maande en jare tussen twee datums in Google Blaaie.

As jou saak nie hierdeur opgelos kan word nie of as jy enige vrae het, moedig ek jou aan om dit te deel saam met ons in die kommentaar afdelinghieronder.