Το σεμινάριο δείχνει πώς να χρησιμοποιείτε τη συνάρτηση TEXTJOIN για τη συγχώνευση κειμένου στο Excel με πρακτικά παραδείγματα.

Μέχρι πρόσφατα, υπήρχαν δύο διαδεδομένες μέθοδοι για τη συνένωση των περιεχομένων των κελιών στο Excel: ο τελεστής συνένωσης και η συνάρτηση CONCATENATE. Με την εισαγωγή του TEXTJOIN, φαίνεται ότι εμφανίστηκε μια πιο ισχυρή εναλλακτική λύση, η οποία σας επιτρέπει να ενώνετε κείμενο με πιο ευέλικτο τρόπο, συμπεριλαμβανομένου οποιουδήποτε διαχωριστικού μεταξύ τους. Αλλά στην πραγματικότητα, υπάρχουν πολλά περισσότερα!

Λειτουργία Excel TEXTJOIN

Το TEXTJOIN στο Excel συγχωνεύει συμβολοσειρές κειμένου από πολλαπλά κελιά ή περιοχές και διαχωρίζει τις συνδυασμένες τιμές με οποιοδήποτε διαχωριστικό που καθορίζετε. Μπορεί είτε να αγνοήσει είτε να συμπεριλάβει κενά κελιά στο αποτέλεσμα.

Η λειτουργία είναι διαθέσιμη στο Excel για το Office 365, το Excel 2021 και το Excel 2019.

Η σύνταξη της συνάρτησης TEXTJOIN έχει ως εξής:

Πού:

• Διαχωριστικό (υποχρεωτικό) - είναι ένα διαχωριστικό μεταξύ κάθε τιμής κειμένου που συνδυάζετε. Συνήθως, παρέχεται ως συμβολοσειρά κειμένου που περικλείεται σε διπλά εισαγωγικά ή ως αναφορά σε ένα κελί που περιέχει μια συμβολοσειρά κειμένου. Ένας αριθμός που παρέχεται ως διαχωριστικό αντιμετωπίζεται ως κείμενο.
• Ignore_empty (υποχρεωτικό) - Καθορίζει αν θα αγνοούνται τα κενά κελιά ή όχι:
  • TRUE - αγνοεί τυχόν κενά κελιά.
  • FALSE - περιλαμβάνει κενά κελιά στην προκύπτουσα συμβολοσειρά.
• Κείμενο1 (υποχρεωτικό) - πρώτη τιμή προς ένωση. Μπορεί να παρέχεται ως συμβολοσειρά κειμένου, αναφορά σε κελί που περιέχει συμβολοσειρά ή πίνακα συμβολοσειρών, όπως μια σειρά κελιών.
• Κείμενο2 , ... (προαιρετικό) - πρόσθετες τιμές κειμένου που πρέπει να ενωθούν μεταξύ τους. Επιτρέπονται το πολύ 252 ορίσματα κειμένου, συμπεριλαμβανομένων των εξής text1 .

Για παράδειγμα, ας συνδυάσουμε τα τμήματα διευθύνσεων από τα κελιά B2, C2 και D2 σε ένα κελί, διαχωρίζοντας τις τιμές με κόμμα και κενό:

Με τη συνάρτηση CONCATENATE, θα πρέπει να καθορίσετε κάθε κελί ξεχωριστά και να βάλετε ένα διαχωριστικό (", ") μετά από κάθε αναφορά, το οποίο μπορεί να είναι ενοχλητικό όταν συγχωνεύετε τα περιεχόμενα πολλών κελιών:

