Udžbenik pokazuje kako koristiti funkciju TEXTJOIN za spajanje teksta u Excelu s praktičnim primjerima.

Donedavno su postojale dvije prevladavajuće metode za spajanje sadržaja ćelija u Excelu: ulančavanje operator i funkcija CONCATENATE. S uvođenjem TEXTJOIN-a, čini se da se pojavila snažnija alternativa koja vam omogućuje spajanje teksta na fleksibilniji način uključujući bilo koji graničnik između. Ali zapravo, tu ima mnogo više!

Funkcija Excel TEXTJOIN

TEXTJOIN u Excelu spaja tekstualne nizove iz više ćelija ili raspona i odvaja kombinirane vrijednosti bilo kojim graničnikom koje navedete. Može ili zanemariti ili uključiti prazne ćelije u rezultat.

Funkcija je dostupna u Excelu za Office 365, Excel 2021 i Excel 2019.

Sintaksa funkcije TEXTJOIN je sljedeća :

Gdje:

• Razdjelnik (obavezno) - je razdjelnik između svake tekstualne vrijednosti koje kombinirate. Obično se isporučuje kao tekstualni niz u dvostrukim navodnicima ili kao referenca na ćeliju koja sadrži tekstualni niz. Broj naveden kao graničnik tretira se kao tekst.
• Ignore_empty (obavezno) - Određuje hoće li se zanemariti prazne ćelije ili ne:
  • TRUE - zanemariti sve prazne ćelije.
  • FALSE - uključi prazne ćelije u rezultirajući niz.
• Tekst1 (obavezno) - prva vrijednost za pridruživanje. Može se dostaviti kao tekstualni niz, referenca na ćeliju koja sadrži niz ili niz nizova kao što je raspon ćelija.
• Tekst2 , … (neobavezno) - dodatne tekstualne vrijednosti da se spoje zajedno. Dopuštena su najviše 252 tekstualna argumenta, uključujući text1 .

Kao primjer, kombinirajmo dijelove adresa iz ćelija B2, C2 i D2 zajedno u jednu ćeliju, odvajajući vrijednosti sa zarezom i razmakom:

S funkcijom CONCATENATE, morali biste navesti svaku ćeliju pojedinačno i staviti razgraničivač (", ") iza svake reference, što bi moglo smetati pri spajanju sadržaja mnogih ćelije:

=CONCATENATE(A2, ", ", B2, ", ", C2)

S Excel TEXTJOIN, određujete graničnik samo jednom u prvom argumentu i dajete raspon ćelija za treći argument:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN u Excelu - 6 stvari koje treba zapamtiti

Da biste učinkovito koristili TEXTJOIN u svojim radnim listovima, morate obratiti pozornost na nekoliko važnih točaka:

1. TEXTJOIN je nova koja je dostupna samo u programu Excel 2019 - Excel 365. U ranijim verzijama programa Excel koristite funkciju CONCATENATE ili "&" umjesto toga operator.
2. U novim verzijama programa Excel možete koristiti i funkciju CONCAT za spajanje vrijednosti iz zasebnih ćelija i raspona, ali bez opcija za razdjelnike ili prazne ćelije.
3. Bilo koji navedeni broj za TEXTJOIN za razdjelnik ili tekst argumenti se pretvaraju u tekst.
4. Ako razdjelnik nije naveden ili je prazan niz (""), tekstualne vrijednosti su spojene bez ikakvog razdjelnika.
5. Funkcija može obraditi do 252 tekstualna argumenta.
6. Rezultirajući niz može sadržavati najviše 32.767 znakova, što je ograničenje ćelije u Excelu. Ako je ovo ograničenje premašeno, formula TEXTJOIN vraća #VALUE! pogreška.

Kako spojiti tekst u Excelu - primjeri formula

Da biste bolje razumjeli sve prednosti TEXTJOIN-a, pogledajmo kako koristiti ovu funkciju u stvarnim scenarijima .

Pretvori stupac u popis odvojen zarezom

