Daftar Isi
Tutorial menunjukkan cara menggunakan fungsi TEXTJOIN untuk menggabungkan teks di Excel dengan contoh praktis.
Sampai saat ini, ada dua metode lazim untuk menggabungkan konten sel di Excel: operator penggabungan dan fungsi CONCATENATE. Dengan diperkenalkannya TEXTJOIN, sepertinya alternatif yang lebih kuat telah muncul, yang memungkinkan Anda untuk menggabungkan teks dengan cara yang lebih fleksibel termasuk pembatas apa pun di antaranya. Namun sebenarnya, ada lebih banyak lagi!
Fungsi TEXTJOIN Excel
TEXTJOIN di Excel menggabungkan string teks dari beberapa sel atau rentang dan memisahkan nilai gabungan dengan pembatas apa pun yang Anda tentukan. Itu bisa mengabaikan atau menyertakan sel kosong dalam hasilnya.
Fungsi ini tersedia di Excel untuk Office 365, Excel 2021, dan Excel 2019.
Sintaks fungsi TEXTJOIN adalah sebagai berikut:
TEXTJOIN(pembatas, abaikan_kosong, text1, [text2], ...)Di mana:
- Pembatas (wajib) - adalah pemisah di antara setiap nilai teks yang Anda gabungkan. Biasanya, ini diberikan sebagai string teks yang diapit oleh tanda kutip ganda atau referensi ke sel yang berisi string teks. Angka yang diberikan sebagai pembatas diperlakukan sebagai teks.
- Abaikan_kosong (wajib) - Menentukan apakah akan mengabaikan sel kosong atau tidak:
- BENAR - abaikan sel kosong apa pun.
- FALSE - menyertakan sel kosong dalam string yang dihasilkan.
- Teks1 (wajib) - nilai pertama yang akan digabungkan. Dapat diberikan sebagai string teks, referensi ke sel yang berisi string, atau larik string seperti rentang sel.
- Teks2 , ... (opsional) - nilai teks tambahan untuk digabungkan bersama. Maksimal 252 argumen teks diperbolehkan, termasuk teks1 .
Sebagai contoh, mari kita gabungkan bagian alamat dari sel B2, C2 dan D2 bersama-sama ke dalam satu sel, memisahkan nilai dengan koma dan spasi:
Dengan fungsi CONCATENATE, Anda harus menentukan setiap sel satu per satu dan meletakkan pembatas (", ") setelah setiap referensi, yang mungkin merepotkan saat menggabungkan konten dari banyak sel:
=CONCATENATE(A2, ", ", B2, ", ", C2)
Dengan Excel TEXTJOIN, Anda menentukan pembatas hanya sekali dalam argumen pertama, dan menyediakan rentang sel untuk argumen ketiga:
=TEXTJOIN(", ", TRUE, A2:C2) 
TEXTJOIN di Excel - 6 hal yang perlu diingat
Untuk menggunakan TEXTJOIN secara efektif dalam lembar kerja Anda, ada beberapa poin penting yang harus diperhatikan:
- TEXTJOIN adalah fungsi baru, yang hanya tersedia di Excel 2019 - Excel 365. Di versi Excel sebelumnya, gunakan fungsi CONCATENATE atau operator "&" sebagai gantinya.
- Di versi baru jika Excel, Anda juga dapat menggunakan fungsi CONCAT untuk menggabungkan nilai dari sel dan rentang terpisah, tetapi tanpa opsi untuk pembatas atau sel kosong.
- Angka apa pun yang diberikan ke TEXTJOIN untuk pembatas atau teks argumen diubah menjadi teks.
- Jika pembatas tidak ditentukan atau merupakan string kosong (""), nilai teks digabungkan tanpa pembatas apa pun.
- Fungsi ini dapat menangani hingga 252 argumen teks.
- String yang dihasilkan dapat berisi maksimal 32,767 karakter, yang merupakan batas sel di Excel. Jika batas ini terlampaui, rumus TEXTJOIN mengembalikan #VALUE! kesalahan.
Cara menggabungkan teks di Excel - contoh rumus
Untuk lebih memahami semua keuntungan TEXTJOIN, mari kita lihat cara menggunakan fungsi ini dalam skenario kehidupan nyata.
Mengkonversi kolom ke daftar yang dipisahkan koma
Saat Anda ingin menggabungkan daftar vertikal yang memisahkan nilai dengan koma, titik koma, atau pembatas lainnya, TEXTJOIN adalah fungsi yang tepat untuk digunakan.
Untuk contoh ini, kita akan menggabungkan kemenangan dan kekalahan setiap tim dari tabel di bawah ini. Ini dapat dilakukan dengan rumus berikut, yang hanya berbeda dalam rentang sel yang digabungkan.
Untuk Tim 1:
=TEXTJOIN(",", FALSE, B2:B6)
Untuk Tim 2:
=TEXTJOIN(",", FALSE, C2:C6)
Dan seterusnya.
Dalam semua rumus, argumen berikut digunakan:
- Pembatas - tanda koma (",").
- Abaikan_kosong diatur ke FALSE untuk menyertakan sel kosong karena kita perlu menunjukkan game mana yang tidak dimainkan.
Sebagai hasilnya, Anda akan mendapatkan empat daftar yang dipisahkan koma yang mewakili kemenangan dan kekalahan masing-masing tim dalam bentuk yang ringkas: 
Gabungkan sel dengan pembatas yang berbeda
Dalam situasi ketika Anda perlu memisahkan nilai gabungan dengan pembatas yang berbeda, Anda bisa menyediakan beberapa pembatas sebagai konstanta larik atau memasukkan tiap pembatas dalam sel terpisah dan menggunakan referensi rentang untuk pembatas argumen.
Misalkan Anda ingin menggabungkan sel yang berisi bagian nama yang berbeda dan mendapatkan hasilnya dalam format ini: Nama belakang , Nama depan Nama tengah .
Seperti yang Anda lihat, Nama belakang dan nama depan dipisahkan oleh koma dan spasi (", ") sedangkan nama depan dan nama tengah hanya oleh spasi (" ") saja. Jadi, kami memasukkan kedua pembatas ini ke dalam konstanta array {", ", ", "} dan mendapatkan rumus berikut:
=TEXTJOIN({", "," "}, TRUE, A2:C2)
Di mana A2:C2 adalah bagian nama yang akan digabungkan.
Alternatifnya, Anda bisa mengetikkan pembatas tanpa tanda petik di beberapa sel kosong (katakanlah, koma dan spasi di F3 dan spasi di G3) dan menggunakan kisaran $F$3:$G$3 (harap perhatikan referensi sel absolut) untuk pembatas argumen:
=TEXTJOIN($F$3:$G$3, TRUE, A2:C2) 
Dengan menggunakan pendekatan umum ini, Anda dapat menggabungkan konten sel dalam berbagai bentuk.
Contohnya, jika Anda menginginkan hasil dalam Nama depan Inisial tengah Nama belakang kemudian gunakan fungsi LEFT untuk mengekstrak karakter pertama (inisial) dari sel C2. Sedangkan untuk pembatasnya, kami menempatkan spasi (" ") antara Nama depan dan inisial Tengah; titik dan spasi (". ") antara Inisial dan Nama belakang:
=TEXTJOIN({" ","."}, TRUE, B2, LEFT(C2,1), A2) 
Gabungkan teks dan tanggal di Excel
Dalam kasus tertentu ketika Anda menggabungkan teks dan tanggal, memasok tanggal langsung ke rumus TEXTJOIN tidak akan berfungsi. Seperti yang Anda ingat, Excel menyimpan tanggal sebagai nomor seri, jadi rumus Anda akan mengembalikan angka yang mewakili tanggal seperti yang ditunjukkan pada gambar di bawah:
=TEXTJOIN(" ", TRUE, A2:B2) 
Untuk memperbaikinya, Anda perlu mengubah tanggal menjadi string teks sebelum menggabungkannya. Dan di sini fungsi TEXT dengan kode format yang diinginkan ("mm/dd/yyyy" dalam kasus kami) sangat berguna:
=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy")) 
Menggabungkan teks dengan jeda baris
Jika Anda ingin menggabungkan teks di Excel sehingga setiap nilai dimulai di baris baru, gunakan CHAR(10) sebagai pembatas (di mana 10 adalah karakter linefeed).
Misalnya, untuk menggabungkan teks dari sel A2 dan B2 yang memisahkan nilai dengan jeda baris, ini adalah rumus yang digunakan:
=TEXTJOIN(CHAR(10), TRUE, A2:B2) 
Tip. Agar hasilnya ditampilkan dalam beberapa baris seperti yang ditunjukkan pada tangkapan layar di atas, pastikan fitur Bungkus teks dihidupkan.
TEXTJOIN IF untuk menggabungkan teks dengan kondisi
Karena kemampuan Excel TEXTJOIN untuk menangani larik string, ini juga dapat digunakan untuk menggabungkan konten dua sel atau lebih secara kondisional. Untuk melakukannya, gunakan fungsi IF untuk mengevaluasi rentang sel dan mengembalikan larik nilai yang memenuhi kondisi ke teks1 argumen dari TEXTJOIN.
Dari tabel yang ditunjukkan dalam screenshot di bawah ini, misalkan Anda ingin mengambil daftar Tim 1 Untuk mencapai hal ini, sarangkan pernyataan IF berikut ini ke dalam teks1 argumen:
IF($B$2:$B$9=1, $A$2:$A$9, "")
Dalam bahasa Inggris sederhana, rumus di atas mengatakan: Jika kolom B sama dengan 1, kembalikan nilai dari kolom A di baris yang sama; jika tidak, kembalikan string kosong.
Rumus lengkap untuk Tim 1 mengambil bentuk ini:
=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))
Dengan cara yang sama, Anda bisa mendapatkan daftar yang dipisahkan koma dari anggota Tim 2:
=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, "")) 
Catatan. Karena Dynamic Arrays fitur yang tersedia di Excel 365 dan 2021, ini berfungsi sebagai rumus biasa, ditunjukkan pada gambar di atas. Di Excel 2019, Anda harus memasukkannya sebagai rumus array tradisional dengan menekan Ctrl + Shift + Enter shortcut.
Mencari dan mengembalikan beberapa kecocokan dalam daftar yang dipisahkan koma
Seperti yang mungkin Anda ketahui, fungsi Excel VLOOKUP hanya bisa mengembalikan kecocokan yang pertama kali ditemukan. Tetapi bagaimana jika Anda perlu mendapatkan semua kecocokan untuk ID, SKU, atau sesuatu yang lain?
Untuk menampilkan hasil dalam sel terpisah, gunakan salah satu rumus yang dijelaskan dalam Cara VLOOKUP beberapa nilai di Excel.
Untuk mencari dan mengembalikan semua nilai yang cocok dalam satu sel sebagai daftar yang dipisahkan koma, gunakan rumus TEXTJOIN IF.
Untuk melihat bagaimana cara kerjanya dalam praktik, mari kita ambil daftar produk yang dibeli oleh penjual tertentu dari tabel contoh di bawah ini. Ini dapat dengan mudah dilakukan dengan rumus berikut:
=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))
Di mana A2:A12 adalah nama penjual, B2:B12 adalah produk, dan D2 adalah penjual yang diminati.
Rumus di atas masuk ke E2 dan membawa semua kecocokan untuk penjual target di D2 (Adam). Karena penggunaan referensi sel relatif (untuk penjual target) dan absolut (untuk nama penjual dan produk) yang cerdik, rumus tersebut dengan benar menyalin ke sel di bawah ini dan berfungsi dengan baik untuk dua penjual lainnya juga: 
Catatan. Seperti contoh sebelumnya, ini berfungsi sebagai rumus biasa di Excel 365 dan 2021, dan sebagai rumus CSE (Ctrl + Shift + Enter ) di Excel 2019.
Logika rumus ini persis sama seperti pada contoh sebelumnya:
Pernyataan IF membandingkan setiap nama di A2:A12 terhadap nama target di D2 (Adam dalam kasus kita):
IF($A$2:$A$12=D2, $B$2:$B$12, "")
Jika tes logika mengevaluasi ke TRUE (yaitu nama di D2 cocok dengan nama di kolom A), rumus mengembalikan produk dari kolom B; jika tidak, string kosong ("") akan dikembalikan. Hasil dari IF adalah larik berikut:
{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}
Larik ini masuk ke fungsi TEXTJOIN sebagai teks1 Dan karena TEXTJOIN dikonfigurasi untuk memisahkan nilai dengan koma dan spasi (", "), kita mendapatkan string ini sebagai hasil akhir:
Pisang, Apel, Jeruk, Lemon
Excel TEXTJOIN tidak berfungsi
Ketika rumus TEXTJOINmu menghasilkan error, kemungkinan besar salah satu dari yang berikut ini:
- #NAME? kesalahan terjadi ketika TEXTJOIN digunakan dalam versi Excel yang lebih lama di mana fungsi ini tidak didukung (pra-2019) atau ketika nama fungsi salah eja.
- #VALUE! kesalahan terjadi jika string yang dihasilkan melebihi 32.767 karakter.
- Kesalahan #VALUE! juga dapat terjadi jika Excel tidak mengenali pembatas sebagai teks, misalnya jika Anda memberikan beberapa karakter yang tidak dapat dicetak seperti CHAR (0).
Itulah cara menggunakan fungsi TEXTJOIN di Excel. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!
Unduhan yang tersedia
Contoh rumus TEXTJOIN Excel
