Das Tutorial zeigt anhand von praktischen Beispielen, wie man die Funktion TEXTJOIN zum Zusammenführen von Text in Excel verwendet.

Bis vor kurzem gab es zwei gängige Methoden zum Zusammenführen von Zellinhalten in Excel: den Verkettungsoperator und die Funktion CONCATENATE. Mit der Einführung von TEXTJOIN scheint es, als ob eine leistungsfähigere Alternative aufgetaucht ist, die es Ihnen ermöglicht, Text auf flexiblere Art und Weise zu verbinden und dabei jedes beliebige Trennzeichen dazwischen zu setzen. Aber in Wahrheit steckt viel mehr dahinter!

Excel-Funktion TEXTJOIN

TEXTJOIN in Excel fügt Textzeichenfolgen aus mehreren Zellen oder Bereichen zusammen und trennt die kombinierten Werte mit einem von Ihnen angegebenen Trennzeichen, wobei leere Zellen entweder ignoriert oder in das Ergebnis einbezogen werden können.

Die Funktion ist in Excel für Office 365, Excel 2021 und Excel 2019 verfügbar.

Die Syntax der Funktion TEXTJOIN lautet wie folgt:

Wo:

• Begrenzungszeichen (erforderlich) - ist ein Trennzeichen zwischen den einzelnen Textwerten, die Sie kombinieren. Normalerweise wird es in Form einer in Anführungszeichen eingeschlossenen Textzeichenfolge oder eines Verweises auf eine Zelle, die eine Textzeichenfolge enthält, angegeben. Eine als Trennzeichen angegebene Zahl wird als Text behandelt.
• Ignorieren_leer (erforderlich) - Bestimmt, ob leere Zellen ignoriert werden sollen oder nicht:
  • TRUE - alle leeren Zellen werden ignoriert.
  • FALSE - schließt leere Zellen in die resultierende Zeichenkette ein.
• Text1 (erforderlich) - erster zu verbindender Wert; kann als Textstring, als Verweis auf eine Zelle, die einen String enthält, oder als Array von Strings, z. B. ein Bereich von Zellen, angegeben werden.
• Text2 , ... (optional) - zusätzliche Textwerte, die miteinander verbunden werden sollen. Es sind maximal 252 Textargumente zulässig, darunter text1 .

Kombinieren wir zum Beispiel die Adressbestandteile der Zellen B2, C2 und D2 in einer Zelle und trennen die Werte durch ein Komma und ein Leerzeichen:

Mit der Funktion KONKATENIEREN müssten Sie jede Zelle einzeln angeben und nach jedem Verweis ein Trennzeichen (", ") einfügen, was beim Zusammenführen der Inhalte vieler Zellen lästig sein könnte:

=VERKETTUNG(A2, ", ", B2, ", ", C2)

Bei Excel TEXTJOIN geben Sie das Trennzeichen nur einmal im ersten Argument an und liefern einen Zellbereich für das dritte Argument:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN in Excel - 6 Dinge zu beachten

Um TEXTJOIN effektiv in Ihren Arbeitsblättern zu verwenden, sind einige wichtige Punkte zu beachten:

1. TEXTJOIN ist eine neue Funktion, die nur in Excel 2019 - Excel 365 verfügbar ist. In früheren Excel-Versionen verwenden Sie bitte stattdessen die Funktion CONCATENATE oder den Operator "&".
2. In den neuen Versionen von Excel können Sie auch die Funktion CONCAT verwenden, um Werte aus separaten Zellen und Bereichen miteinander zu verknüpfen, allerdings ohne Optionen für Trennzeichen oder leere Zellen.
3. Jede an TEXTJOIN übergebene Nummer für die Begrenzungszeichen oder Text Argumente werden in Text umgewandelt.
4. Wenn Begrenzungszeichen nicht angegeben wird oder eine leere Zeichenkette ("") ist, werden die Textwerte ohne Begrenzungszeichen aneinandergehängt.
5. Die Funktion kann bis zu 252 Textargumente verarbeiten.
6. Die resultierende Zeichenkette kann maximal 32.767 Zeichen enthalten, was der Zellgrenze in Excel entspricht. Wird diese Grenze überschritten, gibt eine TEXTJOIN-Formel den Fehler #VALUE! zurück.

Wie man Text in Excel verbindet - Formelbeispiele

Um die Vorteile von TEXTJOIN besser zu verstehen, wollen wir uns ansehen, wie die Funktion in der Praxis eingesetzt wird.

Spalte in kommagetrennte Liste umwandeln

Wenn Sie eine vertikale Liste verketten möchten, deren Werte durch ein Komma, ein Semikolon oder ein anderes Trennzeichen getrennt sind, ist TEXTJOIN die richtige Funktion für Sie.

