Õpetus näitab praktiliste näidetega, kuidas kasutada funktsiooni TEXTJOIN teksti ühendamiseks Excelis.

Kuni viimase ajani oli Excelis kaks levinud meetodit lahtri sisu ühendamiseks: aheldamise operaator ja funktsioon CONCATENATE. TEXTJOINi kasutuselevõtuga tundub, et on ilmunud võimsam alternatiiv, mis võimaldab teksti paindlikumalt ühendada, sealhulgas mis tahes eraldajaid vahepeal. Aga tegelikult on palju rohkem!

Exceli funktsioon TEXTJOIN

TEXTJOIN ühendab Excelis tekstisõnu mitmest lahtrist või vahemikust ja eraldab kombineeritud väärtused mis tahes piiritlejaga, mille te määrate. See võib kas ignoreerida või lisada tulemusse tühjad lahtrid.

Funktsioon on saadaval Office 365, Excel 2021 ja Excel 2019 Excelis.

Funktsiooni TEXTJOIN süntaks on järgmine:

Kus:

• Eraldaja (nõutav) - on eraldaja iga kombineeritava tekstiväärtuse vahel. Tavaliselt esitatakse see tekstijada, mis on suletud topeltlauseidesse, või viide tekstijada sisaldavale lahtrisse. Eraldajana esitatud numbrit käsitletakse tekstina.
• Ignore_empty (nõutav) - määrab, kas tühje lahtreid ignoreeritakse või mitte:
  • TRUE - ignoreerib tühjad lahtrid.
  • FALSE - lisada tühjad lahtrid tulemuseks olevasse stringi.
• Tekst1 (nõutav) - esimene ühendatav väärtus. Võib esitada teksti stringina, viide stringi sisaldavale lahtrisse või stringide massiivi, näiteks lahtrite vahemiku kujul.
• Tekst2 , ... (valikuline) - täiendavad tekstiväärtused, mis liidetakse kokku. Lubatud on maksimaalselt 252 tekstargumenti, sealhulgas text1 .

Näitena ühendame lahtrite B2, C2 ja D2 aadressiosad ühte lahtrisse, eraldades väärtused koma ja tühikuga:

Funktsiooni CONCATENATE abil peate määrama iga lahtri eraldi ja panema iga viite järel eraldaja (", "), mis võib olla tülikas paljude lahtrite sisu ühendamisel:

=CONCATENATE(A2, ", ", B2, ", ", ", C2)

Exceli TEXTJOINi puhul määrate eraldaja vaid üks kord esimeses argumendis ja esitate kolmanda argumendi jaoks lahtrite vahemiku:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN Excelis - 6 asja, mida meeles pidada

TEXTJOINi tõhusaks kasutamiseks oma töölehtedel on mõned olulised punktid, mida tuleb tähele panna:

1. TEXTJOIN on uus funktsioon, mis on saadaval ainult Excel 2019 - Excel 365. Varasemates Exceli versioonides kasutage selle asemel funktsiooni CONCATENATE või operaatorit "&".
2. Uutes Exceli versioonides saate kasutada ka funktsiooni CONCAT, et liita eraldi lahtrite ja vahemike väärtusi, kuid ilma eraldusmärkide või tühjade lahtrite valikudeta.
3. TEXTJOINile esitatud mis tahes number, mis on ette nähtud piiritleja või tekst argumendid teisendatakse tekstiks.
4. Kui piiritleja ei ole määratud või on tühi string (""), siis tekstiväärtused ühendatakse ilma eraldajaid kasutamata.
5. Funktsioon saab töödelda kuni 252 tekstiargumenti.
6. Saadud string võib sisaldada maksimaalselt 32 767 tähemärki, mis on Exceli lahtri piirnorm. Kui see piirnorm ületatakse, annab valem TEXTJOIN tagasi vea #VALUE!.

Kuidas liita teksti Excelis - valemite näited

Et paremini mõista kõiki TEXTJOINi eeliseid, vaatame, kuidas seda funktsiooni reaalsetes stsenaariumides kasutada.

Teisenda veerg komadega eraldatud loendiks

Kui soovite liita vertikaalse loetelu, mis eraldab väärtused komaga, semikooloniga või mõne muu eraldajaga, on TEXTJOIN õige funktsioon.

Selles näites ühendame iga meeskonna võidud ja kaotused allolevast tabelist. Seda saab teha järgmiste valemitega, mis erinevad ainult ühendatavate lahtrite vahemiku poolest.

Meeskonna 1 jaoks:

=TEXTJOIN(",", FALSE, B2:B6)

Meeskonnale 2:

=TEXTJOIN(",", FALSE, C2:C6)

Ja nii edasi.

Kõigis valemites kasutatakse järgmisi argumente:

• Eraldaja - koma (",").
• Ignore_empty on seatud FALSE, et lisada tühjad lahtrid, sest meil on vaja näidata, milliseid mänge ei ole mängitud.

Tulemusena saate neli komadega eraldatud nimekirja, mis esindavad iga meeskonna võite ja kaotusi kompaktsel kujul:

Erinevate eraldusmärkidega lahtrite ühendamine

Olukorras, kus on vaja kombineeritud väärtusi eraldada erinevate eraldusmärkidega, võite kas anda mitu eraldusmärki massiivi konstandina või sisestada iga eraldusmärk eraldi lahtrisse ja kasutada vahemikuviidet jaoks piiritleja argument.

Oletame, et soovite ühendada lahtrid, mis sisaldavad erinevaid nimeosi, ja saada tulemuse sellisel kujul: Perekonnanimi , Eesnimi Keskmine nimi .

Nagu näete, on perekonnanimi ja eesnimi eraldatud koma ja tühikuga (", "), samas kui eesnimi ja kesknimi ainult tühikuga (" "). Seega, lisame need kaks eraldajat massiivi konstanti {", ",""} ja saame järgmise valemi:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Kus A2:C2 on kombineeritavad nimeosad.

Teise võimalusena võite sisestada piiritlejad ilma jutumärkideta mõnda tühja lahtrisse (näiteks koma ja tühik F3-s ja tühik G3-s) ja kasutada vahemikku $F$3:$G$3 (palun arvestage absoluutseid lahtriviiteid). piiritleja argument:

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Kasutades seda üldist lähenemisviisi, saate lahtrite sisu ühendada eri vormidel.

Näiteks, kui soovite, et tulemus oleks aadressil Eesnimi Keskmine algustäht Perekonnanimi formaadis, seejärel kasutame funktsiooni LEFT, et eraldada lahtrist C2 esimene märk (algustäht). Mis puutub eraldusmärkidesse, siis paneme tühiku (" ") eesnime ja keskmise algustähe vahele; punkti ja tühiku (". ") algustähe ja perekonnanime vahele:

=TEXTJOIN({" ","."}, TRUE, B2, LEFT(C2,1), A2)

Teksti ja kuupäevade ühendamine Excelis

Konkreetsel juhul, kui te ühendate teksti ja kuupäevi, ei toimi kuupäevade esitamine otse valemile TEXTJOIN. Nagu te ehk mäletate, salvestab Excel kuupäevi järjekorranumbritena, seega teie valem tagastab kuupäeva tähistava numbri, nagu on näidatud alloleval ekraanipildil:

=TEXTJOIN(" ", TRUE, A2:B2)

Selle parandamiseks tuleb kuupäev enne liitmist konverteerida tekstistringiks. Ja siin tuleb appi funktsioon TEXT koos soovitud vormingukoodiga ("mm/dd/yyyy" meie puhul):

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyyyy"))

Teksti ühendamine reavahetustega

Kui soovite teksti Excelis ühendada nii, et iga väärtus algab uues reas, kasutage eraldusmärkina CHAR(10) (kus 10 on reavahetusmärk).

Näiteks selleks, et ühendada tekst lahtritest A2 ja B2, eraldades väärtused reavahetusega, tuleb kasutada järgmist valemit:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Vihje. Selleks, et tulemus kuvataks mitmes reas, nagu on näidatud ülaltoodud ekraanipildil, veenduge, et funktsioon Wrap text on sisse lülitatud.

TEXTJOIN IF teksti ühendamiseks tingimustega

Tänu Exceli TEXTJOINi võimele käidelda stringide massiive, saab seda kasutada ka kahe või enama lahtri sisu tingimuslikuks ühendamiseks. Selleks kasutage IF-funktsiooni, et hinnata lahtrite vahemikku ja tagastada tingimusele vastavate väärtuste massiivi, et text1 argument TEXTJOIN.

Oletame, et soovite alloleval ekraanipildil näidatud tabelist välja otsida nimekirja Meeskond 1 liikmeid. Selle saavutamiseks pesitsege järgmine IF avaldis sisse text1 argument:

IF($B$2:$B$9=1, $A$2:$A$9, "")

Selgesõnaliselt ütleb ülaltoodud valem: Kui veerg B on võrdne 1, tagasta sama rea veeru A väärtus; vastasel juhul tagasta tühi string.

Täielik valem Meeskond 1 võtab sellise kuju:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Samamoodi saate te saada komadega eraldatud nimekirja liikmetest, mis on seotud Meeskond 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Märkus. Tänu Excel 365 ja 2021 funktsioonile Dynamic Arrays (dünaamilised massiivid) töötab see tavalise valemina, nagu on näidatud ülaltoodud ekraanipildil. Excel 2019-s peate selle sisestama traditsioonilise massiivi valemina, vajutades Ctrl + Shift + Enter kiirklahvi.

Otsi ja tagasta mitu vastet komadega eraldatud nimekirjas

Nagu te ilmselt teate, saab Exceli VLOOKUP-funktsioon tagastada ainult esimese leitud vaste. Aga mis siis, kui teil on vaja saada kõik vasted konkreetse ID, SKU või muu jaoks?

Tulemuste väljastamiseks eraldi lahtritesse kasutage ühte valemit, mida on kirjeldatud jaotises Kuidas VLOOKUP mitu väärtust Excelis.

Selleks, et otsida ja tagastada kõik ühes lahtris olevad sobivad väärtused komadega eraldatud loeteluna, kasutage valemit TEXTJOIN IF.

Et näha, kuidas see praktikas toimib, otsime alljärgnevast näidistabelist antud müüja poolt ostetud toodete nimekirja. Seda saab hõlpsasti teha järgmise valemiga:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Kus A2:A12 on müüjate nimed, B2:B12 on tooted ja D2 on huvipakkuv müüja.

Ülaltoodud valem läheb lahtrisse E2 ja toob kõik sihtmüüja vasted lahtrisse D2 (Adam). Tänu suhteliste (sihtmüüja jaoks) ja absoluutsete (müüja nimede ja toodete jaoks) lahtriviidete nutikale kasutamisele kopeeritakse valem korrektselt allolevatesse lahtritesse ja töötab kenasti ka kahe teise müüja puhul:

Märkus. Nagu eelmise näite puhul, töötab see tavalise valemina Excel 365 ja 2021 ning CSE valemina (Ctrl + Shift + Enter ) Excel 2019is.

Valemi loogika on täpselt sama, mis eelmises näites:

IF avaldis võrdleb iga nime A2:A12 sihtnimega D2-s (meie puhul Adam):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Kui loogiline test annab tulemuseks TRUE (st nimi D2 vastab veerus A olevale nimele), tagastab valem toote veerust B; vastasel juhul tagastatakse tühi string (""). IF tulemuseks on järgmine massiivi:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Massiiv läheb funktsioonile TEXTJOIN kui text1 Ja kuna TEXTJOIN on konfigureeritud nii, et väärtused eraldatakse koma ja tühikuga (", "), saame lõpptulemusena selle stringi:

Banaanid, õunad, apelsinid, sidrunid

Excel TEXTJOIN ei tööta

Kui teie TEXTJOIN-valem annab vea, on tõenäoliselt tegemist ühega järgmistest:

• #NAME? viga tekib, kui TEXTJOINi kasutatakse Exceli vanemas versioonis, kus seda funktsiooni ei toetata (enne 2019. aastat), või kui funktsiooni nimi on valesti kirjutatud.
• #VALUE! viga tekib, kui saadud string ületab 32,767 tähemärki.
• #VALUE! viga võib tekkida ka siis, kui Excel ei tunnista eraldajat tekstina, näiteks kui te esitate mingi mittetrükitava märgi, näiteks CHAR(0).

See on, kuidas kasutada TEXTJOIN funktsiooni Excelis. Tänan teid lugemise eest ja loodan, et näeme teid järgmisel nädalal meie blogis!

Saadaolevad allalaadimised

Exceli TEXTJOIN-valemi näited