Упатството покажува како да се користи функцијата TEXTJOIN за спојување текст во Excel со практични примери.

До неодамна, постоеја два распространети методи за спојување на содржината на ќелијата во Excel: конкатенација оператор и функцијата CONCATENATE. Со воведувањето на TEXTJOIN, се чини дека се појави помоќна алтернатива, која ви овозможува да се придружите на текст на пофлексибилен начин, вклучувајќи кој било разграничувач помеѓу. Но, всушност, има многу повеќе во тоа!

Excel TEXTJOIN функцијата

TEXTJOIN во Excel спојува текстуални низи од повеќе ќелии или опсези и ги одделува комбинираните вредности со кој било разграничувач што ќе го наведете. Може или да игнорира или да вклучи празни ќелии во резултатот.

Функцијата е достапна во Excel за Office 365, Excel 2021 и Excel 2019.

Синтаксата на функцијата TEXTJOIN е следна :

Каде:

• Одделувач (задолжително) - е раздвојувач помеѓу секоја вредност на текстот што ги комбинирате. Вообичаено, тој се доставува како текстуална низа затворена во двојни наводници или упатување на ќелија која содржи текстуална низа. Бројот доставен како разграничувач се третира како текст.
• Игнорирај_празно (задолжително) - Определува дали да се игнорираат празни ќелии или не:
  • ТОЧНО - игнорирајте ги празните ќелии.
  • FALSE - вклучете празни ќелии во добиената низа.
• Text1 (задолжително) - прва вредност за приклучување. Може да се достави како текстуална низа, референца за ќелија која содржи низа или низа низи како што е опсег на ќелии.
• Text2 , … (опционално) - дополнителни текстуални вредности да бидат споени заедно. Дозволени се максимум 252 текстуални аргументи, вклучувајќи text1 .

Како пример, ајде да ги комбинираме адресните делови од ќелиите B2, C2 и D2 заедно во една ќелија, одвојувајќи ги вредностите со запирка и празно место:

Со функцијата CONCATENATE, треба да ја одредите секоја ќелија поединечно и да ставите разграничувач (", ") по секоја референца, што може да биде досадно кога се спојуваат содржините на многу ќелии:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Со Excel TEXTJOIN, го одредувате раздвојувачот само еднаш во првиот аргумент и обезбедувате опсег на ќелии за третиот аргумент:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN во Excel - 6 работи што треба да се запамети

За ефикасно користење на TEXTJOIN во вашите работни листови, има неколку важни точки на кои треба да обрнете внимание:

1. TEXTJOIN е нов функција, која е достапна само во Excel 2019 - Excel 365. Во претходните верзии на Excel, користете ја функцијата CONCATENATE или „&“ Наместо тоа, операторот.
2. Во новите верзии ако Excel, можете исто така да ја користите функцијата CONCAT за поврзување вредности од одделни ќелии и опсези, но без опции за разграничувачи или празни ќелии.
3. Доставен кој било број до TEXTJOIN за разграничувачот или текст аргументите се претвораат во текст.
4. Ако разграничувачот не е наведен или е празна низа (""), вредностите на текстот се спојуваат без никаков разграниувач.
5. Функцијата може да се справува со до 252 текстуални аргументи.
6. Резултирачката низа може да содржи максимум 32.767 знаци, што е ограничување на ќелиите во Excel. Ако оваа граница е надмината, формулата TEXTJOIN ја враќа #VALUE! грешка.

Како да се приклучи текст во Excel - примери на формула

За подобро да ги разбереме сите предности на TEXTJOIN, ајде да погледнеме како да ја користиме функцијата во реални сценарија .

Конвертирај колона во листа одвоена со запирка

Кога сакате да споите вертикална листа која ги одвојува вредностите со запирка, точка-запирка или кој било друг разграничувач, TEXTJOIN е вистинската функција за користење.

За овој пример, ќе ги споиме победите и поразите на секој тим од табелата подолу. Ова може да се направи со следните формули, кои се разликуваат само во опсегот на ќелии што се споени.

За тимот 1:

=TEXTJOIN(",", FALSE, B2:B6)

За тимот 2:

=TEXTJOIN(",", FALSE, C2:C6)

И така натаму.

Во сите формули се користат следните аргументи:

• Одвојувач - a запирка (",").
• Ignore_empty е поставено на FALSE за да вклучува празни ќелии бидејќи треба да покажеме кои игри не се играле.

Како што Како резултат, ќе добиете четири листи разделени со запирки кои ги претставуваат победите и поразите на секој тим во компактна форма:

Спојувајте ќелии со различни разграничувачи

Во ситуација кога треба да ги одделите комбинираните вредности со различни разграничувачи, можете или да наведете неколку разграничи како константа на низа или да го внесете секој разграниувач во посебна ќелија и користете референца за опсег за аргументот разграничувач .

Да претпоставиме дека сакате да ги споите ќелиите што содржат различни делови од името и да го добиете резултатот во овој формат: Презиме , Име Средно име .

Како што можете да видите, Презимето и Името се одделени со запирка и празно (", "), додека името и средното име со празно место само („“). Значи, ги вклучуваме овие два разграничи во константа на низа {", "," "} и ја добиваме следнава формула:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Каде што A2:C2 се деловите со имиња што треба да се комбинираат.

Алтернативно, можете да ги напишете разграничувачите без наводници во некои празни ќелии (на пример, запирка и празно место во F3 и празно место во G3) и да го користите опсегот $F$3:$G$3 (ве молиме имајте предвид апсолутните референци на ќелиите) за аргументот разграничувач :

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Со користење на овој општ пристап, можете да ја споите содржината на ќелијата во различни форми.

