টিউটোরিয়ালটি দেখায় কিভাবে এক্সেলে টেক্সট মার্জ করতে TEXTJOIN ফাংশন ব্যবহার করে ব্যবহারিক উদাহরণ সহ।

সম্প্রতি পর্যন্ত, Excel এ সেল বিষয়বস্তু মার্জ করার দুটি প্রচলিত পদ্ধতি ছিল: সংযোজন অপারেটর এবং CONCATENATE ফাংশন। TEXTJOIN-এর প্রবর্তনের সাথে, মনে হচ্ছে একটি আরও শক্তিশালী বিকল্প উপস্থিত হয়েছে, যা আপনাকে আরও নমনীয় উপায়ে পাঠ্য যোগ করতে সক্ষম করে যার মধ্যে যেকোনও বিভাজন সহ। কিন্তু সত্যি বলতে কি, এতে আরও অনেক কিছু আছে!

Excel TEXTJOIN ফাংশন

Excel-এ TEXTJOIN একাধিক সেল বা রেঞ্জের পাঠ্য স্ট্রিংগুলিকে একত্রিত করে এবং যেকোন ডিলিমিটারের সাথে মিলিত মানগুলিকে আলাদা করে। যে আপনি নির্দিষ্ট. এটি হয় উপেক্ষা করতে পারে বা ফলাফলে খালি কক্ষগুলিকে অন্তর্ভুক্ত করতে পারে৷

ফাংশনটি Office 365, Excel 2021, এবং Excel 2019-এর জন্য Excel-এ উপলব্ধ৷

TEXTJOIN ফাংশনের সিনট্যাক্স নিম্নরূপ :

কোথায়:

• ডিলিমিটার (প্রয়োজনীয়) - প্রতিটি পাঠ্য মানের মধ্যে একটি বিভাজক যে আপনি একত্রিত. সাধারণত, এটি একটি পাঠ্য স্ট্রিং হিসাবে সরবরাহ করা হয় যা ডবল উদ্ধৃতিতে আবদ্ধ বা একটি পাঠ্য স্ট্রিং ধারণকারী একটি কক্ষের একটি রেফারেন্স। ডিলিমিটার হিসাবে সরবরাহ করা একটি সংখ্যাকে পাঠ্য হিসাবে গণ্য করা হয়৷
• উপেক্ষা_খালি (প্রয়োজনীয়) - খালি কক্ষগুলিকে উপেক্ষা করতে হবে কিনা তা নির্ধারণ করে:
  • সত্য - কোনো ফাঁকা ঘর উপেক্ষা করুন৷
  • মিথ্যা - ফলে স্ট্রিংয়ে খালি কক্ষগুলি অন্তর্ভুক্ত করুন৷
• টেক্সট1 (প্রয়োজনীয়) - যোগদানের জন্য প্রথম মান। একটি পাঠ্য স্ট্রিং হিসাবে সরবরাহ করা যেতে পারে, একটি স্ট্রিং সম্বলিত একটি কক্ষের একটি রেফারেন্স, বা স্ট্রিংগুলির অ্যারে যেমন ঘরের পরিসর।
• টেক্সট2 , … (ঐচ্ছিক) - অতিরিক্ত পাঠ্য মান একসাথে যোগদান করা টেক্সট1 সহ সর্বাধিক 252টি টেক্সট আর্গুমেন্ট অনুমোদিত।

উদাহরণস্বরূপ, আসুন B2, C2 এবং D2 সেল থেকে অ্যাড্রেস অংশগুলিকে এক কক্ষে একত্রিত করি, মানগুলিকে আলাদা করে। একটি কমা এবং একটি স্থান সহ:

CONCATENATE ফাংশনের সাথে, আপনাকে প্রতিটি ঘরকে পৃথকভাবে নির্দিষ্ট করতে হবে এবং প্রতিটি রেফারেন্সের পরে একটি বিভাজক (", ") লাগাতে হবে, যা অনেকের বিষয়বস্তু মার্জ করার সময় বিরক্তিকর হতে পারে কোষ:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Excel TEXTJOIN-এর সাথে, আপনি প্রথম আর্গুমেন্টে মাত্র একবার ডিলিমিটার নির্দিষ্ট করুন এবং তৃতীয় আর্গুমেন্টের জন্য সেলের একটি পরিসীমা সরবরাহ করুন:

=TEXTJOIN(", ", TRUE, A2:C2) <12

এক্সেল-এ TEXTJOIN - মনে রাখার 6টি জিনিস

আপনার ওয়ার্কশীটে কার্যকরভাবে TEXTJOIN ব্যবহার করার জন্য, কয়েকটি গুরুত্বপূর্ণ বিষয় লক্ষ্য রাখতে হবে:

1. TEXTJOIN একটি নতুন ফাংশন, যা শুধুমাত্র Excel 2019 - Excel 365-এ উপলব্ধ। পূর্ববর্তী এক্সেল সংস্করণগুলিতে, অনুগ্রহ করে CONCATENATE ফাংশন বা "&" ব্যবহার করুন পরিবর্তে অপারেটর।
2. এক্সেল হলে নতুন সংস্করণে, আপনি আলাদা কক্ষ এবং ব্যাপ্তি থেকে মান সংযুক্ত করতে CONCAT ফাংশনটিও ব্যবহার করতে পারেন, তবে বিভেদক বা খালি কক্ষের জন্য কোনও বিকল্প নেই৷
3. যে কোনও নম্বর সরবরাহ করা হয়েছে৷ ডিলিমিটার বা টেক্সট এর জন্য TEXTJOIN করুনআর্গুমেন্ট টেক্সটে রূপান্তরিত হয়।
4. যদি ডিলিমিটার নির্দিষ্ট করা না থাকে বা একটি খালি স্ট্রিং ("") হয়, তাহলে টেক্সট মানগুলি কোনো ডিলিমিটার ছাড়াই সংযুক্ত করা হয়।
5. ফাংশনটি করতে পারে 252টি পাঠ্য আর্গুমেন্ট পরিচালনা করুন।
6. ফলাফল স্ট্রিংটিতে সর্বাধিক 32,767টি অক্ষর থাকতে পারে, যা এক্সেলের সেল সীমা। এই সীমা অতিক্রম করলে, একটি TEXTJOIN সূত্র #VALUE প্রদান করে! ত্রুটি।

এক্সেল-এ পাঠ্য যোগ করার পদ্ধতি - সূত্র উদাহরণ

টেক্সটজয়নের সমস্ত সুবিধাগুলি আরও ভালভাবে বোঝার জন্য, বাস্তব-জীবনের পরিস্থিতিতে কীভাবে ফাংশনটি ব্যবহার করবেন তা একবার দেখে নেওয়া যাক .

কলামকে কমা বিভক্ত তালিকায় রূপান্তর করুন

যখন আপনি একটি উল্লম্ব তালিকাকে কমা, সেমিকোলন বা অন্য কোনো ডেলিমিটার দ্বারা আলাদা করে মানগুলিকে সংযুক্ত করতে চান, তখন TEXTJOIN ব্যবহার করার জন্য সঠিক ফাংশন৷

এই উদাহরণের জন্য, আমরা নীচের টেবিল থেকে প্রতিটি দলের জয়-পরাজয় সমন্বিত করব। এটি নিম্নলিখিত সূত্রগুলির সাহায্যে করা যেতে পারে, যেগুলি কেবলমাত্র যুক্ত হওয়া কোষগুলির পরিসরে পৃথক৷

টিম 1 এর জন্য:

=TEXTJOIN(",", FALSE, B2:B6)

টিম 2 এর জন্য:<3

=TEXTJOIN(",", FALSE, C2:C6)

এবং আরও।

সমস্ত সূত্রে, নিম্নলিখিত আর্গুমেন্টগুলি ব্যবহার করা হয়:

• ডিলিমিটার - a কমা (",")।
• উপেক্ষা_খালি খালি ঘরগুলি অন্তর্ভুক্ত করার জন্য FALSE এ সেট করা হয়েছে কারণ আমাদের দেখাতে হবে কোন গেমগুলি খেলা হয়নি৷

