Tutorial menunjukkan cara menggunakan fungsi TEXTJOIN untuk menggabungkan teks dalam Excel dengan contoh praktikal.

Sehingga baru-baru ini, terdapat dua kaedah lazim untuk menggabungkan kandungan sel dalam Excel: penggabungan operator dan fungsi CONCATENATE. Dengan pengenalan TEXTJOIN, nampaknya alternatif yang lebih berkuasa telah muncul, yang membolehkan anda menyertai teks dengan cara yang lebih fleksibel termasuk sebarang pembatas di antaranya. Tetapi sebenarnya, banyak lagi yang perlu dilakukan!

Fungsi TEXTJOIN Excel

TEXTJOIN dalam Excel menggabungkan rentetan teks daripada berbilang sel atau julat dan memisahkan nilai gabungan dengan sebarang pembatas yang anda tentukan. Ia boleh sama ada mengabaikan atau memasukkan sel kosong dalam hasilnya.

Fungsi ini tersedia dalam Excel untuk Office 365, Excel 2021 dan Excel 2019.

Sintaks fungsi TEXTJOIN adalah seperti berikut :

Di mana:

• Delimiter (diperlukan) - ialah pemisah antara setiap nilai teks yang anda gabungkan. Biasanya, ia dibekalkan sebagai rentetan teks yang disertakan dalam petikan berganda atau rujukan kepada sel yang mengandungi rentetan teks. Nombor yang dibekalkan sebagai pembatas dianggap sebagai teks.
• Abaikan_kosong (diperlukan) - Menentukan sama ada untuk mengabaikan sel kosong atau tidak:
  • TRUE - mengabaikan sebarang sel kosong.
  • FALSE - masukkan sel kosong dalam rentetan yang terhasil.
• Teks1 (diperlukan) - nilai pertama untuk disertai. Boleh dibekalkan sebagai rentetan teks, rujukan kepada sel yang mengandungi rentetan atau tatasusunan rentetan seperti julat sel.
• Teks2 , … (pilihan) - nilai teks tambahan untuk disatukan. Maksimum 252 argumen teks dibenarkan, termasuk text1 .

Sebagai contoh, mari gabungkan bahagian alamat daripada sel B2, C2 dan D2 bersama-sama ke dalam satu sel, memisahkan nilai dengan koma dan ruang:

Dengan fungsi CONCATENATE, anda perlu menentukan setiap sel secara individu dan meletakkan pembatas (", ") selepas setiap rujukan, yang mungkin menyusahkan apabila menggabungkan kandungan banyak sel:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Dengan Excel TEXTJOIN, anda menentukan pembatas hanya sekali dalam argumen pertama dan membekalkan julat sel untuk argumen ketiga:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN dalam Excel - 6 perkara yang perlu diingat

Untuk menggunakan TEXTJOIN dalam lembaran kerja anda dengan berkesan, terdapat beberapa perkara penting yang perlu diambil perhatian:

1. TEXTJOIN ialah perkara baharu fungsi, yang hanya tersedia dalam Excel 2019 - Excel 365. Dalam versi Excel terdahulu, sila gunakan fungsi CONCATENATE atau "&" operator sebaliknya.
2. Dalam versi baharu jika Excel, anda juga boleh menggunakan fungsi CONCAT untuk menggabungkan nilai daripada sel dan julat yang berasingan, tetapi tanpa pilihan untuk pembatas atau sel kosong.
3. Sebarang nombor yang dibekalkan untuk TEXTJOIN untuk pembatas atau teks argumen ditukar kepada teks.
4. Jika pembatas tidak ditentukan atau rentetan kosong (""), nilai teks digabungkan tanpa sebarang pembatas.
5. Fungsi ini boleh mengendalikan sehingga 252 argumen teks.
6. Rentetan yang terhasil boleh mengandungi maksimum 32,767 aksara, iaitu had sel dalam Excel. Jika had ini melebihi, formula TEXTJOIN mengembalikan #VALUE! ralat.

Cara untuk menyertai teks dalam Excel - contoh formula

Untuk lebih memahami semua kelebihan TEXTJOIN, mari kita lihat cara menggunakan fungsi dalam senario kehidupan sebenar .

Tukar lajur kepada senarai dipisahkan koma

Apabila anda ingin menggabungkan senarai menegak yang memisahkan nilai dengan koma, koma bertitik atau sebarang pembatas lain, TEXTJOIN ialah fungsi yang sesuai untuk digunakan.