=CONCATENATE(A2, ", ", B2, ", ", ", C2)

Με το Excel TEXTJOIN, καθορίζετε τον διαχωριστή μόνο μία φορά στο πρώτο όρισμα και παρέχετε μια περιοχή κελιών για το τρίτο όρισμα:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN στο Excel - 6 πράγματα που πρέπει να θυμάστε

Για να χρησιμοποιήσετε αποτελεσματικά το TEXTJOIN στα φύλλα εργασίας σας, υπάρχουν μερικά σημαντικά σημεία που πρέπει να προσέξετε:

1. Το TEXTJOIN είναι μια νέα συνάρτηση, η οποία είναι διαθέσιμη μόνο στο Excel 2019 - Excel 365. Σε προηγούμενες εκδόσεις του Excel, χρησιμοποιήστε αντ' αυτού τη συνάρτηση CONCATENATE ή τον τελεστή "&".
2. Στις νέες εκδόσεις του Excel, μπορείτε επίσης να χρησιμοποιήσετε τη συνάρτηση CONCAT για τη συνένωση τιμών από ξεχωριστά κελιά και περιοχές, αλλά χωρίς επιλογές για διαχωριστικά ή κενά κελιά.
3. Κάθε αριθμός που παρέχεται στο TEXTJOIN για το διαχωριστικό ή κείμενο τα ορίσματα μετατρέπονται σε κείμενο.
4. Εάν διαχωριστικό δεν καθορίζεται ή είναι κενή συμβολοσειρά (""), οι τιμές κειμένου συνδέονται χωρίς κανένα διαχωριστικό.
5. Η συνάρτηση μπορεί να χειριστεί έως και 252 ορίσματα κειμένου.
6. Η συμβολοσειρά που προκύπτει μπορεί να περιέχει το πολύ 32.767 χαρακτήρες, το οποίο είναι το όριο κελιών στο Excel. Εάν ξεπεραστεί αυτό το όριο, ένας τύπος TEXTJOIN επιστρέφει το σφάλμα #VALUE!.

Πώς να συνδέσετε κείμενο στο Excel - παραδείγματα τύπων

Για να κατανοήσετε καλύτερα όλα τα πλεονεκτήματα του TEXTJOIN, ας ρίξουμε μια ματιά στον τρόπο χρήσης της λειτουργίας σε πραγματικά σενάρια.

Μετατροπή στήλης σε λίστα με διαχωρισμό με κόμμα

Όταν θέλετε να συνδέσετε μια κάθετη λίστα διαχωρίζοντας τις τιμές με κόμμα, άνω και κάτω τελεία ή οποιοδήποτε άλλο διαχωριστικό, η TEXTJOIN είναι η σωστή συνάρτηση που πρέπει να χρησιμοποιήσετε.

Για αυτό το παράδειγμα, θα συνδέσουμε τις νίκες και τις ήττες κάθε ομάδας από τον παρακάτω πίνακα. Αυτό μπορεί να γίνει με τους ακόλουθους τύπους, οι οποίοι διαφέρουν μόνο στο εύρος των κελιών που ενώνονται.

Για την ομάδα 1:

=TEXTJOIN(",", FALSE, B2:B6)

Για την ομάδα 2:

=TEXTJOIN(",", FALSE, C2:C6)

Και ούτω καθεξής.

Σε όλους τους τύπους χρησιμοποιούνται τα ακόλουθα επιχειρήματα:

• Διαχωριστικό - ένα κόμμα (",").
• Ignore_empty τίθεται σε FALSE για να συμπεριλάβει τα κενά κελιά επειδή πρέπει να δείξουμε ποια παιχνίδια δεν παίχτηκαν.

Ως αποτέλεσμα, θα λάβετε τέσσερις λίστες διαχωρισμένες με κόμμα που αντιπροσωπεύουν τις νίκες και τις ήττες κάθε ομάδας σε συμπαγή μορφή:

Ενώνετε κελιά με διαφορετικά διαχωριστικά

Σε περίπτωση που πρέπει να διαχωρίσετε τις συνδυασμένες τιμές με διαφορετικά διαχωριστικά, μπορείτε είτε να παρέχετε διάφορα διαχωριστικά ως σταθερά πίνακα είτε να εισάγετε κάθε διαχωριστικό σε ξεχωριστό κελί και να χρησιμοποιήσετε μια αναφορά περιοχής για το διαχωριστικό επιχείρημα.

Ας υποθέσουμε ότι θέλετε να ενώσετε κελιά που περιέχουν διαφορετικά μέρη ονόματος και να λάβετε το αποτέλεσμα με αυτή τη μορφή: Επώνυμο , Όνομα Μεσαίο όνομα .

Όπως μπορείτε να δείτε, το Επώνυμο και το Όνομα χωρίζονται με κόμμα και κενό (", "), ενώ το Όνομα και το Μεσαίο όνομα μόνο με κενό (" "). Έτσι, συμπεριλαμβάνουμε αυτά τα δύο διαχωριστικά σε μια σταθερά πίνακα {", ", ",""} και παίρνουμε τον ακόλουθο τύπο:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Όπου A2:C2 είναι τα μέρη ονόματος που πρέπει να συνδυαστούν.

Εναλλακτικά, μπορείτε να πληκτρολογήσετε τα διαχωριστικά χωρίς εισαγωγικά σε κάποια κενά κελιά (π.χ. ένα κόμμα και ένα κενό στο F3 και ένα κενό στο G3) και να χρησιμοποιήσετε την περιοχή $F$3:$G$3 (προσέξτε τις απόλυτες αναφορές κελιών) για το διαχωριστικό επιχείρημα:

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Χρησιμοποιώντας αυτή τη γενική προσέγγιση, μπορείτε να συγχωνεύσετε τα περιεχόμενα των κελιών σε διάφορες μορφές.

Για παράδειγμα, αν θέλετε το αποτέλεσμα στο Όνομα Μεσαίο αρχικό Επώνυμο μορφή, στη συνέχεια, χρησιμοποιήστε τη συνάρτηση LEFT για να εξαγάγετε τον πρώτο χαρακτήρα (το αρχικό) από το κελί C2. Όσον αφορά τους διαχωριστές, βάζουμε ένα κενό (" ") μεταξύ του ονόματος First και του μεσαίου αρχικού- μια τελεία και ένα κενό (". ") μεταξύ του αρχικού και του επωνύμου:

=TEXTJOIN({" ","."}, TRUE, B2, LEFT(C2,1), A2)

Συνδέστε κείμενο και ημερομηνίες στο Excel

Σε μια συγκεκριμένη περίπτωση, όταν συγχωνεύετε κείμενο και ημερομηνίες, η παροχή ημερομηνιών απευθείας σε έναν τύπο TEXTJOIN δεν θα λειτουργήσει. Όπως ίσως θυμάστε, το Excel αποθηκεύει τις ημερομηνίες ως αύξοντες αριθμούς, οπότε ο τύπος σας θα επιστρέψει έναν αριθμό που αντιπροσωπεύει την ημερομηνία, όπως φαίνεται στο παρακάτω στιγμιότυπο:

=TEXTJOIN(" ", TRUE, A2:B2)

Για να το διορθώσετε αυτό, πρέπει να μετατρέψετε την ημερομηνία σε συμβολοσειρά κειμένου πριν την ενώσετε. Και εδώ η συνάρτηση TEXT με τον επιθυμητό κωδικό μορφοποίησης ("mm/dd/yyyyyy" στην περίπτωσή μας) είναι χρήσιμη:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyyyy"))

Συγχώνευση κειμένου με διαλείμματα γραμμής

Αν θέλετε να συγχωνεύσετε κείμενο στο Excel έτσι ώστε κάθε τιμή να ξεκινά σε νέα γραμμή, χρησιμοποιήστε CHAR(10) ως διαχωριστικό (όπου το 10 είναι ένας χαρακτήρας αλλαγής γραμμής).

Για παράδειγμα, για να συνδυάσετε κείμενο από τα κελιά Α2 και Β2 διαχωρίζοντας τις τιμές με διάλειμμα γραμμής, αυτός είναι ο τύπος που πρέπει να χρησιμοποιήσετε:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Συμβουλή. Για να εμφανιστεί το αποτέλεσμα σε πολλαπλές γραμμές, όπως φαίνεται στο παραπάνω στιγμιότυπο, βεβαιωθείτε ότι η λειτουργία Wrap text (Αναδίπλωση κειμένου) είναι ενεργοποιημένη.

TEXTJOIN IF για τη συγχώνευση κειμένου με όρους

Λόγω της δυνατότητας του Excel TEXTJOIN να χειρίζεται πίνακες συμβολοσειρών, μπορεί επίσης να χρησιμοποιηθεί για την υπό όρους συγχώνευση των περιεχομένων δύο ή περισσότερων κελιών. Για να γίνει αυτό, χρησιμοποιήστε τη συνάρτηση IF για να αξιολογήσετε μια περιοχή κελιών και να επιστρέψετε έναν πίνακα τιμών που πληρούν τη συνθήκη στην εντολή text1 επιχείρημα του TEXTJOIN.

Από τον πίνακα που φαίνεται στο παρακάτω στιγμιότυπο, ας υποθέσουμε ότι θέλετε να ανακτήσετε μια λίστα των Ομάδα 1 μέλη. Για να το πετύχετε αυτό, τοποθετήστε την ακόλουθη δήλωση IF στην εντολή text1 επιχείρημα:

IF($B$2:$B$9=1, $A$2:$A$9, "")

Σε απλά ελληνικά, ο παραπάνω τύπος λέει: Αν η στήλη B ισούται με 1, επιστρέψτε μια τιμή από τη στήλη A στην ίδια γραμμή, διαφορετικά επιστρέψτε μια κενή συμβολοσειρά.

Ο πλήρης τύπος για Ομάδα 1 παίρνει αυτό το σχήμα:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Με παρόμοιο τρόπο, μπορείτε να λάβετε μια λίστα διαχωρισμένη με κόμμα των μελών της Ομάδα 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Σημείωση. Λόγω της δυνατότητας Dynamic Arrays που είναι διαθέσιμη στο Excel 365 και 2021, αυτό λειτουργεί ως κανονικός τύπος, όπως φαίνεται στο παραπάνω στιγμιότυπο. Στο Excel 2019, πρέπει να το εισαγάγετε ως παραδοσιακό τύπο συστοιχίας πατώντας τη συντόμευση Ctrl + Shift + Enter.

Αναζήτηση και επιστροφή πολλαπλών αντιστοιχιών σε λίστα με διαχωρισμό κόμματος

Όπως πιθανότατα γνωρίζετε, η συνάρτηση VLOOKUP του Excel μπορεί να επιστρέψει μόνο την πρώτη αντιστοιχία που βρέθηκε. Τι γίνεται όμως αν πρέπει να λάβετε όλες τις αντιστοιχίες για ένα συγκεκριμένο αναγνωριστικό, SKU ή κάτι άλλο;

Για να εξάγετε τα αποτελέσματα σε ξεχωριστά κελιά, χρησιμοποιήστε έναν από τους τύπους που περιγράφονται στην ενότητα Πώς να VLOOKUP πολλαπλές τιμές στο Excel.

Για να αναζητήσετε και να επιστρέψετε όλες τις τιμές που ταιριάζουν σε ένα μόνο κελί ως λίστα διαχωρισμένη με κόμμα, χρησιμοποιήστε τον τύπο TEXTJOIN IF.

Για να δείτε πώς λειτουργεί στην πράξη, ας ανακτήσουμε μια λίστα με τα προϊόντα που αγοράστηκαν από έναν συγκεκριμένο πωλητή από τον παρακάτω δειγματικό πίνακα. Αυτό μπορεί να γίνει εύκολα με τον ακόλουθο τύπο:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Όπου A2:A12 είναι ονόματα πωλητών, B2:B12 είναι προϊόντα και D2 είναι ο πωλητής ενδιαφέροντος.

Ο παραπάνω τύπος πηγαίνει στο E2 και φέρνει όλες τις αντιστοιχίες για τον πωλητή-στόχο στο D2 (Adam). Λόγω της έξυπνης χρήσης σχετικών (για τον πωλητή-στόχο) και απόλυτων (για τα ονόματα των πωλητών και τα προϊόντα) αναφορών κελιών, ο τύπος αντιγράφει σωστά στα παρακάτω κελιά και λειτουργεί ωραία και για τους άλλους δύο πωλητές:

Σημείωση. Όπως και με το προηγούμενο παράδειγμα, αυτό λειτουργεί ως κανονικός τύπος στο Excel 365 και 2021 και ως τύπος CSE (Ctrl + Shift + Enter ) στο Excel 2019.

Η λογική του τύπου είναι ακριβώς η ίδια όπως στο προηγούμενο παράδειγμα:

Η εντολή IF συγκρίνει κάθε όνομα στο A2:A12 με το όνομα-στόχο στο D2 (Adam στην περίπτωσή μας):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Εάν ο λογικός έλεγχος αποτιμηθεί σε TRUE (δηλαδή το όνομα στο D2 ταιριάζει με το όνομα στη στήλη Α), ο τύπος επιστρέφει ένα προϊόν από τη στήλη Β- διαφορετικά επιστρέφεται ένα κενό αλφαριθμητικό (""). Το αποτέλεσμα του IF είναι ο ακόλουθος πίνακας:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Ο πίνακας πηγαίνει στη συνάρτηση TEXTJOIN ως η συνάρτηση text1 Και επειδή το TEXTJOIN έχει ρυθμιστεί να διαχωρίζει τις τιμές με κόμμα και κενό (", "), έχουμε αυτή τη συμβολοσειρά ως τελικό αποτέλεσμα:

Μπανάνες, μήλα, πορτοκάλια, λεμόνια

Το Excel TEXTJOIN δεν λειτουργεί

Όταν ο τύπος TEXTJOIN σας οδηγεί σε σφάλμα, το πιο πιθανό είναι να είναι ένα από τα ακόλουθα:

• Το σφάλμα #NAME? εμφανίζεται όταν το TEXTJOIN χρησιμοποιείται σε μια παλαιότερη έκδοση του Excel όπου αυτή η συνάρτηση δεν υποστηρίζεται (πριν από το 2019) ή όταν το όνομα της συνάρτησης είναι ανορθόγραφο.
• Το σφάλμα #VALUE! εμφανίζεται αν η συμβολοσειρά που προκύπτει υπερβαίνει τους 32.767 χαρακτήρες.
• Το σφάλμα #VALUE! μπορεί επίσης να εμφανιστεί εάν το Excel δεν αναγνωρίζει το διαχωριστικό ως κείμενο, για παράδειγμα εάν παρέχετε κάποιον μη εκτυπώσιμο χαρακτήρα, όπως CHAR(0).

Αυτός είναι ο τρόπος χρήσης της συνάρτησης TEXTJOIN στο Excel. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω στο blog μας την επόμενη εβδομάδα!

Διαθέσιμες λήψεις

Παραδείγματα τύπου TEXTJOIN του Excel