Энэ заавар нь TEXTJOIN функцийг ашиглан Excel-ийн текстийг практик жишээн дээр хэрхэн ашиглахыг харуулж байна.

Саяхныг хүртэл Excel-д нүдний агуулгыг нэгтгэх хоёр түгээмэл арга байсан: холболт оператор ба CONCATENATE функц. TEXTJOIN-г нэвтрүүлснээр илүү хүчирхэг хувилбар гарч ирсэн бөгөөд энэ нь танд текстийг илүү уян хатан байдлаар холбох боломжийг олгодог. Гэвч үнэн хэрэгтээ үүнээс илүү олон зүйл бий!

Excel-ийн TEXTJOIN функц

Excel-ийн TEXTJOIN нь олон нүд эсвэл мужаас текст мөрүүдийг нэгтгэж, хосолсон утгуудыг ямар ч хязгаарлагчаар тусгаарладаг. таны тодорхойлсон. Энэ нь үр дүнд хоосон нүдийг үл хэрэгсэх эсвэл оруулах боломжтой.

Энэ функц нь Office 365, Excel 2021, Excel 2019-д зориулагдсан Excel дээр боломжтой.

TEXTJOIN функцийн синтакс дараах байдалтай байна. :

Үүнд:

• Хязгаарлагч (шаардлагатай) - текстийн утга бүрийн хоорондох тусгаарлагч юм таны нэгтгэсэн. Ихэнхдээ энэ нь давхар хашилтанд орсон текстийн мөр эсвэл текст мөр агуулсан нүдний лавлагаа хэлбэрээр ирдэг. Хязгаарлагч болгон өгсөн тоог текст гэж үзнэ.
• Ignore_empty (шаардлагатай) - Хоосон нүднүүдийг үл тоомсорлох эсэхийг тодорхойлно:
  • ҮНЭН - ямар ч хоосон нүдийг үл тоомсорлодог.
  • ХУДАЛ - үүссэн мөрөнд хоосон нүдийг оруулна.
• Текст1 (шаардлагатай) - нэгдэх эхний утга. Текстийн мөр, мөр агуулсан нүдний лавлагаа эсвэл нүдний муж зэрэг мөрийн массив хэлбэрээр нийлүүлж болно.
• Текст2 , … (заавал биш) - нэмэлт текст утгууд хамтдаа нэгдэх. текст1 -г оруулаад дээд тал нь 252 текст аргументыг зөвшөөрнө.

Жишээ нь B2, C2, D2 нүднүүдийн хаягийн хэсгүүдийг нэг нүдэнд нэгтгэж утгуудыг нь салгая. таслал болон хоосон зайтай:

CONCATENATE функцийн хувьд та нүд бүрийг тус тусад нь зааж, лавлагаа бүрийн ард зааглагч (", ") тавих шаардлагатай бөгөөд энэ нь олон агуулгыг нэгтгэхэд хүндрэл учруулж болзошгүй юм. нүдүүд:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Excel TEXTJOIN-ийн тусламжтайгаар та эхний аргумент дээр зөвхөн нэг удаа зааглагчийг зааж өгч, гурав дахь аргументийн нүднүүдийн мужийг өгнө:

=TEXTJOIN(", ", TRUE, A2:C2)

Excel дээрх TEXTJOIN - санаж байх ёстой 6 зүйл

Ажлын хуудсандаа TEXTJOIN-г үр дүнтэй ашиглахын тулд хэд хэдэн чухал зүйлийг анхаарч үзэх хэрэгтэй:

1. TEXTJOIN бол шинэ юм. Энэ функц нь зөвхөн Excel 2019 - Excel 365 дээр боломжтой. Excel-ийн өмнөх хувилбаруудад CONCATENATE функц эсвэл "&"-г ашиглана уу. оператор.
2. Хэрэв Excel-ийн шинэ хувилбаруудад та CONCAT функцийг ашиглан салангид нүд болон мужуудын утгыг нэгтгэх боломжтой боловч хязгаарлагч эсвэл хоосон нүднүүдийн сонголт байхгүй.
3. Ямар ч дугаарыг нийлүүлсэн. хязгаарлагч эсвэл текст -д зориулж TEXTJOIN руу оруулна ууаргументуудыг текст болгон хувиргадаг.
4. Хэрэв хязгаарлагч -г заагаагүй эсвэл хоосон мөр ("") бол текстийн утгуудыг ямар ч хязгаарлагчгүйгээр холбоно.
5. Функц нь 252 хүртэлх текстийн аргументыг зохицуулах боломжтой.
6. Үргэлжлэх мөр нь Excel-ийн нүдний хязгаар болох дээд тал нь 32,767 тэмдэгт агуулж болно. Хэрэв энэ хязгаар хэтэрсэн бол TEXTJOIN томьёо нь #VALUE! алдаа.

Excel дээр текстийг хэрхэн нэгтгэх вэ - томьёоны жишээ

TEXTJOIN-ийн бүх давуу талыг илүү сайн ойлгохын тулд функцийг бодит амьдрал дээр хэрхэн ашиглахыг харцгаая. .

Баганыг таслалаар тусгаарлагдсан жагсаалт болгон хөрвүүлэх

Та утгуудыг таслал, цэгтэй таслал эсвэл өөр ямар нэгэн хязгаарлагчаар тусгаарласан босоо жагсаалтыг хооронд нь холбохыг хайж байгаа бол TEXTJOIN нь зөв функц юм.

Энэ жишээний хувьд бид доорх хүснэгтээс баг бүрийн хожил, хожигдлыг нэгтгэх болно. Үүнийг дараах томьёогоор хийж болох бөгөөд тэдгээр нь зөвхөн нэгдэж буй нүдний мужид ялгаатай.

1-р багийн хувьд:

=TEXTJOIN(",", FALSE, B2:B6)

2-р багийн хувьд:

=TEXTJOIN(",", FALSE, C2:C6)

Гэх мэт.

Бүх томьёонд дараах аргументуудыг ашигладаг:

• Хязгаарлагч - a таслал (",").
• Ignore_empty нь хоосон нүднүүдийг оруулахын тулд ХУДАЛ болгож тохируулсан, учир нь бид ямар тоглоом тоглоогүйг харуулах шаардлагатай.

Үүний үр дүнд та таслалаар тусгаарлагдсан дөрвөн жагсаалтыг авсаархан хэлбэрээр баг бүрийн ялалт, ялагдлыг илэрхийлэх болно.

Өөр өөр хязгаарлагчтай нүднүүдийг нэгтгэх

Нэгдсэн утгуудыг өөр хязгаарлагчаар салгах шаардлагатай үед та хэд хэдэн хязгаарлагчийг массивын тогтмол хэлбэрээр оруулах эсвэл тусгаарлагч бүрийг тусдаа нүдэнд оруулах боломжтой. хязгаарлагч аргументын хувьд мужын лавлагааг ашиглана уу.

Та өөр нэрний хэсгүүдийг агуулсан нүднүүдийг нэгтгэж үр дүнг дараах форматаар авахыг хүсэж байна гэж үзвэл: Овог , Овог нэр .

Таны харж байгаагаар овог болон овог хоёр таслал болон зай (", "), харин нэр болон овог нэр нь хоосон зайгаар тусгаарлагдсан байна. Зөвхөн (""). Тиймээс бид эдгээр хоёр хязгаарлагчийг {", "," "} массив тогтмолт оруулаад дараах томъёог авна:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Энд A2:C2 нь нэгтгэх нэрийн хэсгүүд юм.

Өөр нэг арга бол та зарим хоосон нүдэнд хашилтгүйгээр (F3-д таслал, хоосон зай, G3-д хоосон зай гэх мэт) хашилтгүйгээр бичиж, $F$3:$G$3 мужийг ашиглаж болно (сана уу). үнэмлэхүй нүдний лавлагаа) хязгаарлагч аргументын хувьд:

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Энэ ерөнхий аргыг ашигласнаар та нүдний агуулгыг янз бүрийн хэлбэрээр нэгтгэж болно.