যেমন ফলস্বরূপ, আপনি চারটি কমা-বিচ্ছিন্ন তালিকা পাবেন যা একটি সংক্ষিপ্ত আকারে প্রতিটি দলের জয় এবং পরাজয়ের প্রতিনিধিত্ব করে:

বিভিন্ন ডিলিমিটার সহ কক্ষগুলিতে যোগ দিন

এমন একটি পরিস্থিতিতে যখন আপনাকে বিভিন্ন সীমাবদ্ধতার সাথে সম্মিলিত মানগুলিকে আলাদা করতে হবে, আপনি হয় একটি অ্যারে ধ্রুবক হিসাবে বেশ কয়েকটি ডিলিমিটার সরবরাহ করতে পারেন বা প্রতিটি ডিলিমিটারকে একটি পৃথক ঘরে ইনপুট করতে পারেন এবং ডিলিমিটার আর্গুমেন্টের জন্য একটি রেঞ্জ রেফারেন্স ব্যবহার করুন।

ধরুন আপনি বিভিন্ন নামের অংশ সম্বলিত কক্ষে যোগ দিতে চান এবং এই ফর্ম্যাটে ফলাফল পেতে চান: শেষ নাম , প্রথম নাম মধ্য নাম ।

যেমন আপনি দেখতে পাচ্ছেন, শেষ নাম এবং প্রথম নাম একটি কমা এবং একটি স্পেস (", ") দ্বারা পৃথক করা হয়েছে যেখানে প্রথম নাম এবং মধ্য নাম একটি স্পেস দ্বারা (" ") কেবল. সুতরাং, আমরা এই দুটি ডিলিমিটারকে একটি অ্যারে ধ্রুবক {", "," "}-এ অন্তর্ভুক্ত করি এবং নিম্নলিখিত সূত্রটি পাই:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

যেখানে A2:C2 নামের অংশগুলিকে একত্রিত করতে হবে।

বিকল্পভাবে, আপনি কিছু খালি কক্ষে উদ্ধৃতি চিহ্ন ছাড়াই ডিলিমিটার টাইপ করতে পারেন (বলুন, F3 তে একটি কমা এবং একটি স্পেস এবং G3 তে একটি স্পেস) এবং $F$3:$G$3 ব্যাপ্তি ব্যবহার করতে পারেন (দয়া করে মনে রাখবেন পরম সেল রেফারেন্স) ডিলিমিটার আর্গুমেন্টের জন্য:

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

