Bu eğitimde, Excel'de metin birleştirmek için METİN BİRLEŞTİR işlevinin nasıl kullanılacağı pratik örneklerle gösterilmektedir.

Yakın zamana kadar, Excel'de hücre içeriklerini birleştirmek için iki yaygın yöntem vardı: birleştirme operatörü ve CONCATENATE işlevi. TEXTJOIN'in piyasaya sürülmesiyle, aradaki herhangi bir sınırlayıcı da dahil olmak üzere metni daha esnek bir şekilde birleştirmenize olanak tanıyan daha güçlü bir alternatif ortaya çıkmış gibi görünüyor. Ancak gerçekte, bundan çok daha fazlası var!

Excel TEXTJOIN işlevi

Excel'deki METİN BİRLEŞTİR, birden çok hücre veya aralıktaki metin dizelerini birleştirir ve birleştirilmiş değerleri belirttiğiniz herhangi bir sınırlayıcıyla ayırır. Boş hücreleri yok sayabilir veya sonuca dahil edebilir.

Bu işlev Office 365 için Excel, Excel 2021 ve Excel 2019'da kullanılabilir.

TEXTJOIN fonksiyonunun sözdizimi aşağıdaki gibidir:

Nerede?

• Sınırlayıcı (gerekli) - birleştirdiğiniz her metin değeri arasında bir ayırıcıdır. Genellikle, çift tırnak içine alınmış bir metin dizesi veya metin dizesi içeren bir hücreye başvuru olarak sağlanır. Ayırıcı olarak sağlanan bir sayı metin olarak değerlendirilir.
• Ignore_empty (gerekli) - Boş hücrelerin yok sayılıp sayılmayacağını belirler:
  • DOĞRU - boş hücreleri yoksay.
  • FALSE - sonuç dizesine boş hücreleri dahil eder.
• Metin1 (gerekli) - birleştirilecek ilk değer. Bir metin dizesi, bir dize içeren bir hücreye başvuru veya bir hücre aralığı gibi dizeler dizisi olarak sağlanabilir.
• Metin2 , ... (isteğe bağlı) - birleştirilecek ek metin değerleri. Aşağıdakiler dahil olmak üzere en fazla 252 metin bağımsız değişkenine izin verilir metin1 .

Örnek olarak, B2, C2 ve D2 hücrelerindeki adres parçalarını tek bir hücrede birleştirelim ve değerleri virgül ve boşlukla ayıralım:

CONCATENATE işlevi ile, her hücreyi ayrı ayrı belirtmeniz ve her referanstan sonra bir sınırlayıcı (", ") koymanız gerekir; bu da birçok hücrenin içeriğini birleştirirken rahatsız edici olabilir:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Excel TEXTJOIN ile, sınırlayıcıyı ilk bağımsız değişkende yalnızca bir kez belirtirsiniz ve üçüncü bağımsız değişken için bir hücre aralığı sağlarsınız:

=TEXTJOIN(", ", TRUE, A2:C2)

Excel'de TEXTJOIN - Hatırlanması gereken 6 şey

TEXTJOIN'i çalışma sayfalarınızda etkili bir şekilde kullanmak için dikkat etmeniz gereken birkaç önemli nokta vardır:

1. TEXTJOIN, yalnızca Excel 2019 - Excel 365'te kullanılabilen yeni bir işlevdir. Önceki Excel sürümlerinde, lütfen bunun yerine CONCATENATE işlevini veya "&" operatörünü kullanın.
2. Excel'in yeni sürümlerinde, ayrı hücrelerdeki ve aralıklardaki değerleri birleştirmek için CONCAT işlevini de kullanabilirsiniz, ancak sınırlayıcılar veya boş hücreler için seçenek yoktur.
3. için TEXTJOIN'e verilen herhangi bir sayı sınırlayıcı veya Metin argümanları metne dönüştürülür.
4. Eğer sınırlayıcı belirtilmezse veya boş bir dize ("") ise, metin değerleri herhangi bir sınırlayıcı olmadan birleştirilir.
5. Fonksiyon 252 adede kadar metin bağımsız değişkenini işleyebilir.
6. Ortaya çıkan dize, Excel'deki hücre sınırı olan en fazla 32.767 karakter içerebilir. Bu sınır aşılırsa, bir METİNBİRLEŞTİR formülü #DEĞER! hatası döndürür.

Excel'de metin nasıl birleştirilir - formül örnekleri

TEXTJOIN'in tüm avantajlarını daha iyi anlamak için, fonksiyonun gerçek hayat senaryolarında nasıl kullanılacağına bir göz atalım.

Sütunu virgülle ayrılmış listeye dönüştürme