Жишээлбэл, хэрэв та үр дүнг Нэр Дунд эхний Овог форматаар авахыг хүсвэл эхний тэмдэгтийг (эхний) гаргаж авахын тулд ЗҮҮН функцийг ашиглана уу. C2 нүднээс. Хязгаарлагчдын хувьд бид овог нэр болон дунд үсгийн хооронд зай (" ") тавьдаг; аэхний болон овог хоёрын хооронд үе ба зай (". "):

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Excel-д текст болон огноог нэгтгэх

Та нэгтгэх үед тодорхой тохиолдолд TEXTJOIN томъёонд огноог шууд оруулах нь текст болон огноо ажиллахгүй. Excel нь огноог серийн дугаар болгон хадгалдаг тул таны томьёо доорх дэлгэцийн агшинд үзүүлсэн шиг огноог харуулсан тоог буцаана:

=TEXTJOIN(" ", TRUE, A2:B2)

Үүнийг засахын тулд та хөрвүүлэх хэрэгтэй. огноог текст мөрөнд холбохоос өмнө оруулна. Мөн энд хүссэн форматын код бүхий TEXT функц (манай тохиолдолд "мм/dd/yyyy") хэрэг болно:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Текстийг мөр таслах

Хэрэв та Excel-д текстийг нэгтгэхийн тулд утга бүрийг шинэ мөрөнд оруулахыг хүсвэл CHAR(10)-ыг хязгаарлагч болгон ашиглаарай (10 нь мөрний тэмдэгт).

Жишээ нь, текстийг нэгтгэх А2 ба В2 нүднүүд утгуудыг мөрийн завсараар тусгаарлах бөгөөд энэ нь ашиглах томъёо юм:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Зөвлөгөө. Дээрх дэлгэцийн агшинд үзүүлсэн шиг үр дүнг олон мөрөнд харуулахын тулд Текстийг боох функцийг асаасан эсэхийг шалгаарай.

Текстийг нөхцөлтэй нэгтгэхэд TEXTJOIN IF

Excel TEXTJOIN нь мөрийн массивтай ажиллах чадвартай тул хоёр ба түүнээс дээш нүдний агуулгыг нөхцөлт байдлаар нэгтгэхэд мөн ашиглаж болно. Үүнийг хийхийн тулд IF функцийг ашиглан нүднүүдийн мужийг үнэлж, нөхцөлийг хангасан утгын массивыг текст1 аргумент руу буцаана уу.TEXTJOIN.

Доорх дэлгэцийн агшинд үзүүлсэн хүснэгтээс та Багийн 1 гишүүдийн жагсаалтыг гаргахыг хүсэж байна гэж бодъё. Үүнд хүрэхийн тулд дараах IF хэллэгийг текст1 аргумент дотор оруулаарай:

IF($B$2:$B$9=1, $A$2:$A$9, "")

Энгийн англи хэл дээр дээрх томьёо нь: Хэрэв В багана 1-тэй тэнцүү бол a буцаана. ижил эгнээний А баганаас авсан утга; эс бөгөөс хоосон мөр буцаана.

Багийн 1 -ийн бүрэн томьёо нь дараах хэлбэртэй байна:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Ижил төстэй байдлаар та Багийн 2-ын гишүүдийн таслалаар тусгаарлагдсан жагсаалт:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Тайлбар. Excel 365 болон 2021 дээр ашиглах боломжтой Динамик массивын онцлогийн улмаас энэ нь дээрх дэлгэцийн агшинд үзүүлсэн ердийн томъёогоор ажилладаг. Excel 2019 дээр та үүнийг Ctrl + Shift + Enter товчлолыг дарж уламжлалт массивын томьёо болгон оруулах ёстой.

Таслалаар тусгаарлагдсан жагсаалтаас олон таарч хайж олоод буцаана