In diesem Beispiel werden die Siege und Niederlagen der einzelnen Mannschaften aus der unten stehenden Tabelle miteinander verknüpft. Dies kann mit den folgenden Formeln geschehen, die sich nur durch den Bereich der verbundenen Zellen unterscheiden.

Für Team 1:

=TEXTJOIN(",", FALSE, B2:B6)

Für Team 2:

=TEXTJOIN(",", FALSE, C2:C6)

Und so weiter.

In allen Formeln werden die folgenden Argumente verwendet:

• Begrenzungszeichen - ein Komma (",").
• Ignorieren_leer ist auf FALSE gesetzt, um leere Zellen einzuschließen, da wir zeigen müssen, welche Spiele nicht gespielt wurden.

Als Ergebnis erhalten Sie vier durch Kommata getrennte Listen, die die Siege und Niederlagen der einzelnen Mannschaften in kompakter Form darstellen:

Zellen mit unterschiedlichen Begrenzungszeichen verbinden

In einer Situation, in der Sie die kombinierten Werte mit verschiedenen Begrenzungszeichen trennen müssen, können Sie entweder mehrere Begrenzungszeichen als Array-Konstante angeben oder jedes Begrenzungszeichen in eine separate Zelle eingeben und einen Bereichsbezug für die Begrenzungszeichen Argument.

Angenommen, Sie möchten Zellen mit unterschiedlichen Namensteilen verbinden und das Ergebnis in diesem Format erhalten: Nachname , Vorname Zweiter Vorname .

Wie Sie sehen, sind Nachname und Vorname durch ein Komma und ein Leerzeichen (", ") getrennt, während der Vorname und der mittlere Name nur durch ein Leerzeichen (" ") getrennt sind. Wir fügen also diese beiden Trennzeichen in eine Array-Konstante {", "," "} ein und erhalten die folgende Formel:

=TEXTJOIN({", ",""}, TRUE, A2:C2)

Dabei sind A2:C2 die zu kombinierenden Namensteile.

Alternativ können Sie die Begrenzungszeichen ohne Anführungszeichen in einige leere Zellen eingeben (z.B. ein Komma und ein Leerzeichen in F3 und ein Leerzeichen in G3) und den Bereich $F$3:$G$3 (bitte beachten Sie die absoluten Zellbezüge) für die Begrenzungszeichen Argument:

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Mit Hilfe dieses allgemeinen Ansatzes können Sie Zellinhalte in verschiedenen Formen zusammenführen.

Wenn Sie zum Beispiel das Ergebnis in der Datei Vornamen Mittlere Initiale Nachname Als Begrenzungszeichen setzen wir ein Leerzeichen (" ") zwischen den Vornamen und den mittleren Anfangsbuchstaben, einen Punkt und ein Leerzeichen (". ") zwischen den Anfangsbuchstaben und den Nachnamen:

=TEXTJOIN({" ","."}, TRUE, B2, LEFT(C2,1), A2)

Text und Daten in Excel verbinden

In einem speziellen Fall, in dem Sie Text und Datumsangaben zusammenführen, funktioniert die direkte Eingabe von Datumsangaben in eine TEXTJOIN-Formel nicht. Wie Sie sich vielleicht erinnern, speichert Excel Datumsangaben als fortlaufende Nummern, so dass Ihre Formel eine Zahl zurückgibt, die das Datum repräsentiert, wie in der folgenden Abbildung gezeigt:

=TEXTJOIN(" ", TRUE, A2:B2)

Um dies zu beheben, müssen Sie das Datum in einen Textstring umwandeln, bevor Sie es zusammenfügen. Und hier kommt die Funktion TEXT mit dem gewünschten Formatcode (in unserem Fall "mm/dd/yyyy") zum Einsatz:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Text mit Zeilenumbrüchen zusammenführen

Wenn Sie Text in Excel so zusammenführen möchten, dass jeder Wert in einer neuen Zeile beginnt, verwenden Sie CHAR(10) als Begrenzungszeichen (wobei 10 ein Zeilenvorschubzeichen ist).

Um beispielsweise Text aus den Zellen A2 und B2 zu kombinieren und die Werte durch einen Zeilenumbruch zu trennen, ist die folgende Formel zu verwenden:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Tipp: Damit das Ergebnis wie im obigen Screenshot in mehreren Zeilen angezeigt wird, muss die Funktion Textumbruch aktiviert sein.

TEXTJOIN IF zum Zusammenführen von Text mit Bedingungen

Aufgrund der Fähigkeit von Excel TEXTJOIN, Arrays von Zeichenketten zu verarbeiten, kann es auch verwendet werden, um den Inhalt von zwei oder mehr Zellen bedingt zusammenzuführen. Dazu verwenden Sie die IF-Funktion, um einen Bereich von Zellen auszuwerten und ein Array von Werten, die die Bedingung erfüllen, an die text1 Argument von TEXTJOIN.