Değerleri virgül, noktalı virgül veya başka bir sınırlayıcı ile ayıran dikey bir listeyi birleştirmek istediğinizde, TEXTJOIN kullanılacak doğru fonksiyondur.

Bu örnekte, aşağıdaki tablodan her takımın galibiyet ve mağlubiyetlerini birleştireceğiz. Bu, yalnızca birleştirilen hücre aralığında farklılık gösteren aşağıdaki formüllerle yapılabilir.

Takım 1 için:

=TEXTJOIN(",", FALSE, B2:B6)

2. Takım için:

=TEXTJOIN(",", FALSE, C2:C6)

Ve böyle devam eder.

Tüm formüllerde aşağıdaki argümanlar kullanılır:

• Sınırlayıcı - virgül (",").
• Ignore_empty boş hücreleri dahil etmek için FALSE olarak ayarlanır çünkü hangi oyunların oynanmadığını göstermemiz gerekir.

Sonuç olarak, her takımın galibiyet ve mağlubiyetlerini kompakt bir biçimde temsil eden virgülle ayrılmış dört liste elde edeceksiniz:

Farklı sınırlayıcılara sahip hücreleri birleştirme

Birleşik değerleri farklı sınırlayıcılarla ayırmanız gereken bir durumda, bir dizi sabiti olarak birkaç sınırlayıcı sağlayabilir veya her sınırlayıcıyı ayrı bir hücreye girebilir ve sınırlayıcı Tartışma.

Farklı ad bölümleri içeren hücreleri birleştirmek ve sonucu bu biçimde almak istediğinizi varsayalım: Soyadı , İlk isim İkinci isim .

Gördüğünüz gibi, Soyadı ve Adı virgül ve bir boşlukla (", "), Adı ve Orta adı ise yalnızca bir boşlukla (" ") ayrılmıştır. Dolayısıyla, bu iki sınırlayıcıyı {", "," "} dizi sabitine dahil eder ve aşağıdaki formülü elde ederiz:

=TEXTJOIN({", ",""}, TRUE, A2:C2)

Burada A2:C2 birleştirilecek isim parçalarıdır.

Alternatif olarak, sınırlayıcıları tırnak işaretleri olmadan bazı boş hücrelere yazabilir (örneğin, F3'te virgül ve boşluk ve G3'te boşluk) ve $F$3:$G$3 aralığını kullanabilirsiniz (lütfen mutlak hücre referanslarına dikkat edin). sınırlayıcı Tartışma:

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Bu genel yaklaşımı kullanarak hücre içeriklerini çeşitli biçimlerde birleştirebilirsiniz.

Örneğin, eğer sonucu İlk isim Orta baş harf Soyadı biçimini seçin, ardından C2 hücresinden ilk karakteri (baş harf) çıkarmak için LEFT işlevini kullanın. Sınırlayıcılara gelince, İlk ad ile Orta baş harf arasına bir boşluk (" "); İlk ad ile Soyadı arasına bir nokta ve bir boşluk (". ") koyarız:

=TEXTJOIN({" ","."}, TRUE, B2, LEFT(C2,1), A2)

Excel'de metin ve tarihleri birleştirme

Metin ve tarihleri birleştirdiğiniz özel bir durumda, tarihleri doğrudan bir TEXTJOIN formülüne sağlamak işe yaramayacaktır. Hatırlayabileceğiniz gibi, Excel tarihleri seri numaraları olarak saklar, bu nedenle formülünüz aşağıdaki ekran görüntüsünde gösterildiği gibi tarihi temsil eden bir sayı döndürecektir:

=TEXTJOIN(" ", TRUE, A2:B2)

Bunu düzeltmek için, tarihi birleştirmeden önce bir metin dizesine dönüştürmeniz gerekir. Ve burada, istenen biçim koduna sahip TEXT işlevi (bizim durumumuzda "mm/dd/yyyy") kullanışlı olur:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Metni satır sonlarıyla birleştirme

Excel'de metni her değer yeni bir satırda başlayacak şekilde birleştirmek isterseniz, sınırlayıcı olarak CHAR(10) kullanın (burada 10 satır besleme karakteridir).

Örneğin, A2 ve B2 hücrelerindeki metinleri değerleri bir satır sonu ile ayırarak birleştirmek için kullanılacak formül budur:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

İpucu: Sonucun yukarıdaki ekran görüntüsünde gösterildiği gibi birden fazla satır halinde görüntülenmesi için Metni kaydır özelliğinin açık olduğundan emin olun.

TEXTJOIN IF metni koşullarla birleştirmek için

Excel TEXTJOIN'in dize dizilerini işleme yeteneği nedeniyle, iki veya daha fazla hücrenin içeriğini koşullu olarak birleştirmek için de kullanılabilir. Bunu yapmak için, bir hücre aralığını değerlendirmek ve koşulu karşılayan bir dizi değeri döndürmek üzere IF işlevini kullanın. metin1 TEXTJOIN argümanı.

