Mục lục
Hướng dẫn cho biết cách sử dụng hàm TEXTJOIN để hợp nhất văn bản trong Excel với các ví dụ thực tế.
Cho đến gần đây, có hai phương pháp phổ biến để hợp nhất nội dung ô trong Excel: phép nối toán tử và hàm CONCATENATE. Với sự ra đời của TEXTJOIN, có vẻ như một giải pháp thay thế mạnh mẽ hơn đã xuất hiện, cho phép bạn nối văn bản theo cách linh hoạt hơn bao gồm cả bất kỳ dấu phân cách nào ở giữa. Nhưng trên thực tế, còn nhiều hơn thế nữa!
Hàm TEXTJOIN trong Excel
TEXTJOIN trong Excel hợp nhất các chuỗi văn bản từ nhiều ô hoặc phạm vi và phân tách các giá trị được kết hợp bằng bất kỳ dấu phân cách nào mà bạn chỉ định. Nó có thể bỏ qua hoặc bao gồm các ô trống trong kết quả.
Hàm này có sẵn trong Excel cho Office 365, Excel 2021 và Excel 2019.
Cú pháp của hàm TEXTJOIN như sau :
TEXTJOIN(dấu phân cách, bỏ qua_empty, text1, [text2],…)Ở đâu:
- Dấu phân cách (bắt buộc) - là dấu phân cách giữa mỗi giá trị văn bản mà bạn kết hợp. Thông thường, nó được cung cấp dưới dạng chuỗi văn bản nằm trong dấu ngoặc kép hoặc tham chiếu đến ô chứa chuỗi văn bản. Một số được cung cấp dưới dạng dấu phân cách được coi là văn bản.
- Ignore_empty (bắt buộc) - Xác định xem có bỏ qua các ô trống hay không:
- TRUE - bỏ qua mọi ô trống.
- SAI - bao gồm các ô trống trong chuỗi kết quả.
- Văn bản1 (bắt buộc) - giá trị đầu tiên để tham gia. Có thể được cung cấp dưới dạng chuỗi văn bản, tham chiếu đến ô chứa chuỗi hoặc mảng chuỗi, chẳng hạn như một dải ô.
- Text2 , … (tùy chọn) - giá trị văn bản bổ sung để được kết hợp với nhau. Cho phép tối đa 252 đối số văn bản, bao gồm text1 .
Ví dụ: hãy kết hợp các phần địa chỉ từ các ô B2, C2 và D2 lại với nhau thành một ô, tách các giá trị bằng dấu phẩy và khoảng trắng:
Với hàm CONCATENATE, bạn cần chỉ định từng ô riêng lẻ và đặt dấu phân cách (", ") sau mỗi tham chiếu, điều này có thể gây khó chịu khi hợp nhất nội dung của nhiều ô ô:
=CONCATENATE(A2, ", ", B2, ", ", C2)
Với Excel TEXTJOIN, bạn chỉ định dấu phân cách một lần trong đối số đầu tiên và cung cấp một dải ô cho đối số thứ ba:
=TEXTJOIN(", ", TRUE, A2:C2) 
TEXTJOIN trong Excel - 6 điều cần nhớ
Để sử dụng hiệu quả TEXTJOIN trong trang tính của bạn, bạn cần lưu ý một số điểm quan trọng sau:
- TEXTJOIN là một công cụ mới chỉ khả dụng trong Excel 2019 - Excel 365. Trong các phiên bản Excel cũ hơn, vui lòng sử dụng hàm CONCATENATE hoặc "&" thay vào đó.
- Trong các phiên bản mới nếu là Excel, bạn cũng có thể sử dụng hàm CONCAT để nối các giá trị từ các ô và phạm vi riêng biệt, nhưng không có tùy chọn cho dấu phân cách hoặc ô trống.
- Bất kỳ số nào được cung cấp để TEXTJOIN cho dấu phân cách hoặc văn bản đối số được chuyển đổi thành văn bản.
- Nếu dấu phân cách không được chỉ định hoặc là một chuỗi rỗng (""), các giá trị văn bản sẽ được nối mà không có bất kỳ dấu phân cách nào.
- Hàm có thể xử lý tối đa 252 đối số văn bản.
- Chuỗi kết quả có thể chứa tối đa 32.767 ký tự, đây là giới hạn ô trong Excel. Nếu vượt quá giới hạn này, công thức TEXTJOIN sẽ trả về lỗi #VALUE! lỗi.
Cách nối văn bản trong Excel - ví dụ về công thức
Để hiểu rõ hơn về tất cả các ưu điểm của TEXTJOIN, chúng ta hãy xem cách sử dụng hàm trong các tình huống thực tế .
Chuyển đổi cột thành danh sách được phân tách bằng dấu phẩy
Khi bạn đang tìm cách nối một danh sách dọc phân tách các giá trị bằng dấu phẩy, dấu chấm phẩy hoặc bất kỳ dấu phân cách nào khác, TEXTJOIN là chức năng phù hợp để sử dụng.
Trong ví dụ này, chúng tôi sẽ kết hợp các trận thắng và thua của từng đội từ bảng bên dưới. Điều này có thể được thực hiện bằng các công thức sau, các công thức này chỉ khác nhau về phạm vi ô được nối.
Đối với Nhóm 1:
=TEXTJOIN(",", FALSE, B2:B6)
Đối với Nhóm 2:
=TEXTJOIN(",", FALSE, C2:C6)
V.v.
Trong tất cả các công thức, các đối số sau được sử dụng:
- Dấu phân cách - a dấu phẩy (",").
- Ignore_empty được đặt thành FALSE để bao gồm các ô trống vì chúng tôi cần hiển thị trò chơi nào không được chơi.
Là kết quả, bạn sẽ nhận được bốn danh sách được phân tách bằng dấu phẩy thể hiện các trận thắng và trận thua của mỗi đội ở dạng thu gọn: 
Nối các ô bằng các dấu phân cách khác nhau
Trong trường hợp bạn cần tách các giá trị được kết hợp bằng các dấu phân cách khác nhau, bạn có thể cung cấp một số dấu phân cách dưới dạng hằng số mảng hoặc nhập từng dấu phân cách vào một ô riêng biệt và sử dụng tham chiếu phạm vi cho đối số dấu phân cách .
Giả sử bạn muốn nối các ô chứa các phần tên khác nhau và nhận kết quả ở định dạng sau: Họ , Tên Tên đệm .
Như bạn có thể thấy, Họ và Tên được phân tách bằng dấu phẩy và dấu cách (", ") trong khi Tên và Tên đệm được phân tách bằng dấu cách (" ") chỉ có. Vì vậy, chúng ta đưa hai dấu phân cách này vào một hằng số mảng {", "," "} và nhận được công thức sau:
=TEXTJOIN({", "," "}, TRUE, A2:C2)
Trong đó A2:C2 là các phần tên được kết hợp.
Ngoài ra, bạn có thể nhập dấu phân cách không có dấu ngoặc kép vào một số ô trống (ví dụ: dấu phẩy và dấu cách trong F3 và dấu cách trong G3) và sử dụng phạm vi $F$3:$G$3 (vui lòng lưu ý tham chiếu ô tuyệt đối) cho đối số dấu phân cách :
=TEXTJOIN($F$3:$G$3, TRUE, A2:C2) 
Bằng cách sử dụng phương pháp chung này, bạn có thể hợp nhất nội dung ô ở nhiều dạng khác nhau.
Ví dụ: nếu bạn muốn kết quả ở định dạng Tên Tên đệm ban đầu Họ thì hãy sử dụng hàm LEFT để trích xuất ký tự đầu tiên (ký tự đầu tiên) từ ô C2. Đối với các dấu phân cách, chúng tôi đặt khoảng trắng ("") giữa Tên và Chữ cái đầu tên đệm; mộtdấu chấm và khoảng trắng (".") giữa Tên viết tắt và Họ:
=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2) 
Nối văn bản và ngày tháng trong Excel
Trong một trường hợp cụ thể khi bạn hợp nhất văn bản và ngày tháng, việc cung cấp ngày tháng trực tiếp cho công thức TEXTJOIN sẽ không hoạt động. Như bạn có thể nhớ, Excel lưu trữ ngày tháng dưới dạng số sê-ri, vì vậy, công thức của bạn sẽ trả về một số đại diện cho ngày tháng như trong ảnh chụp màn hình bên dưới:
=TEXTJOIN(" ", TRUE, A2:B2) 
Để khắc phục điều này, bạn cần chuyển đổi ngày thành một chuỗi văn bản trước khi nối nó. Và ở đây hàm TEXT với mã định dạng mong muốn (trong trường hợp của chúng tôi là "mm/dd/yyyy") rất hữu ích:
=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy")) 
Hợp nhất văn bản với dấu ngắt dòng
Nếu bạn muốn hợp nhất văn bản trong Excel để mỗi giá trị bắt đầu trong một dòng mới, hãy sử dụng CHAR(10) làm dấu phân cách (trong đó 10 là ký tự xuống dòng).
Ví dụ: để kết hợp văn bản từ các ô A2 và B2 phân tách các giá trị bằng dấu ngắt dòng, đây là công thức sẽ sử dụng:
=TEXTJOIN(CHAR(10), TRUE, A2:B2) 
Mẹo. Để kết quả hiển thị thành nhiều dòng như trong ảnh chụp màn hình ở trên, hãy đảm bảo rằng tính năng Ngắt dòng văn bản được bật.
TEXTJOIN IF để hợp nhất văn bản có điều kiện
Do khả năng TEXTJOIN của Excel xử lý các mảng chuỗi, nó cũng có thể được sử dụng để hợp nhất có điều kiện nội dung của hai hoặc nhiều ô. Để hoàn thành, hãy sử dụng hàm IF để đánh giá một dải ô và trả về một mảng giá trị đáp ứng điều kiện cho đối số text1 củaTEXTJOIN.
Từ bảng hiển thị trong ảnh chụp màn hình bên dưới, giả sử bạn muốn truy xuất danh sách các thành viên Nhóm 1 . Để đạt được điều này, hãy lồng câu lệnh IF sau vào đối số text1 :
IF($B$2:$B$9=1, $A$2:$A$9, "")
Nói bằng tiếng Anh đơn giản, công thức trên cho biết: Nếu cột B bằng 1, hãy trả về a giá trị từ cột A trong cùng một hàng; nếu không thì trả về một chuỗi rỗng.
Công thức hoàn chỉnh cho Đội 1 có dạng sau:
=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))
Theo cách tương tự, bạn có thể nhận được một danh sách các thành viên của Nhóm 2:
=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, "")) 
Lưu ý, được phân tách bằng dấu phẩy. Do tính năng Mảng động có sẵn trong Excel 365 và 2021, tính năng này hoạt động như một công thức thông thường, được hiển thị trong ảnh chụp màn hình ở trên. Trong Excel 2019, bạn phải nhập nó dưới dạng công thức mảng truyền thống bằng cách nhấn phím tắt Ctrl + Shift + Enter.
Tra cứu và trả về nhiều kết quả khớp trong danh sách được phân tách bằng dấu phẩy
Có thể bạn đã biết, Hàm VLOOKUP của Excel chỉ có thể trả về kết quả khớp tìm thấy đầu tiên. Nhưng nếu bạn cần lấy tất cả các kết quả trùng khớp cho một ID, SKU cụ thể hoặc thứ gì khác thì sao?
Để xuất kết quả trong các ô riêng biệt, hãy sử dụng một trong các công thức được mô tả trong Cách VLOOKUP nhiều giá trị trong Excel.
Để tra cứu và trả về tất cả các giá trị phù hợp trong một ô dưới dạng danh sách được phân tách bằng dấu phẩy, hãy sử dụng công thức TEXTJOIN IF.
Để xem cách thức hoạt động của công thức này trong thực tế, hãy truy xuất danh sách sản phẩm được mua bởi một người bán nhất định từ bảng mẫuphía dưới. Điều này có thể dễ dàng thực hiện với công thức sau:
=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))
Trong đó A2:A12 là tên người bán, B2:B12 là sản phẩm và D2 là người bán quan tâm.
Công thức trên chuyển sang E2 và mang lại tất cả các kết quả phù hợp cho người bán mục tiêu trong D2 (Adam). Do việc sử dụng khéo léo các tham chiếu ô tương đối (đối với người bán mục tiêu) và tuyệt đối (đối với tên người bán và sản phẩm), công thức sao chép chính xác vào các ô bên dưới và cũng hoạt động tốt cho hai người bán khác: 
Ghi chú. Giống như ví dụ trước, công thức này hoạt động như một công thức thông thường trong Excel 365 và 2021 cũng như dưới dạng công thức CSE (Ctrl + Shift + Enter ) trong Excel 2019.
Logic của công thức hoàn toàn giống như trong ví dụ trước:
Câu lệnh IF so sánh từng tên trong A2:A12 với tên mục tiêu trong D2 (trong trường hợp của chúng ta là Adam):
IF($A$2:$A$12=D2, $B$2:$B$12, "")
Nếu kiểm tra logic đánh giá thành TRUE (tức là tên trong D2 khớp với tên trong cột A), công thức trả về một tích từ cột B; nếu không thì một chuỗi rỗng ("") được trả về. Kết quả của IF là mảng sau:
{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}
Mảng chuyển đến hàm TEXTJOIN dưới dạng đối số text1 . Và vì TEXTJOIN được định cấu hình để phân tách các giá trị bằng dấu phẩy và dấu cách (", "), chúng tôi nhận được chuỗi này làm kết quả cuối cùng:
Chuối, Táo, Cam, Chanh
Excel TEXTJOIN không hoạt động
Khi công thức TEXTJOIN của bạn bị lỗi, rất có thể đó làtrở thành một trong những người sau:
- #NAME? lỗi xảy ra khi TEXTJOIN được sử dụng trong phiên bản Excel cũ hơn mà chức năng này không được hỗ trợ (trước năm 2019) hoặc khi tên của hàm bị sai chính tả.
- #VALUE! xảy ra lỗi nếu chuỗi kết quả vượt quá 32.767 ký tự.
- #VALUE! lỗi cũng có thể xảy ra nếu Excel không nhận dạng được dấu phân cách dưới dạng văn bản, chẳng hạn như nếu bạn cung cấp một số ký tự không in được như CHAR(0).
Đó là cách sử dụng hàm TEXTJOIN trong Excel. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!
Các bản tải xuống có sẵn
Ví dụ về công thức Excel TEXTJOIN