Nehmen wir an, Sie möchten aus der Tabelle in der folgenden Abbildung eine Liste mit folgenden Daten abrufen Mannschaft 1 Um dies zu erreichen, fügen Sie die folgende IF-Anweisung in die Datei text1 Argument:

IF($B$2:$B$9=1, $A$2:$A$9, "")

Im Klartext bedeutet die obige Formel: Wenn Spalte B gleich 1 ist, gib einen Wert aus Spalte A in derselben Zeile zurück; andernfalls gib eine leere Zeichenfolge zurück.

Die vollständige Formel für Mannschaft 1 nimmt diese Form an:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Auf ähnliche Weise können Sie eine kommagetrennte Liste der Mitglieder von Team 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Hinweis: Aufgrund der Funktion Dynamische Arrays in Excel 365 und 2021 funktioniert dies als reguläre Formel, wie im Screenshot oben gezeigt. In Excel 2019 müssen Sie es als herkömmliche Array-Formel eingeben, indem Sie die Tastenkombination Strg + Umschalt + Eingabe drücken.

Suche und Rückgabe mehrerer Treffer in einer durch Kommata getrennten Liste

Wie Sie wahrscheinlich wissen, kann die Excel-Funktion VLOOKUP nur die erste gefundene Übereinstimmung zurückgeben. Was aber, wenn Sie alle Übereinstimmungen für eine bestimmte ID, SKU oder etwas anderes abrufen müssen?

Um die Ergebnisse in separaten Zellen auszugeben, verwenden Sie eine der Formeln, die in How to VLOOKUP multiple values in Excel beschrieben sind.

Um alle übereinstimmenden Werte in einer einzelnen Zelle zu suchen und als kommagetrennte Liste zurückzugeben, verwenden Sie die Formel TEXTJOIN WENN.

Um zu sehen, wie es in der Praxis funktioniert, lassen Sie uns eine Liste von Produkten, die von einem bestimmten Verkäufer gekauft wurden, aus der Beispieltabelle unten abrufen. Dies kann leicht mit der folgenden Formel geschehen:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

A2:A12 sind Verkäufernamen, B2:B12 sind Produkte, und D2 ist der Verkäufer, der von Interesse ist.

Die obige Formel geht zu E2 und bringt alle Übereinstimmungen für den Zielverkäufer in D2 (Adam). Dank der geschickten Verwendung von relativen (für den Zielverkäufer) und absoluten (für die Verkäufernamen und Produkte) Zellverweisen wird die Formel korrekt in die darunter liegenden Zellen kopiert und funktioniert auch für die beiden anderen Verkäufer gut:

Hinweis: Wie im vorherigen Beispiel funktioniert dies als reguläre Formel in Excel 365 und 2021 und als CSE-Formel (Strg + Umschalt + Eingabe) in Excel 2019.

Die Logik der Formel ist genau dieselbe wie im vorherigen Beispiel:

Die IF-Anweisung vergleicht jeden Namen in A2:A12 mit dem Zielnamen in D2 (in unserem Fall Adam):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Wenn der logische Test TRUE ergibt (d.h. der Name in D2 stimmt mit dem Namen in Spalte A überein), gibt die Formel ein Produkt aus Spalte B zurück; andernfalls wird ein leerer String ("") zurückgegeben. Das Ergebnis von IF ist das folgende Array:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Das Array geht an die Funktion TEXTJOIN als text1 Und da TEXTJOIN so konfiguriert ist, dass die Werte durch ein Komma und ein Leerzeichen (", ") getrennt werden, erhalten wir diese Zeichenfolge als Endergebnis:

Bananen, Äpfel, Orangen, Zitronen

Excel TEXTJOIN funktioniert nicht

Wenn Ihre TEXTJOIN-Formel zu einem Fehler führt, liegt höchstwahrscheinlich einer der folgenden Fälle vor:

• Der Fehler #NAME? tritt auf, wenn TEXTJOIN in einer älteren Excel-Version verwendet wird, in der diese Funktion nicht unterstützt wird (vor 2019), oder wenn der Name der Funktion falsch geschrieben ist.
• Der Fehler #VALUE! tritt auf, wenn die resultierende Zeichenkette 32.767 Zeichen überschreitet.
• Der Fehler #VALUE! kann auch auftreten, wenn Excel das Trennzeichen nicht als Text erkennt, z. B. wenn Sie ein nicht druckbares Zeichen wie CHAR(0) eingeben.

So wird die Funktion TEXTJOIN in Excel verwendet. Ich danke Ihnen für die Lektüre und hoffe, Sie nächste Woche in unserem Blog begrüßen zu dürfen!

Verfügbare Downloads

Excel TEXTJOIN Formel Beispiele