ਵਿਸ਼ਾ - ਸੂਚੀ
ਟਿਊਟੋਰਿਅਲ ਦਿਖਾਉਂਦਾ ਹੈ ਕਿ ਐਕਸਲ ਵਿੱਚ ਟੈਕਸਟ ਨੂੰ ਵਿਹਾਰਕ ਉਦਾਹਰਣਾਂ ਦੇ ਨਾਲ ਮਿਲਾਉਣ ਲਈ TEXTJOIN ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਿਵੇਂ ਕਰਨੀ ਹੈ।
ਹਾਲ ਹੀ ਤੱਕ, ਐਕਸਲ ਵਿੱਚ ਸੈੱਲ ਸਮੱਗਰੀ ਨੂੰ ਮਿਲਾਉਣ ਲਈ ਦੋ ਪ੍ਰਚਲਿਤ ਤਰੀਕੇ ਸਨ: ਸੰਯੋਜਨ ਆਪਰੇਟਰ ਅਤੇ CONCATENATE ਫੰਕਸ਼ਨ। TEXTJOIN ਦੀ ਸ਼ੁਰੂਆਤ ਦੇ ਨਾਲ, ਅਜਿਹਾ ਲਗਦਾ ਹੈ ਕਿ ਇੱਕ ਵਧੇਰੇ ਸ਼ਕਤੀਸ਼ਾਲੀ ਵਿਕਲਪ ਪ੍ਰਗਟ ਹੋਇਆ ਹੈ, ਜੋ ਤੁਹਾਨੂੰ ਟੈਕਸਟ ਨੂੰ ਵਧੇਰੇ ਲਚਕਦਾਰ ਤਰੀਕੇ ਨਾਲ ਜੋੜਨ ਦੇ ਯੋਗ ਬਣਾਉਂਦਾ ਹੈ ਜਿਸ ਵਿੱਚ ਵਿਚਕਾਰ ਕੋਈ ਵੀ ਸੀਮਾਕਾਰ ਸ਼ਾਮਲ ਹੈ। ਪਰ ਅਸਲ ਵਿੱਚ, ਇਸ ਵਿੱਚ ਹੋਰ ਵੀ ਬਹੁਤ ਕੁਝ ਹੈ!
Excel TEXTJOIN ਫੰਕਸ਼ਨ
Excel ਵਿੱਚ TEXTJOIN ਇੱਕ ਤੋਂ ਵੱਧ ਸੈੱਲਾਂ ਜਾਂ ਰੇਂਜਾਂ ਤੋਂ ਟੈਕਸਟ ਸਤਰ ਨੂੰ ਮਿਲਾਉਂਦਾ ਹੈ ਅਤੇ ਸੰਯੁਕਤ ਮੁੱਲਾਂ ਨੂੰ ਕਿਸੇ ਵੀ ਡੀਲੀਮੀਟਰ ਨਾਲ ਵੱਖ ਕਰਦਾ ਹੈ। ਜੋ ਤੁਸੀਂ ਨਿਸ਼ਚਿਤ ਕਰਦੇ ਹੋ। ਇਹ ਜਾਂ ਤਾਂ ਅਣਡਿੱਠ ਕਰ ਸਕਦਾ ਹੈ ਜਾਂ ਨਤੀਜੇ ਵਿੱਚ ਖਾਲੀ ਸੈੱਲਾਂ ਨੂੰ ਸ਼ਾਮਲ ਕਰ ਸਕਦਾ ਹੈ।
ਫੰਕਸ਼ਨ Office 365, Excel 2021, ਅਤੇ Excel 2019 ਲਈ Excel ਵਿੱਚ ਉਪਲਬਧ ਹੈ।
TEXTJOIN ਫੰਕਸ਼ਨ ਦਾ ਸੰਟੈਕਸ ਇਸ ਤਰ੍ਹਾਂ ਹੈ :
TEXTJOIN(delimiter, ignore_empty, text1, [text2], …)ਕਿੱਥੇ:
- ਡਿਲੀਮੀਟਰ (ਲੋੜੀਂਦਾ) - ਹਰੇਕ ਟੈਕਸਟ ਮੁੱਲ ਦੇ ਵਿਚਕਾਰ ਇੱਕ ਵੱਖਰਾ ਹੈ ਜੋ ਤੁਸੀਂ ਜੋੜਦੇ ਹੋ। ਆਮ ਤੌਰ 'ਤੇ, ਇਹ ਡਬਲ ਕੋਟਸ ਵਿੱਚ ਬੰਦ ਇੱਕ ਟੈਕਸਟ ਸਤਰ ਦੇ ਰੂਪ ਵਿੱਚ ਜਾਂ ਇੱਕ ਟੈਕਸਟ ਸਤਰ ਵਾਲੇ ਸੈੱਲ ਦੇ ਹਵਾਲੇ ਵਜੋਂ ਸਪਲਾਈ ਕੀਤਾ ਜਾਂਦਾ ਹੈ। ਡੀਲੀਮੀਟਰ ਦੇ ਤੌਰ 'ਤੇ ਦਿੱਤੇ ਗਏ ਨੰਬਰ ਨੂੰ ਟੈਕਸਟ ਮੰਨਿਆ ਜਾਂਦਾ ਹੈ।
- ਇਗਨੋਰ_ਇੰਪਟੀ (ਲੋੜੀਂਦਾ) - ਇਹ ਨਿਰਧਾਰਤ ਕਰਦਾ ਹੈ ਕਿ ਖਾਲੀ ਸੈੱਲਾਂ ਨੂੰ ਅਣਡਿੱਠ ਕਰਨਾ ਹੈ ਜਾਂ ਨਹੀਂ:
- ਸੱਚ - ਕਿਸੇ ਵੀ ਖਾਲੀ ਸੈੱਲਾਂ ਨੂੰ ਅਣਡਿੱਠ ਕਰੋ।
- ਗਲਤ - ਨਤੀਜੇ ਵਾਲੀ ਸਤਰ ਵਿੱਚ ਖਾਲੀ ਸੈੱਲ ਸ਼ਾਮਲ ਕਰੋ।
- ਟੈਕਸਟ1 (ਲੋੜੀਂਦਾ) - ਸ਼ਾਮਲ ਹੋਣ ਲਈ ਪਹਿਲਾ ਮੁੱਲ। ਇੱਕ ਟੈਕਸਟ ਸਟ੍ਰਿੰਗ ਦੇ ਤੌਰ 'ਤੇ ਸਪਲਾਈ ਕੀਤਾ ਜਾ ਸਕਦਾ ਹੈ, ਇੱਕ ਸਟ੍ਰਿੰਗ ਵਾਲੇ ਸੈੱਲ ਦਾ ਹਵਾਲਾ, ਜਾਂ ਸੈੱਲਾਂ ਦੀ ਇੱਕ ਰੇਂਜ ਵਰਗੀਆਂ ਸਟ੍ਰਿੰਗਾਂ ਦੀ ਲੜੀ।
- ਟੈਕਸਟ2 , … (ਵਿਕਲਪਿਕ) - ਵਾਧੂ ਟੈਕਸਟ ਮੁੱਲ ਇਕੱਠੇ ਜੁੜਨ ਲਈ. ਅਧਿਕਤਮ 252 ਟੈਕਸਟ ਆਰਗੂਮੈਂਟਾਂ ਦੀ ਇਜਾਜ਼ਤ ਹੈ, ਜਿਸ ਵਿੱਚ text1 ਸ਼ਾਮਲ ਹੈ।
ਇੱਕ ਉਦਾਹਰਨ ਦੇ ਤੌਰ 'ਤੇ, ਚਲੋ ਮੁੱਲਾਂ ਨੂੰ ਵੱਖ ਕਰਦੇ ਹੋਏ, ਸੈੱਲ B2, C2 ਅਤੇ D2 ਦੇ ਪਤੇ ਦੇ ਹਿੱਸਿਆਂ ਨੂੰ ਇੱਕ ਸੈੱਲ ਵਿੱਚ ਜੋੜਦੇ ਹਾਂ। ਕਾਮੇ ਅਤੇ ਸਪੇਸ ਦੇ ਨਾਲ:
CONCATENATE ਫੰਕਸ਼ਨ ਦੇ ਨਾਲ, ਤੁਹਾਨੂੰ ਹਰੇਕ ਸੈੱਲ ਨੂੰ ਵੱਖਰੇ ਤੌਰ 'ਤੇ ਨਿਸ਼ਚਿਤ ਕਰਨ ਅਤੇ ਹਰੇਕ ਸੰਦਰਭ ਦੇ ਬਾਅਦ ਇੱਕ ਡੀਲੀਮੀਟਰ (", ") ਲਗਾਉਣ ਦੀ ਜ਼ਰੂਰਤ ਹੋਏਗੀ, ਜੋ ਕਿ ਬਹੁਤ ਸਾਰੀਆਂ ਸਮੱਗਰੀਆਂ ਨੂੰ ਮਿਲਾਉਂਦੇ ਸਮੇਂ ਪਰੇਸ਼ਾਨ ਹੋ ਸਕਦਾ ਹੈ ਸੈੱਲ:
=CONCATENATE(A2, ", ", B2, ", ", C2)
Excel TEXTJOIN ਦੇ ਨਾਲ, ਤੁਸੀਂ ਪਹਿਲੀ ਆਰਗੂਮੈਂਟ ਵਿੱਚ ਸਿਰਫ਼ ਇੱਕ ਵਾਰ ਡੀਲੀਮੀਟਰ ਨਿਰਧਾਰਤ ਕਰਦੇ ਹੋ, ਅਤੇ ਤੀਜੇ ਆਰਗੂਮੈਂਟ ਲਈ ਸੈੱਲਾਂ ਦੀ ਇੱਕ ਰੇਂਜ ਦੀ ਸਪਲਾਈ ਕਰਦੇ ਹੋ:
=TEXTJOIN(", ", TRUE, A2:C2) <12
ਐਕਸਲ ਵਿੱਚ TEXTJOIN - ਯਾਦ ਰੱਖਣ ਵਾਲੀਆਂ 6 ਗੱਲਾਂ
ਆਪਣੀ ਵਰਕਸ਼ੀਟਾਂ ਵਿੱਚ TEXTJOIN ਨੂੰ ਪ੍ਰਭਾਵਸ਼ਾਲੀ ਢੰਗ ਨਾਲ ਵਰਤਣ ਲਈ, ਧਿਆਨ ਦੇਣ ਲਈ ਕੁਝ ਮਹੱਤਵਪੂਰਨ ਨੁਕਤੇ ਹਨ:
- TEXTJOIN ਇੱਕ ਨਵਾਂ ਹੈ ਫੰਕਸ਼ਨ, ਜੋ ਸਿਰਫ ਐਕਸਲ 2019 - ਐਕਸਲ 365 ਵਿੱਚ ਉਪਲਬਧ ਹੈ। ਪੁਰਾਣੇ ਐਕਸਲ ਸੰਸਕਰਣਾਂ ਵਿੱਚ, ਕਿਰਪਾ ਕਰਕੇ CONCATENATE ਫੰਕਸ਼ਨ ਜਾਂ "&" ਦੀ ਵਰਤੋਂ ਕਰੋ। ਇਸਦੀ ਬਜਾਏ ਆਪਰੇਟਰ।
- ਨਵੇਂ ਸੰਸਕਰਣਾਂ ਵਿੱਚ ਜੇਕਰ Excel, ਤੁਸੀਂ ਵੱਖਰੇ ਸੈੱਲਾਂ ਅਤੇ ਰੇਂਜਾਂ ਤੋਂ ਮੁੱਲਾਂ ਨੂੰ ਜੋੜਨ ਲਈ CONCAT ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਵੀ ਕਰ ਸਕਦੇ ਹੋ, ਪਰ ਸੀਮਾਕਾਰਾਂ ਜਾਂ ਖਾਲੀ ਸੈੱਲਾਂ ਲਈ ਕੋਈ ਵਿਕਲਪ ਨਹੀਂ ਹਨ।
- ਕੋਈ ਵੀ ਨੰਬਰ ਸਪਲਾਈ ਕੀਤਾ ਗਿਆ ਹੈ। ਡੀਲੀਮੀਟਰ ਜਾਂ ਟੈਕਸਟ ਲਈ TEXTJOIN ਕਰੋਆਰਗੂਮੈਂਟਾਂ ਨੂੰ ਟੈਕਸਟ ਵਿੱਚ ਬਦਲਿਆ ਜਾਂਦਾ ਹੈ।
- ਜੇਕਰ ਡਿਲੀਮੀਟਰ ਨਿਰਧਾਰਤ ਨਹੀਂ ਕੀਤਾ ਗਿਆ ਹੈ ਜਾਂ ਇੱਕ ਖਾਲੀ ਸਤਰ ("") ਹੈ, ਤਾਂ ਟੈਕਸਟ ਮੁੱਲਾਂ ਨੂੰ ਬਿਨਾਂ ਕਿਸੇ ਡੀਲੀਮੀਟਰ ਦੇ ਜੋੜਿਆ ਜਾਂਦਾ ਹੈ।
- ਫੰਕਸ਼ਨ ਕਰ ਸਕਦਾ ਹੈ 252 ਟੈਕਸਟ ਆਰਗੂਮੈਂਟਾਂ ਨੂੰ ਹੈਂਡਲ ਕਰੋ।
- ਨਤੀਜੇ ਵਾਲੀ ਸਤਰ ਵਿੱਚ ਅਧਿਕਤਮ 32,767 ਅੱਖਰ ਹੋ ਸਕਦੇ ਹਨ, ਜੋ ਕਿ Excel ਵਿੱਚ ਸੈੱਲ ਸੀਮਾ ਹੈ। ਜੇਕਰ ਇਹ ਸੀਮਾ ਵੱਧ ਜਾਂਦੀ ਹੈ, ਤਾਂ ਇੱਕ TEXTJOIN ਫਾਰਮੂਲਾ #VALUE! ਗਲਤੀ।
ਐਕਸਲ ਵਿੱਚ ਟੈਕਸਟ ਨੂੰ ਕਿਵੇਂ ਜੋੜਿਆ ਜਾਵੇ - ਫਾਰਮੂਲਾ ਉਦਾਹਰਣ
TEXTJOIN ਦੇ ਸਾਰੇ ਫਾਇਦਿਆਂ ਨੂੰ ਬਿਹਤਰ ਤਰੀਕੇ ਨਾਲ ਸਮਝਣ ਲਈ, ਆਓ ਇੱਕ ਝਾਤ ਮਾਰੀਏ ਕਿ ਅਸਲ-ਜੀਵਨ ਦੇ ਦ੍ਰਿਸ਼ਾਂ ਵਿੱਚ ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਿਵੇਂ ਕਰੀਏ। .
ਕਾਲਮ ਨੂੰ ਕਾਮੇ ਤੋਂ ਵੱਖ ਕੀਤੀ ਸੂਚੀ ਵਿੱਚ ਬਦਲੋ
ਜਦੋਂ ਤੁਸੀਂ ਇੱਕ ਲੰਬਕਾਰੀ ਸੂਚੀ ਨੂੰ ਕਾਮੇ, ਸੈਮੀਕੋਲਨ ਜਾਂ ਕਿਸੇ ਹੋਰ ਡੀਲੀਮੀਟਰ ਦੁਆਰਾ ਵੱਖ ਕਰਨ ਵਾਲੀ ਇੱਕ ਲੰਬਕਾਰੀ ਸੂਚੀ ਨੂੰ ਜੋੜਨਾ ਚਾਹੁੰਦੇ ਹੋ, ਤਾਂ TEXTJOIN ਵਰਤਣ ਲਈ ਸਹੀ ਫੰਕਸ਼ਨ ਹੈ।
ਇਸ ਉਦਾਹਰਨ ਲਈ, ਅਸੀਂ ਹੇਠਾਂ ਦਿੱਤੀ ਸਾਰਣੀ ਤੋਂ ਹਰੇਕ ਟੀਮ ਦੀਆਂ ਜਿੱਤਾਂ ਅਤੇ ਹਾਰਾਂ ਨੂੰ ਜੋੜਾਂਗੇ। ਇਹ ਨਿਮਨਲਿਖਤ ਫਾਰਮੂਲੇ ਨਾਲ ਕੀਤਾ ਜਾ ਸਕਦਾ ਹੈ, ਜੋ ਕਿ ਸਿਰਫ ਉਹਨਾਂ ਸੈੱਲਾਂ ਦੀ ਰੇਂਜ ਵਿੱਚ ਵੱਖਰਾ ਹੈ ਜੋ ਜੁੜਿਆ ਹੋਇਆ ਹੈ।
ਟੀਮ 1 ਲਈ:
=TEXTJOIN(",", FALSE, B2:B6)
ਟੀਮ 2 ਲਈ:<3
=TEXTJOIN(",", FALSE, C2:C6)
ਅਤੇ ਇਸ ਤਰ੍ਹਾਂ ਹੀ।
ਸਾਰੇ ਫਾਰਮੂਲੇ ਵਿੱਚ, ਹੇਠਾਂ ਦਿੱਤੇ ਆਰਗੂਮੈਂਟਾਂ ਦੀ ਵਰਤੋਂ ਕੀਤੀ ਜਾਂਦੀ ਹੈ:
- ਡਿਲੀਮੀਟਰ - a ਕੌਮਾ (",").
- Ignore_empty ਨੂੰ ਖਾਲੀ ਸੈੱਲਾਂ ਨੂੰ ਸ਼ਾਮਲ ਕਰਨ ਲਈ FALSE 'ਤੇ ਸੈੱਟ ਕੀਤਾ ਗਿਆ ਹੈ ਕਿਉਂਕਿ ਸਾਨੂੰ ਇਹ ਦਿਖਾਉਣ ਦੀ ਲੋੜ ਹੈ ਕਿ ਕਿਹੜੀਆਂ ਗੇਮਾਂ ਨਹੀਂ ਖੇਡੀਆਂ ਗਈਆਂ ਸਨ।
ਜਿਵੇਂ ਕਿ ਨਤੀਜੇ ਵਜੋਂ, ਤੁਹਾਨੂੰ ਚਾਰ ਕਾਮੇ ਨਾਲ ਵੱਖ ਕੀਤੀਆਂ ਸੂਚੀਆਂ ਮਿਲਣਗੀਆਂ ਜੋ ਇੱਕ ਸੰਖੇਪ ਰੂਪ ਵਿੱਚ ਹਰੇਕ ਟੀਮ ਦੀ ਜਿੱਤ ਅਤੇ ਹਾਰ ਨੂੰ ਦਰਸਾਉਂਦੀਆਂ ਹਨ: 
ਵੱਖ-ਵੱਖ ਡੈਲੀਮੀਟਰਾਂ ਨਾਲ ਸੈੱਲਾਂ ਵਿੱਚ ਸ਼ਾਮਲ ਹੋਵੋ
ਅਜਿਹੀ ਸਥਿਤੀ ਵਿੱਚ ਜਦੋਂ ਤੁਹਾਨੂੰ ਸੰਯੁਕਤ ਮੁੱਲਾਂ ਨੂੰ ਵੱਖ-ਵੱਖ ਡੈਲੀਮੀਟਰਾਂ ਨਾਲ ਵੱਖ ਕਰਨ ਦੀ ਲੋੜ ਹੁੰਦੀ ਹੈ, ਤੁਸੀਂ ਜਾਂ ਤਾਂ ਕਈ ਡੀਲੀਮੀਟਰਾਂ ਨੂੰ ਇੱਕ ਐਰੇ ਸਥਿਰਾਂਕ ਵਜੋਂ ਸਪਲਾਈ ਕਰ ਸਕਦੇ ਹੋ ਜਾਂ ਹਰੇਕ ਡੀਲੀਮੀਟਰ ਨੂੰ ਇੱਕ ਵੱਖਰੇ ਸੈੱਲ ਵਿੱਚ ਇਨਪੁਟ ਕਰ ਸਕਦੇ ਹੋ। ਅਤੇ ਡੀਲੀਮੀਟਰ ਆਰਗੂਮੈਂਟ ਲਈ ਇੱਕ ਰੇਂਜ ਹਵਾਲੇ ਦੀ ਵਰਤੋਂ ਕਰੋ।
ਮੰਨ ਲਓ ਕਿ ਤੁਸੀਂ ਵੱਖ-ਵੱਖ ਨਾਮ ਵਾਲੇ ਭਾਗਾਂ ਵਾਲੇ ਸੈੱਲਾਂ ਵਿੱਚ ਸ਼ਾਮਲ ਹੋਣਾ ਚਾਹੁੰਦੇ ਹੋ ਅਤੇ ਇਸ ਫਾਰਮੈਟ ਵਿੱਚ ਨਤੀਜਾ ਪ੍ਰਾਪਤ ਕਰਨਾ ਚਾਹੁੰਦੇ ਹੋ: ਆਖਰੀ ਨਾਮ , ਪਹਿਲਾ ਨਾਮ ਮੱਧ ਨਾਮ ।
ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਵੇਖ ਸਕਦੇ ਹੋ, ਆਖਰੀ ਨਾਮ ਅਤੇ ਪਹਿਲਾ ਨਾਮ ਇੱਕ ਕਾਮੇ ਅਤੇ ਸਪੇਸ (", ") ਦੁਆਰਾ ਵੱਖ ਕੀਤਾ ਗਿਆ ਹੈ ਜਦੋਂ ਕਿ ਪਹਿਲਾ ਨਾਮ ਅਤੇ ਮੱਧ ਨਾਮ ਇੱਕ ਸਪੇਸ ਦੁਆਰਾ (" ") ਸਿਰਫ. ਇਸ ਲਈ, ਅਸੀਂ ਇਹਨਾਂ ਦੋ ਡੀਲੀਮੀਟਰਾਂ ਨੂੰ ਇੱਕ ਐਰੇ ਸਥਿਰਾਂਕ {", "," "} ਵਿੱਚ ਸ਼ਾਮਲ ਕਰਦੇ ਹਾਂ ਅਤੇ ਹੇਠਾਂ ਦਿੱਤੇ ਫਾਰਮੂਲੇ ਨੂੰ ਪ੍ਰਾਪਤ ਕਰਦੇ ਹਾਂ:
=TEXTJOIN({", "," "}, TRUE, A2:C2)
ਜਿੱਥੇ A2:C2 ਨਾਮ ਦੇ ਭਾਗਾਂ ਨੂੰ ਜੋੜਿਆ ਜਾਣਾ ਹੈ।
ਵਿਕਲਪਿਕ ਤੌਰ 'ਤੇ, ਤੁਸੀਂ ਕੁਝ ਖਾਲੀ ਸੈੱਲਾਂ (ਜਿਵੇਂ ਕਿ, F3 ਵਿੱਚ ਇੱਕ ਕਾਮੇ ਅਤੇ ਇੱਕ ਸਪੇਸ ਅਤੇ G3 ਵਿੱਚ ਇੱਕ ਸਪੇਸ) ਵਿੱਚ ਬਿਨਾਂ ਹਵਾਲਾ ਚਿੰਨ੍ਹ ਦੇ ਡੀਲੀਮੀਟਰ ਟਾਈਪ ਕਰ ਸਕਦੇ ਹੋ ਅਤੇ $F$3:$G$3 (ਕਿਰਪਾ ਕਰਕੇ ਧਿਆਨ ਰੱਖੋ) ਦੀ ਵਰਤੋਂ ਕਰੋ। ਡੀਲੀਮੀਟਰ ਆਰਗੂਮੈਂਟ ਲਈ ਪੂਰਨ ਸੈੱਲ ਸੰਦਰਭਾਂ:
=TEXTJOIN($F$3:$G$3, TRUE, A2:C2) 
ਇਸ ਆਮ ਪਹੁੰਚ ਦੀ ਵਰਤੋਂ ਕਰਕੇ, ਤੁਸੀਂ ਸੈੱਲ ਸਮੱਗਰੀ ਨੂੰ ਵੱਖ-ਵੱਖ ਰੂਪਾਂ ਵਿੱਚ ਮਿਲਾ ਸਕਦੇ ਹੋ।
ਉਦਾਹਰਨ ਲਈ, ਜੇਕਰ ਤੁਸੀਂ ਪਹਿਲਾ ਨਾਮ ਮਿਡਲ ਸ਼ੁਰੂਆਤੀ ਆਖਰੀ ਨਾਮ ਫਾਰਮੈਟ ਵਿੱਚ ਨਤੀਜਾ ਚਾਹੁੰਦੇ ਹੋ, ਤਾਂ ਪਹਿਲੇ ਅੱਖਰ (ਸ਼ੁਰੂਆਤੀ) ਨੂੰ ਐਕਸਟਰੈਕਟ ਕਰਨ ਲਈ ਖੱਬੇ ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰੋ। ਸੈੱਲ C2 ਤੋਂ. ਜਿਵੇਂ ਕਿ ਸੀਮਾਕਾਰਾਂ ਲਈ, ਅਸੀਂ ਪਹਿਲੇ ਨਾਮ ਅਤੇ ਮੱਧ ਦੇ ਅਰੰਭ ਦੇ ਵਿਚਕਾਰ ਇੱਕ ਸਪੇਸ ("") ਰੱਖਦੇ ਹਾਂ; aਅਰੰਭਕ ਅਤੇ ਆਖਰੀ ਨਾਮ ਦੇ ਵਿਚਕਾਰ ਮਿਆਦ ਅਤੇ ਇੱਕ ਸਪੇਸ (" ") ਟੈਕਸਟ ਅਤੇ ਮਿਤੀਆਂ, TEXTJOIN ਫਾਰਮੂਲੇ ਨੂੰ ਸਿੱਧੀਆਂ ਤਾਰੀਖਾਂ ਦੀ ਸਪਲਾਈ ਕਰਨਾ ਕੰਮ ਨਹੀਂ ਕਰੇਗਾ। ਜਿਵੇਂ ਕਿ ਤੁਹਾਨੂੰ ਯਾਦ ਹੋਵੇਗਾ, ਐਕਸਲ ਮਿਤੀਆਂ ਨੂੰ ਸੀਰੀਅਲ ਨੰਬਰਾਂ ਵਜੋਂ ਸਟੋਰ ਕਰਦਾ ਹੈ, ਇਸਲਈ ਤੁਹਾਡਾ ਫਾਰਮੂਲਾ ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ੌਟ ਵਿੱਚ ਦਰਸਾਏ ਗਏ ਮਿਤੀ ਨੂੰ ਦਰਸਾਉਂਦਾ ਇੱਕ ਨੰਬਰ ਵਾਪਸ ਕਰੇਗਾ:
=TEXTJOIN(" ", TRUE, A2:B2) 
ਇਸ ਨੂੰ ਠੀਕ ਕਰਨ ਲਈ, ਤੁਹਾਨੂੰ ਬਦਲਣ ਦੀ ਲੋੜ ਹੈ। ਇਸ ਵਿੱਚ ਸ਼ਾਮਲ ਹੋਣ ਤੋਂ ਪਹਿਲਾਂ ਇੱਕ ਟੈਕਸਟ ਸਤਰ ਵਿੱਚ ਮਿਤੀ। ਅਤੇ ਇੱਥੇ ਲੋੜੀਂਦੇ ਫਾਰਮੈਟ ਕੋਡ ਨਾਲ ਟੈਕਸਟ ਫੰਕਸ਼ਨ (ਸਾਡੇ ਕੇਸ ਵਿੱਚ "mm/dd/yyyy") ਕੰਮ ਆਉਂਦਾ ਹੈ:
=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy")) 
ਲਾਈਨ ਬਰੇਕਾਂ ਨਾਲ ਟੈਕਸਟ ਨੂੰ ਮਿਲਾਓ
ਜੇਕਰ ਤੁਸੀਂ ਐਕਸਲ ਵਿੱਚ ਟੈਕਸਟ ਨੂੰ ਮਿਲਾਉਣਾ ਚਾਹੁੰਦੇ ਹੋ ਤਾਂ ਕਿ ਹਰੇਕ ਮੁੱਲ ਇੱਕ ਨਵੀਂ ਲਾਈਨ ਵਿੱਚ ਸ਼ੁਰੂ ਹੋਵੇ, ਤਾਂ ਸੀਮਾਕਾਰ ਵਜੋਂ CHAR(10) ਦੀ ਵਰਤੋਂ ਕਰੋ (ਜਿੱਥੇ 10 ਇੱਕ ਲਾਈਨਫੀਡ ਅੱਖਰ ਹੈ)।
ਉਦਾਹਰਣ ਲਈ, ਇਸ ਤੋਂ ਟੈਕਸਟ ਨੂੰ ਜੋੜਨ ਲਈ ਸੈੱਲ A2 ਅਤੇ B2 ਇੱਕ ਲਾਈਨ ਬ੍ਰੇਕ ਦੁਆਰਾ ਮੁੱਲਾਂ ਨੂੰ ਵੱਖ ਕਰਦੇ ਹਨ, ਇਹ ਵਰਤਣ ਲਈ ਫਾਰਮੂਲਾ ਹੈ:
=TEXTJOIN(CHAR(10), TRUE, A2:B2) 
ਟਿਪ। ਨਤੀਜੇ ਨੂੰ ਕਈ ਲਾਈਨਾਂ ਵਿੱਚ ਪ੍ਰਦਰਸ਼ਿਤ ਕਰਨ ਲਈ ਜਿਵੇਂ ਕਿ ਉੱਪਰ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ਾਟ ਵਿੱਚ ਦਿਖਾਇਆ ਗਿਆ ਹੈ, ਯਕੀਨੀ ਬਣਾਓ ਕਿ ਰੈਪ ਟੈਕਸਟ ਵਿਸ਼ੇਸ਼ਤਾ ਚਾਲੂ ਹੈ।
ਸ਼ਰਤਾਂ ਦੇ ਨਾਲ ਟੈਕਸਟ ਨੂੰ ਮਿਲਾਉਣ ਲਈ TEXTJOIN IF
ਐਕਸਲ TEXTJOIN ਦੀ ਸਤਰ ਦੇ ਐਰੇ ਨੂੰ ਹੈਂਡਲ ਕਰਨ ਦੀ ਯੋਗਤਾ ਦੇ ਕਾਰਨ, ਇਸਦੀ ਵਰਤੋਂ ਦੋ ਜਾਂ ਦੋ ਤੋਂ ਵੱਧ ਸੈੱਲਾਂ ਦੀ ਸਮੱਗਰੀ ਨੂੰ ਸ਼ਰਤ ਅਨੁਸਾਰ ਮਿਲਾਉਣ ਲਈ ਵੀ ਕੀਤੀ ਜਾ ਸਕਦੀ ਹੈ। ਇਸ ਨੂੰ ਪੂਰਾ ਕਰਨ ਲਈ, ਸੈੱਲਾਂ ਦੀ ਇੱਕ ਰੇਂਜ ਦਾ ਮੁਲਾਂਕਣ ਕਰਨ ਲਈ IF ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰੋ ਅਤੇ ਮੁੱਲਾਂ ਦੀ ਇੱਕ ਐਰੇ ਵਾਪਸ ਕਰੋ ਜੋ ਸ਼ਰਤ ਨੂੰ ਪੂਰਾ ਕਰਦੇ ਹਨ text1 ਆਰਗੂਮੈਂਟTEXTJOIN।
ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ਾਟ ਵਿੱਚ ਦਿਖਾਈ ਗਈ ਸਾਰਣੀ ਤੋਂ, ਮੰਨ ਲਓ ਕਿ ਤੁਸੀਂ ਟੀਮ 1 ਮੈਂਬਰਾਂ ਦੀ ਸੂਚੀ ਪ੍ਰਾਪਤ ਕਰਨਾ ਚਾਹੁੰਦੇ ਹੋ। ਇਸ ਨੂੰ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ, ਹੇਠਾਂ ਦਿੱਤੀ IF ਸਟੇਟਮੈਂਟ ਨੂੰ text1 ਆਰਗੂਮੈਂਟ ਵਿੱਚ ਨੇਸਟ ਕਰੋ:
IF($B$2:$B$9=1, $A$2:$A$9, "")
ਸਾਦੀ ਅੰਗਰੇਜ਼ੀ ਵਿੱਚ, ਉਪਰੋਕਤ ਫਾਰਮੂਲਾ ਕਹਿੰਦਾ ਹੈ: ਜੇਕਰ ਕਾਲਮ B 1 ਦੇ ਬਰਾਬਰ ਹੈ, ਤਾਂ ਇੱਕ ਵਾਪਸ ਕਰੋ। ਉਸੇ ਕਤਾਰ ਵਿੱਚ ਕਾਲਮ A ਤੋਂ ਮੁੱਲ; ਨਹੀਂ ਤਾਂ ਇੱਕ ਖਾਲੀ ਸਤਰ ਵਾਪਸ ਕਰੋ।
ਟੀਮ 1 ਲਈ ਪੂਰਾ ਫਾਰਮੂਲਾ ਇਹ ਆਕਾਰ ਲੈਂਦਾ ਹੈ:
=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))
ਇਸੇ ਤਰ੍ਹਾਂ ਨਾਲ, ਤੁਸੀਂ ਇੱਕ ਪ੍ਰਾਪਤ ਕਰ ਸਕਦੇ ਹੋ ਟੀਮ 2:
=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, "")) 
ਨੋਟ ਦੇ ਮੈਂਬਰਾਂ ਦੀ ਕੌਮੇ ਨਾਲ ਵੱਖ ਕੀਤੀ ਸੂਚੀ। ਐਕਸਲ 365 ਅਤੇ 2021 ਵਿੱਚ ਉਪਲਬਧ ਡਾਇਨਾਮਿਕ ਐਰੇ ਵਿਸ਼ੇਸ਼ਤਾ ਦੇ ਕਾਰਨ, ਇਹ ਇੱਕ ਨਿਯਮਤ ਫਾਰਮੂਲੇ ਦੇ ਰੂਪ ਵਿੱਚ ਕੰਮ ਕਰਦਾ ਹੈ, ਉੱਪਰ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ਾਟ ਵਿੱਚ ਦਿਖਾਇਆ ਗਿਆ ਹੈ। ਐਕਸਲ 2019 ਵਿੱਚ, ਤੁਹਾਨੂੰ Ctrl + Shift + Enter ਸ਼ਾਰਟਕੱਟ ਨੂੰ ਦਬਾ ਕੇ ਇਸਨੂੰ ਇੱਕ ਰਵਾਇਤੀ ਐਰੇ ਫਾਰਮੂਲੇ ਦੇ ਰੂਪ ਵਿੱਚ ਦਰਜ ਕਰਨਾ ਚਾਹੀਦਾ ਹੈ।
ਕੌਮਾ ਨਾਲ ਵੱਖ ਕੀਤੀ ਸੂਚੀ ਵਿੱਚ ਕਈ ਮੈਚਾਂ ਨੂੰ ਲੱਭੋ ਅਤੇ ਵਾਪਸ ਕਰੋ
ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਸ਼ਾਇਦ ਜਾਣਦੇ ਹੋਵੋਗੇ, ਐਕਸਲ VLOOKUP ਫੰਕਸ਼ਨ ਸਿਰਫ ਪਹਿਲਾ ਮਿਲਿਆ ਮੈਚ ਵਾਪਸ ਕਰ ਸਕਦਾ ਹੈ। ਪਰ ਉਦੋਂ ਕੀ ਜੇ ਤੁਹਾਨੂੰ ਕਿਸੇ ਖਾਸ ID, SKU, ਜਾਂ ਕਿਸੇ ਹੋਰ ਚੀਜ਼ ਲਈ ਸਾਰੇ ਮੈਚ ਪ੍ਰਾਪਤ ਕਰਨ ਦੀ ਲੋੜ ਹੈ?
ਵੱਖਰੇ ਸੈੱਲਾਂ ਵਿੱਚ ਨਤੀਜਿਆਂ ਨੂੰ ਆਊਟਪੁੱਟ ਕਰਨ ਲਈ, Excel ਵਿੱਚ ਮਲਟੀਪਲ ਵੈਲਯੂਜ਼ ਨੂੰ ਕਿਵੇਂ VLOOKUP ਕਰਨਾ ਹੈ ਵਿੱਚ ਵਰਣਿਤ ਫਾਰਮੂਲੇ ਵਿੱਚੋਂ ਇੱਕ ਦੀ ਵਰਤੋਂ ਕਰੋ।
ਇੱਕ ਸੈੱਲ ਵਿੱਚ ਸਾਰੇ ਮੇਲ ਖਾਂਦੇ ਮੁੱਲਾਂ ਨੂੰ ਕਾਮੇ ਨਾਲ ਵੱਖ ਕੀਤੀ ਸੂਚੀ ਦੇ ਰੂਪ ਵਿੱਚ ਵੇਖਣ ਅਤੇ ਵਾਪਸ ਕਰਨ ਲਈ, TEXTJOIN IF ਫਾਰਮੂਲਾ ਦੀ ਵਰਤੋਂ ਕਰੋ।
ਇਹ ਦੇਖਣ ਲਈ ਕਿ ਇਹ ਅਭਿਆਸ ਵਿੱਚ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ, ਆਓ ਇਹਨਾਂ ਦੀ ਇੱਕ ਸੂਚੀ ਪ੍ਰਾਪਤ ਕਰੀਏ ਨਮੂਨਾ ਸਾਰਣੀ ਤੋਂ ਦਿੱਤੇ ਗਏ ਵਿਕਰੇਤਾ ਦੁਆਰਾ ਖਰੀਦੇ ਗਏ ਉਤਪਾਦਹੇਠਾਂ। ਇਹ ਹੇਠਾਂ ਦਿੱਤੇ ਫਾਰਮੂਲੇ ਨਾਲ ਆਸਾਨੀ ਨਾਲ ਕੀਤਾ ਜਾ ਸਕਦਾ ਹੈ:
=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))
ਜਿੱਥੇ A2:A12 ਵਿਕਰੇਤਾ ਦੇ ਨਾਮ ਹਨ, B2:B12 ਉਤਪਾਦ ਹਨ, ਅਤੇ D2 ਦਿਲਚਸਪੀ ਦਾ ਵਿਕਰੇਤਾ ਹੈ।
ਉਪਰੋਕਤ ਫਾਰਮੂਲਾ E2 'ਤੇ ਜਾਂਦਾ ਹੈ ਅਤੇ D2 (ਐਡਮ) ਵਿੱਚ ਟੀਚਾ ਵੇਚਣ ਵਾਲੇ ਲਈ ਸਾਰੇ ਮੈਚ ਲਿਆਉਂਦਾ ਹੈ। ਸਾਪੇਖਿਕ (ਨਿਸ਼ਾਨਾ ਵਿਕਰੇਤਾ ਲਈ) ਅਤੇ ਸੰਪੂਰਨ (ਵਿਕਰੇਤਾ ਦੇ ਨਾਮ ਅਤੇ ਉਤਪਾਦਾਂ ਲਈ) ਸੈੱਲ ਸੰਦਰਭਾਂ ਦੀ ਹੁਸ਼ਿਆਰ ਵਰਤੋਂ ਦੇ ਕਾਰਨ, ਫਾਰਮੂਲਾ ਹੇਠਾਂ ਦਿੱਤੇ ਸੈੱਲਾਂ ਵਿੱਚ ਸਹੀ ਢੰਗ ਨਾਲ ਨਕਲ ਕਰਦਾ ਹੈ ਅਤੇ ਦੂਜੇ ਦੋ ਵਿਕਰੇਤਾਵਾਂ ਲਈ ਵੀ ਵਧੀਆ ਢੰਗ ਨਾਲ ਕੰਮ ਕਰਦਾ ਹੈ: 
ਨੋਟ ਕਰੋ। ਪਿਛਲੀ ਉਦਾਹਰਨ ਦੇ ਨਾਲ, ਇਹ ਐਕਸਲ 365 ਅਤੇ 2021 ਵਿੱਚ ਇੱਕ ਨਿਯਮਤ ਫਾਰਮੂਲੇ ਦੇ ਤੌਰ 'ਤੇ ਕੰਮ ਕਰਦਾ ਹੈ, ਅਤੇ ਐਕਸਲ 2019 ਵਿੱਚ ਇੱਕ CSE ਫਾਰਮੂਲੇ (Ctrl + Shift + Enter ) ਦੇ ਤੌਰ 'ਤੇ ਕੰਮ ਕਰਦਾ ਹੈ।
ਫ਼ਾਰਮੂਲੇ ਦਾ ਤਰਕ ਬਿਲਕੁਲ ਉਹੀ ਹੈ ਜਿਵੇਂ ਕਿ ਪਿਛਲਾ ਉਦਾਹਰਨ:
IF ਸਟੇਟਮੈਂਟ A2:A12 ਵਿੱਚ ਹਰੇਕ ਨਾਮ ਦੀ ਤੁਲਨਾ D2 (ਸਾਡੇ ਕੇਸ ਵਿੱਚ ਐਡਮ) ਦੇ ਟਾਰਗੇਟ ਨਾਮ ਨਾਲ ਕਰਦੀ ਹੈ:
IF($A$2:$A$12=D2, $B$2:$B$12, "")
ਜੇਕਰ ਲਾਜ਼ੀਕਲ ਟੈਸਟ ਦਾ ਮੁਲਾਂਕਣ ਕੀਤਾ ਜਾਂਦਾ ਹੈ TRUE (ਜਿਵੇਂ ਕਿ D2 ਦਾ ਨਾਮ ਕਾਲਮ A ਦੇ ਨਾਮ ਨਾਲ ਮੇਲ ਖਾਂਦਾ ਹੈ), ਫਾਰਮੂਲਾ ਕਾਲਮ B ਤੋਂ ਉਤਪਾਦ ਵਾਪਸ ਕਰਦਾ ਹੈ; ਨਹੀਂ ਤਾਂ ਇੱਕ ਖਾਲੀ ਸਤਰ ("") ਵਾਪਸ ਕੀਤੀ ਜਾਂਦੀ ਹੈ। IF ਦਾ ਨਤੀਜਾ ਹੇਠ ਦਿੱਤੀ ਐਰੇ ਹੈ:
{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}
ਐਰੇ TEXTJOIN ਫੰਕਸ਼ਨ ਨੂੰ text1 ਆਰਗੂਮੈਂਟ ਵਜੋਂ ਜਾਂਦਾ ਹੈ। ਅਤੇ ਕਿਉਂਕਿ TEXTJOIN ਨੂੰ ਕੌਮੇ ਅਤੇ ਸਪੇਸ (", ") ਨਾਲ ਮੁੱਲਾਂ ਨੂੰ ਵੱਖ ਕਰਨ ਲਈ ਕੌਂਫਿਗਰ ਕੀਤਾ ਗਿਆ ਹੈ, ਸਾਨੂੰ ਅੰਤਿਮ ਨਤੀਜੇ ਵਜੋਂ ਇਹ ਸਤਰ ਮਿਲਦੀ ਹੈ:
ਕੇਲੇ, ਸੇਬ, ਸੰਤਰੇ, ਨਿੰਬੂ
ਐਕਸਲ TEXTJOIN ਕੰਮ ਨਹੀਂ ਕਰ ਰਿਹਾ
ਜਦੋਂ ਤੁਹਾਡੇ TEXTJOIN ਫਾਰਮੂਲੇ ਦੇ ਨਤੀਜੇ ਵਜੋਂ ਗਲਤੀ ਹੁੰਦੀ ਹੈ, ਤਾਂ ਇਹ ਸਭ ਤੋਂ ਵੱਧ ਸੰਭਾਵਨਾ ਹੈਇਹਨਾਂ ਵਿੱਚੋਂ ਇੱਕ ਬਣਨ ਲਈ:
- #NAME? ਗਲਤੀ ਉਦੋਂ ਹੁੰਦੀ ਹੈ ਜਦੋਂ TEXTJOIN ਦੀ ਵਰਤੋਂ Excel ਦੇ ਪੁਰਾਣੇ ਸੰਸਕਰਣ ਵਿੱਚ ਕੀਤੀ ਜਾਂਦੀ ਹੈ ਜਿੱਥੇ ਇਹ ਫੰਕਸ਼ਨ ਸਮਰਥਿਤ ਨਹੀਂ ਹੈ (2019 ਤੋਂ ਪਹਿਲਾਂ) ਜਾਂ ਜਦੋਂ ਫੰਕਸ਼ਨ ਦਾ ਨਾਮ ਗਲਤ ਲਿਖਿਆ ਗਿਆ ਹੈ।
- #VALUE! ਗਲਤੀ ਹੁੰਦੀ ਹੈ ਜੇਕਰ ਨਤੀਜੇ ਵਾਲੀ ਸਤਰ 32,767 ਅੱਖਰਾਂ ਤੋਂ ਵੱਧ ਜਾਂਦੀ ਹੈ।
- #VALUE! ਗਲਤੀ ਉਦੋਂ ਵੀ ਹੋ ਸਕਦੀ ਹੈ ਜੇਕਰ ਐਕਸਲ ਡੀਲੀਮੀਟਰ ਨੂੰ ਟੈਕਸਟ ਦੇ ਤੌਰ 'ਤੇ ਨਹੀਂ ਪਛਾਣਦਾ, ਉਦਾਹਰਨ ਲਈ ਜੇਕਰ ਤੁਸੀਂ ਕੁਝ ਗੈਰ-ਪ੍ਰਿੰਟ ਕਰਨ ਯੋਗ ਅੱਖਰ ਜਿਵੇਂ ਕਿ CHAR(0) ਦੀ ਸਪਲਾਈ ਕਰਦੇ ਹੋ।
ਇਸ ਤਰ੍ਹਾਂ ਐਕਸਲ ਵਿੱਚ TEXTJOIN ਫੰਕਸ਼ਨ ਨੂੰ ਵਰਤਣਾ ਹੈ। ਮੈਂ ਪੜ੍ਹਨ ਲਈ ਤੁਹਾਡਾ ਧੰਨਵਾਦ ਕਰਦਾ ਹਾਂ ਅਤੇ ਅਗਲੇ ਹਫ਼ਤੇ ਤੁਹਾਨੂੰ ਸਾਡੇ ਬਲੌਗ 'ਤੇ ਮਿਲਣ ਦੀ ਉਮੀਦ ਕਰਦਾ ਹਾਂ!
ਉਪਲੱਬਧ ਡਾਊਨਲੋਡ
Excel TEXTJOIN ਫਾਰਮੂਲੇ ਦੀਆਂ ਉਦਾਹਰਣਾਂ