Untuk contoh ini, kami akan menggabungkan kemenangan dan kekalahan setiap pasukan daripada jadual di bawah. Ini boleh dilakukan dengan formula berikut, yang berbeza hanya dalam julat sel yang dicantumkan.

Untuk Pasukan 1:

=TEXTJOIN(",", FALSE, B2:B6)

Untuk Pasukan 2:

=TEXTJOIN(",", FALSE, C2:C6)

Dan seterusnya.

Dalam semua formula, argumen berikut digunakan:

• Pembatas - a koma (",").
• Ignore_empty ditetapkan kepada FALSE untuk memasukkan sel kosong kerana kita perlu menunjukkan permainan yang tidak dimainkan.

Sebagai Hasilnya, anda akan mendapat empat senarai dipisahkan koma yang mewakili kemenangan dan kekalahan setiap pasukan dalam bentuk padat:

Sertai sel dengan pembatas berbeza

Dalam situasi apabila anda perlu memisahkan nilai gabungan dengan pembatas berbeza, anda boleh sama ada membekalkan beberapa pembatas sebagai pemalar tatasusunan atau memasukkan setiap pembatas dalam sel yang berasingan dan gunakan rujukan julat untuk hujah pembatas .

Andaikata anda ingin menyertai sel yang mengandungi bahagian nama yang berbeza dan mendapatkan hasil dalam format ini: Nama akhir , Nama pertama Nama tengah .

Seperti yang anda lihat, Nama Akhir dan Nama Pertama dipisahkan dengan koma dan ruang (", ") manakala Nama Pertama dan Nama Tengah dengan ruang (" ") sahaja. Jadi, kami memasukkan kedua-dua pembatas ini dalam pemalar tatasusunan {", "," "} dan dapatkan formula berikut:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Di mana A2:C2 ialah bahagian nama yang akan digabungkan.

Sebagai alternatif, anda boleh menaip pembatas tanpa tanda petikan dalam beberapa sel kosong (katakan, koma dan ruang dalam F3 dan ruang dalam G3) dan gunakan julat $F$3:$G$3 (sila ambil perhatian rujukan sel mutlak) untuk hujah pembatas :

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Dengan menggunakan pendekatan umum ini, anda boleh menggabungkan kandungan sel dalam pelbagai bentuk.

Sebagai contoh, jika anda mahukan hasil dalam format Nama pertama Awal tengah Nama akhir , kemudian gunakan fungsi LEFT untuk mengekstrak aksara pertama (huruf awal) daripada sel C2. Bagi pembatas, kami meletakkan ruang (" ") antara nama Pertama dan awalan Tengah; atempoh dan ruang (". ") antara Nama Awal dan Nama Akhir:

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Sertai teks dan tarikh dalam Excel

Dalam kes tertentu apabila anda menggabungkan teks dan tarikh, membekalkan tarikh terus kepada formula TEXTJOIN tidak akan berfungsi. Seperti yang anda ingat, Excel menyimpan tarikh sebagai nombor siri, jadi formula anda akan mengembalikan nombor yang mewakili tarikh seperti yang ditunjukkan dalam tangkapan skrin di bawah:

=TEXTJOIN(" ", TRUE, A2:B2)

Untuk membetulkannya, anda perlu menukar tarikh ke dalam rentetan teks sebelum menyertainya. Dan di sini fungsi TEXT dengan kod format yang diingini ("mm/dd/yyyy" dalam kes kami) berguna:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Gabungkan teks dengan pemisah baris

Jika anda ingin menggabungkan teks dalam Excel supaya setiap nilai bermula dalam baris baharu, gunakan CHAR(10) sebagai pembatas (di mana 10 ialah aksara suapan baris).

Sebagai contoh, untuk menggabungkan teks daripada sel A2 dan B2 yang memisahkan nilai dengan pemisah baris, ini ialah formula untuk digunakan:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Petua. Untuk hasil dipaparkan dalam berbilang baris seperti yang ditunjukkan dalam tangkapan skrin di atas, pastikan ciri teks Balut dihidupkan.

TEXTJOIN JIKA untuk menggabungkan teks dengan syarat

Disebabkan keupayaan Excel TEXTJOIN mengendalikan tatasusunan rentetan, ia juga boleh digunakan untuk menggabungkan kandungan dua atau lebih sel secara bersyarat. Untuk melakukannya, gunakan fungsi IF untuk menilai julat sel dan mengembalikan tatasusunan nilai yang memenuhi syarat kepada argumen text1 bagiTEXTJOIN.