Kada želite spojiti okomiti popis odvajajući vrijednosti zarezom, točkom sa zarezom ili bilo kojim drugim graničnikom, TEXTJOIN je prava funkcija za korištenje.

Za ovaj primjer, spajat ćemo pobjede i poraze svakog tima iz tablice u nastavku. To se može učiniti sa sljedećim formulama, koje se razlikuju samo u rasponu ćelija koje se spajaju.

Za tim 1:

=TEXTJOIN(",", FALSE, B2:B6)

Za tim 2:

=TEXTJOIN(",", FALSE, C2:C6)

I tako dalje.

U svim formulama koriste se sljedeći argumenti:

• Razdjelnik - a zarez (",").
• Ignore_empty postavljeno je na FALSE da uključi prazne ćelije jer moramo pokazati koje igre nisu igrane.

Kao što Rezultat, dobit ćete četiri popisa odvojena zarezima koji predstavljaju pobjede i poraze svakog tima u kompaktnom obliku:

Spajanje ćelija s različitim graničnicima

U situaciji kada trebate razdvojiti kombinirane vrijednosti različitim graničnicima, možete unijeti nekoliko graničnika kao konstantu niza ili unijeti svaki graničnik u zasebnu ćeliju i koristite referencu raspona za argument razdjelnik .

Pretpostavimo da želite spojiti ćelije koje sadrže različite dijelove naziva i dobiti rezultat u ovom formatu: Prezime , Ime Srednje ime .

Kao što vidite, prezime i ime odvojeni su zarezom i razmakom (", "), dok su ime i srednje ime razmakom (" ") samo. Dakle, uključujemo ova dva graničnika u konstantu polja {", "," "} i dobivamo sljedeću formulu:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Gdje su A2:C2 dijelovi naziva koji se kombiniraju.

Alternativno, možete upisati razdjelnike bez navodnika u neke prazne ćelije (recimo, zarez i razmak u F3 i razmak u G3) i koristiti raspon $F$3:$G$3 (molimo imajte na umu apsolutne reference ćelije) za argument razdjelnik :

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Upotrebom ovog općeg pristupa možete spojiti sadržaj ćelije u različitim oblicima.

Na primjer, ako želite rezultat u formatu Ime Srednji inicijali Prezime , tada upotrijebite funkciju LIJEVO da izdvojite prvi znak (početak) iz ćelije C2. Što se tiče graničnika, stavili smo razmak (" ") između imena i srednjeg inicijala; atočka i razmak (". ") između početnog i prezimena:

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Spajanje teksta i datuma u Excelu

U konkretnom slučaju kada spajate teksta i datuma, dostavljanje datuma izravno u TEXTJOIN formulu neće raditi. Kao što se možda sjećate, Excel pohranjuje datume kao serijske brojeve, tako da će vaša formula vratiti broj koji predstavlja datum kao što je prikazano na snimci zaslona u nastavku:

=TEXTJOIN(" ", TRUE, A2:B2)

Da biste to popravili, trebate pretvoriti datum u tekstualni niz prije nego što mu se pridruži. I ovdje funkcija TEXT sa željenim kodom formata ("mm/dd/gggg" u našem slučaju) dobro dolazi:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Spoji tekst s prijelomima redaka

Ako želite spojiti tekst u Excelu tako da svaka vrijednost počinje u novom retku, koristite CHAR(10) kao razdjelnik (gdje je 10 znak za novi redak).

Na primjer, za kombiniranje teksta iz ćelije A2 i B2 odvajajući vrijednosti prijelomom retka, ovo je formula za korištenje:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Savjet. Da bi se rezultat prikazao u više redaka kao što je prikazano na gornjoj snimci zaslona, ​​provjerite je li uključena značajka Prelom teksta.

TEXTJOIN IF za spajanje teksta s uvjetima

Zbog mogućnosti Excel TEXTJOIN-a da rukuje s nizovima nizova, također se može koristiti za uvjetno spajanje sadržaja dviju ili više ćelija. Da biste to učinili, upotrijebite funkciju IF za procjenu raspona ćelija i vraćanje niza vrijednosti koje ispunjavaju uvjet za argument text1 odTEXTJOIN.

