V učbeniku je na praktičnih primerih prikazana uporaba funkcije TEXTJOIN za združevanje besedila v Excelu.

Do nedavnega sta v Excelu prevladovala dva načina združevanja vsebine celic: operator concatenation in funkcija CONCATENATE. Z uvedbo funkcije TEXTJOIN se zdi, da se je pojavila močnejša alternativa, ki omogoča bolj prilagodljivo združevanje besedila, vključno z vsemi vmesnimi ločili. V resnici pa je v tem veliko več!

Excelova funkcija TEXTJOIN

TEXTJOIN v Excelu združi besedilne nize iz več celic ali razponov in združene vrednosti loči s katerim koli ločilom, ki ga določite. Rezultat lahko prezre ali vključi prazne celice.

Funkcija je na voljo v programih Excel za Office 365, Excel 2021 in Excel 2019.

Sintaksa funkcije TEXTJOIN je naslednja:

Kje:

• Razmejitev (obvezno) - je ločilo med posameznimi besedilnimi vrednostmi, ki jih združujete. Običajno se navede kot besedilni niz, zaprt v dvojne narekovaje, ali kot sklic na celico, ki vsebuje besedilni niz. Številka, navedena kot ločilo, se obravnava kot besedilo.
• Ignore_empty (obvezno) - Določa, ali naj se prazne celice ignorirajo ali ne:
  • TRUE - prezrite vse prazne celice.
  • FALSE - v dobljeni niz vključite prazne celice.
• Besedilo1 (obvezno) - prva vrednost, ki se združi. Lahko se navede kot besedilni niz, referenca na celico, ki vsebuje niz, ali niz nizov, kot je razpon celic.
• Besedilo2 , ... (neobvezno) - dodatne besedilne vrednosti, ki se združijo. Dovoljenih je največ 252 besedilnih argumentov, vključno z besedilo1 .

Kot primer združimo dele naslovov iz celic B2, C2 in D2 v eno celico in vrednosti ločimo z vejico in presledkom:

S funkcijo CONCATENATE bi morali določiti vsako celico posebej in za vsako referenco vstaviti ločilo (", "), kar je lahko moteče pri združevanju vsebine več celic:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Pri Excelovem TEXTJOIN v prvem argumentu samo enkrat določite ločilo, v tretjem argumentu pa navedete območje celic:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN v Excelu - 6 stvari, ki si jih morate zapomniti

Za učinkovito uporabo TEXTJOIN v delovnih listih morate upoštevati nekaj pomembnih točk:

1. TEXTJOIN je nova funkcija, ki je na voljo samo v Excelu 2019 - Excel 365. V prejšnjih različicah Excela namesto nje uporabite funkcijo CONCATENATE ali operator "&".
2. V novih različicah programa Excel lahko uporabite tudi funkcijo CONCAT za združevanje vrednosti iz ločenih celic in razponov, vendar brez možnosti za razmejitve ali prazne celice.
3. Katera koli številka, posredovana TEXTJOIN za razmejitev ali besedilo argumentov pretvori v besedilo.
4. Če razmejitev ni določena ali je prazen niz (""), se besedilne vrednosti povežejo brez razmejitve.
5. Funkcija lahko obdeluje do 252 besedilnih argumentov.
6. Dobljeni niz lahko vsebuje največ 32.767 znakov, kar je omejitev celice v programu Excel. Če je ta omejitev presežena, formula TEXTJOIN vrne napako #VALUE!.

Kako združiti besedilo v Excelu - primeri formul

Da bi bolje razumeli vse prednosti funkcije TEXTJOIN, si poglejmo, kako jo uporabiti v resničnih scenarijih.

Pretvarjanje stolpca v seznam, ločen z vejico

Če želite združiti navpični seznam, ki ločuje vrednosti z vejico, podpičjem ali katerim koli drugim ločilom, je funkcija TEXTJOIN prava za uporabo.