এই সাধারণ পদ্ধতি ব্যবহার করে, আপনি বিভিন্ন আকারে সেল বিষয়বস্তু একত্র করতে পারেন। উদাহরণ স্বরূপ, আপনি যদি প্রথম নাম মাঝের আদ্যক্ষর শেষ নাম বিন্যাসে ফলাফল চান, তাহলে প্রথম অক্ষর (প্রাথমিক) বের করতে LEFT ফাংশন ব্যবহার করুন সেল C2 থেকে। ডিলিমিটারের জন্য, আমরা প্রথম নাম এবং মধ্যবর্তী আদ্যক্ষরের মধ্যে একটি স্পেস ("") রাখি; কপিরিয়ড এবং একটি স্পেস (") প্রারম্ভিক এবং শেষ নামের মধ্যে:

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Excel এ পাঠ্য এবং তারিখগুলিতে যোগ দিন

একটি নির্দিষ্ট ক্ষেত্রে যখন আপনি মার্জ করছেন টেক্সট এবং তারিখ, সরাসরি একটি TEXTJOIN সূত্রে তারিখ সরবরাহ করা কাজ করবে না। আপনি মনে করতে পারেন, এক্সেল তারিখগুলিকে ক্রমিক সংখ্যা হিসাবে সংরক্ষণ করে, তাই আপনার সূত্রটি নীচের স্ক্রিনশটে দেখানো তারিখের প্রতিনিধিত্বকারী একটি সংখ্যা প্রদান করবে:

=TEXTJOIN(" ", TRUE, A2:B2)

এটি ঠিক করতে, আপনাকে রূপান্তর করতে হবে যোগ করার আগে একটি টেক্সট স্ট্রিং এ তারিখ। এবং এখানে পছন্দসই ফরম্যাট কোড সহ TEXT ফাংশন (আমাদের ক্ষেত্রে "mm/dd/yyyy") কাজে আসে:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

লাইন বিরতির সাথে পাঠ্য একত্রিত করুন

আপনি যদি এক্সেলে পাঠ্যকে একত্রিত করতে চান যাতে প্রতিটি মান একটি নতুন লাইনে শুরু হয়, CHAR(10) ব্যবহার করুন বিভাজনকারী হিসাবে (যেখানে 10 একটি লাইনফিড অক্ষর)।

উদাহরণস্বরূপ, থেকে পাঠ্য একত্রিত করতে কক্ষ A2 এবং B2 একটি লাইন বিরতি দ্বারা মান পৃথক করে, এটি ব্যবহার করার সূত্র:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

টিপ। উপরের স্ক্রিনশটে দেখানো মত একাধিক লাইনে ফলাফল দেখানোর জন্য, নিশ্চিত করুন যে Wrap টেক্সট বৈশিষ্ট্যটি চালু আছে।

পরিস্থিতির সাথে পাঠ্য একত্রিত করতে TEXTJOIN IF

এক্সেল TEXTJOIN এর স্ট্রিংগুলির অ্যারেগুলি পরিচালনা করার ক্ষমতার কারণে, এটি শর্তসাপেক্ষে দুই বা ততোধিক ঘরের বিষয়বস্তু একত্রিত করতেও ব্যবহার করা যেতে পারে। এটি সম্পন্ন করতে, IF ফাংশনটি ব্যবহার করে কক্ষের পরিসরের মূল্যায়ন করুন এবং শর্ত পূরণকারী মানগুলির একটি অ্যারে ফেরত দিন যা text1 আর্গুমেন্টেTEXTJOIN।

নীচের স্ক্রিনশটে দেখানো টেবিল থেকে, ধরুন আপনি টিম 1 সদস্যদের একটি তালিকা পুনরুদ্ধার করতে চান। এটি অর্জন করতে, নিচের IF স্টেটমেন্টটিকে text1 আর্গুমেন্টে নেস্ট করুন:

IF($B$2:$B$9=1, $A$2:$A$9, "")

সাধারণ ইংরেজিতে, উপরের সূত্রটি বলে: যদি কলাম B 1 এর সমান হয়, তাহলে a ফেরত দিন একই সারিতে কলাম A থেকে মান; অন্যথায় একটি খালি স্ট্রিং ফিরিয়ে দিন।

টিম 1 এর সম্পূর্ণ সূত্রটি এই আকার নেয়:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

একইভাবে, আপনি একটি পেতে পারেন টিম 2 এর সদস্যদের কমা দ্বারা পৃথক করা তালিকা:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

নোট। এক্সেল 365 এবং 2021 এ উপলব্ধ ডায়নামিক অ্যারে বৈশিষ্ট্যের কারণে, এটি একটি নিয়মিত সূত্র হিসাবে কাজ করে, উপরের স্ক্রিনশটে দেখানো হয়েছে। Excel 2019-এ, আপনাকে Ctrl + Shift + Enter শর্টকাট টিপে এটিকে একটি প্রথাগত অ্যারে সূত্র হিসেবে লিখতে হবে।

কমা থেকে আলাদা করা তালিকায় একাধিক মিল দেখুন এবং ফেরত দিন

আপনি সম্ভবত জানেন, Excel VLOOKUP ফাংশন শুধুমাত্র প্রথম পাওয়া মিল ফিরিয়ে দিতে পারে। কিন্তু আপনি যদি একটি নির্দিষ্ট আইডি, SKU বা অন্য কিছুর জন্য সমস্ত মিল পেতে চান?

ফলাফল আলাদা কক্ষে আউটপুট করতে, Excel-এ একাধিক মান VLOOKUP করতে বর্ণিত সূত্রগুলির একটি ব্যবহার করুন।

কমা দ্বারা পৃথক তালিকা হিসাবে একটি একক কক্ষে সমস্ত মিলে যাওয়া মানগুলি সন্ধান করতে এবং ফেরত দিতে, TEXTJOIN IF সূত্রটি ব্যবহার করুন৷

এটি কীভাবে কাজ করে তা দেখতে, আসুন একটি তালিকা পুনরুদ্ধার করি নমুনা টেবিল থেকে একটি প্রদত্ত বিক্রেতার দ্বারা কেনা পণ্যনিচে. নিম্নলিখিত সূত্র দিয়ে এটি সহজেই করা যেতে পারে:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

যেখানে A2:A12 হল বিক্রেতার নাম, B2:B12 হল পণ্য এবং D2 হল আগ্রহের বিক্রেতা৷

উপরের সূত্রটি E2 তে যায় এবং D2 (এডাম) এ লক্ষ্য বিক্রেতার জন্য সমস্ত মিল নিয়ে আসে। আপেক্ষিক (লক্ষ্য বিক্রেতার জন্য) এবং পরম (বিক্রেতার নাম এবং পণ্যের জন্য) সেল রেফারেন্সের চতুর ব্যবহারের কারণে, সূত্রটি নীচের ঘরে সঠিকভাবে অনুলিপি করে এবং অন্য দুটি বিক্রেতার জন্যও চমৎকারভাবে কাজ করে:

বিঃদ্রঃ. আগের উদাহরণের মতো, এটি Excel 365 এবং 2021-এ একটি নিয়মিত সূত্র হিসাবে কাজ করে এবং Excel 2019-এ CSE সূত্র (Ctrl + Shift + Enter ) হিসাবে কাজ করে৷

সূত্রটির যুক্তি ঠিক একই রকম পূর্ববর্তী উদাহরণ:

IF বিবৃতিটি A2:A12-এর প্রতিটি নামের সাথে D2 (আমাদের ক্ষেত্রে অ্যাডাম) লক্ষ্য নামের সাথে তুলনা করে:

IF($A$2:$A$12=D2, $B$2:$B$12, "")

যদি যৌক্তিক পরীক্ষা মূল্যায়ন করে TRUE থেকে (অর্থাৎ D2-এর নামটি কলাম A-এর নামের সাথে মিলে যায়), সূত্রটি কলাম B থেকে একটি পণ্য প্রদান করে; অন্যথায় একটি খালি স্ট্রিং ("") ফেরত দেওয়া হয়। IF এর ফলাফল হল নিম্নলিখিত অ্যারে:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

অ্যারেটি text1 আর্গুমেন্ট হিসাবে TEXTJOIN ফাংশনে যায়। এবং যেহেতু TEXTJOIN একটি কমা এবং একটি স্পেস (", ") দিয়ে মানগুলিকে আলাদা করার জন্য কনফিগার করা হয়েছে, তাই আমরা চূড়ান্ত ফলাফল হিসাবে এই স্ট্রিংটি পেয়েছি:

কলা, আপেল, কমলা, লেবু

এক্সেল TEXTJOIN কাজ করছে না

যখন আপনার TEXTJOIN সূত্রে একটি ত্রুটি দেখা দেয়, এটি সম্ভবতনিম্নলিখিতগুলির মধ্যে একটি হতে হবে:

• #NAME? ত্রুটি ঘটে যখন TEXTJOIN এক্সেলের একটি পুরানো সংস্করণে ব্যবহার করা হয় যেখানে এই ফাংশনটি সমর্থিত নয় (প্রাক-2019) অথবা যখন ফাংশনের নামের বানান ভুল হয়৷
• #VALUE! ফলাফল স্ট্রিং 32,767 অক্ষর অতিক্রম করলে ত্রুটি ঘটে।
• #VALUE! এক্সেল যদি ডিলিমিটারটিকে পাঠ্য হিসাবে চিনতে না পারে তাহলেও ত্রুটি ঘটতে পারে, উদাহরণস্বরূপ যদি আপনি CHAR(0) এর মতো কিছু অ-মুদ্রণযোগ্য অক্ষর সরবরাহ করেন।

এভাবে এক্সেলে TEXTJOIN ফাংশনটি ব্যবহার করতে হয়। আমি পড়ার জন্য আপনাকে ধন্যবাদ এবং আশা করি আগামী সপ্তাহে আমাদের ব্লগে দেখা হবে!

উপলভ্য ডাউনলোড

Excel TEXTJOIN সূত্র উদাহরণ