Iz tablice prikazane na slici ispod, pretpostavimo da želite dohvatiti popis članova Tima 1 . Da biste to postigli, ugniježdite sljedeću IF naredbu u argument text1 :

IF($B$2:$B$9=1, $A$2:$A$9, "")

Na običnom engleskom, gornja formula kaže: Ako je stupac B jednak 1, vratite vrijednost iz stupca A u istom redu; inače vrati prazan niz.

Kompletna formula za Tim 1 ima ovaj oblik:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Na sličan način možete dobiti popis članova tima 2 odvojen zarezima:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Napomena. Zbog značajke Dynamic Arrays dostupne u Excelu 365 i 2021, ovo funkcionira kao uobičajena formula, prikazana na gornjoj snimci zaslona. U programu Excel 2019 morate ga unijeti kao tradicionalnu formulu polja pritiskom na prečac Ctrl + Shift + Enter.

Traženje i vraćanje više rezultata na popisu odvojenom zarezima

Kao što vjerojatno znate, Funkcija Excel VLOOKUP može vratiti samo prvo pronađeno podudaranje. Ali što ako trebate dobiti sva podudaranja za određeni ID, SKU ili nešto drugo?

Da biste ispisali rezultate u odvojenim ćelijama, upotrijebite jednu od formula opisanih u Kako VLOOKUPirati više vrijednosti u Excelu.

Da biste potražili i vratili sve podudarne vrijednosti u jednoj ćeliji kao popis odvojen zarezom, upotrijebite formulu TEXTJOIN IF.

Da biste vidjeli kako funkcionira u praksi, dohvatimo popis proizvoda koje je kupio određeni prodavač iz tablice uzorakaispod. To se lako može učiniti sljedećom formulom:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Gdje su A2:A12 imena prodavača, B2:B12 su proizvodi, a D2 je prodavač od interesa.

Gornja formula ide na E2 i donosi sva podudaranja za ciljnog prodavača u D2 (Adam). Zbog pametne upotrebe relativnih (za ciljnog prodavača) i apsolutnih (za imena prodavača i proizvoda) referenci ćelija, formula se ispravno kopira u donje ćelije i dobro funkcionira i za druga dva prodavača:

Bilješka. Kao i u prethodnom primjeru, ovo funkcionira kao redovita formula u Excelu 365 i 2021, te kao CSE formula (Ctrl + Shift + Enter ) u Excelu 2019.

Logika formule potpuno je ista kao u prethodni primjer:

IF izjava uspoređuje svako ime u A2:A12 s ciljnim imenom u D2 (Adam u našem slučaju):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Ako logički test procjenjuje na TRUE (tj. ime u D2 odgovara imenu u stupcu A), formula vraća proizvod iz stupca B; inače se vraća prazan niz (""). Rezultat IF je sljedeći niz:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Niz ide u funkciju TEXTJOIN kao argument text1 . Budući da je TEXTJOIN konfiguriran za odvajanje vrijednosti zarezom i razmakom (", "), dobivamo ovaj niz kao konačni rezultat:

Banane, Jabuke, Naranče, Limuni

Excel TEXTJOIN ne radi

Kada vaša formula TEXTJOIN rezultira pogreškom, najvjerojatnije jebiti jedno od sljedećeg:

• #IME? pogreška se javlja kada se TEXTJOIN koristi u starijoj verziji Excela gdje ova funkcija nije podržana (prije 2019.) ili kada je naziv funkcije pogrešno napisan.
• #VALUE! dolazi do pogreške ako rezultirajući niz premašuje 32.767 znakova.
• #VALUE! do pogreške može doći i ako Excel ne prepozna graničnik kao tekst, na primjer ako unesete neki znak koji se ne može ispisati kao što je CHAR(0).

Tako se koristi funkcija TEXTJOIN u Excelu. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!

Dostupna preuzimanja

Excel TEXTJOIN primjeri formula