Та мэдэж байгаа байх. Excel-ийн VLOOKUP функц нь зөвхөн эхний олдсон тохирохыг буцаах боломжтой. Гэхдээ та тодорхой ID, SKU эсвэл өөр зүйлд тохирох бүх зүйлийг авах шаардлагатай бол яах вэ?

Үр дүнг тус тусад нь нүднүүдэд гаргахын тулд Excel-ийн олон утгыг хэрхэн яаж VLOOKUP хийх талаар тайлбарласан томъёоны аль нэгийг ашиглана уу.

Нэг нүдэнд тохирох бүх утгыг таслалаар тусгаарласан жагсаалт болгон хайж олоод буцаахын тулд TEXTJOIN IF томьёог ашиглана уу.

Энэ нь практикт хэрхэн ажилладагийг харахын тулд дараах жагсаалтыг гаргая. түүвэр хүснэгтээс тухайн худалдагчийн худалдан авсан бүтээгдэхүүндоор. Үүнийг дараах томъёогоор хялбархан хийж болно:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Энд A2:A12 нь худалдагчийн нэр, B2:B12 нь бүтээгдэхүүн, D2 нь сонирхсон худалдагч юм.

Дээрх томъёо нь E2 руу орж, D2 (Адам) дээрх зорилтот худалдагчийн бүх тохирлыг авчирдаг. Харьцангуй (зорилтот худалдагчийн хувьд) болон үнэмлэхүй (худалдагчийн нэр, бүтээгдэхүүний хувьд) нүдний лавлагааг ухаалаг ашигласан тул томъёо нь доорх нүднүүдэд зөв хуулж, бусад хоёр худалдагч дээр ч сайн ажиллана:

Анхаарна уу. Өмнөх жишээний нэгэн адил энэ нь Excel 365 болон 2021 дээр ердийн томьёо болон Excel 2019 дээр CSE томьёогоор (Ctrl + Shift + Enter ) ажилладаг.

Томьёоны логик нь дараахтай яг ижил байна. өмнөх жишээ:

IF мэдэгдэл нь A2:A12 дахь нэр тус бүрийг D2 дахь зорилтот нэртэй харьцуулдаг (манай тохиолдолд Адам):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Хэрэв логик тест үнэлдэг бол ҮНЭН бол (өөрөөр хэлбэл D2 дахь нэр нь А баганад байгаа нэртэй таарч байгаа) томъёо нь В баганаас бүтээгдэхүүнийг буцаана; эс бөгөөс хоосон мөр ("") буцаана. IF-ийн үр дүн нь дараах массив байна:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Масиви нь text1 аргумент болж TEXTJOIN функц руу очно. Мөн TEXTJOIN нь утгуудыг таслал, зай (", ")-ээр тусгаарлахаар тохируулагдсан тул бид энэ мөрийг эцсийн үр дүн болгон авна:

Банана, Алим, Жүрж, Нимбэг

Excel TEXTJOIN ажиллахгүй байна

Таны TEXTJOIN томьёо алдаа гаргахад хамгийн их магадлалтайдараахын нэг байх:

• #NAME? Excel-ийн хуучин хувилбарт TEXTJOIN-г ашиглах үед энэ функцийг дэмждэггүй (2019 оноос өмнө) эсвэл функцийн нэрийг буруу бичсэн үед алдаа гардаг.
• #VALUE! Хэрэв үүссэн мөр 32,767 тэмдэгтээс хэтэрсэн бол алдаа гарна.
• #VALUE! Excel нь зааглагчийг текст гэж танихгүй, жишээ нь та CHAR(0) гэх мэт хэвлэх боломжгүй тэмдэгт оруулбал алдаа гарч болно.

Excel-д TEXTJOIN функцийг ингэж ашиглах боломжтой. Уншиж байгаад баярлалаа, дараа долоо хоногт манай блог дээр уулзана гэж найдаж байна!

Татаж авах боломжтой

Excel TEXTJOIN томъёоны жишээ