Daripada jadual yang ditunjukkan dalam tangkapan skrin di bawah, katakan anda ingin mendapatkan semula senarai ahli Pasukan 1 . Untuk mencapai matlamat ini, sarangkan pernyataan IF berikut ke dalam argumen text1 :

IF($B$2:$B$9=1, $A$2:$A$9, "")

Dalam bahasa Inggeris biasa, formula di atas mengatakan: Jika lajur B sama dengan 1, kembalikan a nilai dari lajur A dalam baris yang sama; sebaliknya kembalikan rentetan kosong.

Formula lengkap untuk Pasukan 1 mengambil bentuk ini:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Dengan cara yang sama, anda boleh mendapatkan senarai ahli Pasukan yang dipisahkan koma 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Nota. Disebabkan ciri Tatasusunan Dinamik yang tersedia dalam Excel 365 dan 2021, ini berfungsi sebagai formula biasa, ditunjukkan dalam tangkapan skrin di atas. Dalam Excel 2019, anda mesti memasukkannya sebagai formula tatasusunan tradisional dengan menekan pintasan Ctrl + Shift + Enter.

Cari dan kembalikan berbilang padanan dalam senarai dipisahkan koma

Seperti yang anda mungkin tahu, Fungsi Excel VLOOKUP hanya boleh mengembalikan padanan pertama yang ditemui. Tetapi bagaimana jika anda perlu mendapatkan semua padanan untuk ID tertentu, SKU atau sesuatu yang lain?

Untuk mengeluarkan hasil dalam sel berasingan, gunakan salah satu formula yang diterangkan dalam Cara VLOOKUP berbilang nilai dalam Excel.

Untuk mencari dan mengembalikan semua nilai yang sepadan dalam sel tunggal sebagai senarai yang dipisahkan koma, gunakan formula TEXTJOIN IF.

Untuk melihat cara ia berfungsi dalam amalan, mari dapatkan semula senarai produk yang dibeli oleh penjual tertentu daripada jadual sampeldi bawah. Ini boleh dilakukan dengan mudah dengan formula berikut:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Di mana A2:A12 ialah nama penjual, B2:B12 ialah produk dan D2 ialah penjual yang diminati.

Formula di atas pergi ke E2 dan membawa semua padanan untuk penjual sasaran dalam D2 (Adam). Disebabkan penggunaan rujukan sel relatif (untuk penjual sasaran) dan mutlak (untuk nama dan produk penjual) yang bijak, formula menyalin dengan betul ke sel di bawah dan berfungsi dengan baik untuk dua penjual yang lain juga:

Catatan. Seperti contoh sebelumnya, ini berfungsi sebagai formula biasa dalam Excel 365 dan 2021, dan sebagai formula CSE (Ctrl + Shift + Enter ) dalam Excel 2019.

Logik formula adalah sama seperti dalam contoh sebelumnya:

Pernyataan IF membandingkan setiap nama dalam A2:A12 dengan nama sasaran dalam D2 (Adam dalam kes kami):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Jika ujian logik menilai kepada BENAR (iaitu nama dalam D2 sepadan dengan nama dalam lajur A), formula mengembalikan produk daripada lajur B; jika tidak, rentetan kosong ("") dikembalikan. Hasil IF ialah tatasusunan berikut:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Tasusunan pergi ke fungsi TEXTJOIN sebagai argumen text1 . Dan kerana TEXTJOIN dikonfigurasikan untuk memisahkan nilai dengan koma dan ruang (", "), kami mendapat rentetan ini sebagai hasil akhir:

Pisang, Epal, Oren, Limau

Excel TEXTJOIN tidak berfungsi

Apabila formula TEXTJOIN anda menghasilkan ralat, kemungkinan besarmenjadi salah satu daripada yang berikut:

• #NAME? ralat berlaku apabila TEXTJOIN digunakan dalam versi Excel yang lebih lama di mana fungsi ini tidak disokong (pra-2019) atau apabila nama fungsi tersebut disalah eja.
• #VALUE! ralat berlaku jika rentetan yang terhasil melebihi 32,767 aksara.
• #VALUE! ralat juga mungkin berlaku jika Excel tidak mengenali pembatas sebagai teks, contohnya jika anda membekalkan beberapa aksara tidak boleh cetak seperti CHAR(0).

Begitulah cara menggunakan fungsi TEXTJOIN dalam Excel. Saya berterima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!

Muat turun yang tersedia

Contoh formula Excel TEXTJOIN