V tem primeru bomo združili zmage in poraze vsake ekipe iz spodnje tabele. To lahko storimo z naslednjimi formulami, ki se razlikujejo le po obsegu združenih celic.

Za ekipo 1:

=TEXTJOIN(",", FALSE, B2:B6)

Za ekipo 2:

=TEXTJOIN(",", FALSE, C2:C6)

In tako naprej.

V vseh formulah so uporabljeni naslednji argumenti:

• Razmejitev - vejica (",").
• Ignore_empty je nastavljena na FALSE, da se vključijo prazne celice, saj moramo prikazati, katere igre niso bile odigrane.

Tako boste dobili štiri sezname, ločene z vejico, ki predstavljajo zmage in poraze vsake ekipe v kompaktni obliki:

Združite celice z različnimi razmejitvami

Če morate kombinirane vrednosti ločiti z različnimi ločili, lahko več ločil navedete kot konstanto polja ali pa vsako ločilo vnesete v ločeno celico in uporabite sklic na območje za razmejitev argument.

Recimo, da želite združiti celice, ki vsebujejo različne dele imen, in dobiti rezultat v tej obliki: Priimek , Ime Srednje ime .

Kot lahko vidite, sta priimek in ime ločena z vejico in presledkom (", "), medtem ko sta ime in srednje ime ločena samo s presledkom (" "). Zato ta dva ločila vključimo v polje konstant {", "," "} in dobimo naslednjo formulo:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Pri čemer so A2:C2 deli imena, ki jih je treba združiti.

Druga možnost je, da ločila brez narekovajev vnesete v nekaj praznih celic (na primer vejico in presledek v F3 in presledek v G3) in uporabite območje $F$3:$G$3 (upoštevajte absolutne reference celic) za razmejitev argument:

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

S tem splošnim pristopom lahko združite vsebino celic v različnih oblikah.

Če želite na primer rezultat v polju Ime in priimek Srednja začetnica Priimek nato pa s funkcijo LEFT iz celice C2 izločite prvi znak (začetnico). Kar zadeva razmejitvene elemente, vstavimo presledek (" ") med prvo ime in srednjo začetnico ter piko in presledek (". ") med začetnico in priimkom:

=TEXTJOIN({" ","."}, TRUE, B2, LEFT(C2,1), A2)

Združevanje besedila in datumov v Excelu

V posebnem primeru, ko združujete besedilo in datume, neposredno podajanje datumov formuli TEXTJOIN ne bo delovalo. Kot se morda spomnite, Excel shranjuje datume kot zaporedne številke, zato bo vaša formula vrnila številko, ki predstavlja datum, kot je prikazano na spodnji sliki zaslona:

=TEXTJOIN(" ", TRUE, A2:B2)

Če želite to odpraviti, morate datum pred združitvijo pretvoriti v besedilni niz. Pri tem vam pride prav funkcija TEXT z želeno kodo formata ("mm/dd/yyyy" v našem primeru):

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/rrrr"))

Združevanje besedila s prelomi vrstic

Če želite besedilo v Excelu združiti tako, da se vsaka vrednost začne v novi vrstici, uporabite CHAR(10) kot ločilo (kjer je 10 znak za zaključek vrstice).

Če želite na primer združiti besedilo iz celic A2 in B2, pri čemer vrednosti ločite s prekinitvijo vrstice, uporabite to formulo:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Nasvet. Če želite, da se rezultat prikaže v več vrsticah, kot je prikazano na zgornji sliki zaslona, se prepričajte, da je vklopljena funkcija zavijanja besedila.

TEXTJOIN IF za združevanje besedila s pogoji

Zaradi zmožnosti Excelovega TEXTJOIN-a, da obdeluje nize nizov, ga lahko uporabite tudi za pogojno združevanje vsebine dveh ali več celic. Če želite to narediti, uporabite funkcijo IF, da ovrednoti območje celic in vrne niz vrednosti, ki izpolnjujejo pogoj, v besedilo1 argument TEXTJOIN.

