Tutorial nunjukkeun kumaha ngagunakeun pungsi TEXTJOIN pikeun ngahijikeun téks dina Excel sareng conto praktis.

Nepi ka ayeuna, aya dua cara umum pikeun ngahijikeun eusi sél dina Excel: concatenation operator jeung fungsi CONCATENATE. Kalayan ngenalkeun TEXTJOIN, sigana aya alternatif anu langkung kuat, anu ngamungkinkeun anjeun ngagabung téks dina cara anu langkung fleksibel kalebet pembatas naon waé. Tapi saleresna, aya seueur deui!

Fungsi Excel TEXTJOIN

TEXTJOIN dina Excel ngagabungkeun string téks tina sababaraha sél atanapi rentang sareng misahkeun nilai gabungan sareng pembatas naon waé. anu anjeun tangtukeun. Bisa jadi teu malire atawa ngasupkeun sél kosong dina hasil.

Pungsi ieu sadia dina Excel pikeun Office 365, Excel 2021, jeung Excel 2019.

Sintaksis fungsi TEXTJOIN nyaéta kieu. :

Dimana:

• Delimiter (diperlukeun) - mangrupakeun pemisah antara unggal nilai téks yén anjeun ngagabungkeun. Biasana, éta disayogikeun salaku string téks anu ditutupan ku tanda petik ganda atanapi rujukan ka sél anu ngandung string téks. Nomer anu disayogikeun salaku pangwatesan dianggap téks.
• Ignore_empty (diperlukeun) - Nangtukeun naha teu malire sél kosong atanapi henteu:
  • BENER - malire sél kosong.
  • FALSE - kaasup sél kosong dina string anu dihasilkeun.
• Teks1 (diperlukeun) - nilai munggaran pikeun gabung. Bisa disadiakeun salaku string téks, rujukan ka sél nu ngandung string, atawa susunan string kayaning rentang sél.
• Text2 , ... (opsional) - nilai téks tambahan pikeun dihijikeun. Maksimum 252 argumen téks anu diidinan, kalebet text1 .

Salaku conto, hayu urang ngagabungkeun bagéan alamat tina sél B2, C2 sareng D2 janten hiji sél, misahkeun nilai. kalayan koma sareng spasi:

Kalayan fungsi CONCATENATE, anjeun kedah netepkeun unggal sél masing-masing sareng nempatkeun wates (", ") saatos unggal rujukan, anu tiasa ngaganggu nalika ngahijikeun eusi seueur. sél:

=CONCATENATE(A2, ", ", B2, ", ", C2)

Kalayan Excel TEXTJOIN, anjeun tangtukeun pangwatesan ngan sakali dina argumen kahiji, sarta nyadiakeun rentang sél pikeun argumen katilu:

=TEXTJOIN(", ", TRUE, A2:C2)

TEXTJOIN dina Excel - 6 hal anu kudu diinget

Pikeun ngagunakeun TEXTJOIN sacara efektif dina lembar kerja anjeun, aya sababaraha poin penting anu kedah diperhatoskeun:

1. TEXTJOIN mangrupikeun énggal. fungsi, nu ngan sadia dina Excel 2019 - Excel 365. Dina versi Excel saméméhna, mangga nganggo fungsi CONCATENATE atawa "& amp;" operator.
2. Dina vérsi anyar upami Excel, anjeun ogé tiasa nganggo pungsi CONCAT pikeun ngahijikeun niléy tina sél sareng rentang anu misah, tapi tanpa pilihan pikeun pembatas atanapi sél kosong.
3. Sakur nomer anu disayogikeun. pikeun TEXTJOIN pikeun wates atawa teks Arguméntasi dirobah jadi téks.
4. Lamun pangwatesan teu ditangtukeun atawa mangrupa string kosong (""), niléy téks dihijikeun tanpa wates.
5. Pungsi bisa nanganan nepi ka 252 argumen téks.
6. Senar nu dihasilkeun bisa ngandung maksimum 32.767 karakter, nu mangrupakeun wates sél dina Excel. Upami wates ieu ngaleuwihan, rumus TEXTJOIN ngabalikeun #VALUE! kasalahan.

Kumaha cara gabung téks dina Excel - conto rumus

Pikeun leuwih paham kana sagala kaunggulan TEXTJOIN, hayu urang tingali kumaha ngagunakeun fungsi dina skenario kahirupan nyata. .

Ngarobih kolom kana daptar anu dipisahkeun koma

Nalika anjeun milarian ngahijikeun daptar nangtung anu misahkeun nilai-nilai ku koma, titik koma atanapi pembatas anu sanés, TEXTJOIN mangrupikeun fungsi anu pas pikeun dianggo.

Pikeun conto ieu, urang bakal ngahijikeun kameunangan sareng karugian unggal tim tina tabel di handap ieu. Ieu bisa dilakukeun ku rumus di handap ieu, nu béda ngan dina rentang sél nu ngagabung.

Pikeun Tim 1:

=TEXTJOIN(",", FALSE, B2:B6)

Pikeun Tim 2:

=TEXTJOIN(",", FALSE, C2:C6)

Jeung saterusna.

Dina sakabéh rumus, argumen di handap ieu dipaké:

• Delimiter - a koma (",").
• Ignore_empty disetel ka FALSE pikeun ngawengku sél kosong sabab urang kudu némbongkeun kaulinan mana nu teu diputer.

Salaku Hasilna, anjeun bakal nampi opat daptar anu dipisahkeun koma anu ngagambarkeun kameunangan sareng karugian unggal tim dina bentuk kompak:

Gabungkeun sél anu nganggo pembatas anu béda

Dina kaayaan nalika anjeun kedah misahkeun nilai gabungan sareng pembatas anu béda, anjeun tiasa nyayogikeun sababaraha pembatas salaku konstanta array atanapi input unggal pembatas dina sél anu misah. jeung make rujukan rentang pikeun argumen delimiter .

Misalna anjeun hayang ngagabung ka sél nu ngandung bagian ngaran béda jeung meunang hasilna dina format kieu: Nami tukang , Ngaran hareup Nami Tengah .

Sakumaha anjeun tiasa tingali, Ngaran Tukang sareng Ngaran Mimiti dipisahkeun ku koma sareng spasi (", ") sedengkeun nami Mimiti sareng nami Tengah ku spasi. (" ") ngan. Janten, urang kalebetkeun dua pembatas ieu dina konstanta array {", "," "} sareng kéngingkeun rumus ieu:

=TEXTJOIN({", "," "}, TRUE, A2:C2)

Dimana A2:C2 mangrupikeun bagian nami anu bakal digabungkeun.

Alternatipna, anjeun tiasa ngetik wates tanpa tanda petik dina sababaraha sél kosong (sebutkeun, koma sareng spasi dina F3 sareng spasi dina G3) sareng nganggo rentang $F$3:$G$3 (mangga rujukan sél absolut) pikeun argumen pangwatesan :

=TEXTJOIN($F$3:$G$3, TRUE, A2:C2)

Ku ngagunakeun pendekatan umum ieu, anjeun bisa ngagabungkeun eusi sél dina sagala rupa wangun.

Contona, upami anjeun hoyong hasilna dina format Ngaran hareup Awal tengah Ngaran tukang , teras nganggo pungsi LEFT pikeun nimba karakter kahiji (awal) ti sél C2. Sedengkeun pikeun delimiters, urang nempatkeun spasi (" ") antara ngaran hareup jeung awal Tengah; atitik jeung spasi (". ") antara Ngaran Awal jeung Ahir:

=TEXTJOIN({" ",". "}, TRUE, B2, LEFT(C2,1), A2)

Gabungkeun téks jeung kaping dina Excel

Dina kasus husus nalika anjeun ngagabung téks sareng kaping, nyayogikeun tanggal langsung kana rumus TEXTJOIN moal jalan. Sakumaha anjeun émut, Excel nyimpen kaping salaku nomer séri, janten rumus anjeun bakal ngabalikeun nomer anu ngagambarkeun tanggal sapertos anu dipidangkeun dina screenshot di handap ieu:

=TEXTJOIN(" ", TRUE, A2:B2)

Pikeun ngalereskeun ieu, anjeun kedah ngarobih tanggal kana string téks saméméh ngagabung. Sareng di dieu fungsi TEXT sareng kode format anu dipikahoyong ("mm/dd/yyyy" dina kasus urang) tiasa dianggo:

=TEXTJOIN(" ", TRUE, A2, TEXT(B2, "mm/dd/yyyy"))

Gabungkeun téks sareng putus garis

Upami anjeun hoyong ngahijikeun téks dina Excel supados unggal nilai dimimitian dina baris anyar, paké CHAR(10) sabagé pembatas (dimana 10 mangrupikeun karakter linefeed).

Contona, pikeun ngagabungkeun téks ti sél A2 jeung B2 misahkeun nilai ku garis putus, ieu rumus ngagunakeun:

=TEXTJOIN(CHAR(10), TRUE, A2:B2)

Tip. Pikeun hasil dipintonkeun dina sababaraha garis sapertos anu dipidangkeun dina layar di luhur, pastikeun fitur Wrap text diaktipkeun.

TEXTJOIN IF pikeun ngagabungkeun téks sareng kaayaan

Kusabab kamampuan Excel TEXTJOIN pikeun nanganan susunan string, éta ogé tiasa dianggo pikeun ngahijikeun eusi dua atanapi langkung sél sacara kondisional. Jang ngalampahkeunana, paké fungsi IF pikeun ngévaluasi sauntuyan sél sareng mulangkeun sajumlah nilai anu nyumponan kaayaan kana argumen text1 tinaTEXTJOIN.

Tina tabel anu dipidangkeun dina screenshot di handap, anggap anjeun hoyong nyandak daptar anggota Tim 1 . Pikeun ngahontal ieu, sarang pernyataan IF di handap ieu kana argumen text1 :