На пример, ако сакате резултатот во формат Име Средно почетно Презиме , тогаш користете ја функцијата LEFT за да го извлечете првиот знак (почетниот) од ќелијата C2. Што се однесува до разграничувачите, ставаме празно место (" ") помеѓу Првото име и средниот иницијал; аточка и празно место (". ") помеѓу почетното и презимето:

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Придружете се на текст и датуми во Excel

Во конкретен случај кога се спојувате текст и датуми, доставувањето датуми директно на формулата TEXTJOIN нема да работи. Како што се сеќавате, Excel ги складира датумите како сериски броеви, така што вашата формула ќе врати број што го претставува датумот како што е прикажано на сликата подолу:

=TEXTJOIN(" ", TRUE, A2:B2)

За да го поправите ова, треба да го конвертирате датумот во текстуална низа пред да се приклучи. И тука функцијата TEXT со саканиот формат код („mm/dd/yyyy“ во нашиот случај) ни доаѓа:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Спојување на текст со прекини на линии

Ако сакате да го споите текстот во Excel, така што секоја вредност започнува во нова линија, користете го CHAR(10) како разграничувач (каде што 10 е знак за довод на линија).

На пример, за комбинирање на текст од ќелиите A2 и B2 ги одвојуваат вредностите со прекин на линијата, ова е формулата што треба да се користи:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Совет. За резултатот да се прикаже во повеќе линии како што е прикажано на сликата од екранот погоре, проверете дали е вклучена функцијата Завиткајте текст.

TEXTJOIN IF за спојување текст со услови

Поради способноста на Excel TEXTJOIN да се справува со низи низи, може да се користи и за условно спојување на содржината на две или повеќе ќелии. За да го направите тоа, користете ја функцијата IF за да оцените опсег на ќелии и да вратите низа вредности што го исполнуваат условот на аргументот text1 наTEXTJOIN.

Од табелата прикажана на екранот подолу, да претпоставиме дека сакате да преземете список со членови на Тимот 1 . За да го постигнете ова, вметнете ја следнава изјава IF во аргументот text1 :

IF($B$2:$B$9=1, $A$2:$A$9, "")

На обичен англиски јазик, горната формула вели: Ако колоната B е еднаква на 1, вратете вредност од колоната А во истиот ред; инаку вратете празна низа.

Комплетната формула за Тимот 1 ја има оваа форма:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

На сличен начин, можете да добиете Список од членовите на Тимот 2, разделен со запирки:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Забелешка. Поради функцијата Динамички низи достапна во Excel 365 и 2021, ова функционира како редовна формула, прикажана на сликата од екранот погоре. Во Excel 2019, мора да ја внесете како традиционална формула за низа со притискање на кратенката Ctrl + Shift + Enter.

Пребарајте и вратите повеќе совпаѓања во списокот разделен со запирки

Како што веројатно знаете, Функцијата Excel VLOOKUP може да го врати само првото пронајдено совпаѓање. Но, што ако треба да ги добиете сите совпаѓања за одредена лична карта, SKU или нешто друго?

За да ги дадете резултатите во посебни ќелии, користете една од формулите опишани во Како да ВЛОКУПИРАТЕ повеќе вредности во Excel.

За да ги побарате и да ги вратите сите соодветни вредности во една ќелија како листа одвоена со запирка, користете ја формулата TEXTJOIN IF.

За да видите како функционира во пракса, ајде да преземеме листа на производи купени од даден продавач од табелата со примероциподолу. Ова може лесно да се направи со следнава формула:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Каде што A2:A12 се имињата на продавачите, B2:B12 се производите, а D2 е продавачот на интерес.

Горенаведената формула оди на Е2 и ги носи сите совпаѓања за целниот продавач во Д2 (Адам). Поради паметната употреба на референци на релативни (за целниот продавач) и апсолутни (за имиња и производи на продавачите), формулата правилно се копира во долунаведените ќелии и работи убаво и за другите двајца продавачи:

Забелешка. Како и со претходниот пример, ова функционира како обична формула во Excel 365 и 2021, и како формула за CSE (Ctrl + Shift + Enter ) во Excel 2019 година.

Логиката на формулата е потполно иста како во претходен пример:

Изјавата IF го споредува секое име во A2:A12 со целното име во D2 (Адам во нашиот случај):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Ако логичкиот тест процени до ТОЧНО (т.е. името во D2 се совпаѓа со името во колоната А), формулата враќа производ од колоната Б; во спротивно се враќа празна низа („“). Резултатот од IF е следнава низа:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Низата оди во функцијата TEXTJOIN како аргумент text1 . И бидејќи TEXTJOIN е конфигуриран да ги одделува вредностите со запирка и празно место (", "), ја добиваме оваа низа како конечен резултат:

Банани, јаболка, портокали, лимони

Excel TEXTJOIN не работи

Кога формулата TEXTJOIN резултира со грешка, најверојатно еда биде едно од следниве:

• #NAME? се појавува грешка кога TEXTJOIN се користи во постара верзија на Excel каде оваа функција не е поддржана (пред 2019 година) или кога името на функцијата е погрешно напишано.
• #VALUE! се појавува грешка ако добиената низа надминува 32.767 знаци.
• #VALUE! може да се појави и грешка ако Excel не го препознае разграничувачот како текст, на пример, ако внесете некој знак што не може да се печати, како што е CHAR(0).

Така се користи функцијата TEXTJOIN во Excel. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!

Достапни преземања

Примери на формулата Excel TEXTJOIN