Predpostavimo, da želite iz tabele, prikazane na spodnji sliki zaslona, pridobiti seznam Ekipa 1 članov. To dosežete tako, da vnesete naslednji stavek IF v besedilo1 argument:

IF($B$2:$B$9=1, $A$2:$A$9, "")

V preprosti angleščini zgornja formula pravi: Če je stolpec B enak 1, vrnite vrednost iz stolpca A v isti vrstici; v nasprotnem primeru vrnite prazen niz.

Celotna formula za Ekipa 1 ima takšno obliko:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Na podoben način lahko dobite z vejico ločen seznam članov Ekipa 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Opomba: Zaradi funkcije dinamičnih nizov, ki je na voljo v Excelu 365 in 2021, ta formula deluje kot običajna formula, prikazana na zgornji sliki zaslona. V Excelu 2019 jo morate vnesti kot tradicionalno formulo z nizom, tako da pritisnete bližnjico Ctrl + Shift + Enter.

Poiščite in vrnite več zadetkov na seznamu, ločenem z vejico

Kot verjetno veste, lahko funkcija Excel VLOOKUP vrne le prvo najdeno ujemanje. Kaj pa, če želite dobiti vsa ujemanja za določen ID, SKU ali kaj drugega?

Če želite rezultate prikazati v ločenih celicah, uporabite eno od formul, ki so opisane v poglavju Kako v Excelu izvesti VLOOKUP z več vrednostmi.

Če želite poiskati in vrniti vse ujemajoče se vrednosti v eni celici kot seznam, ločen z vejico, uporabite formulo TEXTJOIN IF.

Če želite videti, kako to deluje v praksi, pridobite seznam izdelkov, ki jih je kupil določen prodajalec, iz spodnje vzorčne preglednice. To lahko preprosto storite z naslednjo formulo:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Pri čemer so A2:A12 imena prodajalcev, B2:B12 so izdelki, D2 pa je prodajalec, ki vas zanima.

Zgornja formula gre v E2 in prikaže vse zadetke za ciljnega prodajalca v D2 (Adam). Zaradi pametne uporabe relativnih (za ciljnega prodajalca) in absolutnih (za imena prodajalcev in izdelke) referenc celic se formula pravilno kopira v spodnje celice in lepo deluje tudi za druga dva prodajalca:

Opomba: Tako kot prejšnji primer tudi ta deluje kot običajna formula v Excelu 365 in 2021 ter kot formula CSE (Ctrl + Shift + Enter ) v Excelu 2019.

Logika formule je popolnoma enaka kot v prejšnjem primeru:

Stavek IF primerja vsako ime v A2:A12 s ciljnim imenom v D2 (v našem primeru Adam):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Če je logični test ovrednoten kot TRUE (tj. ime v D2 se ujema z imenom v stolpcu A), formula vrne izdelek iz stolpca B, sicer se vrne prazen niz (""). Rezultat funkcije IF je naslednje polje:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Polje je v funkciji TEXTJOIN kot besedilo1 ker je TEXTJOIN nastavljen tako, da vrednosti ločuje z vejico in presledkom (", "), dobimo ta niz kot končni rezultat:

Banane, jabolka, pomaranče, limone

Excel TEXTJOIN ne deluje

Če se v formuli TEXTJOIN pojavi napaka, je najverjetneje ena od naslednjih:

• Napaka #NAME? se pojavi, če se TEXTJOIN uporablja v starejši različici programa Excel, v kateri ta funkcija ni podprta (pred letom 2019), ali če je ime funkcije napačno zapisano.
• #VALUE! napaka se pojavi, če dobljeni niz presega 32.767 znakov.
• Napaka #VALUE! se lahko pojavi tudi, če Excel ločilnika ne prepozna kot besedilo, na primer če navedete kakšen netiskljiv znak, kot je CHAR(0).

To je način uporabe funkcije TEXTJOIN v Excelu. Zahvaljujem se vam za branje in upam, da se naslednji teden vidimo na našem blogu!

Razpoložljivi prenosi

Primeri formule Excel TEXTJOIN