IF($B$2:$B$9=1, $A$2:$A$9, "")

Dina basa Inggris biasa, rumus di luhur nyebutkeun: Lamun kolom B sarua jeung 1, balikkeun a nilai ti kolom A dina baris sarua; sabalikna, balikkeun string kosong.

Rumus lengkep pikeun Tim 1 bentukna kieu:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=1, $A$2:$A$9, ""))

Ku cara nu sarua, anjeun bisa meunangkeun Daptar anggota dipisahkeun koma Tim 2:

=TEXTJOIN(", ", TRUE, IF($B$2:$B$9=2, $A$2:$A$9, ""))

Catetan. Kusabab fitur Dynamic Arrays sayogi dina Excel 365 sareng 2021, ieu tiasa dianggo salaku rumus biasa, dipidangkeun dina layar di luhur. Dina Excel 2019, anjeun kedah ngasupkeun éta salaku rumus array tradisional ku mencét potong kompas Ctrl + Shift + Enter.

Paluruh jeung mulangkeun sababaraha patandingan dina daptar anu dipisahkeun koma

Sakumaha anjeun terang, Fungsi Excel VLOOKUP ngan ukur tiasa ngabalikeun pertandingan anu munggaran kapanggih. Tapi kumaha upami anjeun kedah kéngingkeun sadaya patandingan pikeun ID khusus, SKU, atanapi anu sanés?

Pikeun ngahasilkeun hasil dina sél anu misah, paké salah sahiji rumus anu dijelaskeun dina Kumaha VLOOKUP sababaraha nilai dina Excel.

Pikeun néangan jeung mulangkeun sakabéh niléy nu cocog dina hiji sél sabagé daptar nu dipisahkeun koma, paké rumus TEXTJOIN IF.

Pikeun nempo kumaha gawéna dina prakna, hayu urang meunangkeun daptar produk dibeuli ku seller dibikeun tina tabel sampelhandap. Ieu tiasa gampang dilakukeun ku rumus ieu:

=TEXTJOIN(", ", TRUE, IF($A$2:$A$12=D2, $B$2:$B$12, ""))

Dimana A2:A12 mangrupikeun nami penjual, B2:B12 mangrupikeun produk, sareng D2 mangrupikeun penjual anu dipikaresep.

Rumus di luhur mana anu ka E2 sarta brings sakabeh patandingan pikeun seller target di D2 (Adam). Kusabab pinter ngagunakeun référénsi sél rélatif (pikeun udagan anu ngajual) sareng mutlak (pikeun nami anu ngajual sareng produk), rumusna leres nyalin kana sél di handap ieu sareng tiasa dianggo ogé pikeun dua anu ngajual anu sanés:

Catetan. Sapertos conto saacanna, ieu tiasa dianggo salaku rumus biasa dina Excel 365 sareng 2021, sareng salaku rumus CSE (Ctrl + Shift + Enter ) dina Excel 2019.

Logika rumus sami persis sareng dina conto saméméhna:

Pernyataan IF ngabandingkeun unggal ngaran dina A2:A12 ngalawan ngaran udagan dina D2 (Adam dina kasus urang):

IF($A$2:$A$12=D2, $B$2:$B$12, "")

Lamun tes logis ngaevaluasi mun BENER (i.e. ngaran dina D2 cocog ngaran dina kolom A), rumus mulih produk ti kolom B; disebutkeun string kosong ("") balik. Hasil tina IF nyaéta array di handap ieu:

{"";"";"Bananas";"Apples";"";"";"";"Oranges";"";"Lemons";""}

Asép Sunandar Sunarya asup kana fungsi TEXTJOIN salaku argumen text1 . Sareng kusabab TEXTJOIN dikonpigurasi pikeun misahkeun nilai ku koma sareng spasi (", "), urang nampi string ieu salaku hasil ahir:

Pisang, Apel, Jeruk, Lemon

Excel TEXTJOIN henteu jalan

Nalika rumus TEXTJOIN anjeun nyababkeun kasalahan, sigana mahjanten salah sahiji ieu:

• #NAME? Aya kasalahan nalika TEXTJOIN dianggo dina vérsi Excel anu langkung lami dimana pungsi ieu henteu dirojong (saméméh 2019) atanapi nalika nami fungsina salah éja.
• #VALUE! kasalahan lumangsung lamun string hasilna ngaleuwihan 32.767 karakter.
• #VALUE! kasalahan ogé bisa lumangsung lamun Excel teu ngakuan delimiter salaku téks, contona lamun nyadiakeun sababaraha karakter non-dicitak kayaning CHAR(0).

Kitu cara ngagunakeun fungsi TEXTJOIN dina Excel. Hatur nuhun pikeun maca sareng ngarepkeun anjeun tiasa ningali dina blog kami minggu payun!

Sadia undeuran

Conto rumus Excel TEXTJOIN