Aşağıdaki ekran görüntüsünde gösterilen tablodan, aşağıdakilerin bir listesini almak istediğinizi varsayalım Takım 1 Bunu başarmak için aşağıdaki EĞER ifadesini metin1 Tartışma:

IF($B$2:$B$9=1, $A$2:$A$9, "")

Düz İngilizce olarak, yukarıdaki formül şunu söyler: B sütunu 1'e eşitse, aynı satırdaki A sütunundan bir değer döndür; aksi takdirde boş bir dize döndür.

için tam formül Takım 1 bu şekli alır:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Benzer bir şekilde, aşağıdaki öğelerin virgülle ayrılmış bir listesini alabilirsiniz Takım 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Not: Excel 365 ve 2021'de bulunan Dinamik Diziler özelliği nedeniyle bu, yukarıdaki ekran görüntüsünde gösterilen normal bir formül olarak çalışır. Excel 2019'da, Ctrl + Shift + Enter kısayoluna basarak bunu geleneksel bir dizi formülü olarak girmelisiniz.

Virgülle ayrılmış listede birden çok eşleşmeyi arama ve döndürme

Muhtemelen bildiğiniz gibi, Excel DÜŞEYARA işlevi yalnızca bulunan ilk eşleşmeyi döndürebilir. Peki ya belirli bir kimlik, SKU veya başka bir şey için tüm eşleşmeleri almanız gerekiyorsa?

Sonuçların çıktısını ayrı hücrelerde almak için, Excel'de birden çok değer DÜŞEYARA nasıl kullanılır bölümünde açıklanan formüllerden birini kullanın.

Tek bir hücredeki tüm eşleşen değerleri virgülle ayrılmış bir liste olarak aramak ve döndürmek için METİNBİRLEŞTİR EĞER formülünü kullanın.

Pratikte nasıl çalıştığını görmek için, aşağıdaki örnek tablodan belirli bir satıcı tarafından satın alınan ürünlerin bir listesini alalım. Bu, aşağıdaki formülle kolayca yapılabilir:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Burada A2:A12 satıcı adları, B2:B12 ürünler ve D2 ilgilenilen satıcıdır.

Yukarıdaki formül E2'ye gider ve D2'deki (Adam) hedef satıcı için tüm eşleşmeleri getirir. Göreli (hedef satıcı için) ve mutlak (satıcı adları ve ürünler için) hücre referanslarının akıllıca kullanılması nedeniyle, formül aşağıdaki hücrelere doğru şekilde kopyalanır ve diğer iki satıcı için de güzel bir şekilde çalışır:

Not: Önceki örnekte olduğu gibi, bu Excel 365 ve 2021'de normal bir formül olarak ve Excel 2019'da bir CSE formülü (Ctrl + Shift + Enter ) olarak çalışır.

Formülün mantığı önceki örnektekiyle tamamen aynıdır:

IF deyimi A2:A12'deki her bir ismi D2'deki hedef isimle karşılaştırır (bizim durumumuzda Adam):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Mantıksal test DOĞRU olarak değerlendirilirse (yani D2'deki ad A sütunundaki adla eşleşirse), formül B sütunundan bir ürün döndürür; aksi takdirde boş bir dize ("") döndürülür. IF'nin sonucu aşağıdaki dizidir:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Dizi, TEXTJOIN işlevine şu şekilde gider metin1 TEXTJOIN değerleri virgül ve boşlukla (", ") ayıracak şekilde yapılandırıldığından, nihai sonuç olarak bu dizeyi elde ederiz:

Muz, Elma, Portakal, Limon

Excel TEXTJOIN çalışmıyor

TEXTJOIN formülünüz bir hatayla sonuçlandığında, büyük olasılıkla aşağıdakilerden biri söz konusudur:

• TEXTJOIN, bu işlevin desteklenmediği eski bir Excel sürümünde (2019 öncesi) kullanıldığında veya işlevin adı yanlış yazıldığında #NAME? hatası oluşur.
• Elde edilen dize 32.767 karakteri aşarsa #VALUE! hatası oluşur.
• Excel sınırlayıcıyı metin olarak tanımazsa, örneğin CHAR(0) gibi yazdırılamayan bir karakter sağlarsanız da #VALUE! hatası oluşabilir.

TEXTJOIN işlevini Excel'de bu şekilde kullanabilirsiniz. Okuduğunuz için teşekkür eder, gelecek hafta blogumuzda görüşmek dileğiyle!

Mevcut indirmeler

Excel TEXTJOIN formülü örnekleri